Debian/Dgit.pm

   1 # -*- perl -*-
   2
   3 package Debian::Dgit;
   4
   5 use strict;
   6 use warnings;
   7
   8 use POSIX;
   9 use IO::Handle;
  10
  11 BEGIN {
  12     use Exporter   ();
  13     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  14
  15     $VERSION     = 1.00;
  16     @ISA         = qw(Exporter);
  17     @EXPORT      = qw(debiantag server_branch server_ref
  18                       stat_exists git_for_each_ref
  19                       git_for_each_tag_referring
  20                       $package_re $component_re $deliberately_re
  21                       $branchprefix
  22                       initdebug enabledebug enabledebuglevel
  23                       printdebug debugcmd
  24                       $debugprefix *debuglevel *DEBUG
  25                       shellquote printcmd);
  26     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  27     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  28 }
  29
  30 our @EXPORT_OK;
  31
  32 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  33 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  34 our $deliberately_re = "(?:TEST-)?$package_re";
  35 our $branchprefix = 'dgit';
  36
  37 # policy hook exit status bits
  38 # see dgit-repos-server head comment for documentation
  39 # 1 is reserved in case something fails with `exit 1' and to spot
  40 # dynamic loader, runtime, etc., failures, which report 127 or 255
  41 sub NOFFCHECK () { return 0x2; }
  42 sub FRESHREPO () { return 0x4; }
  43
  44 our $debugprefix;
  45 our $debuglevel = 0;
  46
  47 sub initdebug ($) {
  48     ($debugprefix) = @_;
  49     open DEBUG, ">/dev/null" or die $!;
  50 }
  51
  52 sub enabledebug () {
  53     open DEBUG, ">&STDERR" or die $!;
  54     DEBUG->autoflush(1);
  55     $debuglevel ||= 1;
  56 }
  57
  58 sub enabledebuglevel ($) {
  59     my ($newlevel) = @_; # may be undef (eg from env var)
  60     die if $debuglevel;
  61     $newlevel //= 0;
  62     $newlevel += 0;
  63     return unless $newlevel;
  64     $debuglevel = $newlevel;
  65     enabledebug();
  66 }
  67
  68 sub printdebug {
  69     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
  70 }
  71
  72 sub shellquote {
  73     my @out;
  74     local $_;
  75     foreach my $a (@_) {
  76         $_ = $a;
  77         if (!length || m{[^-=_./0-9a-z]}i) {
  78             s{['\\]}{'\\$&'}g;
  79             push @out, "'$_'";
  80         } else {
  81             push @out, $_;
  82         }
  83     }
  84     return join ' ', @out;
  85 }
  86
  87 sub printcmd {
  88     my $fh = shift @_;
  89     my $intro = shift @_;
  90     print $fh $intro," " or die $!;
  91     print $fh shellquote @_ or die $!;
  92     print $fh "\n" or die $!;
  93 }
  94
  95 sub debugcmd {
  96     my $extraprefix = shift @_;
  97     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
  98 }
  99
 100 sub debiantag ($) {
 101     my ($v) = @_;
 102     $v =~ y/~:/_%/;
 103     return "debian/$v";
 104 }
 105
 106 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 107 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 108
 109 sub stat_exists ($) {
 110     my ($f) = @_;
 111     return 1 if stat $f;
 112     return 0 if $!==&ENOENT;
 113     die "stat $f: $!";
 114 }
 115
 116 sub git_for_each_ref ($$) {
 117     my ($pattern,$func) = @_;
 118     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 119     # $reftail is RHS of ref after refs/\w+/
 120     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 121     my @cmd = (qw(git for-each-ref), $pattern);
 122     open GFER, "-|", @cmd or die $!;
 123     debugcmd "|", @cmd;
 124     while (<GFER>) {
 125         chomp or die "$_ ?";
 126         printdebug "|> ", $_, "\n";
 127         m#^(\w+)\s+(\w+)\s+(refs/\w+/(\S+))$# or die "$_ ?";
 128         $func->($1,$2,$3,$4);
 129     }
 130     $!=0; $?=0; close GFER or die "$pattern $? $!";
 131 }
 132
 133 sub git_for_each_tag_referring ($$) {
 134     my ($objreferring, $func) = @_;
 135     # calls $func->($objid,$fullrefname,$tagname);
 136     printdebug "git_for_each_tag_referring ",
 137         ($objreferring // 'UNDEF'),"\n";
 138     git_for_each_ref('refs/tags', sub {
 139         my ($objid,$objtype,$fullrefname,$tagname) = @_;
 140         return unless $objtype eq 'tag';
 141         return if defined $objreferring and $objid ne $objreferring;
 142         $func->($objid,$fullrefname,$tagname);
 143     });
 144 }
 145
 146 1;