Debian/Dgit.pm

   1 # -*- perl -*-
   2
   3 package Debian::Dgit;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp;
   9 use POSIX;
  10 use IO::Handle;
  11 use Config;
  12 use Digest::SHA;
  13 use Data::Dumper;
  14
  15 BEGIN {
  16     use Exporter   ();
  17     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  18
  19     $VERSION     = 1.00;
  20     @ISA         = qw(Exporter);
  21     @EXPORT      = qw(setup_sigwarn
  22                       debiantag_old server_branch server_ref
  23                       stat_exists link_ltarget
  24                       hashfile
  25                       fail ensuredir executable_on_path
  26                       waitstatusmsg failedcmd
  27                       cmdoutput cmdoutput_errok
  28                       git_rev_parse git_get_ref git_for_each_ref
  29                       git_for_each_tag_referring is_fast_fwd
  30                       $package_re $component_re $deliberately_re
  31                       $branchprefix
  32                       initdebug enabledebug enabledebuglevel
  33                       printdebug debugcmd
  34                       $debugprefix *debuglevel *DEBUG
  35                       shellquote printcmd messagequote);
  36     # implicitly uses $main::us
  37     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  38     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  39 }
  40
  41 our @EXPORT_OK;
  42
  43 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  44 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  45 our $deliberately_re = "(?:TEST-)?$package_re";
  46 our $branchprefix = 'dgit';
  47
  48 # policy hook exit status bits
  49 # see dgit-repos-server head comment for documentation
  50 # 1 is reserved in case something fails with `exit 1' and to spot
  51 # dynamic loader, runtime, etc., failures, which report 127 or 255
  52 sub NOFFCHECK () { return 0x2; }
  53 sub FRESHREPO () { return 0x4; }
  54
  55 our $debugprefix;
  56 our $debuglevel = 0;
  57
  58 sub setup_sigwarn () {
  59     our $sigwarn_mainprocess = $$;
  60     $SIG{__WARN__} = sub {
  61         die $_[0] unless getppid == $sigwarn_mainprocess;
  62     };
  63 }
  64
  65 sub initdebug ($) {
  66     ($debugprefix) = @_;
  67     open DEBUG, ">/dev/null" or die $!;
  68 }
  69
  70 sub enabledebug () {
  71     open DEBUG, ">&STDERR" or die $!;
  72     DEBUG->autoflush(1);
  73     $debuglevel ||= 1;
  74 }
  75
  76 sub enabledebuglevel ($) {
  77     my ($newlevel) = @_; # may be undef (eg from env var)
  78     die if $debuglevel;
  79     $newlevel //= 0;
  80     $newlevel += 0;
  81     return unless $newlevel;
  82     $debuglevel = $newlevel;
  83     enabledebug();
  84 }
  85
  86 sub printdebug {
  87     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
  88 }
  89
  90 sub messagequote ($) {
  91     local ($_) = @_;
  92     s{\\}{\\\\}g;
  93     s{\n}{\\n}g;
  94     s{\x08}{\\b}g;
  95     s{\t}{\\t}g;
  96     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
  97     $_;
  98 }
  99
 100 sub shellquote {
 101     my @out;
 102     local $_;
 103     foreach my $a (@_) {
 104         $_ = $a;
 105         if (!length || m{[^-=_./:0-9a-z]}i) {
 106             s{['\\]}{'\\$&'}g;
 107             push @out, "'$_'";
 108         } else {
 109             push @out, $_;
 110         }
 111     }
 112     return join ' ', @out;
 113 }
 114
 115 sub printcmd {
 116     my $fh = shift @_;
 117     my $intro = shift @_;
 118     print $fh $intro," " or die $!;
 119     print $fh shellquote @_ or die $!;
 120     print $fh "\n" or die $!;
 121 }
 122
 123 sub debugcmd {
 124     my $extraprefix = shift @_;
 125     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 126 }
 127
 128 sub debiantag_old ($$) {
 129     my ($v,$distro) = @_;
 130     $v =~ y/~:/_%/;
 131     return "$distro/$v";
 132 }
 133
 134 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 135 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 136
 137 sub stat_exists ($) {
 138     my ($f) = @_;
 139     return 1 if stat $f;
 140     return 0 if $!==&ENOENT;
 141     die "stat $f: $!";
 142 }
 143
 144 sub _us () {
 145     $::us // ($0 =~ m#[^/]*$#, $&);
 146 }
 147
 148 sub fail {
 149     my $s = "@_\n";
 150     my $prefix = _us().": ";
 151     $s =~ s/^/$prefix/gm;
 152     die $s;
 153 }
 154
 155 sub ensuredir ($) {
 156     my ($dir) = @_; # does not create parents
 157     return if mkdir $dir;
 158     return if $! == EEXIST;
 159     die "mkdir $dir: $!";
 160 }
 161
 162 sub executable_on_path ($) {
 163     my ($program) = @_;
 164     return 1 if $program =~ m{/};
 165     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 166     foreach my $pe (@path) {
 167         my $here = "$pe/$program";
 168         return $here if stat_exists $here && -x _;
 169     }
 170     return undef;
 171 }
 172
 173 our @signames = split / /, $Config{sig_name};
 174
 175 sub waitstatusmsg () {
 176     if (!$?) {
 177         return "terminated, reporting successful completion";
 178     } elsif (!($? & 255)) {
 179         return "failed with error exit status ".WEXITSTATUS($?);
 180     } elsif (WIFSIGNALED($?)) {
 181         my $signum=WTERMSIG($?);
 182         return "died due to fatal signal ".
 183             ($signames[$signum] // "number $signum").
 184             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 185     } else {
 186         return "failed with unknown wait status ".$?;
 187     }
 188 }
 189
 190 sub failedcmd {
 191     # Expects $!,$? as set by close - see below.
 192     # To use with system(), set $?=-1 first.
 193     #
 194     # Actual behaviour of perl operations:
 195     #   success              $!==0       $?==0       close of piped open
 196     #   program failed       $!==0       $? >0       close of piped open
 197     #   syscall failure      $! >0       $?=-1       close of piped open
 198     #   failure              $! >0       unchanged   close of something else
 199     #   success              trashed     $?==0       system
 200     #   program failed       trashed     $? >0       system
 201     #   syscall failure      $! >0       unchanged   system
 202     { local ($!); printcmd \*STDERR, _us().": failed command:", @_ or die $!; };
 203     if ($? < 0) {
 204         fail "failed to fork/exec: $!";
 205     } elsif ($?) {
 206         fail "subprocess ".waitstatusmsg();
 207     } else {
 208         fail "subprocess produced invalid output";
 209     }
 210 }
 211
 212 sub cmdoutput_errok {
 213     confess Dumper(\@_)." ?" if grep { !defined } @_;
 214     debugcmd "|",@_;
 215     open P, "-|", @_ or die "$_[0] $!";
 216     my $d;
 217     $!=0; $?=0;
 218     { local $/ = undef; $d = <P>; }
 219     die $! if P->error;
 220     if (!close P) { printdebug "=>!$?\n"; return undef; }
 221     chomp $d;
 222     if ($debuglevel > 0) {
 223         $d =~ m/^.*/;
 224         my $dd = $&;
 225         my $more = (length $' ? '...' : ''); #');
 226         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 227         printdebug "=> \`$dd'",$more,"\n";
 228     }
 229     return $d;
 230 }
 231
 232 sub cmdoutput {
 233     my $d = cmdoutput_errok @_;
 234     defined $d or failedcmd @_;
 235     return $d;
 236 }
 237
 238 sub link_ltarget ($$) {
 239     my ($old,$new) = @_;
 240     lstat $old or return undef;
 241     if (-l _) {
 242         $old = cmdoutput qw(realpath  --), $old;
 243     }
 244     link $old, $new or die "link $old $new: $!";
 245 }
 246
 247 sub hashfile ($) {
 248     my ($fn) = @_;
 249     my $h = Digest::SHA->new(256);
 250     $h->addfile($fn);
 251     return $h->hexdigest();
 252 }
 253
 254 sub git_rev_parse ($) {
 255     return cmdoutput qw(git rev-parse), "$_[0]~0";
 256 }
 257
 258 sub git_for_each_ref ($$;$) {
 259     my ($pattern,$func,$gitdir) = @_;
 260     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 261     # $reftail is RHS of ref after refs/[^/]+/
 262     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 263     my @cmd = (qw(git for-each-ref), $pattern);
 264     if (defined $gitdir) {
 265         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 266     }
 267     open GFER, "-|", @cmd or die $!;
 268     debugcmd "|", @cmd;
 269     while (<GFER>) {
 270         chomp or die "$_ ?";
 271         printdebug "|> ", $_, "\n";
 272         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 273         $func->($1,$2,$3,$4);
 274     }
 275     $!=0; $?=0; close GFER or die "$pattern $? $!";
 276 }
 277
 278 sub git_get_ref ($) {
 279     # => '' if no such ref
 280     my ($refname) = @_;
 281     local $_ = $refname;
 282     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 283     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 284 }
 285
 286 sub git_for_each_tag_referring ($$) {
 287     my ($objreferring, $func) = @_;
 288     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 289     printdebug "git_for_each_tag_referring ",
 290         ($objreferring // 'UNDEF'),"\n";
 291     git_for_each_ref('refs/tags', sub {
 292         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 293         return unless $objtype eq 'tag';
 294         my $refobjid = git_rev_parse $tagobjid;
 295         return unless
 296             !defined $objreferring # caller wants them all
 297             or $tagobjid eq $objreferring
 298             or $refobjid eq $objreferring;
 299         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 300     });
 301 }
 302
 303 sub is_fast_fwd ($$) {
 304     my ($ancestor,$child) = @_;
 305     my @cmd = (qw(git merge-base), $ancestor, $child);
 306     my $mb = cmdoutput_errok @cmd;
 307     if (defined $mb) {
 308         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 309     } else {
 310         $?==256 or failedcmd @cmd;
 311         return 0;
 312     }
 313 }
 314
 315 1;