Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31 use IPC::Open2;
  32
  33 BEGIN {
  34     use Exporter   ();
  35     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  36
  37     $VERSION     = 1.00;
  38     @ISA         = qw(Exporter);
  39     @EXPORT      = qw(setup_sigwarn forkcheck_setup forkcheck_mainprocess
  40                       dep14_version_mangle
  41                       debiantags debiantag_old debiantag_new
  42                       server_branch server_ref
  43                       stat_exists link_ltarget
  44                       hashfile
  45                       fail ensuredir executable_on_path
  46                       waitstatusmsg failedcmd_waitstatus
  47                       failedcmd_report_cmd failedcmd
  48                       cmdoutput cmdoutput_errok
  49                       git_rev_parse git_cat_file
  50                       git_get_ref git_for_each_ref
  51                       git_for_each_tag_referring is_fast_fwd
  52                       $package_re $component_re $deliberately_re
  53                       $distro_re $versiontag_re
  54                       $branchprefix
  55                       initdebug enabledebug enabledebuglevel
  56                       printdebug debugcmd
  57                       $debugprefix *debuglevel *DEBUG
  58                       shellquote printcmd messagequote);
  59     # implicitly uses $main::us
  60     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO NOCOMMITCHECK)] );
  61     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  62 }
  63
  64 our @EXPORT_OK;
  65
  66 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  67 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  68 our $deliberately_re = "(?:TEST-)?$package_re";
  69 our $distro_re = $component_re;
  70 our $versiontag_re = qr{[-+.\%_0-9a-zA-Z/]+};
  71 our $branchprefix = 'dgit';
  72
  73 # policy hook exit status bits
  74 # see dgit-repos-server head comment for documentation
  75 # 1 is reserved in case something fails with `exit 1' and to spot
  76 # dynamic loader, runtime, etc., failures, which report 127 or 255
  77 sub NOFFCHECK () { return 0x2; }
  78 sub FRESHREPO () { return 0x4; }
  79 sub NOCOMMITCHECK () { return 0x8; }
  80
  81 our $debugprefix;
  82 our $debuglevel = 0;
  83
  84 our $forkcheck_mainprocess;
  85
  86 sub forkcheck_setup () {
  87     $forkcheck_mainprocess = $$;
  88 }
  89
  90 sub forkcheck_mainprocess () {
  91     # You must have called forkcheck_setup or setup_sigwarn already
  92     getppid != $forkcheck_mainprocess;
  93 }
  94
  95 sub setup_sigwarn () {
  96     forkcheck_setup();
  97     $SIG{__WARN__} = sub {
  98         die $_[0] if forkcheck_mainprocess;
  99     };
 100 }
 101
 102 sub initdebug ($) {
 103     ($debugprefix) = @_;
 104     open DEBUG, ">/dev/null" or die $!;
 105 }
 106
 107 sub enabledebug () {
 108     open DEBUG, ">&STDERR" or die $!;
 109     DEBUG->autoflush(1);
 110     $debuglevel ||= 1;
 111 }
 112
 113 sub enabledebuglevel ($) {
 114     my ($newlevel) = @_; # may be undef (eg from env var)
 115     die if $debuglevel;
 116     $newlevel //= 0;
 117     $newlevel += 0;
 118     return unless $newlevel;
 119     $debuglevel = $newlevel;
 120     enabledebug();
 121 }
 122
 123 sub printdebug {
 124     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 125 }
 126
 127 sub messagequote ($) {
 128     local ($_) = @_;
 129     s{\\}{\\\\}g;
 130     s{\n}{\\n}g;
 131     s{\x08}{\\b}g;
 132     s{\t}{\\t}g;
 133     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 134     $_;
 135 }
 136
 137 sub shellquote {
 138     my @out;
 139     local $_;
 140     foreach my $a (@_) {
 141         $_ = $a;
 142         if (!length || m{[^-=_./:0-9a-z]}i) {
 143             s{['\\]}{'\\$&'}g;
 144             push @out, "'$_'";
 145         } else {
 146             push @out, $_;
 147         }
 148     }
 149     return join ' ', @out;
 150 }
 151
 152 sub printcmd {
 153     my $fh = shift @_;
 154     my $intro = shift @_;
 155     print $fh $intro," " or die $!;
 156     print $fh shellquote @_ or die $!;
 157     print $fh "\n" or die $!;
 158 }
 159
 160 sub debugcmd {
 161     my $extraprefix = shift @_;
 162     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 163 }
 164
 165 sub dep14_version_mangle ($) {
 166     my ($v) = @_;
 167     # DEP-14 patch proposed 2016-11-09  "Version Mangling"
 168     $v =~ y/~:/_%/;
 169     $v =~ s/\.(?=\.|$|lock$)/.#/g;
 170     return $v;
 171 }
 172
 173 sub debiantag_old ($$) {
 174     my ($v,$distro) = @_;
 175     return "$distro/". dep14_version_mangle $v;
 176 }
 177
 178 sub debiantag_new ($$) {
 179     my ($v,$distro) = @_;
 180     return "archive/$distro/".dep14_version_mangle $v;
 181 }
 182
 183 sub debiantags ($$) {
 184     my ($version,$distro) = @_;
 185     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 186 }
 187
 188 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 189 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 190
 191 sub stat_exists ($) {
 192     my ($f) = @_;
 193     return 1 if stat $f;
 194     return 0 if $!==&ENOENT;
 195     die "stat $f: $!";
 196 }
 197
 198 sub _us () {
 199     $::us // ($0 =~ m#[^/]*$#, $&);
 200 }
 201
 202 sub fail {
 203     my $s = "@_\n";
 204     $s =~ s/\n\n$/\n/;
 205     my $prefix = _us().": ";
 206     $s =~ s/^/$prefix/gm;
 207     die $s;
 208 }
 209
 210 sub ensuredir ($) {
 211     my ($dir) = @_; # does not create parents
 212     return if mkdir $dir;
 213     return if $! == EEXIST;
 214     die "mkdir $dir: $!";
 215 }
 216
 217 sub executable_on_path ($) {
 218     my ($program) = @_;
 219     return 1 if $program =~ m{/};
 220     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 221     foreach my $pe (@path) {
 222         my $here = "$pe/$program";
 223         return $here if stat_exists $here && -x _;
 224     }
 225     return undef;
 226 }
 227
 228 our @signames = split / /, $Config{sig_name};
 229
 230 sub waitstatusmsg () {
 231     if (!$?) {
 232         return "terminated, reporting successful completion";
 233     } elsif (!($? & 255)) {
 234         return "failed with error exit status ".WEXITSTATUS($?);
 235     } elsif (WIFSIGNALED($?)) {
 236         my $signum=WTERMSIG($?);
 237         return "died due to fatal signal ".
 238             ($signames[$signum] // "number $signum").
 239             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 240     } else {
 241         return "failed with unknown wait status ".$?;
 242     }
 243 }
 244
 245 sub failedcmd_report_cmd {
 246     my $intro = shift @_;
 247     $intro //= "failed command";
 248     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or die $!; };
 249 }
 250
 251 sub failedcmd_waitstatus {
 252     if ($? < 0) {
 253         return "failed to fork/exec: $!";
 254     } elsif ($?) {
 255         return "subprocess ".waitstatusmsg();
 256     } else {
 257         return "subprocess produced invalid output";
 258     }
 259 }
 260
 261 sub failedcmd {
 262     # Expects $!,$? as set by close - see below.
 263     # To use with system(), set $?=-1 first.
 264     #
 265     # Actual behaviour of perl operations:
 266     #   success              $!==0       $?==0       close of piped open
 267     #   program failed       $!==0       $? >0       close of piped open
 268     #   syscall failure      $! >0       $?=-1       close of piped open
 269     #   failure              $! >0       unchanged   close of something else
 270     #   success              trashed     $?==0       system
 271     #   program failed       trashed     $? >0       system
 272     #   syscall failure      $! >0       unchanged   system
 273     failedcmd_report_cmd undef, @_;
 274     fail failedcmd_waitstatus();
 275 }
 276
 277 sub cmdoutput_errok {
 278     confess Dumper(\@_)." ?" if grep { !defined } @_;
 279     debugcmd "|",@_;
 280     open P, "-|", @_ or die "$_[0] $!";
 281     my $d;
 282     $!=0; $?=0;
 283     { local $/ = undef; $d = <P>; }
 284     die $! if P->error;
 285     if (!close P) { printdebug "=>!$?\n"; return undef; }
 286     chomp $d;
 287     if ($debuglevel > 0) {
 288         $d =~ m/^.*/;
 289         my $dd = $&;
 290         my $more = (length $' ? '...' : ''); #');
 291         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 292         printdebug "=> \`$dd'",$more,"\n";
 293     }
 294     return $d;
 295 }
 296
 297 sub cmdoutput {
 298     my $d = cmdoutput_errok @_;
 299     defined $d or failedcmd @_;
 300     return $d;
 301 }
 302
 303 sub link_ltarget ($$) {
 304     my ($old,$new) = @_;
 305     lstat $old or return undef;
 306     if (-l _) {
 307         $old = cmdoutput qw(realpath  --), $old;
 308     }
 309     my $r = link $old, $new;
 310     $r = symlink $old, $new if !$r && $!==EXDEV;
 311     $r or die "(sym)link $old $new: $!";
 312 }
 313
 314 sub hashfile ($) {
 315     my ($fn) = @_;
 316     my $h = Digest::SHA->new(256);
 317     $h->addfile($fn);
 318     return $h->hexdigest();
 319 }
 320
 321 sub git_rev_parse ($) {
 322     return cmdoutput qw(git rev-parse), "$_[0]~0";
 323 }
 324
 325 sub git_cat_file ($) {
 326     my ($objname) = @_;
 327     # => ($type, $data) or ('missing', undef)
 328     # in scalar context, just the data
 329     our ($gcf_pid, $gcf_i, $gcf_o);
 330     if (!$gcf_pid) {
 331         my @cmd = qw(git cat-file --batch);
 332         debugcmd "GCF|", @cmd;
 333         $gcf_pid = open2 $gcf_o, $gcf_i, @cmd or die $!;
 334     }
 335     printdebug "GCF>| ", $objname, "\n";
 336     print $gcf_i $objname, "\n" or die $!;
 337     my $x = <$gcf_o>;
 338     printdebug "GCF<| ", $x;
 339     if ($x =~ m/ (missing)$/) { return ($1, undef); }
 340     my ($type, $size) = $x =~ m/^.* (\w+) (\d+)\n/ or die "$objname ?";
 341     my $data;
 342     (read $gcf_o, $data, $size) == $size or die "$objname $!";
 343     $x = <$gcf_o>;
 344     $x eq "\n" or die "$objname ($_) $!";
 345     return ($type, $data);
 346 }
 347
 348 sub git_for_each_ref ($$;$) {
 349     my ($pattern,$func,$gitdir) = @_;
 350     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 351     # $reftail is RHS of ref after refs/[^/]+/
 352     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 353     # $pattern may be an array ref to mean multiple patterns
 354     $pattern = [ $pattern ] unless ref $pattern;
 355     my @cmd = (qw(git for-each-ref), @$pattern);
 356     if (defined $gitdir) {
 357         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 358     }
 359     open GFER, "-|", @cmd or die $!;
 360     debugcmd "|", @cmd;
 361     while (<GFER>) {
 362         chomp or die "$_ ?";
 363         printdebug "|> ", $_, "\n";
 364         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 365         $func->($1,$2,$3,$4);
 366     }
 367     $!=0; $?=0; close GFER or die "$pattern $? $!";
 368 }
 369
 370 sub git_get_ref ($) {
 371     # => '' if no such ref
 372     my ($refname) = @_;
 373     local $_ = $refname;
 374     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 375     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 376 }
 377
 378 sub git_for_each_tag_referring ($$) {
 379     my ($objreferring, $func) = @_;
 380     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 381     printdebug "git_for_each_tag_referring ",
 382         ($objreferring // 'UNDEF'),"\n";
 383     git_for_each_ref('refs/tags', sub {
 384         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 385         return unless $objtype eq 'tag';
 386         my $refobjid = git_rev_parse $tagobjid;
 387         return unless
 388             !defined $objreferring # caller wants them all
 389             or $tagobjid eq $objreferring
 390             or $refobjid eq $objreferring;
 391         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 392     });
 393 }
 394
 395 sub is_fast_fwd ($$) {
 396     my ($ancestor,$child) = @_;
 397     my @cmd = (qw(git merge-base), $ancestor, $child);
 398     my $mb = cmdoutput_errok @cmd;
 399     if (defined $mb) {
 400         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 401     } else {
 402         $?==256 or failedcmd @cmd;
 403         return 0;
 404     }
 405 }
 406
 407 1;