Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31 use IPC::Open2;
  32 use File::Path;
  33 use File::Basename;
  34
  35 BEGIN {
  36     use Exporter   ();
  37     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  38
  39     $VERSION     = 1.00;
  40     @ISA         = qw(Exporter);
  41     @EXPORT      = qw(setup_sigwarn forkcheck_setup forkcheck_mainprocess
  42                       dep14_version_mangle
  43                       debiantags debiantag_old debiantag_new
  44                       server_branch server_ref
  45                       stat_exists link_ltarget
  46                       hashfile
  47                       fail failmsg ensuredir must_getcwd executable_on_path
  48                       waitstatusmsg failedcmd_waitstatus
  49                       failedcmd_report_cmd failedcmd
  50                       runcmd cmdoutput cmdoutput_errok
  51                       git_rev_parse git_cat_file
  52                       git_get_ref git_get_symref git_for_each_ref
  53                       git_for_each_tag_referring is_fast_fwd
  54                       git_check_unmodified
  55                       $package_re $component_re $deliberately_re
  56                       $distro_re $versiontag_re $series_filename_re
  57                       $extra_orig_namepart_re
  58                       $git_null_obj
  59                       $branchprefix
  60                       $ffq_refprefix $gdrlast_refprefix
  61                       initdebug enabledebug enabledebuglevel
  62                       printdebug debugcmd
  63                       $debugprefix *debuglevel *DEBUG
  64                       shellquote printcmd messagequote
  65                       $negate_harmful_gitattrs
  66                       changedir git_slurp_config_src
  67                       gdr_ffq_prev_branchinfo
  68                       playtree_setup);
  69     # implicitly uses $main::us
  70     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO NOCOMMITCHECK)],
  71                      playground => [qw(record_maindir $maindir $local_git_cfg
  72                                        $maindir_gitdir $maindir_gitcommon
  73                                        fresh_playground
  74                                        ensure_a_playground)]);
  75     @EXPORT_OK   = ( @{ $EXPORT_TAGS{policyflags} },
  76                      @{ $EXPORT_TAGS{playground} } );
  77 }
  78
  79 our @EXPORT_OK;
  80
  81 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  82 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  83 our $deliberately_re = "(?:TEST-)?$package_re";
  84 our $distro_re = $component_re;
  85 our $versiontag_re = qr{[-+.\%_0-9a-zA-Z/]+};
  86 our $branchprefix = 'dgit';
  87 our $series_filename_re = qr{(?:^|\.)series(?!\n)$}s;
  88 our $extra_orig_namepart_re = qr{[-0-9a-z]+};
  89 our $git_null_obj = '0' x 40;
  90 our $ffq_refprefix = 'ffq-prev';
  91 our $gdrlast_refprefix = 'debrebase-last';
  92
  93 # policy hook exit status bits
  94 # see dgit-repos-server head comment for documentation
  95 # 1 is reserved in case something fails with `exit 1' and to spot
  96 # dynamic loader, runtime, etc., failures, which report 127 or 255
  97 sub NOFFCHECK () { return 0x2; }
  98 sub FRESHREPO () { return 0x4; }
  99 sub NOCOMMITCHECK () { return 0x8; }
 100
 101 our $debugprefix;
 102 our $debuglevel = 0;
 103
 104 our $negate_harmful_gitattrs = "-text -eol -crlf -ident -filter";
 105
 106 our $forkcheck_mainprocess;
 107
 108 sub forkcheck_setup () {
 109     $forkcheck_mainprocess = $$;
 110 }
 111
 112 sub forkcheck_mainprocess () {
 113     # You must have called forkcheck_setup or setup_sigwarn already
 114     getppid != $forkcheck_mainprocess;
 115 }
 116
 117 sub setup_sigwarn () {
 118     forkcheck_setup();
 119     $SIG{__WARN__} = sub {
 120         confess $_[0] if forkcheck_mainprocess;
 121     };
 122 }
 123
 124 sub initdebug ($) {
 125     ($debugprefix) = @_;
 126     open DEBUG, ">/dev/null" or die $!;
 127 }
 128
 129 sub enabledebug () {
 130     open DEBUG, ">&STDERR" or die $!;
 131     DEBUG->autoflush(1);
 132     $debuglevel ||= 1;
 133 }
 134
 135 sub enabledebuglevel ($) {
 136     my ($newlevel) = @_; # may be undef (eg from env var)
 137     die if $debuglevel;
 138     $newlevel //= 0;
 139     $newlevel += 0;
 140     return unless $newlevel;
 141     $debuglevel = $newlevel;
 142     enabledebug();
 143 }
 144
 145 sub printdebug {
 146     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 147 }
 148
 149 sub messagequote ($) {
 150     local ($_) = @_;
 151     s{\\}{\\\\}g;
 152     s{\n}{\\n}g;
 153     s{\x08}{\\b}g;
 154     s{\t}{\\t}g;
 155     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 156     $_;
 157 }
 158
 159 sub shellquote {
 160     my @out;
 161     local $_;
 162     defined or confess 'internal error' foreach @_;
 163     foreach my $a (@_) {
 164         $_ = $a;
 165         if (!length || m{[^-=_./:0-9a-z]}i) {
 166             s{['\\]}{'\\$&'}g;
 167             push @out, "'$_'";
 168         } else {
 169             push @out, $_;
 170         }
 171     }
 172     return join ' ', @out;
 173 }
 174
 175 sub printcmd {
 176     my $fh = shift @_;
 177     my $intro = shift @_;
 178     print $fh $intro," " or die $!;
 179     print $fh shellquote @_ or die $!;
 180     print $fh "\n" or die $!;
 181 }
 182
 183 sub debugcmd {
 184     my $extraprefix = shift @_;
 185     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 186 }
 187
 188 sub dep14_version_mangle ($) {
 189     my ($v) = @_;
 190     # DEP-14 patch proposed 2016-11-09  "Version Mangling"
 191     $v =~ y/~:/_%/;
 192     $v =~ s/\.(?=\.|$|lock$)/.#/g;
 193     return $v;
 194 }
 195
 196 sub debiantag_old ($$) {
 197     my ($v,$distro) = @_;
 198     return "$distro/". dep14_version_mangle $v;
 199 }
 200
 201 sub debiantag_new ($$) {
 202     my ($v,$distro) = @_;
 203     return "archive/$distro/".dep14_version_mangle $v;
 204 }
 205
 206 sub debiantags ($$) {
 207     my ($version,$distro) = @_;
 208     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 209 }
 210
 211 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 212 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 213
 214 sub stat_exists ($) {
 215     my ($f) = @_;
 216     return 1 if stat $f;
 217     return 0 if $!==&ENOENT;
 218     die "stat $f: $!";
 219 }
 220
 221 sub _us () {
 222     $::us // ($0 =~ m#[^/]*$#, $&);
 223 }
 224
 225 sub failmsg {
 226     my $s = "@_\n";
 227     $s =~ s/\n\n$/\n/;
 228     my $prefix = _us().": ";
 229     $s =~ s/^/$prefix/gm;
 230     return $s;
 231 }
 232
 233 sub fail {
 234     die failmsg @_;
 235 }
 236
 237 sub ensuredir ($) {
 238     my ($dir) = @_; # does not create parents
 239     return if mkdir $dir;
 240     return if $! == EEXIST;
 241     die "mkdir $dir: $!";
 242 }
 243
 244 sub must_getcwd () {
 245     my $d = getcwd();
 246     defined $d or fail "getcwd failed: $!";
 247     return $d;
 248 }
 249
 250 sub executable_on_path ($) {
 251     my ($program) = @_;
 252     return 1 if $program =~ m{/};
 253     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 254     foreach my $pe (@path) {
 255         my $here = "$pe/$program";
 256         return $here if stat_exists $here && -x _;
 257     }
 258     return undef;
 259 }
 260
 261 our @signames = split / /, $Config{sig_name};
 262
 263 sub waitstatusmsg () {
 264     if (!$?) {
 265         return "terminated, reporting successful completion";
 266     } elsif (!($? & 255)) {
 267         return "failed with error exit status ".WEXITSTATUS($?);
 268     } elsif (WIFSIGNALED($?)) {
 269         my $signum=WTERMSIG($?);
 270         return "died due to fatal signal ".
 271             ($signames[$signum] // "number $signum").
 272             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 273     } else {
 274         return "failed with unknown wait status ".$?;
 275     }
 276 }
 277
 278 sub failedcmd_report_cmd {
 279     my $intro = shift @_;
 280     $intro //= "failed command";
 281     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or die $!; };
 282 }
 283
 284 sub failedcmd_waitstatus {
 285     if ($? < 0) {
 286         return "failed to fork/exec: $!";
 287     } elsif ($?) {
 288         return "subprocess ".waitstatusmsg();
 289     } else {
 290         return "subprocess produced invalid output";
 291     }
 292 }
 293
 294 sub failedcmd {
 295     # Expects $!,$? as set by close - see below.
 296     # To use with system(), set $?=-1 first.
 297     #
 298     # Actual behaviour of perl operations:
 299     #   success              $!==0       $?==0       close of piped open
 300     #   program failed       $!==0       $? >0       close of piped open
 301     #   syscall failure      $! >0       $?=-1       close of piped open
 302     #   failure              $! >0       unchanged   close of something else
 303     #   success              trashed     $?==0       system
 304     #   program failed       trashed     $? >0       system
 305     #   syscall failure      $! >0       unchanged   system
 306     failedcmd_report_cmd undef, @_;
 307     fail failedcmd_waitstatus();
 308 }
 309
 310 sub runcmd {
 311     debugcmd "+",@_;
 312     $!=0; $?=-1;
 313     failedcmd @_ if system @_;
 314 }
 315
 316 sub cmdoutput_errok {
 317     confess Dumper(\@_)." ?" if grep { !defined } @_;
 318     debugcmd "|",@_;
 319     open P, "-|", @_ or die "$_[0] $!";
 320     my $d;
 321     $!=0; $?=0;
 322     { local $/ = undef; $d = <P>; }
 323     die $! if P->error;
 324     if (!close P) { printdebug "=>!$?\n"; return undef; }
 325     chomp $d;
 326     if ($debuglevel > 0) {
 327         $d =~ m/^.*/;
 328         my $dd = $&;
 329         my $more = (length $' ? '...' : ''); #');
 330         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 331         printdebug "=> \`$dd'",$more,"\n";
 332     }
 333     return $d;
 334 }
 335
 336 sub cmdoutput {
 337     my $d = cmdoutput_errok @_;
 338     defined $d or failedcmd @_;
 339     return $d;
 340 }
 341
 342 sub link_ltarget ($$) {
 343     my ($old,$new) = @_;
 344     lstat $old or return undef;
 345     if (-l _) {
 346         $old = cmdoutput qw(realpath  --), $old;
 347     }
 348     my $r = link $old, $new;
 349     $r = symlink $old, $new if !$r && $!==EXDEV;
 350     $r or die "(sym)link $old $new: $!";
 351 }
 352
 353 sub hashfile ($) {
 354     my ($fn) = @_;
 355     my $h = Digest::SHA->new(256);
 356     $h->addfile($fn);
 357     return $h->hexdigest();
 358 }
 359
 360 sub git_rev_parse ($) {
 361     return cmdoutput qw(git rev-parse), "$_[0]~0";
 362 }
 363
 364 sub git_cat_file ($;$) {
 365     my ($objname, $etype) = @_;
 366     # => ($type, $data) or ('missing', undef)
 367     # in scalar context, just the data
 368     # if $etype defined, dies unless type is $etype or in @$etype
 369     our ($gcf_pid, $gcf_i, $gcf_o);
 370     my $chk = sub {
 371         my ($gtype, $data) = @_;
 372         if ($etype) {
 373             $etype = [$etype] unless ref $etype;
 374             confess "$objname expected @$etype but is $gtype"
 375                 unless grep { $gtype eq $_ } @$etype;
 376         }
 377         return ($gtype, $data);
 378     };
 379     if (!$gcf_pid) {
 380         my @cmd = qw(git cat-file --batch);
 381         debugcmd "GCF|", @cmd;
 382         $gcf_pid = open2 $gcf_o, $gcf_i, @cmd or die $!;
 383     }
 384     printdebug "GCF>| ", $objname, "\n";
 385     print $gcf_i $objname, "\n" or die $!;
 386     my $x = <$gcf_o>;
 387     printdebug "GCF<| ", $x;
 388     if ($x =~ m/ (missing)$/) { return $chk->($1, undef); }
 389     my ($type, $size) = $x =~ m/^.* (\w+) (\d+)\n/ or die "$objname ?";
 390     my $data;
 391     (read $gcf_o, $data, $size) == $size or die "$objname $!";
 392     $x = <$gcf_o>;
 393     $x eq "\n" or die "$objname ($_) $!";
 394     return $chk->($type, $data);
 395 }
 396
 397 sub git_get_symref (;$) {
 398     my ($symref) = @_;  $symref //= 'HEAD';
 399     # => undef if not a symref, otherwise refs/...
 400     my @cmd = (qw(git symbolic-ref -q HEAD));
 401     my $branch = cmdoutput_errok @cmd;
 402     if (!defined $branch) {
 403         $?==256 or failedcmd @cmd;
 404     } else {
 405         chomp $branch;
 406     }
 407     return $branch;
 408 }
 409
 410 sub git_for_each_ref ($$;$) {
 411     my ($pattern,$func,$gitdir) = @_;
 412     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 413     # $reftail is RHS of ref after refs/[^/]+/
 414     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 415     # $pattern may be an array ref to mean multiple patterns
 416     $pattern = [ $pattern ] unless ref $pattern;
 417     my @cmd = (qw(git for-each-ref), @$pattern);
 418     if (defined $gitdir) {
 419         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 420     }
 421     open GFER, "-|", @cmd or die $!;
 422     debugcmd "|", @cmd;
 423     while (<GFER>) {
 424         chomp or die "$_ ?";
 425         printdebug "|> ", $_, "\n";
 426         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 427         $func->($1,$2,$3,$4);
 428     }
 429     $!=0; $?=0; close GFER or die "$pattern $? $!";
 430 }
 431
 432 sub git_get_ref ($) {
 433     # => '' if no such ref
 434     my ($refname) = @_;
 435     local $_ = $refname;
 436     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 437     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 438 }
 439
 440 sub git_for_each_tag_referring ($$) {
 441     my ($objreferring, $func) = @_;
 442     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 443     printdebug "git_for_each_tag_referring ",
 444         ($objreferring // 'UNDEF'),"\n";
 445     git_for_each_ref('refs/tags', sub {
 446         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 447         return unless $objtype eq 'tag';
 448         my $refobjid = git_rev_parse $tagobjid;
 449         return unless
 450             !defined $objreferring # caller wants them all
 451             or $tagobjid eq $objreferring
 452             or $refobjid eq $objreferring;
 453         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 454     });
 455 }
 456
 457 sub git_check_unmodified () {
 458     foreach my $cached (qw(0 1)) {
 459         my @cmd = qw(git diff --quiet);
 460         push @cmd, qw(--cached) if $cached;
 461         push @cmd, qw(HEAD);
 462         debugcmd "+",@cmd;
 463         $!=0; $?=-1; system @cmd;
 464         return if !$?;
 465         if ($?==256) {
 466             fail
 467                 $cached
 468                 ? "git index contains changes (does not match HEAD)"
 469                 : "working tree is dirty (does not match HEAD)";
 470         } else {
 471             failedcmd @cmd;
 472         }
 473     }
 474 }
 475
 476 sub is_fast_fwd ($$) {
 477     my ($ancestor,$child) = @_;
 478     my @cmd = (qw(git merge-base), $ancestor, $child);
 479     my $mb = cmdoutput_errok @cmd;
 480     if (defined $mb) {
 481         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 482     } else {
 483         $?==256 or failedcmd @cmd;
 484         return 0;
 485     }
 486 }
 487
 488 sub changedir ($) {
 489     my ($newdir) = @_;
 490     printdebug "CD $newdir\n";
 491     chdir $newdir or confess "chdir: $newdir: $!";
 492 }
 493
 494 sub git_slurp_config_src ($) {
 495     my ($src) = @_;
 496     # returns $r such that $r->{KEY}[] = VALUE
 497     my @cmd = (qw(git config -z --get-regexp), "--$src", qw(.*));
 498     debugcmd "|",@cmd;
 499
 500     local ($debuglevel) = $debuglevel-2;
 501     local $/="\0";
 502
 503     my $r = { };
 504     open GITS, "-|", @cmd or die $!;
 505     while (<GITS>) {
 506         chomp or die;
 507         printdebug "=> ", (messagequote $_), "\n";
 508         m/\n/ or die "$_ ?";
 509         push @{ $r->{$`} }, $'; #';
 510     }
 511     $!=0; $?=0;
 512     close GITS
 513         or ($!==0 && $?==256)
 514         or failedcmd @cmd;
 515     return $r;
 516 }
 517
 518 sub gdr_ffq_prev_branchinfo ($) {
 519     my ($symref) = @_;
 520     # => ('status', "message", [$symref, $ffq_prev, $gdrlast])
 521     # 'status' may be
 522     #    branch         message is undef
 523     #    weird-symref   } no $symref,
 524     #    notbranch      }  no $ffq_prev
 525     return ('detached', 'detached HEAD') unless defined $symref;
 526     return ('weird-symref', 'HEAD symref is not to refs/')
 527         unless $symref =~ m{^refs/};
 528     my $ffq_prev = "refs/$ffq_refprefix/$'";
 529     my $gdrlast = "refs/$gdrlast_refprefix/$'";
 530     printdebug "ffq_prev_branchinfo branch current $symref\n";
 531     return ('branch', undef, $symref, $ffq_prev, $gdrlast);
 532 }
 533
 534 # ========== playground handling ==========
 535
 536 # terminology:
 537 #
 538 #   $maindir      user's git working tree
 539 #   playground    area in .git/ where we can make files, unpack, etc. etc.
 540 #   playtree      git working tree sharing object store with the user's
 541 #                 inside playground, or identical to it
 542 #
 543 # other globals
 544 #
 545 #   $local_git_cfg    hash of arrays of values: git config from $maindir
 546 #
 547 # expected calling pattern
 548 #
 549 #  firstly
 550 #
 551 #    [record_maindir]
 552 #      must be run in directory containing .git
 553 #      assigns to $maindir if not already set
 554 #      also calls git_slurp_config_src to record git config
 555 #        in $local_git_cfg, unless it's already set
 556 #
 557 #    fresh_playground SUBDIR_PATH_COMPONENTS
 558 #      e.g fresh_playground 'dgit/unpack' ('.git/' is implied)
 559 #      default SUBDIR_PATH_COMPONENTS is playground_subdir
 560 #      calls record_maindir
 561 #      sets up a new playground (destroying any old one)
 562 #      returns playground pathname
 563 #      caller may call multiple times with different subdir paths
 564 #       createing different playgrounds
 565 #
 566 #    ensure_a_playground SUBDIR_PATH_COMPONENTS
 567 #      like fresh_playground except:
 568 #      merely ensures the directory exists; does not delete an existing one
 569 #
 570 #  then can use
 571 #
 572 #    changedir playground
 573 #    changedir $maindir
 574 #
 575 #    playtree_setup $local_git_cfg
 576 #            # ^ call in some (perhaps trivial) subdir of playground
 577 #
 578 #    rmtree playground
 579
 580 # ----- maindir -----
 581
 582 # these three all go together
 583 our $maindir;
 584 our $maindir_gitdir;
 585 our $maindir_gitcommon;
 586
 587 our $local_git_cfg;
 588
 589 sub record_maindir () {
 590     if (!defined $maindir) {
 591         $maindir = must_getcwd();
 592         if (!stat "$maindir/.git") {
 593             fail "cannot stat $maindir/.git: $!";
 594         }
 595         if (-d _) {
 596             # we fall back to this in case we have a pre-worktree
 597             # git, which may not know git rev-parse --git-common-dir
 598             $maindir_gitdir    = "$maindir/.git";
 599             $maindir_gitcommon = "$maindir/.git";
 600         } else {
 601             $maindir_gitdir    = cmdoutput qw(git rev-parse --git-dir);
 602             $maindir_gitcommon = cmdoutput qw(git rev-parse --git-common-dir);
 603         }
 604     }
 605     $local_git_cfg //= git_slurp_config_src 'local';
 606 }
 607
 608 # ----- playgrounds -----
 609
 610 sub ensure_a_playground_parent ($) {
 611     my ($spc) = @_;
 612     record_maindir();
 613     $spc = "$maindir_gitdir/$spc";
 614     my $parent = dirname $spc;
 615     mkdir $parent or $!==EEXIST
 616         or fail "failed to mkdir playground parent $parent: $!";
 617     return $spc;
 618 }
 619
 620 sub ensure_a_playground ($) {
 621     my ($spc) = @_;
 622     $spc = ensure_a_playground_parent $spc;
 623     mkdir $spc or $!==EEXIST or fail "failed to mkdir a playground $spc: $!";
 624     return $spc;
 625 }
 626
 627 sub fresh_playground ($) {
 628     my ($spc) = @_;
 629     $spc = ensure_a_playground_parent $spc;
 630     rmtree $spc;
 631     mkdir $spc or fail "failed to mkdir the playground $spc: $!";
 632     return $spc;
 633 }
 634
 635 # ----- playtrees -----
 636
 637 sub playtree_setup (;$) {
 638     my ($t_local_git_cfg) = @_;
 639     $t_local_git_cfg //= $local_git_cfg;
 640     # for use in the playtree
 641     # $maindir must be set, eg by calling record_maindir or fresh_playground
 642     runcmd qw(git init -q);
 643     runcmd qw(git config gc.auto 0);
 644     foreach my $copy (qw(user.email user.name user.useConfigOnly
 645                          core.sharedRepository
 646                          core.compression core.looseCompression
 647                          core.bigFileThreshold core.fsyncObjectFiles)) {
 648         my $v = $t_local_git_cfg->{$copy};
 649         next unless $v;
 650         runcmd qw(git config), $copy, $_ foreach @$v;
 651     }
 652     # this is confusing: we have
 653     #   .                   playtree, not a worktree, has .git/, our cwd
 654     #   $maindir            might be a worktree so
 655     #   $maindir_gitdir     contains our main working "dgit", HEAD, etc.
 656     #   $maindir_gitcommon  the shared stuff, including .objects
 657     rmtree('.git/objects');
 658     symlink "$maindir_gitcommon/objects",'.git/objects' or die $!;
 659     ensuredir '.git/info';
 660     open GA, "> .git/info/attributes" or die $!;
 661     print GA "* $negate_harmful_gitattrs\n" or die $!;
 662     close GA or die $!;
 663 }
 664
 665 1;