Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31 use IPC::Open2;
  32 use File::Path;
  33 use File::Basename;
  34
  35 BEGIN {
  36     use Exporter   ();
  37     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  38
  39     $VERSION     = 1.00;
  40     @ISA         = qw(Exporter);
  41     @EXPORT      = qw(setup_sigwarn forkcheck_setup forkcheck_mainprocess
  42                       dep14_version_mangle
  43                       debiantags debiantag_old debiantag_new
  44                       server_branch server_ref
  45                       stat_exists link_ltarget
  46                       hashfile
  47                       fail ensuredir must_getcwd executable_on_path
  48                       waitstatusmsg failedcmd_waitstatus
  49                       failedcmd_report_cmd failedcmd
  50                       runcmd cmdoutput cmdoutput_errok
  51                       git_rev_parse git_cat_file
  52                       git_get_ref git_get_symref git_for_each_ref
  53                       git_for_each_tag_referring is_fast_fwd
  54                       git_check_unmodified
  55                       $package_re $component_re $deliberately_re
  56                       $distro_re $versiontag_re $series_filename_re
  57                       $extra_orig_namepart_re
  58                       $branchprefix
  59                       initdebug enabledebug enabledebuglevel
  60                       printdebug debugcmd
  61                       $debugprefix *debuglevel *DEBUG
  62                       shellquote printcmd messagequote
  63                       $negate_harmful_gitattrs
  64                       changedir git_slurp_config_src
  65                       playtree_setup);
  66     # implicitly uses $main::us
  67     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO NOCOMMITCHECK)],
  68                      playground => [qw(record_maindir $maindir $local_git_cfg
  69                                        $maindir_gitdir $maindir_gitcommon
  70                                        fresh_playground
  71                                        ensure_a_playground)]);
  72     @EXPORT_OK   = ( @{ $EXPORT_TAGS{policyflags} },
  73                      @{ $EXPORT_TAGS{playground} } );
  74 }
  75
  76 our @EXPORT_OK;
  77
  78 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  79 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  80 our $deliberately_re = "(?:TEST-)?$package_re";
  81 our $distro_re = $component_re;
  82 our $versiontag_re = qr{[-+.\%_0-9a-zA-Z/]+};
  83 our $branchprefix = 'dgit';
  84 our $series_filename_re = qr{(?:^|\.)series(?!\n)$}s;
  85 our $extra_orig_namepart_re = qr{[-0-9a-z]+};
  86
  87 # policy hook exit status bits
  88 # see dgit-repos-server head comment for documentation
  89 # 1 is reserved in case something fails with `exit 1' and to spot
  90 # dynamic loader, runtime, etc., failures, which report 127 or 255
  91 sub NOFFCHECK () { return 0x2; }
  92 sub FRESHREPO () { return 0x4; }
  93 sub NOCOMMITCHECK () { return 0x8; }
  94
  95 our $debugprefix;
  96 our $debuglevel = 0;
  97
  98 our $negate_harmful_gitattrs = "-text -eol -crlf -ident -filter";
  99
 100 our $forkcheck_mainprocess;
 101
 102 sub forkcheck_setup () {
 103     $forkcheck_mainprocess = $$;
 104 }
 105
 106 sub forkcheck_mainprocess () {
 107     # You must have called forkcheck_setup or setup_sigwarn already
 108     getppid != $forkcheck_mainprocess;
 109 }
 110
 111 sub setup_sigwarn () {
 112     forkcheck_setup();
 113     $SIG{__WARN__} = sub {
 114         confess $_[0] if forkcheck_mainprocess;
 115     };
 116 }
 117
 118 sub initdebug ($) {
 119     ($debugprefix) = @_;
 120     open DEBUG, ">/dev/null" or die $!;
 121 }
 122
 123 sub enabledebug () {
 124     open DEBUG, ">&STDERR" or die $!;
 125     DEBUG->autoflush(1);
 126     $debuglevel ||= 1;
 127 }
 128
 129 sub enabledebuglevel ($) {
 130     my ($newlevel) = @_; # may be undef (eg from env var)
 131     die if $debuglevel;
 132     $newlevel //= 0;
 133     $newlevel += 0;
 134     return unless $newlevel;
 135     $debuglevel = $newlevel;
 136     enabledebug();
 137 }
 138
 139 sub printdebug {
 140     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 141 }
 142
 143 sub messagequote ($) {
 144     local ($_) = @_;
 145     s{\\}{\\\\}g;
 146     s{\n}{\\n}g;
 147     s{\x08}{\\b}g;
 148     s{\t}{\\t}g;
 149     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 150     $_;
 151 }
 152
 153 sub shellquote {
 154     my @out;
 155     local $_;
 156     defined or confess 'internal error' foreach @_;
 157     foreach my $a (@_) {
 158         $_ = $a;
 159         if (!length || m{[^-=_./:0-9a-z]}i) {
 160             s{['\\]}{'\\$&'}g;
 161             push @out, "'$_'";
 162         } else {
 163             push @out, $_;
 164         }
 165     }
 166     return join ' ', @out;
 167 }
 168
 169 sub printcmd {
 170     my $fh = shift @_;
 171     my $intro = shift @_;
 172     print $fh $intro," " or die $!;
 173     print $fh shellquote @_ or die $!;
 174     print $fh "\n" or die $!;
 175 }
 176
 177 sub debugcmd {
 178     my $extraprefix = shift @_;
 179     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 180 }
 181
 182 sub dep14_version_mangle ($) {
 183     my ($v) = @_;
 184     # DEP-14 patch proposed 2016-11-09  "Version Mangling"
 185     $v =~ y/~:/_%/;
 186     $v =~ s/\.(?=\.|$|lock$)/.#/g;
 187     return $v;
 188 }
 189
 190 sub debiantag_old ($$) {
 191     my ($v,$distro) = @_;
 192     return "$distro/". dep14_version_mangle $v;
 193 }
 194
 195 sub debiantag_new ($$) {
 196     my ($v,$distro) = @_;
 197     return "archive/$distro/".dep14_version_mangle $v;
 198 }
 199
 200 sub debiantags ($$) {
 201     my ($version,$distro) = @_;
 202     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 203 }
 204
 205 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 206 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 207
 208 sub stat_exists ($) {
 209     my ($f) = @_;
 210     return 1 if stat $f;
 211     return 0 if $!==&ENOENT;
 212     die "stat $f: $!";
 213 }
 214
 215 sub _us () {
 216     $::us // ($0 =~ m#[^/]*$#, $&);
 217 }
 218
 219 sub fail {
 220     my $s = "@_\n";
 221     $s =~ s/\n\n$/\n/;
 222     my $prefix = _us().": ";
 223     $s =~ s/^/$prefix/gm;
 224     die $s;
 225 }
 226
 227 sub ensuredir ($) {
 228     my ($dir) = @_; # does not create parents
 229     return if mkdir $dir;
 230     return if $! == EEXIST;
 231     die "mkdir $dir: $!";
 232 }
 233
 234 sub must_getcwd () {
 235     my $d = getcwd();
 236     defined $d or fail "getcwd failed: $!";
 237     return $d;
 238 }
 239
 240 sub executable_on_path ($) {
 241     my ($program) = @_;
 242     return 1 if $program =~ m{/};
 243     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 244     foreach my $pe (@path) {
 245         my $here = "$pe/$program";
 246         return $here if stat_exists $here && -x _;
 247     }
 248     return undef;
 249 }
 250
 251 our @signames = split / /, $Config{sig_name};
 252
 253 sub waitstatusmsg () {
 254     if (!$?) {
 255         return "terminated, reporting successful completion";
 256     } elsif (!($? & 255)) {
 257         return "failed with error exit status ".WEXITSTATUS($?);
 258     } elsif (WIFSIGNALED($?)) {
 259         my $signum=WTERMSIG($?);
 260         return "died due to fatal signal ".
 261             ($signames[$signum] // "number $signum").
 262             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 263     } else {
 264         return "failed with unknown wait status ".$?;
 265     }
 266 }
 267
 268 sub failedcmd_report_cmd {
 269     my $intro = shift @_;
 270     $intro //= "failed command";
 271     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or die $!; };
 272 }
 273
 274 sub failedcmd_waitstatus {
 275     if ($? < 0) {
 276         return "failed to fork/exec: $!";
 277     } elsif ($?) {
 278         return "subprocess ".waitstatusmsg();
 279     } else {
 280         return "subprocess produced invalid output";
 281     }
 282 }
 283
 284 sub failedcmd {
 285     # Expects $!,$? as set by close - see below.
 286     # To use with system(), set $?=-1 first.
 287     #
 288     # Actual behaviour of perl operations:
 289     #   success              $!==0       $?==0       close of piped open
 290     #   program failed       $!==0       $? >0       close of piped open
 291     #   syscall failure      $! >0       $?=-1       close of piped open
 292     #   failure              $! >0       unchanged   close of something else
 293     #   success              trashed     $?==0       system
 294     #   program failed       trashed     $? >0       system
 295     #   syscall failure      $! >0       unchanged   system
 296     failedcmd_report_cmd undef, @_;
 297     fail failedcmd_waitstatus();
 298 }
 299
 300 sub runcmd {
 301     debugcmd "+",@_;
 302     $!=0; $?=-1;
 303     failedcmd @_ if system @_;
 304 }
 305
 306 sub cmdoutput_errok {
 307     confess Dumper(\@_)." ?" if grep { !defined } @_;
 308     debugcmd "|",@_;
 309     open P, "-|", @_ or die "$_[0] $!";
 310     my $d;
 311     $!=0; $?=0;
 312     { local $/ = undef; $d = <P>; }
 313     die $! if P->error;
 314     if (!close P) { printdebug "=>!$?\n"; return undef; }
 315     chomp $d;
 316     if ($debuglevel > 0) {
 317         $d =~ m/^.*/;
 318         my $dd = $&;
 319         my $more = (length $' ? '...' : ''); #');
 320         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 321         printdebug "=> \`$dd'",$more,"\n";
 322     }
 323     return $d;
 324 }
 325
 326 sub cmdoutput {
 327     my $d = cmdoutput_errok @_;
 328     defined $d or failedcmd @_;
 329     return $d;
 330 }
 331
 332 sub link_ltarget ($$) {
 333     my ($old,$new) = @_;
 334     lstat $old or return undef;
 335     if (-l _) {
 336         $old = cmdoutput qw(realpath  --), $old;
 337     }
 338     my $r = link $old, $new;
 339     $r = symlink $old, $new if !$r && $!==EXDEV;
 340     $r or die "(sym)link $old $new: $!";
 341 }
 342
 343 sub hashfile ($) {
 344     my ($fn) = @_;
 345     my $h = Digest::SHA->new(256);
 346     $h->addfile($fn);
 347     return $h->hexdigest();
 348 }
 349
 350 sub git_rev_parse ($) {
 351     return cmdoutput qw(git rev-parse), "$_[0]~0";
 352 }
 353
 354 sub git_cat_file ($;$) {
 355     my ($objname, $etype) = @_;
 356     # => ($type, $data) or ('missing', undef)
 357     # in scalar context, just the data
 358     # if $etype defined, dies unless type is $etype or in @$etype
 359     our ($gcf_pid, $gcf_i, $gcf_o);
 360     my $chk = sub {
 361         my ($gtype, $data) = @_;
 362         if ($etype) {
 363             $etype = [$etype] unless ref $etype;
 364             confess "$objname expected @$etype but is $gtype"
 365                 unless grep { $gtype eq $_ } @$etype;
 366         }
 367         return ($gtype, $data);
 368     };
 369     if (!$gcf_pid) {
 370         my @cmd = qw(git cat-file --batch);
 371         debugcmd "GCF|", @cmd;
 372         $gcf_pid = open2 $gcf_o, $gcf_i, @cmd or die $!;
 373     }
 374     printdebug "GCF>| ", $objname, "\n";
 375     print $gcf_i $objname, "\n" or die $!;
 376     my $x = <$gcf_o>;
 377     printdebug "GCF<| ", $x;
 378     if ($x =~ m/ (missing)$/) { return $chk->($1, undef); }
 379     my ($type, $size) = $x =~ m/^.* (\w+) (\d+)\n/ or die "$objname ?";
 380     my $data;
 381     (read $gcf_o, $data, $size) == $size or die "$objname $!";
 382     $x = <$gcf_o>;
 383     $x eq "\n" or die "$objname ($_) $!";
 384     return $chk->($type, $data);
 385 }
 386
 387 sub git_get_symref (;$) {
 388     my ($symref) = @_;  $symref //= 'HEAD';
 389     # => undef if not a symref, otherwise refs/...
 390     my @cmd = (qw(git symbolic-ref -q HEAD));
 391     my $branch = cmdoutput_errok @cmd;
 392     if (!defined $branch) {
 393         $?==256 or failedcmd @cmd;
 394     } else {
 395         chomp $branch;
 396     }
 397     return $branch;
 398 }
 399
 400 sub git_for_each_ref ($$;$) {
 401     my ($pattern,$func,$gitdir) = @_;
 402     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 403     # $reftail is RHS of ref after refs/[^/]+/
 404     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 405     # $pattern may be an array ref to mean multiple patterns
 406     $pattern = [ $pattern ] unless ref $pattern;
 407     my @cmd = (qw(git for-each-ref), @$pattern);
 408     if (defined $gitdir) {
 409         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 410     }
 411     open GFER, "-|", @cmd or die $!;
 412     debugcmd "|", @cmd;
 413     while (<GFER>) {
 414         chomp or die "$_ ?";
 415         printdebug "|> ", $_, "\n";
 416         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 417         $func->($1,$2,$3,$4);
 418     }
 419     $!=0; $?=0; close GFER or die "$pattern $? $!";
 420 }
 421
 422 sub git_get_ref ($) {
 423     # => '' if no such ref
 424     my ($refname) = @_;
 425     local $_ = $refname;
 426     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 427     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 428 }
 429
 430 sub git_for_each_tag_referring ($$) {
 431     my ($objreferring, $func) = @_;
 432     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 433     printdebug "git_for_each_tag_referring ",
 434         ($objreferring // 'UNDEF'),"\n";
 435     git_for_each_ref('refs/tags', sub {
 436         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 437         return unless $objtype eq 'tag';
 438         my $refobjid = git_rev_parse $tagobjid;
 439         return unless
 440             !defined $objreferring # caller wants them all
 441             or $tagobjid eq $objreferring
 442             or $refobjid eq $objreferring;
 443         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 444     });
 445 }
 446
 447 sub git_check_unmodified () {
 448     foreach my $cached (qw(0 1)) {
 449         my @cmd = qw(git diff --quiet);
 450         push @cmd, qw(--cached) if $cached;
 451         push @cmd, qw(HEAD);
 452         debugcmd "+",@cmd;
 453         $!=0; $?=-1; system @cmd;
 454         return if !$?;
 455         if ($?==256) {
 456             fail
 457                 $cached
 458                 ? "git index contains changes (does not match HEAD)"
 459                 : "working tree is dirty (does not match HEAD)";
 460         } else {
 461             failedcmd @cmd;
 462         }
 463     }
 464 }
 465
 466 sub is_fast_fwd ($$) {
 467     my ($ancestor,$child) = @_;
 468     my @cmd = (qw(git merge-base), $ancestor, $child);
 469     my $mb = cmdoutput_errok @cmd;
 470     if (defined $mb) {
 471         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 472     } else {
 473         $?==256 or failedcmd @cmd;
 474         return 0;
 475     }
 476 }
 477
 478 sub changedir ($) {
 479     my ($newdir) = @_;
 480     printdebug "CD $newdir\n";
 481     chdir $newdir or confess "chdir: $newdir: $!";
 482 }
 483
 484 sub git_slurp_config_src ($) {
 485     my ($src) = @_;
 486     # returns $r such that $r->{KEY}[] = VALUE
 487     my @cmd = (qw(git config -z --get-regexp), "--$src", qw(.*));
 488     debugcmd "|",@cmd;
 489
 490     local ($debuglevel) = $debuglevel-2;
 491     local $/="\0";
 492
 493     my $r = { };
 494     open GITS, "-|", @cmd or die $!;
 495     while (<GITS>) {
 496         chomp or die;
 497         printdebug "=> ", (messagequote $_), "\n";
 498         m/\n/ or die "$_ ?";
 499         push @{ $r->{$`} }, $'; #';
 500     }
 501     $!=0; $?=0;
 502     close GITS
 503         or ($!==0 && $?==256)
 504         or failedcmd @cmd;
 505     return $r;
 506 }
 507
 508 # ========== playground handling ==========
 509
 510 # terminology:
 511 #
 512 #   $maindir      user's git working tree
 513 #   playground    area in .git/ where we can make files, unpack, etc. etc.
 514 #   playtree      git working tree sharing object store with the user's
 515 #                 inside playground, or identical to it
 516 #
 517 # other globals
 518 #
 519 #   $local_git_cfg    hash of arrays of values: git config from $maindir
 520 #
 521 # expected calling pattern
 522 #
 523 #  firstly
 524 #
 525 #    [record_maindir]
 526 #      must be run in directory containing .git
 527 #      assigns to $maindir if not already set
 528 #      also calls git_slurp_config_src to record git config
 529 #        in $local_git_cfg, unless it's already set
 530 #
 531 #    fresh_playground SUBDIR_PATH_COMPONENTS
 532 #      e.g fresh_playground 'dgit/unpack' ('.git/' is implied)
 533 #      default SUBDIR_PATH_COMPONENTS is playground_subdir
 534 #      calls record_maindir
 535 #      sets up a new playground (destroying any old one)
 536 #      returns playground pathname
 537 #      caller may call multiple times with different subdir paths
 538 #       createing different playgrounds
 539 #
 540 #    ensure_a_playground SUBDIR_PATH_COMPONENTS
 541 #      like fresh_playground except:
 542 #      merely ensures the directory exists; does not delete an existing one
 543 #
 544 #  then can use
 545 #
 546 #    changedir playground
 547 #    changedir $maindir
 548 #
 549 #    playtree_setup $local_git_cfg
 550 #            # ^ call in some (perhaps trivial) subdir of playground
 551 #
 552 #    rmtree playground
 553
 554 # ----- maindir -----
 555
 556 # these three all go together
 557 our $maindir;
 558 our $maindir_gitdir;
 559 our $maindir_gitcommon;
 560
 561 our $local_git_cfg;
 562
 563 sub record_maindir () {
 564     if (!defined $maindir) {
 565         $maindir = must_getcwd();
 566         if (!stat "$maindir/.git") {
 567             fail "cannot stat $maindir/.git: $!";
 568         }
 569         if (-d _) {
 570             # we fall back to this in case we have a pre-worktree
 571             # git, which may not know git rev-parse --git-common-dir
 572             $maindir_gitdir    = "$maindir/.git";
 573             $maindir_gitcommon = "$maindir/.git";
 574         } else {
 575             $maindir_gitdir    = cmdoutput qw(git rev-parse --git-dir);
 576             $maindir_gitcommon = cmdoutput qw(git rev-parse --git-common-dir);
 577         }
 578     }
 579     $local_git_cfg //= git_slurp_config_src 'local';
 580 }
 581
 582 # ----- playgrounds -----
 583
 584 sub ensure_a_playground_parent ($) {
 585     my ($spc) = @_;
 586     record_maindir();
 587     $spc = "$maindir_gitdir/$spc";
 588     my $parent = dirname $spc;
 589     mkdir $parent or $!==EEXIST
 590         or fail "failed to mkdir playground parent $parent: $!";
 591     return $spc;
 592 }
 593
 594 sub ensure_a_playground ($) {
 595     my ($spc) = @_;
 596     $spc = ensure_a_playground_parent $spc;
 597     mkdir $spc or $!==EEXIST or fail "failed to mkdir a playground $spc: $!";
 598     return $spc;
 599 }
 600
 601 sub fresh_playground ($) {
 602     my ($spc) = @_;
 603     $spc = ensure_a_playground_parent $spc;
 604     rmtree $spc;
 605     mkdir $spc or fail "failed to mkdir the playground $spc: $!";
 606     return $spc;
 607 }
 608
 609 # ----- playtrees -----
 610
 611 sub playtree_setup (;$) {
 612     my ($t_local_git_cfg) = @_;
 613     $t_local_git_cfg //= $local_git_cfg;
 614     # for use in the playtree
 615     # $maindir must be set, eg by calling record_maindir or fresh_playground
 616     runcmd qw(git init -q);
 617     runcmd qw(git config gc.auto 0);
 618     foreach my $copy (qw(user.email user.name user.useConfigOnly
 619                          core.sharedRepository
 620                          core.compression core.looseCompression
 621                          core.bigFileThreshold core.fsyncObjectFiles)) {
 622         my $v = $t_local_git_cfg->{$copy};
 623         next unless $v;
 624         runcmd qw(git config), $copy, $_ foreach @$v;
 625     }
 626     # this is confusing: we have
 627     #   .                   playtree, not a worktree, has .git/, our cwd
 628     #   $maindir            might be a worktree so
 629     #   $maindir_gitdir     contains our main working "dgit", HEAD, etc.
 630     #   $maindir_gitcommon  the shared stuff, including .objects
 631     rmtree('.git/objects');
 632     symlink "$maindir_gitcommon/objects",'.git/objects' or die $!;
 633     ensuredir '.git/info';
 634     open GA, "> .git/info/attributes" or die $!;
 635     print GA "* $negate_harmful_gitattrs\n" or die $!;
 636     close GA or die $!;
 637 }
 638
 639 1;