Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31 use IPC::Open2;
  32 use File::Path;
  33 use File::Basename;
  34 use Dpkg::Control::Hash;
  35 use Debian::Dgit::ExitStatus;
  36 use Debian::Dgit::I18n;
  37
  38 BEGIN {
  39     use Exporter   ();
  40     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  41
  42     $VERSION     = 1.00;
  43     @ISA         = qw(Exporter);
  44     @EXPORT      = qw(setup_sigwarn forkcheck_setup forkcheck_mainprocess
  45                       dep14_version_mangle
  46                       debiantags debiantag_old debiantag_new
  47                       debiantag_maintview
  48                       upstreamversion
  49                       stripepoch source_file_leafname is_orig_file_of_p_v
  50                       server_branch server_ref
  51                       stat_exists link_ltarget rename_link_xf
  52                       hashfile
  53                       fail failmsg ensuredir must_getcwd executable_on_path
  54                       waitstatusmsg failedcmd_waitstatus
  55                       failedcmd_report_cmd failedcmd
  56                       runcmd shell_cmd cmdoutput cmdoutput_errok
  57                       git_rev_parse changedir_git_toplevel git_cat_file
  58                       git_get_ref git_get_symref git_for_each_ref
  59                       git_for_each_tag_referring is_fast_fwd
  60                       git_check_unmodified
  61                       git_reflog_action_msg  git_update_ref_cmd
  62                       make_commit_text
  63                       reflog_cache_insert reflog_cache_lookup
  64                       $package_re $component_re $deliberately_re
  65                       $distro_re $versiontag_re $series_filename_re
  66                       $orig_f_comp_re $orig_f_sig_re $orig_f_tail_re
  67                       $extra_orig_namepart_re
  68                       $git_null_obj
  69                       $branchprefix
  70                       $ffq_refprefix $gdrlast_refprefix
  71                       initdebug enabledebug enabledebuglevel
  72                       printdebug debugcmd
  73                       $printdebug_when_debuglevel $debugcmd_when_debuglevel
  74                       $debugprefix *debuglevel *DEBUG
  75                       shellquote printcmd messagequote
  76                       $negate_harmful_gitattrs
  77                       changedir git_slurp_config_src
  78                       gdr_ffq_prev_branchinfo
  79                       parsecontrolfh parsecontrol parsechangelog
  80                       getfield parsechangelog_loop
  81                       playtree_setup);
  82     # implicitly uses $main::us
  83     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO NOCOMMITCHECK)],
  84                      playground => [qw(record_maindir $maindir $local_git_cfg
  85                                        $maindir_gitdir $maindir_gitcommon
  86                                        fresh_playground
  87                                        ensure_a_playground)]);
  88     @EXPORT_OK   = ( @{ $EXPORT_TAGS{policyflags} },
  89                      @{ $EXPORT_TAGS{playground} } );
  90 }
  91
  92 our @EXPORT_OK;
  93
  94 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  95 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  96 our $deliberately_re = "(?:TEST-)?$package_re";
  97 our $distro_re = $component_re;
  98 our $versiontag_re = qr{[-+.\%_0-9a-zA-Z/]+};
  99 our $branchprefix = 'dgit';
 100 our $series_filename_re = qr{(?:^|\.)series(?!\n)$}s;
 101 our $extra_orig_namepart_re = qr{[-0-9a-z]+};
 102 our $orig_f_comp_re = qr{orig(?:-$extra_orig_namepart_re)?};
 103 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
 104 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
 105 our $git_null_obj = '0' x 40;
 106 our $ffq_refprefix = 'ffq-prev';
 107 our $gdrlast_refprefix = 'debrebase-last';
 108 our $printdebug_when_debuglevel = 1;
 109 our $debugcmd_when_debuglevel = 1;
 110
 111 # these three all go together, only valid after record_maindir
 112 our $maindir;
 113 our $maindir_gitdir;
 114 our $maindir_gitcommon;
 115
 116 # policy hook exit status bits
 117 # see dgit-repos-server head comment for documentation
 118 # 1 is reserved in case something fails with `exit 1' and to spot
 119 # dynamic loader, runtime, etc., failures, which report 127 or 255
 120 sub NOFFCHECK () { return 0x2; }
 121 sub FRESHREPO () { return 0x4; }
 122 sub NOCOMMITCHECK () { return 0x8; }
 123
 124 our $debugprefix;
 125 our $debuglevel = 0;
 126
 127 our $negate_harmful_gitattrs =
 128     "-text -eol -crlf -ident -filter -working-tree-encoding";
 129     # ^ when updating this, alter the regexp in dgit:is_gitattrs_setup
 130
 131 our $forkcheck_mainprocess;
 132
 133 sub forkcheck_setup () {
 134     $forkcheck_mainprocess = $$;
 135 }
 136
 137 sub forkcheck_mainprocess () {
 138     # You must have called forkcheck_setup or setup_sigwarn already
 139     getppid != $forkcheck_mainprocess;
 140 }
 141
 142 sub setup_sigwarn () {
 143     forkcheck_setup();
 144     $SIG{__WARN__} = sub {
 145         confess $_[0] if forkcheck_mainprocess;
 146     };
 147 }
 148
 149 sub initdebug ($) {
 150     ($debugprefix) = @_;
 151     open DEBUG, ">/dev/null" or confess $!;
 152 }
 153
 154 sub enabledebug () {
 155     open DEBUG, ">&STDERR" or confess $!;
 156     DEBUG->autoflush(1);
 157     $debuglevel ||= 1;
 158 }
 159
 160 sub enabledebuglevel ($) {
 161     my ($newlevel) = @_; # may be undef (eg from env var)
 162     confess if $debuglevel;
 163     $newlevel //= 0;
 164     $newlevel += 0;
 165     return unless $newlevel;
 166     $debuglevel = $newlevel;
 167     enabledebug();
 168 }
 169
 170 sub printdebug {
 171     # Prints a prefix, and @_, to DEBUG.  @_ should normally contain
 172     # a trailing \n.
 173
 174     # With no (or only empty) arguments just prints the prefix and
 175     # leaves the caller to do more with DEBUG.  The caller should make
 176     # sure then to call printdebug with something ending in "\n" to
 177     # get the prefix right in subsequent calls.
 178
 179     return unless $debuglevel >= $printdebug_when_debuglevel;
 180     our $printdebug_noprefix;
 181     print DEBUG $debugprefix unless $printdebug_noprefix;
 182     pop @_ while @_ and !length $_[-1];
 183     return unless @_;
 184     print DEBUG @_ or confess $!;
 185     $printdebug_noprefix = $_[-1] !~ m{\n$};
 186 }
 187
 188 sub messagequote ($) {
 189     local ($_) = @_;
 190     s{\\}{\\\\}g;
 191     s{\n}{\\n}g;
 192     s{\x08}{\\b}g;
 193     s{\t}{\\t}g;
 194     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 195     $_;
 196 }
 197
 198 sub shellquote {
 199     my @out;
 200     local $_;
 201     defined or confess __ 'internal error' foreach @_;
 202     foreach my $a (@_) {
 203         $_ = $a;
 204         if (!length || m{[^-=_./:0-9a-z]}i) {
 205             s{['\\]}{'\\$&'}g;
 206             push @out, "'$_'";
 207         } else {
 208             push @out, $_;
 209         }
 210     }
 211     return join ' ', @out;
 212 }
 213
 214 sub printcmd {
 215     my $fh = shift @_;
 216     my $intro = shift @_;
 217     print $fh $intro," " or confess $!;
 218     print $fh shellquote @_ or confess $!;
 219     print $fh "\n" or confess $!;
 220 }
 221
 222 sub debugcmd {
 223     my $extraprefix = shift @_;
 224     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_)
 225         if $debuglevel >= $debugcmd_when_debuglevel;
 226 }
 227
 228 sub dep14_version_mangle ($) {
 229     my ($v) = @_;
 230     # DEP-14 patch proposed 2016-11-09  "Version Mangling"
 231     $v =~ y/~:/_%/;
 232     $v =~ s/\.(?=\.|$|lock$)/.#/g;
 233     return $v;
 234 }
 235
 236 sub debiantag_old ($$) {
 237     my ($v,$distro) = @_;
 238     return "$distro/". dep14_version_mangle $v;
 239 }
 240
 241 sub debiantag_new ($$) {
 242     my ($v,$distro) = @_;
 243     return "archive/$distro/".dep14_version_mangle $v;
 244 }
 245
 246 sub debiantag_maintview ($$) {
 247     my ($v,$distro) = @_;
 248     return "$distro/".dep14_version_mangle $v;
 249 }
 250
 251 sub debiantags ($$) {
 252     my ($version,$distro) = @_;
 253     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 254 }
 255
 256 sub stripepoch ($) {
 257     my ($vsn) = @_;
 258     $vsn =~ s/^\d+\://;
 259     return $vsn;
 260 }
 261
 262 sub upstreamversion ($) {
 263     my ($vsn) = @_;
 264     $vsn =~ s/-[^-]+$//;
 265     return $vsn;
 266 }
 267
 268 sub source_file_leafname ($$$) {
 269     my ($package,$vsn,$sfx) = @_;
 270     return "${package}_".(stripepoch $vsn).$sfx
 271 }
 272
 273 sub is_orig_file_of_p_v ($$$) {
 274     my ($f, $package, $upstreamvsn) = @_;
 275     my $base = source_file_leafname $package, $upstreamvsn, '';
 276     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
 277     return 1;
 278 }
 279
 280 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 281 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 282
 283 sub stat_exists ($) {
 284     my ($f) = @_;
 285     return 1 if stat $f;
 286     return 0 if $!==&ENOENT;
 287     confess "stat $f: $!";
 288 }
 289
 290 sub _us () {
 291     $::us // ($0 =~ m#[^/]*$#, $&);
 292 }
 293
 294 sub failmsg {
 295     my $s = f_ "error: %s\n", "@_";
 296     $s =~ s/\n\n$/\n/g;
 297     my $prefix = _us().": ";
 298     $s =~ s/^/$prefix/gm;
 299     return "\n".$s;
 300 }
 301
 302 sub fail {
 303     die failmsg @_;
 304 }
 305
 306 sub ensuredir ($) {
 307     my ($dir) = @_; # does not create parents
 308     return if mkdir $dir;
 309     return if $! == EEXIST;
 310     confess "mkdir $dir: $!";
 311 }
 312
 313 sub must_getcwd () {
 314     my $d = getcwd();
 315     defined $d or fail f_ "getcwd failed: %s\n", $!;
 316     return $d;
 317 }
 318
 319 sub executable_on_path ($) {
 320     my ($program) = @_;
 321     return 1 if $program =~ m{/};
 322     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 323     foreach my $pe (@path) {
 324         my $here = "$pe/$program";
 325         return $here if stat_exists $here && -x _;
 326     }
 327     return undef;
 328 }
 329
 330 our @signames = split / /, $Config{sig_name};
 331
 332 sub waitstatusmsg () {
 333     if (!$?) {
 334         return __ "terminated, reporting successful completion";
 335     } elsif (!($? & 255)) {
 336         return f_ "failed with error exit status %s", WEXITSTATUS($?);
 337     } elsif (WIFSIGNALED($?)) {
 338         my $signum=WTERMSIG($?);
 339         return f_ "died due to fatal signal %s",
 340             ($signames[$signum] // "number $signum").
 341             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 342     } else {
 343         return f_ "failed with unknown wait status %s", $?;
 344     }
 345 }
 346
 347 sub failedcmd_report_cmd {
 348     my $intro = shift @_;
 349     $intro //= __ "failed command";
 350     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or confess $!; };
 351 }
 352
 353 sub failedcmd_waitstatus {
 354     if ($? < 0) {
 355         return f_ "failed to fork/exec: %s", $!;
 356     } elsif ($?) {
 357         return f_ "subprocess %s", waitstatusmsg();
 358     } else {
 359         return __ "subprocess produced invalid output";
 360     }
 361 }
 362
 363 sub failedcmd {
 364     # Expects $!,$? as set by close - see below.
 365     # To use with system(), set $?=-1 first.
 366     #
 367     # Actual behaviour of perl operations:
 368     #   success              $!==0       $?==0       close of piped open
 369     #   program failed       $!==0       $? >0       close of piped open
 370     #   syscall failure      $! >0       $?=-1       close of piped open
 371     #   failure              $! >0       unchanged   close of something else
 372     #   success              trashed     $?==0       system
 373     #   program failed       trashed     $? >0       system
 374     #   syscall failure      $! >0       unchanged   system
 375     failedcmd_report_cmd undef, @_;
 376     fail failedcmd_waitstatus();
 377 }
 378
 379 sub runcmd {
 380     debugcmd "+",@_;
 381     $!=0; $?=-1;
 382     failedcmd @_ if system @_;
 383 }
 384
 385 sub shell_cmd {
 386     my ($first_shell, @cmd) = @_;
 387     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 388 }
 389
 390 sub cmdoutput_errok {
 391     confess Dumper(\@_)." ?" if grep { !defined } @_;
 392     local $printdebug_when_debuglevel = $debugcmd_when_debuglevel;
 393     debugcmd "|",@_;
 394     open P, "-|", @_ or confess "$_[0] $!";
 395     my $d;
 396     $!=0; $?=0;
 397     { local $/ = undef; $d = <P>; }
 398     confess $! if P->error;
 399     if (!close P) { printdebug "=>!$?\n"; return undef; }
 400     chomp $d;
 401     if ($debuglevel > 0) {
 402         $d =~ m/^.*/;
 403         my $dd = $&;
 404         my $more = (length $' ? '...' : ''); #');
 405         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 406         printdebug "=> \`$dd'",$more,"\n";
 407     }
 408     return $d;
 409 }
 410
 411 sub cmdoutput {
 412     my $d = cmdoutput_errok @_;
 413     defined $d or failedcmd @_;
 414     return $d;
 415 }
 416
 417 sub link_ltarget ($$) {
 418     my ($old,$new) = @_;
 419     lstat $old or return undef;
 420     if (-l _) {
 421         $old = cmdoutput qw(realpath  --), $old;
 422     }
 423     my $r = link $old, $new;
 424     $r = symlink $old, $new if !$r && $!==EXDEV;
 425     $r or fail "(sym)link $old $new: $!\n";
 426 }
 427
 428 sub rename_link_xf ($$$) {
 429     # renames/moves or links/copies $src to $dst,
 430     # even if $dst is on a different fs
 431     # (May use the filename "$dst.tmp".);
 432     # On success, returns true.
 433     # On failure, returns false and sets
 434     #    $@ to a reason message
 435     #    $! to an errno value, or -1 if not known
 436     # having possibly printed something about mv to stderr.
 437     # Not safe to use without $keeporig if $dst might be a symlink
 438     # to $src, as it might delete $src leaving $dst invalid.
 439     my ($keeporig,$src,$dst) = @_;
 440     if ($keeporig
 441         ? link   $src, $dst
 442         : rename $src, $dst) {
 443         return 1;
 444     }
 445     if ($! != EXDEV) {
 446         $@ = "$!";
 447         return 0;
 448     }
 449     if (!stat $src) {
 450         $@ = f_ "stat source file: %S", $!;
 451         return 0;
 452     }
 453     my @src_stat = (stat _)[0..1];
 454
 455     my @dst_stat;
 456     if (stat $dst) {
 457         @dst_stat = (stat _)[0..1];
 458     } elsif ($! == ENOENT) {
 459     } else {
 460         $@ = f_ "stat destination file: %S", $!;
 461         return 0;
 462     }
 463
 464     if ("@src_stat" eq "@dst_stat") {
 465         # (Symlinks to) the same file.  No need for a copy but
 466         # we may need to delete the original.
 467         printdebug "rename_link_xf $keeporig $src $dst EXDEV but same\n";
 468     } else {
 469         $!=0; $?=0;
 470         my @cmd = (qw(cp --), $src, "$dst.tmp");
 471         debugcmd '+',@cmd;
 472         if (system @cmd) {
 473             failedcmd_report_cmd undef, @cmd;
 474             $@ = failedcmd_waitstatus();
 475             $! = -1;
 476             return 0;
 477         }
 478         if (!rename "$dst.tmp", $dst) {
 479             $@ = f_ "finally install file after cp: %S", $!;
 480             return 0;
 481         }
 482     }
 483     if (!$keeporig) {
 484         if (!unlink $src) {
 485             $@ = f_ "delete old file after cp: %S", $!;
 486             return 0;
 487         }
 488     }
 489     return 1;
 490 }
 491
 492 sub hashfile ($) {
 493     my ($fn) = @_;
 494     my $h = Digest::SHA->new(256);
 495     $h->addfile($fn);
 496     return $h->hexdigest();
 497 }
 498
 499 sub git_rev_parse ($) {
 500     return cmdoutput qw(git rev-parse), "$_[0]~0";
 501 }
 502
 503 sub changedir_git_toplevel () {
 504     my $toplevel = cmdoutput qw(git rev-parse --show-toplevel);
 505     chdir $toplevel or fail f_ "chdir toplevel %s: %s\n", $toplevel, $!;
 506 }
 507
 508 sub git_cat_file ($;$) {
 509     my ($objname, $etype) = @_;
 510     # => ($type, $data) or ('missing', undef)
 511     # in scalar context, just the data
 512     # if $etype defined, dies unless type is $etype or in @$etype
 513     our ($gcf_pid, $gcf_i, $gcf_o);
 514     local $printdebug_when_debuglevel = $debugcmd_when_debuglevel;
 515     my $chk = sub {
 516         my ($gtype, $data) = @_;
 517         if ($etype) {
 518             $etype = [$etype] unless ref $etype;
 519             confess "$objname expected @$etype but is $gtype"
 520                 unless grep { $gtype eq $_ } @$etype;
 521         }
 522         return ($gtype, $data);
 523     };
 524     if (!$gcf_pid) {
 525         my @cmd = qw(git cat-file --batch);
 526         debugcmd "GCF|", @cmd;
 527         $gcf_pid = open2 $gcf_o, $gcf_i, @cmd or confess $!;
 528     }
 529     printdebug "GCF>| $objname\n";
 530     print $gcf_i $objname, "\n" or confess $!;
 531     my $x = <$gcf_o>;
 532     printdebug "GCF<| ", $x;
 533     if ($x =~ m/ (missing)$/) { return $chk->($1, undef); }
 534     my ($type, $size) = $x =~ m/^.* (\w+) (\d+)\n/ or confess "$objname ?";
 535     my $data;
 536     (read $gcf_o, $data, $size) == $size or confess "$objname $!";
 537     $x = <$gcf_o>;
 538     $x eq "\n" or confess "$objname ($_) $!";
 539     return $chk->($type, $data);
 540 }
 541
 542 sub git_get_symref (;$) {
 543     my ($symref) = @_;  $symref //= 'HEAD';
 544     # => undef if not a symref, otherwise refs/...
 545     my @cmd = (qw(git symbolic-ref -q HEAD));
 546     my $branch = cmdoutput_errok @cmd;
 547     if (!defined $branch) {
 548         $?==256 or failedcmd @cmd;
 549     } else {
 550         chomp $branch;
 551     }
 552     return $branch;
 553 }
 554
 555 sub git_for_each_ref ($$;$) {
 556     my ($pattern,$func,$gitdir) = @_;
 557     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 558     # $reftail is RHS of ref after refs/[^/]+/
 559     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 560     # $pattern may be an array ref to mean multiple patterns
 561     $pattern = [ $pattern ] unless ref $pattern;
 562     my @cmd = (qw(git for-each-ref), @$pattern);
 563     if (defined $gitdir) {
 564         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 565     }
 566     open GFER, "-|", @cmd or confess $!;
 567     debugcmd "|", @cmd;
 568     while (<GFER>) {
 569         chomp or confess "$_ ?";
 570         printdebug "|> ", $_, "\n";
 571         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or confess "$_ ?";
 572         $func->($1,$2,$3,$4);
 573     }
 574     $!=0; $?=0; close GFER or confess "$pattern $? $!";
 575 }
 576
 577 sub git_get_ref ($) {
 578     # => '' if no such ref
 579     my ($refname) = @_;
 580     local $_ = $refname;
 581     s{^refs/}{[r]efs/} or confess "$refname $_ ?";
 582     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 583 }
 584
 585 sub git_for_each_tag_referring ($$) {
 586     my ($objreferring, $func) = @_;
 587     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 588     printdebug "git_for_each_tag_referring ",
 589         ($objreferring // 'UNDEF'),"\n";
 590     git_for_each_ref('refs/tags', sub {
 591         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 592         return unless $objtype eq 'tag';
 593         my $refobjid = git_rev_parse $tagobjid;
 594         return unless
 595             !defined $objreferring # caller wants them all
 596             or $tagobjid eq $objreferring
 597             or $refobjid eq $objreferring;
 598         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 599     });
 600 }
 601
 602 sub git_check_unmodified () {
 603     foreach my $cached (qw(0 1)) {
 604         my @cmd = qw(git diff --quiet);
 605         push @cmd, qw(--cached) if $cached;
 606         push @cmd, qw(HEAD);
 607         debugcmd "+",@cmd;
 608         $!=0; $?=-1; system @cmd;
 609         return if !$?;
 610         if ($?==256) {
 611             fail
 612                 $cached
 613                 ? __ "git index contains changes (does not match HEAD)"
 614                 : __ "working tree is dirty (does not match HEAD)";
 615         } else {
 616             failedcmd @cmd;
 617         }
 618     }
 619 }
 620
 621 sub is_fast_fwd ($$) {
 622     my ($ancestor,$child) = @_;
 623     my @cmd = (qw(git merge-base), $ancestor, $child);
 624     my $mb = cmdoutput_errok @cmd;
 625     if (defined $mb) {
 626         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 627     } else {
 628         $?==256 or failedcmd @cmd;
 629         return 0;
 630     }
 631 }
 632
 633 sub git_reflog_action_msg ($) {
 634     my ($msg) = @_;
 635     my $rla = $ENV{GIT_REFLOG_ACTION};
 636     $msg = "$rla: $msg" if length $rla;
 637     return $msg;
 638 }
 639
 640 sub git_update_ref_cmd {
 641     # returns  qw(git update-ref), qw(-m), @_
 642     # except that message may be modified to honour GIT_REFLOG_ACTION
 643     my $msg = shift @_;
 644     $msg = git_reflog_action_msg $msg;
 645     return qw(git update-ref -m), $msg, @_;
 646 }
 647
 648 sub changedir ($) {
 649     my ($newdir) = @_;
 650     printdebug "CD $newdir\n";
 651     chdir $newdir or confess "chdir: $newdir: $!";
 652 }
 653
 654 sub git_slurp_config_src ($) {
 655     my ($src) = @_;
 656     # returns $r such that $r->{KEY}[] = VALUE
 657     my @cmd = (qw(git config -z --get-regexp), "--$src", qw(.*));
 658     debugcmd "|",@cmd;
 659
 660     local ($debuglevel) = $debuglevel-2;
 661     local $/="\0";
 662
 663     my $r = { };
 664     open GITS, "-|", @cmd or confess $!;
 665     while (<GITS>) {
 666         chomp or confess;
 667         printdebug "=> ", (messagequote $_), "\n";
 668         m/\n/ or confess "$_ ?";
 669         push @{ $r->{$`} }, $'; #';
 670     }
 671     $!=0; $?=0;
 672     close GITS
 673         or ($!==0 && $?==256)
 674         or failedcmd @cmd;
 675     return $r;
 676 }
 677
 678 sub gdr_ffq_prev_branchinfo ($) {
 679     my ($symref) = @_;
 680     # => ('status', "message", [$symref, $ffq_prev, $gdrlast])
 681     # 'status' may be
 682     #    branch         message is undef
 683     #    weird-symref   } no $symref,
 684     #    notbranch      }  no $ffq_prev
 685     return ('detached', __ 'detached HEAD') unless defined $symref;
 686     return ('weird-symref', __ 'HEAD symref is not to refs/')
 687         unless $symref =~ m{^refs/};
 688     my $ffq_prev = "refs/$ffq_refprefix/$'";
 689     my $gdrlast = "refs/$gdrlast_refprefix/$'";
 690     printdebug "ffq_prev_branchinfo branch current $symref\n";
 691     return ('branch', undef, $symref, $ffq_prev, $gdrlast);
 692 }
 693
 694 sub parsecontrolfh ($$;$) {
 695     my ($fh, $desc, $allowsigned) = @_;
 696     our $dpkgcontrolhash_noissigned;
 697     my $c;
 698     for (;;) {
 699         my %opts = ('name' => $desc);
 700         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 701         $c = Dpkg::Control::Hash->new(%opts);
 702         $c->parse($fh,$desc) or fail f_ "parsing of %s failed", $desc;
 703         last if $allowsigned;
 704         last if $dpkgcontrolhash_noissigned;
 705         my $issigned= $c->get_option('is_pgp_signed');
 706         if (!defined $issigned) {
 707             $dpkgcontrolhash_noissigned= 1;
 708             seek $fh, 0,0 or confess "seek $desc: $!";
 709         } elsif ($issigned) {
 710             fail f_
 711                 "control file %s is (already) PGP-signed. ".
 712                 " Note that dgit push needs to modify the .dsc and then".
 713                 " do the signature itself",
 714                 $desc;
 715         } else {
 716             last;
 717         }
 718     }
 719     return $c;
 720 }
 721
 722 sub parsecontrol {
 723     my ($file, $desc, $allowsigned) = @_;
 724     my $fh = new IO::Handle;
 725     open $fh, '<', $file or fail f_ "open %s (%s): %s", $file, $desc, $!;
 726     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 727     $fh->error and confess $!;
 728     close $fh;
 729     return $c;
 730 }
 731
 732 sub parsechangelog {
 733     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 734     my $p = new IO::Handle;
 735     my @cmd = (qw(dpkg-parsechangelog), @_);
 736     open $p, '-|', @cmd or confess $!;
 737     $c->parse($p);
 738     $?=0; $!=0; close $p or failedcmd @cmd;
 739     return $c;
 740 }
 741
 742 sub getfield ($$) {
 743     my ($dctrl,$field) = @_;
 744     my $v = $dctrl->{$field};
 745     return $v if defined $v;
 746     fail f_ "missing field %s in %s", $field, $dctrl->get_option('name');
 747 }
 748
 749 sub parsechangelog_loop ($$$) {
 750     my ($clogcmd, $descbase, $fn) = @_;
 751     # @$clogcmd is qw(dpkg-parsechangelog ...some...options...)
 752     # calls $fn->($thisstanza, $desc);
 753     debugcmd "|",@$clogcmd;
 754     open CLOGS, "-|", @$clogcmd or confess $!;
 755     for (;;) {
 756         my $stanzatext = do { local $/=""; <CLOGS>; };
 757         printdebug "clogp stanza ".Dumper($stanzatext) if $debuglevel>1;
 758         last if !defined $stanzatext;
 759
 760         my $desc = "$descbase, entry no.$.";
 761         open my $stanzafh, "<", \$stanzatext or confess;
 762         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
 763
 764         $fn->($thisstanza, $desc);
 765     }
 766     confess $! if CLOGS->error;
 767     close CLOGS or $?==SIGPIPE or failedcmd @$clogcmd;
 768 }
 769
 770 sub make_commit_text ($) {
 771     my ($text) = @_;
 772     my ($out, $in);
 773     my @cmd = (qw(git hash-object -w -t commit --stdin));
 774     debugcmd "|",@cmd;
 775     print Dumper($text) if $debuglevel > 1;
 776     my $child = open2($out, $in, @cmd) or confess $!;
 777     my $h;
 778     eval {
 779         print $in $text or confess $!;
 780         close $in or confess $!;
 781         $h = <$out>;
 782         $h =~ m/^\w+$/ or confess;
 783         $h = $&;
 784         printdebug "=> $h\n";
 785     };
 786     close $out;
 787     waitpid $child, 0 == $child or confess "$child $!";
 788     $? and failedcmd @cmd;
 789     return $h;
 790 }
 791
 792 sub reflog_cache_insert ($$$) {
 793     my ($ref, $cachekey, $value) = @_;
 794     # you must call this in $maindir
 795     # you must have called record_maindir
 796
 797     # When we no longer need to support squeeze, use --create-reflog
 798     # instead of this:
 799     my $parent = $ref; $parent =~ s{/[^/]+$}{};
 800     ensuredir "$maindir_gitcommon/logs/$parent";
 801     my $makelogfh = new IO::File "$maindir_gitcommon/logs/$ref", '>>'
 802       or confess $!;
 803
 804     my $oldcache = git_get_ref $ref;
 805
 806     if ($oldcache eq $value) {
 807         my $tree = cmdoutput qw(git rev-parse), "$value:";
 808         # git update-ref doesn't always update, in this case.  *sigh*
 809         my $authline = (ucfirst _us()).
 810             ' <'._us().'@example.com> 1000000000 +0000';
 811         my $dummy = make_commit_text <<ENDU.(__ <<END);
 812 tree $tree
 813 parent $value
 814 author $authline
 815 committer $authline
 816
 817 ENDU
 818 Dummy commit - do not use
 819 END
 820         runcmd qw(git update-ref -m), _us()." - dummy", $ref, $dummy;
 821     }
 822     runcmd qw(git update-ref -m), $cachekey, $ref, $value;
 823 }
 824
 825 sub reflog_cache_lookup ($$) {
 826     my ($ref, $cachekey) = @_;
 827     # you may call this in $maindir or in a playtree
 828     # you must have called record_maindir
 829     my @cmd = (qw(git log -g), '--pretty=format:%H %gs', $ref);
 830     debugcmd "|(probably)",@cmd;
 831     my $child = open GC, "-|";  defined $child or confess $!;
 832     if (!$child) {
 833         chdir $maindir or confess $!;
 834         if (!stat "$maindir_gitcommon/logs/$ref") {
 835             $! == ENOENT or confess $!;
 836             printdebug ">(no reflog)\n";
 837             finish 0;
 838         }
 839         exec @cmd; die f_ "exec %s: %s\n", $cmd[0], $!;
 840     }
 841     while (<GC>) {
 842         chomp;
 843         printdebug ">| ", $_, "\n" if $debuglevel > 1;
 844         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $cachekey;
 845         close GC;
 846         return $1;
 847     }
 848     confess $! if GC->error;
 849     failedcmd unless close GC;
 850     return undef;
 851 }
 852
 853 # ========== playground handling ==========
 854
 855 # terminology:
 856 #
 857 #   $maindir      user's git working tree
 858 #   playground    area in .git/ where we can make files, unpack, etc. etc.
 859 #   playtree      git working tree sharing object store with the user's
 860 #                 inside playground, or identical to it
 861 #
 862 # other globals
 863 #
 864 #   $local_git_cfg    hash of arrays of values: git config from $maindir
 865 #
 866 # expected calling pattern
 867 #
 868 #  firstly
 869 #
 870 #    [record_maindir]
 871 #      must be run in directory containing .git
 872 #      assigns to $maindir if not already set
 873 #      also calls git_slurp_config_src to record git config
 874 #        in $local_git_cfg, unless it's already set
 875 #
 876 #    fresh_playground SUBDIR_PATH_COMPONENTS
 877 #      e.g fresh_playground 'dgit/unpack' ('.git/' is implied)
 878 #      default SUBDIR_PATH_COMPONENTS is playground_subdir
 879 #      calls record_maindir
 880 #      sets up a new playground (destroying any old one)
 881 #      returns playground pathname
 882 #      caller may call multiple times with different subdir paths
 883 #       createing different playgrounds
 884 #
 885 #    ensure_a_playground SUBDIR_PATH_COMPONENTS
 886 #      like fresh_playground except:
 887 #      merely ensures the directory exists; does not delete an existing one
 888 #
 889 #  then can use
 890 #
 891 #    changedir playground
 892 #    changedir $maindir
 893 #
 894 #    playtree_setup $local_git_cfg
 895 #            # ^ call in some (perhaps trivial) subdir of playground
 896 #
 897 #    rmtree playground
 898
 899 # ----- maindir -----
 900
 901 our $local_git_cfg;
 902
 903 sub record_maindir () {
 904     if (!defined $maindir) {
 905         $maindir = must_getcwd();
 906         if (!stat "$maindir/.git") {
 907             fail f_ "cannot stat %s/.git: %s", $maindir, $!;
 908         }
 909         if (-d _) {
 910             # we fall back to this in case we have a pre-worktree
 911             # git, which may not know git rev-parse --git-common-dir
 912             $maindir_gitdir    = "$maindir/.git";
 913             $maindir_gitcommon = "$maindir/.git";
 914         } else {
 915             $maindir_gitdir    = cmdoutput qw(git rev-parse --git-dir);
 916             $maindir_gitcommon = cmdoutput qw(git rev-parse --git-common-dir);
 917         }
 918     }
 919     $local_git_cfg //= git_slurp_config_src 'local';
 920 }
 921
 922 # ----- playgrounds -----
 923
 924 sub ensure_a_playground_parent ($) {
 925     my ($spc) = @_;
 926     record_maindir();
 927     $spc = "$maindir_gitdir/$spc";
 928     my $parent = dirname $spc;
 929     mkdir $parent or $!==EEXIST or fail f_
 930         "failed to mkdir playground parent %s: %s", $parent, $!;
 931     return $spc;
 932 }
 933
 934 sub ensure_a_playground ($) {
 935     my ($spc) = @_;
 936     $spc = ensure_a_playground_parent $spc;
 937     mkdir $spc or $!==EEXIST or fail f_
 938         "failed to mkdir a playground %s: %s", $spc, $!;
 939     return $spc;
 940 }
 941
 942 sub fresh_playground ($) {
 943     my ($spc) = @_;
 944     $spc = ensure_a_playground_parent $spc;
 945     rmtree $spc;
 946     mkdir $spc or fail f_
 947         "failed to mkdir the playground %s: %s", $spc, $!;
 948     return $spc;
 949 }
 950
 951 # ----- playtrees -----
 952
 953 sub playtree_setup (;$) {
 954     my ($t_local_git_cfg) = @_;
 955     $t_local_git_cfg //= $local_git_cfg;
 956     # for use in the playtree
 957     # $maindir must be set, eg by calling record_maindir or fresh_playground
 958     runcmd qw(git init -q);
 959     runcmd qw(git config gc.auto 0);
 960     foreach my $copy (qw(user.email user.name user.useConfigOnly
 961                          core.sharedRepository
 962                          core.compression core.looseCompression
 963                          core.bigFileThreshold core.fsyncObjectFiles)) {
 964         my $v = $t_local_git_cfg->{$copy};
 965         next unless $v;
 966         runcmd qw(git config), $copy, $_ foreach @$v;
 967     }
 968     # this is confusing: we have
 969     #   .                   playtree, not a worktree, has .git/, our cwd
 970     #   $maindir            might be a worktree so
 971     #   $maindir_gitdir     contains our main working "dgit", HEAD, etc.
 972     #   $maindir_gitcommon  the shared stuff, including .objects
 973     rmtree('.git/objects');
 974     symlink "$maindir_gitcommon/objects",'.git/objects' or confess $!;
 975     ensuredir '.git/info';
 976     open GA, "> .git/info/attributes" or confess $!;
 977     print GA "* $negate_harmful_gitattrs\n" or confess $!;
 978     close GA or confess $!;
 979 }
 980
 981 1;