Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31 use IPC::Open2;
  32
  33 BEGIN {
  34     use Exporter   ();
  35     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  36
  37     $VERSION     = 1.00;
  38     @ISA         = qw(Exporter);
  39     @EXPORT      = qw(setup_sigwarn forkcheck_setup forkcheck_mainprocess
  40                       dep14_version_mangle
  41                       debiantags debiantag_old debiantag_new
  42                       server_branch server_ref
  43                       stat_exists link_ltarget
  44                       hashfile
  45                       fail ensuredir executable_on_path
  46                       waitstatusmsg failedcmd_waitstatus
  47                       failedcmd_report_cmd failedcmd
  48                       runcmd cmdoutput cmdoutput_errok
  49                       git_rev_parse git_cat_file
  50                       git_get_ref git_for_each_ref
  51                       git_for_each_tag_referring is_fast_fwd
  52                       $package_re $component_re $deliberately_re
  53                       $distro_re $versiontag_re $series_filename_re
  54                       $branchprefix
  55                       initdebug enabledebug enabledebuglevel
  56                       printdebug debugcmd
  57                       $debugprefix *debuglevel *DEBUG
  58                       shellquote printcmd messagequote
  59                       $negate_harmful_gitattrs);
  60     # implicitly uses $main::us
  61     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO NOCOMMITCHECK)] );
  62     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  63 }
  64
  65 our @EXPORT_OK;
  66
  67 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  68 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  69 our $deliberately_re = "(?:TEST-)?$package_re";
  70 our $distro_re = $component_re;
  71 our $versiontag_re = qr{[-+.\%_0-9a-zA-Z/]+};
  72 our $branchprefix = 'dgit';
  73 our $series_filename_re = qr{(?:^|\.)series(?!\n)$}s;
  74
  75 # policy hook exit status bits
  76 # see dgit-repos-server head comment for documentation
  77 # 1 is reserved in case something fails with `exit 1' and to spot
  78 # dynamic loader, runtime, etc., failures, which report 127 or 255
  79 sub NOFFCHECK () { return 0x2; }
  80 sub FRESHREPO () { return 0x4; }
  81 sub NOCOMMITCHECK () { return 0x8; }
  82
  83 our $debugprefix;
  84 our $debuglevel = 0;
  85
  86 our $negate_harmful_gitattrs = "-text -eol -crlf -ident -filter";
  87
  88 our $forkcheck_mainprocess;
  89
  90 sub forkcheck_setup () {
  91     $forkcheck_mainprocess = $$;
  92 }
  93
  94 sub forkcheck_mainprocess () {
  95     # You must have called forkcheck_setup or setup_sigwarn already
  96     getppid != $forkcheck_mainprocess;
  97 }
  98
  99 sub setup_sigwarn () {
 100     forkcheck_setup();
 101     $SIG{__WARN__} = sub {
 102         die $_[0] if forkcheck_mainprocess;
 103     };
 104 }
 105
 106 sub initdebug ($) {
 107     ($debugprefix) = @_;
 108     open DEBUG, ">/dev/null" or die $!;
 109 }
 110
 111 sub enabledebug () {
 112     open DEBUG, ">&STDERR" or die $!;
 113     DEBUG->autoflush(1);
 114     $debuglevel ||= 1;
 115 }
 116
 117 sub enabledebuglevel ($) {
 118     my ($newlevel) = @_; # may be undef (eg from env var)
 119     die if $debuglevel;
 120     $newlevel //= 0;
 121     $newlevel += 0;
 122     return unless $newlevel;
 123     $debuglevel = $newlevel;
 124     enabledebug();
 125 }
 126
 127 sub printdebug {
 128     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 129 }
 130
 131 sub messagequote ($) {
 132     local ($_) = @_;
 133     s{\\}{\\\\}g;
 134     s{\n}{\\n}g;
 135     s{\x08}{\\b}g;
 136     s{\t}{\\t}g;
 137     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 138     $_;
 139 }
 140
 141 sub shellquote {
 142     my @out;
 143     local $_;
 144     defined or confess 'internal error' foreach @_;
 145     foreach my $a (@_) {
 146         $_ = $a;
 147         if (!length || m{[^-=_./:0-9a-z]}i) {
 148             s{['\\]}{'\\$&'}g;
 149             push @out, "'$_'";
 150         } else {
 151             push @out, $_;
 152         }
 153     }
 154     return join ' ', @out;
 155 }
 156
 157 sub printcmd {
 158     my $fh = shift @_;
 159     my $intro = shift @_;
 160     print $fh $intro," " or die $!;
 161     print $fh shellquote @_ or die $!;
 162     print $fh "\n" or die $!;
 163 }
 164
 165 sub debugcmd {
 166     my $extraprefix = shift @_;
 167     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 168 }
 169
 170 sub dep14_version_mangle ($) {
 171     my ($v) = @_;
 172     # DEP-14 patch proposed 2016-11-09  "Version Mangling"
 173     $v =~ y/~:/_%/;
 174     $v =~ s/\.(?=\.|$|lock$)/.#/g;
 175     return $v;
 176 }
 177
 178 sub debiantag_old ($$) {
 179     my ($v,$distro) = @_;
 180     return "$distro/". dep14_version_mangle $v;
 181 }
 182
 183 sub debiantag_new ($$) {
 184     my ($v,$distro) = @_;
 185     return "archive/$distro/".dep14_version_mangle $v;
 186 }
 187
 188 sub debiantags ($$) {
 189     my ($version,$distro) = @_;
 190     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 191 }
 192
 193 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 194 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 195
 196 sub stat_exists ($) {
 197     my ($f) = @_;
 198     return 1 if stat $f;
 199     return 0 if $!==&ENOENT;
 200     die "stat $f: $!";
 201 }
 202
 203 sub _us () {
 204     $::us // ($0 =~ m#[^/]*$#, $&);
 205 }
 206
 207 sub fail {
 208     my $s = "@_\n";
 209     $s =~ s/\n\n$/\n/;
 210     my $prefix = _us().": ";
 211     $s =~ s/^/$prefix/gm;
 212     die $s;
 213 }
 214
 215 sub ensuredir ($) {
 216     my ($dir) = @_; # does not create parents
 217     return if mkdir $dir;
 218     return if $! == EEXIST;
 219     die "mkdir $dir: $!";
 220 }
 221
 222 sub executable_on_path ($) {
 223     my ($program) = @_;
 224     return 1 if $program =~ m{/};
 225     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 226     foreach my $pe (@path) {
 227         my $here = "$pe/$program";
 228         return $here if stat_exists $here && -x _;
 229     }
 230     return undef;
 231 }
 232
 233 our @signames = split / /, $Config{sig_name};
 234
 235 sub waitstatusmsg () {
 236     if (!$?) {
 237         return "terminated, reporting successful completion";
 238     } elsif (!($? & 255)) {
 239         return "failed with error exit status ".WEXITSTATUS($?);
 240     } elsif (WIFSIGNALED($?)) {
 241         my $signum=WTERMSIG($?);
 242         return "died due to fatal signal ".
 243             ($signames[$signum] // "number $signum").
 244             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 245     } else {
 246         return "failed with unknown wait status ".$?;
 247     }
 248 }
 249
 250 sub failedcmd_report_cmd {
 251     my $intro = shift @_;
 252     $intro //= "failed command";
 253     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or die $!; };
 254 }
 255
 256 sub failedcmd_waitstatus {
 257     if ($? < 0) {
 258         return "failed to fork/exec: $!";
 259     } elsif ($?) {
 260         return "subprocess ".waitstatusmsg();
 261     } else {
 262         return "subprocess produced invalid output";
 263     }
 264 }
 265
 266 sub failedcmd {
 267     # Expects $!,$? as set by close - see below.
 268     # To use with system(), set $?=-1 first.
 269     #
 270     # Actual behaviour of perl operations:
 271     #   success              $!==0       $?==0       close of piped open
 272     #   program failed       $!==0       $? >0       close of piped open
 273     #   syscall failure      $! >0       $?=-1       close of piped open
 274     #   failure              $! >0       unchanged   close of something else
 275     #   success              trashed     $?==0       system
 276     #   program failed       trashed     $? >0       system
 277     #   syscall failure      $! >0       unchanged   system
 278     failedcmd_report_cmd undef, @_;
 279     fail failedcmd_waitstatus();
 280 }
 281
 282 sub runcmd {
 283     debugcmd "+",@_;
 284     $!=0; $?=-1;
 285     failedcmd @_ if system @_;
 286 }
 287
 288 sub cmdoutput_errok {
 289     confess Dumper(\@_)." ?" if grep { !defined } @_;
 290     debugcmd "|",@_;
 291     open P, "-|", @_ or die "$_[0] $!";
 292     my $d;
 293     $!=0; $?=0;
 294     { local $/ = undef; $d = <P>; }
 295     die $! if P->error;
 296     if (!close P) { printdebug "=>!$?\n"; return undef; }
 297     chomp $d;
 298     if ($debuglevel > 0) {
 299         $d =~ m/^.*/;
 300         my $dd = $&;
 301         my $more = (length $' ? '...' : ''); #');
 302         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 303         printdebug "=> \`$dd'",$more,"\n";
 304     }
 305     return $d;
 306 }
 307
 308 sub cmdoutput {
 309     my $d = cmdoutput_errok @_;
 310     defined $d or failedcmd @_;
 311     return $d;
 312 }
 313
 314 sub link_ltarget ($$) {
 315     my ($old,$new) = @_;
 316     lstat $old or return undef;
 317     if (-l _) {
 318         $old = cmdoutput qw(realpath  --), $old;
 319     }
 320     my $r = link $old, $new;
 321     $r = symlink $old, $new if !$r && $!==EXDEV;
 322     $r or die "(sym)link $old $new: $!";
 323 }
 324
 325 sub hashfile ($) {
 326     my ($fn) = @_;
 327     my $h = Digest::SHA->new(256);
 328     $h->addfile($fn);
 329     return $h->hexdigest();
 330 }
 331
 332 sub git_rev_parse ($) {
 333     return cmdoutput qw(git rev-parse), "$_[0]~0";
 334 }
 335
 336 sub git_cat_file ($) {
 337     my ($objname) = @_;
 338     # => ($type, $data) or ('missing', undef)
 339     # in scalar context, just the data
 340     our ($gcf_pid, $gcf_i, $gcf_o);
 341     if (!$gcf_pid) {
 342         my @cmd = qw(git cat-file --batch);
 343         debugcmd "GCF|", @cmd;
 344         $gcf_pid = open2 $gcf_o, $gcf_i, @cmd or die $!;
 345     }
 346     printdebug "GCF>| ", $objname, "\n";
 347     print $gcf_i $objname, "\n" or die $!;
 348     my $x = <$gcf_o>;
 349     printdebug "GCF<| ", $x;
 350     if ($x =~ m/ (missing)$/) { return ($1, undef); }
 351     my ($type, $size) = $x =~ m/^.* (\w+) (\d+)\n/ or die "$objname ?";
 352     my $data;
 353     (read $gcf_o, $data, $size) == $size or die "$objname $!";
 354     $x = <$gcf_o>;
 355     $x eq "\n" or die "$objname ($_) $!";
 356     return ($type, $data);
 357 }
 358
 359 sub git_for_each_ref ($$;$) {
 360     my ($pattern,$func,$gitdir) = @_;
 361     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 362     # $reftail is RHS of ref after refs/[^/]+/
 363     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 364     # $pattern may be an array ref to mean multiple patterns
 365     $pattern = [ $pattern ] unless ref $pattern;
 366     my @cmd = (qw(git for-each-ref), @$pattern);
 367     if (defined $gitdir) {
 368         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 369     }
 370     open GFER, "-|", @cmd or die $!;
 371     debugcmd "|", @cmd;
 372     while (<GFER>) {
 373         chomp or die "$_ ?";
 374         printdebug "|> ", $_, "\n";
 375         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 376         $func->($1,$2,$3,$4);
 377     }
 378     $!=0; $?=0; close GFER or die "$pattern $? $!";
 379 }
 380
 381 sub git_get_ref ($) {
 382     # => '' if no such ref
 383     my ($refname) = @_;
 384     local $_ = $refname;
 385     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 386     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 387 }
 388
 389 sub git_for_each_tag_referring ($$) {
 390     my ($objreferring, $func) = @_;
 391     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 392     printdebug "git_for_each_tag_referring ",
 393         ($objreferring // 'UNDEF'),"\n";
 394     git_for_each_ref('refs/tags', sub {
 395         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 396         return unless $objtype eq 'tag';
 397         my $refobjid = git_rev_parse $tagobjid;
 398         return unless
 399             !defined $objreferring # caller wants them all
 400             or $tagobjid eq $objreferring
 401             or $refobjid eq $objreferring;
 402         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 403     });
 404 }
 405
 406 sub is_fast_fwd ($$) {
 407     my ($ancestor,$child) = @_;
 408     my @cmd = (qw(git merge-base), $ancestor, $child);
 409     my $mb = cmdoutput_errok @cmd;
 410     if (defined $mb) {
 411         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 412     } else {
 413         $?==256 or failedcmd @cmd;
 414         return 0;
 415     }
 416 }
 417
 418 1;