Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31
  32 BEGIN {
  33     use Exporter   ();
  34     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  35
  36     $VERSION     = 1.00;
  37     @ISA         = qw(Exporter);
  38     @EXPORT      = qw(setup_sigwarn
  39                       dep14_version_mangle
  40                       debiantags debiantag_old debiantag_new
  41                       server_branch server_ref
  42                       stat_exists link_ltarget
  43                       hashfile
  44                       fail ensuredir executable_on_path
  45                       waitstatusmsg failedcmd_waitstatus
  46                       failedcmd_report_cmd failedcmd
  47                       cmdoutput cmdoutput_errok
  48                       git_rev_parse git_get_ref git_for_each_ref
  49                       git_for_each_tag_referring is_fast_fwd
  50                       $package_re $component_re $deliberately_re
  51                       $branchprefix
  52                       initdebug enabledebug enabledebuglevel
  53                       printdebug debugcmd
  54                       $debugprefix *debuglevel *DEBUG
  55                       shellquote printcmd messagequote);
  56     # implicitly uses $main::us
  57     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  58     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  59 }
  60
  61 our @EXPORT_OK;
  62
  63 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  64 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  65 our $deliberately_re = "(?:TEST-)?$package_re";
  66 our $branchprefix = 'dgit';
  67
  68 # policy hook exit status bits
  69 # see dgit-repos-server head comment for documentation
  70 # 1 is reserved in case something fails with `exit 1' and to spot
  71 # dynamic loader, runtime, etc., failures, which report 127 or 255
  72 sub NOFFCHECK () { return 0x2; }
  73 sub FRESHREPO () { return 0x4; }
  74
  75 our $debugprefix;
  76 our $debuglevel = 0;
  77
  78 sub setup_sigwarn () {
  79     our $sigwarn_mainprocess = $$;
  80     $SIG{__WARN__} = sub {
  81         die $_[0] unless getppid == $sigwarn_mainprocess;
  82     };
  83 }
  84
  85 sub initdebug ($) {
  86     ($debugprefix) = @_;
  87     open DEBUG, ">/dev/null" or die $!;
  88 }
  89
  90 sub enabledebug () {
  91     open DEBUG, ">&STDERR" or die $!;
  92     DEBUG->autoflush(1);
  93     $debuglevel ||= 1;
  94 }
  95
  96 sub enabledebuglevel ($) {
  97     my ($newlevel) = @_; # may be undef (eg from env var)
  98     die if $debuglevel;
  99     $newlevel //= 0;
 100     $newlevel += 0;
 101     return unless $newlevel;
 102     $debuglevel = $newlevel;
 103     enabledebug();
 104 }
 105
 106 sub printdebug {
 107     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 108 }
 109
 110 sub messagequote ($) {
 111     local ($_) = @_;
 112     s{\\}{\\\\}g;
 113     s{\n}{\\n}g;
 114     s{\x08}{\\b}g;
 115     s{\t}{\\t}g;
 116     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 117     $_;
 118 }
 119
 120 sub shellquote {
 121     my @out;
 122     local $_;
 123     foreach my $a (@_) {
 124         $_ = $a;
 125         if (!length || m{[^-=_./:0-9a-z]}i) {
 126             s{['\\]}{'\\$&'}g;
 127             push @out, "'$_'";
 128         } else {
 129             push @out, $_;
 130         }
 131     }
 132     return join ' ', @out;
 133 }
 134
 135 sub printcmd {
 136     my $fh = shift @_;
 137     my $intro = shift @_;
 138     print $fh $intro," " or die $!;
 139     print $fh shellquote @_ or die $!;
 140     print $fh "\n" or die $!;
 141 }
 142
 143 sub debugcmd {
 144     my $extraprefix = shift @_;
 145     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 146 }
 147
 148 sub dep14_version_mangle ($) {
 149     my ($v) = @_;
 150     # DEP-14 2014-11-05 "Version Mangling"
 151     $v =~ y/~:/_%/;
 152     return $v;
 153 }
 154
 155 sub debiantag_old ($$) {
 156     my ($v,$distro) = @_;
 157     return "$distro/". dep14_version_mangle $v;
 158 }
 159
 160 sub debiantag_new ($$) {
 161     my ($v,$distro) = @_;
 162     return "archive/$distro/".dep14_version_mangle $v;
 163 }
 164
 165 sub debiantags ($$) {
 166     my ($version,$distro) = @_;
 167     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 168 }
 169
 170 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 171 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 172
 173 sub stat_exists ($) {
 174     my ($f) = @_;
 175     return 1 if stat $f;
 176     return 0 if $!==&ENOENT;
 177     die "stat $f: $!";
 178 }
 179
 180 sub _us () {
 181     $::us // ($0 =~ m#[^/]*$#, $&);
 182 }
 183
 184 sub fail {
 185     my $s = "@_\n";
 186     $s =~ s/\n\n$/\n/;
 187     my $prefix = _us().": ";
 188     $s =~ s/^/$prefix/gm;
 189     die $s;
 190 }
 191
 192 sub ensuredir ($) {
 193     my ($dir) = @_; # does not create parents
 194     return if mkdir $dir;
 195     return if $! == EEXIST;
 196     die "mkdir $dir: $!";
 197 }
 198
 199 sub executable_on_path ($) {
 200     my ($program) = @_;
 201     return 1 if $program =~ m{/};
 202     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 203     foreach my $pe (@path) {
 204         my $here = "$pe/$program";
 205         return $here if stat_exists $here && -x _;
 206     }
 207     return undef;
 208 }
 209
 210 our @signames = split / /, $Config{sig_name};
 211
 212 sub waitstatusmsg () {
 213     if (!$?) {
 214         return "terminated, reporting successful completion";
 215     } elsif (!($? & 255)) {
 216         return "failed with error exit status ".WEXITSTATUS($?);
 217     } elsif (WIFSIGNALED($?)) {
 218         my $signum=WTERMSIG($?);
 219         return "died due to fatal signal ".
 220             ($signames[$signum] // "number $signum").
 221             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 222     } else {
 223         return "failed with unknown wait status ".$?;
 224     }
 225 }
 226
 227 sub failedcmd_report_cmd {
 228     my $intro = shift @_;
 229     $intro //= "failed command";
 230     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or die $!; };
 231 }
 232
 233 sub failedcmd_waitstatus {
 234     if ($? < 0) {
 235         return "failed to fork/exec: $!";
 236     } elsif ($?) {
 237         return "subprocess ".waitstatusmsg();
 238     } else {
 239         return "subprocess produced invalid output";
 240     }
 241 }
 242
 243 sub failedcmd {
 244     # Expects $!,$? as set by close - see below.
 245     # To use with system(), set $?=-1 first.
 246     #
 247     # Actual behaviour of perl operations:
 248     #   success              $!==0       $?==0       close of piped open
 249     #   program failed       $!==0       $? >0       close of piped open
 250     #   syscall failure      $! >0       $?=-1       close of piped open
 251     #   failure              $! >0       unchanged   close of something else
 252     #   success              trashed     $?==0       system
 253     #   program failed       trashed     $? >0       system
 254     #   syscall failure      $! >0       unchanged   system
 255     failedcmd_report_cmd undef, @_;
 256     fail failedcmd_waitstatus();
 257 }
 258
 259 sub cmdoutput_errok {
 260     confess Dumper(\@_)." ?" if grep { !defined } @_;
 261     debugcmd "|",@_;
 262     open P, "-|", @_ or die "$_[0] $!";
 263     my $d;
 264     $!=0; $?=0;
 265     { local $/ = undef; $d = <P>; }
 266     die $! if P->error;
 267     if (!close P) { printdebug "=>!$?\n"; return undef; }
 268     chomp $d;
 269     if ($debuglevel > 0) {
 270         $d =~ m/^.*/;
 271         my $dd = $&;
 272         my $more = (length $' ? '...' : ''); #');
 273         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 274         printdebug "=> \`$dd'",$more,"\n";
 275     }
 276     return $d;
 277 }
 278
 279 sub cmdoutput {
 280     my $d = cmdoutput_errok @_;
 281     defined $d or failedcmd @_;
 282     return $d;
 283 }
 284
 285 sub link_ltarget ($$) {
 286     my ($old,$new) = @_;
 287     lstat $old or return undef;
 288     if (-l _) {
 289         $old = cmdoutput qw(realpath  --), $old;
 290     }
 291     link $old, $new or die "link $old $new: $!";
 292 }
 293
 294 sub hashfile ($) {
 295     my ($fn) = @_;
 296     my $h = Digest::SHA->new(256);
 297     $h->addfile($fn);
 298     return $h->hexdigest();
 299 }
 300
 301 sub git_rev_parse ($) {
 302     return cmdoutput qw(git rev-parse), "$_[0]~0";
 303 }
 304
 305 sub git_for_each_ref ($$;$) {
 306     my ($pattern,$func,$gitdir) = @_;
 307     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 308     # $reftail is RHS of ref after refs/[^/]+/
 309     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 310     # $pattern may be an array ref to mean multiple patterns
 311     $pattern = [ $pattern ] unless ref $pattern;
 312     my @cmd = (qw(git for-each-ref), @$pattern);
 313     if (defined $gitdir) {
 314         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 315     }
 316     open GFER, "-|", @cmd or die $!;
 317     debugcmd "|", @cmd;
 318     while (<GFER>) {
 319         chomp or die "$_ ?";
 320         printdebug "|> ", $_, "\n";
 321         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 322         $func->($1,$2,$3,$4);
 323     }
 324     $!=0; $?=0; close GFER or die "$pattern $? $!";
 325 }
 326
 327 sub git_get_ref ($) {
 328     # => '' if no such ref
 329     my ($refname) = @_;
 330     local $_ = $refname;
 331     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 332     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 333 }
 334
 335 sub git_for_each_tag_referring ($$) {
 336     my ($objreferring, $func) = @_;
 337     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 338     printdebug "git_for_each_tag_referring ",
 339         ($objreferring // 'UNDEF'),"\n";
 340     git_for_each_ref('refs/tags', sub {
 341         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 342         return unless $objtype eq 'tag';
 343         my $refobjid = git_rev_parse $tagobjid;
 344         return unless
 345             !defined $objreferring # caller wants them all
 346             or $tagobjid eq $objreferring
 347             or $refobjid eq $objreferring;
 348         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 349     });
 350 }
 351
 352 sub is_fast_fwd ($$) {
 353     my ($ancestor,$child) = @_;
 354     my @cmd = (qw(git merge-base), $ancestor, $child);
 355     my $mb = cmdoutput_errok @cmd;
 356     if (defined $mb) {
 357         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 358     } else {
 359         $?==256 or failedcmd @cmd;
 360         return 0;
 361     }
 362 }
 363
 364 1;