Debian/Dgit.pm

   1 # -*- perl -*-
   2
   3 package Debian::Dgit;
   4
   5 use strict;
   6 use warnings;
   7
   8 use POSIX;
   9 use IO::Handle;
  10 use Config;
  11 use Digest::SHA;
  12
  13 BEGIN {
  14     use Exporter   ();
  15     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  16
  17     $VERSION     = 1.00;
  18     @ISA         = qw(Exporter);
  19     @EXPORT      = qw(setup_sigwarn
  20                       debiantag server_branch server_ref
  21                       stat_exists link_ltarget
  22                       hashfile
  23                       fail ensuredir executable_on_path
  24                       waitstatusmsg failedcmd
  25                       cmdoutput cmdoutput_errok
  26                       git_rev_parse git_get_ref git_for_each_ref
  27                       git_for_each_tag_referring is_fast_fwd
  28                       $package_re $component_re $deliberately_re
  29                       $branchprefix
  30                       initdebug enabledebug enabledebuglevel
  31                       printdebug debugcmd
  32                       $debugprefix *debuglevel *DEBUG
  33                       shellquote printcmd messagequote);
  34     # implicitly uses $main::us
  35     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  36     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  37 }
  38
  39 our @EXPORT_OK;
  40
  41 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  42 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  43 our $deliberately_re = "(?:TEST-)?$package_re";
  44 our $branchprefix = 'dgit';
  45
  46 # policy hook exit status bits
  47 # see dgit-repos-server head comment for documentation
  48 # 1 is reserved in case something fails with `exit 1' and to spot
  49 # dynamic loader, runtime, etc., failures, which report 127 or 255
  50 sub NOFFCHECK () { return 0x2; }
  51 sub FRESHREPO () { return 0x4; }
  52
  53 our $debugprefix;
  54 our $debuglevel = 0;
  55
  56 sub setup_sigwarn () {
  57     our $sigwarn_mainprocess = $$;
  58     $SIG{__WARN__} = sub {
  59         die $_[0] unless getppid == $sigwarn_mainprocess;
  60     };
  61 }
  62
  63 sub initdebug ($) {
  64     ($debugprefix) = @_;
  65     open DEBUG, ">/dev/null" or die $!;
  66 }
  67
  68 sub enabledebug () {
  69     open DEBUG, ">&STDERR" or die $!;
  70     DEBUG->autoflush(1);
  71     $debuglevel ||= 1;
  72 }
  73
  74 sub enabledebuglevel ($) {
  75     my ($newlevel) = @_; # may be undef (eg from env var)
  76     die if $debuglevel;
  77     $newlevel //= 0;
  78     $newlevel += 0;
  79     return unless $newlevel;
  80     $debuglevel = $newlevel;
  81     enabledebug();
  82 }
  83
  84 sub printdebug {
  85     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
  86 }
  87
  88 sub messagequote ($) {
  89     local ($_) = @_;
  90     s{\\}{\\\\}g;
  91     s{\n}{\\n}g;
  92     s{\x08}{\\b}g;
  93     s{\t}{\\t}g;
  94     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
  95     $_;
  96 }
  97
  98 sub shellquote {
  99     my @out;
 100     local $_;
 101     foreach my $a (@_) {
 102         $_ = $a;
 103         if (!length || m{[^-=_./:0-9a-z]}i) {
 104             s{['\\]}{'\\$&'}g;
 105             push @out, "'$_'";
 106         } else {
 107             push @out, $_;
 108         }
 109     }
 110     return join ' ', @out;
 111 }
 112
 113 sub printcmd {
 114     my $fh = shift @_;
 115     my $intro = shift @_;
 116     print $fh $intro," " or die $!;
 117     print $fh shellquote @_ or die $!;
 118     print $fh "\n" or die $!;
 119 }
 120
 121 sub debugcmd {
 122     my $extraprefix = shift @_;
 123     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 124 }
 125
 126 sub debiantag ($$) {
 127     my ($v,$distro) = @_;
 128     $v =~ y/~:/_%/;
 129     return "$distro/$v";
 130 }
 131
 132 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 133 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 134
 135 sub stat_exists ($) {
 136     my ($f) = @_;
 137     return 1 if stat $f;
 138     return 0 if $!==&ENOENT;
 139     die "stat $f: $!";
 140 }
 141
 142 sub _us () {
 143     $::us // ($0 =~ m#[^/]*$#, $&);
 144 }
 145
 146 sub fail {
 147     my $s = "@_\n";
 148     my $prefix = _us().": ";
 149     $s =~ s/^/$prefix/gm;
 150     die $s;
 151 }
 152
 153 sub ensuredir ($) {
 154     my ($dir) = @_; # does not create parents
 155     return if mkdir $dir;
 156     return if $! == EEXIST;
 157     die "mkdir $dir: $!";
 158 }
 159
 160 sub executable_on_path ($) {
 161     my ($program) = @_;
 162     return 1 if $program =~ m{/};
 163     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 164     foreach my $pe (@path) {
 165         my $here = "$pe/$program";
 166         return $here if stat_exists $here && -x _;
 167     }
 168     return undef;
 169 }
 170
 171 our @signames = split / /, $Config{sig_name};
 172
 173 sub waitstatusmsg () {
 174     if (!$?) {
 175         return "terminated, reporting successful completion";
 176     } elsif (!($? & 255)) {
 177         return "failed with error exit status ".WEXITSTATUS($?);
 178     } elsif (WIFSIGNALED($?)) {
 179         my $signum=WTERMSIG($?);
 180         return "died due to fatal signal ".
 181             ($signames[$signum] // "number $signum").
 182             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 183     } else {
 184         return "failed with unknown wait status ".$?;
 185     }
 186 }
 187
 188 sub failedcmd {
 189     { local ($!); printcmd \*STDERR, _us().": failed command:", @_ or die $!; };
 190     if ($!) {
 191         fail "failed to fork/exec: $!";
 192     } elsif ($?) {
 193         fail "subprocess ".waitstatusmsg();
 194     } else {
 195         fail "subprocess produced invalid output";
 196     }
 197 }
 198
 199 sub cmdoutput_errok {
 200     die Dumper(\@_)." ?" if grep { !defined } @_;
 201     debugcmd "|",@_;
 202     open P, "-|", @_ or die "$_[0] $!";
 203     my $d;
 204     $!=0; $?=0;
 205     { local $/ = undef; $d = <P>; }
 206     die $! if P->error;
 207     if (!close P) { printdebug "=>!$?\n"; return undef; }
 208     chomp $d;
 209     if ($debuglevel > 0) {
 210         $d =~ m/^.*/;
 211         my $dd = $&;
 212         my $more = (length $' ? '...' : ''); #');
 213         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 214         printdebug "=> \`$dd'",$more,"\n";
 215     }
 216     return $d;
 217 }
 218
 219 sub cmdoutput {
 220     my $d = cmdoutput_errok @_;
 221     defined $d or failedcmd @_;
 222     return $d;
 223 }
 224
 225 sub link_ltarget ($$) {
 226     my ($old,$new) = @_;
 227     lstat $old or return undef;
 228     if (-l _) {
 229         $old = cmdoutput qw(realpath  --), $old;
 230     }
 231     link $old, $new or die "link $old $new: $!";
 232 }
 233
 234 sub hashfile ($) {
 235     my ($fn) = @_;
 236     my $h = Digest::SHA->new(256);
 237     $h->addfile($fn);
 238     return $h->hexdigest();
 239 }
 240
 241 sub git_rev_parse ($) {
 242     return cmdoutput qw(git rev-parse), "$_[0]~0";
 243 }
 244
 245 sub git_for_each_ref ($$;$) {
 246     my ($pattern,$func,$gitdir) = @_;
 247     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 248     # $reftail is RHS of ref after refs/[^/]+/
 249     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 250     my @cmd = (qw(git for-each-ref), $pattern);
 251     if (defined $gitdir) {
 252         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 253     }
 254     open GFER, "-|", @cmd or die $!;
 255     debugcmd "|", @cmd;
 256     while (<GFER>) {
 257         chomp or die "$_ ?";
 258         printdebug "|> ", $_, "\n";
 259         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 260         $func->($1,$2,$3,$4);
 261     }
 262     $!=0; $?=0; close GFER or die "$pattern $? $!";
 263 }
 264
 265 sub git_get_ref ($) {
 266     # => '' if no such ref
 267     my ($refname) = @_;
 268     local $_ = $refname;
 269     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 270     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 271 }
 272
 273 sub git_for_each_tag_referring ($$) {
 274     my ($objreferring, $func) = @_;
 275     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 276     printdebug "git_for_each_tag_referring ",
 277         ($objreferring // 'UNDEF'),"\n";
 278     git_for_each_ref('refs/tags', sub {
 279         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 280         return unless $objtype eq 'tag';
 281         my $refobjid = git_rev_parse $tagobjid;
 282         return unless
 283             !defined $objreferring # caller wants them all
 284             or $tagobjid eq $objreferring
 285             or $refobjid eq $objreferring;
 286         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 287     });
 288 }
 289
 290 sub is_fast_fwd ($$) {
 291     my ($ancestor,$child) = @_;
 292     my @cmd = (qw(git merge-base), $ancestor, $child);
 293     my $mb = cmdoutput_errok @cmd;
 294     if (defined $mb) {
 295         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 296     } else {
 297         $?==256 or failedcmd @cmd;
 298         return 0;
 299     }
 300 }
 301
 302 1;