update-xfonts-traditional

   1 #!/usr/bin/perl -w
   2 use strict;
   3 use POSIX;
   4 use IO::File;
   5 use Getopt::Long;
   6 use File::Glob qw(:glob);
   7 use Data::Dumper;
   8 use IO::Pipe;
   9 use File::Find;
  10 use Sys::CPU;
  11
  12 our $prefix="/usr/local";
  13 our $package='xfonts-traditional';
  14 our $sharedir="$prefix/share/$package";
  15 our @fonttrees=qw(/usr/share/fonts/X11 /usr/local/share/fonts/X11);
  16 our $donefile="$package.done";
  17 our $logfile="$package.log";
  18 our $fontprefix="trad--";
  19 our @rulespath;
  20 our $mode;
  21 our %foundrymap;
  22 our $verbose=0;
  23 our $reportfh;
  24 our $foundryinfo;
  25 our %props;
  26 our $wanted_parallel;
  27
  28 sub reportloaded {
  29     return unless $verbose;
  30     print $reportfh @_,"\n" or die $!;
  31 }
  32
  33 sub statsummary () {
  34     return join ' ', ((stat _)[1,7,9,10]);
  35 }
  36
  37 sub loadrules ($) {
  38     my ($key) = @_;
  39     our %cache;
  40     my $fc=$cache{$key};
  41     return $fc if $fc;
  42     foreach my $path (@rulespath) {
  43         my $script="$path/$key.rules";
  44         $!=0; $@=''; my $f = do $script;
  45         if (defined $f) {
  46             reportloaded("rules: loaded ",$script);
  47             $cache{$key}=$f;
  48             return $f;
  49         }
  50         die "$! $? $script" unless $! == &ENOENT;
  51     }
  52     return $cache{$key}=undef;
  53 }
  54
  55 sub processbdf ($$$$) {
  56     my ($inbdf,$outbdf,$logfile,$what) = @_;
  57     my $state='idle';
  58     my ($foundry,$font);
  59     my ($w,$h,$xo,$yo,$y,$bitmap,$glyph);
  60     my $modified=0;
  61     %props = ();
  62     my $anyinput=0;
  63     while (<$inbdf>) {
  64         $anyinput=1;
  65         if ($state eq 'bitmap' && $y==$h) {
  66             $glyph = uc $glyph;
  67             $glyph =~ s/\;$//;
  68             local ($_) = $glyph;
  69             my $key= sprintf "%s,%d,%d,%d,%d", $foundry,$w,$h,$xo,$yo;
  70             my $rules= loadrules($key);
  71             return 'no rules' if !$rules;
  72             $rules->();
  73             $modified += ($_ ne $glyph);
  74             print $outbdf $_,"\n" or die $!
  75                 foreach split /\;/, $_; # /;
  76             $state='idle';
  77         }
  78         if ($state eq 'bitmap') {
  79             m/^([0-9a-fA-F]+)\s+$/ or die $y;
  80             length($1) == (($w+7 >> 3) << 1) or die "$1 $w";
  81             $glyph .= "$1;";
  82             $y++;
  83             next;
  84         }
  85         if ($state eq 'idle' && m/^FOUNDRY\s+/) {
  86             die if defined $foundry;
  87             return 'foundry syntax' unless m/^FOUNDRY\s+\"(\w+)\"\s+/;
  88             $foundry = $foundrymap{lc $1};
  89             return 'no foundry' unless defined $foundry;
  90             $_ = "FOUNDRY \"$foundry\"\n";
  91         }
  92         if ($state eq 'idle' && m/^FONT\s+/) {
  93             die if defined $font;
  94             return 'simple font name' unless m/^(FONT\s+)\-(\w+)\-/;
  95             $font = $foundrymap{lc $2};
  96             return 'no foundry' unless defined $font;
  97             $_ = "FONT -$font-$'";
  98         }
  99         if ($state eq 'idle' && m/^STARTCHAR\s/) {
 100             die unless defined $foundry;
 101             die unless defined $font;
 102             return 'foundry != font' unless $foundry eq $font;
 103             $state='startchar';
 104             $w=undef;
 105         }
 106         if (($state eq 'idle' || $state eq 'startchar') &&
 107             m/^([A-Z_]+)\s+(.*\S)\s+$/) {
 108             $props{$1}=$2;
 109         }
 110         if ($state eq 'startchar') {
 111             if (m/^BBX\s+(\+?\d+)\s+(\+?\d+)\s+([-+]?\d+)\s+([-+]?\d+)\s+$/) {
 112                 ($w,$h,$xo,$yo) = ($1,$2,$3,$4);
 113             }
 114             if (m/^BITMAP\s+$/) {
 115                 die unless defined $w;
 116                 $y=0;
 117                 $glyph='';
 118                 $state='bitmap';
 119                 $props{' 7bit'}=
 120                     ($props{'CHARSET_REGISTRY'} =~ m/iso8859|utf|iso10646/i &&
 121                      $props{'ENCODING'} <= 127);
 122             }
 123         }
 124         print $outbdf $_ or die $!;
 125     }
 126     die $! if $inbdf->error;
 127     die $! if $outbdf->error or !$outbdf->flush;
 128     die unless $state eq 'idle';
 129     return 'no bdf data' # also special cased in processpcfgz
 130         if !$anyinput;
 131     if ($modified) {
 132         printf $logfile "%s: %d glyphs changed\n", $what, $modified
 133             or die $!;
 134     } else {
 135         printf $logfile "%s: unchanged - no rules matched\n", $what
 136             or die $!;
 137     }
 138     return $modified;
 139 }
 140
 141 sub loadfoundries () {
 142     $foundryinfo = '';
 143     foreach my $path (@rulespath) {
 144         if (!stat $path) {
 145             die "$path $!" unless $!==&ENOENT;
 146             next;
 147         }
 148         $foundryinfo .= statsummary().' '.$path."\0\n";
 149
 150         my $p = "$path/foundries";
 151         my $f = new IO::File $p;
 152         if (!$f) {
 153             die "$p $!" unless $!==&ENOENT;
 154             print $reportfh "foundries: none in $p\n" or die $! if $verbose;
 155             next;
 156         }
 157         stat $f or die $!;
 158         while (<$f>) {
 159             s/^\s*//; s/\s+$//;
 160             next if m/^\#/;
 161             m/^(\w+)\s+(\w+)$/ or die;
 162             my $k = lc $1;
 163             next if exists $foundrymap{$k};
 164             $foundrymap{$k}=$2;
 165         }
 166         $f->error and die $!;
 167         reportloaded('foundries: loaded ',$p);
 168     }
 169     die "no foundry maps\n" unless %foundrymap;
 170 }
 171
 172 sub processpcfgz ($$$$) {
 173     my ($inpcfgz,$outpcfgz,$logfile,$what) = @_;
 174     print $reportfh "processing $inpcfgz to $outpcfgz\n" if $verbose>=2;
 175     my $current = new IO::File $inpcfgz, '<' or die "$inpcfgz $!";
 176     my ($usread,$uswrite);
 177     my ($reader,$writer);
 178     my @children;
 179     foreach my $proc (['gunzip'], ['pcf2bdf'], [],
 180                       ['bdftopcf'],['',qw(gzip -1 -n)]) {
 181         my $isfinal = (@$proc && $proc->[0] eq '');
 182         if (!$isfinal) {
 183             $reader = new IO::Handle or die $!;
 184             $writer = new IO::Handle or die $!;
 185             new IO::Pipe($reader,$writer) or die $!;
 186         } else {
 187             shift @$proc;
 188             $reader = undef;
 189             $writer = new IO::File $outpcfgz, '>' or die "$outpcfgz $!";
 190         }
 191         if (@$proc) {
 192             my $exe = $proc->[0];
 193             my $child = fork;  defined $child or die $!;
 194             if (!$child) {
 195                 open STDIN, '<&', $current or die $!;
 196                 open STDOUT, '>&', $writer or die $!;
 197                 if (!$isfinal) {
 198                     close $reader or die $!;
 199                 }
 200                 close $usread or die $! if $usread;
 201                 close $uswrite or die $! if $uswrite;
 202                 exec $exe @$proc or die "$exe $!";
 203             }
 204             push @children, [ $child, $exe, defined $usread ];
 205             close $current or die $!;
 206             close $writer or die $!;
 207             $current = $reader;
 208         } else {
 209             $usread = $current;
 210             $uswrite = $writer;
 211             $current = $reader;
 212         }
 213     }
 214     my $r = processbdf($usread,$uswrite,$logfile,$what);
 215     my $none = $r !~ m/^\d/;
 216     if ($none) {
 217         flush $uswrite or die $!;
 218     } else {
 219         close $uswrite or die $!;
 220     }
 221     close $usread or die $!;
 222     foreach my $chinfo (@children) {
 223         my ($child,$exe,$isoutput)=@$chinfo;
 224         my $sigok = 0;
 225         if ($none) {
 226             if ($isoutput) {
 227                 $sigok = 9;
 228                 kill 9, $child or die "$child $!";
 229             } else {
 230                 $sigok = 13;
 231             }
 232         }
 233         $!=0; waitpid($child, 0) == $child or die "$child $!";
 234         !$? or ($?&~128)==$sigok or die "$exe [$child] $sigok $?";
 235     }
 236     return $r;
 237 }
 238
 239 sub processfontdir ($) {
 240     my ($fontdir) = @_;
 241     if (!opendir FD, $fontdir) {
 242         die "$fontdir $!" unless $!==&ENOENT;
 243         return;
 244     }
 245     my $changed = 0;
 246     my $olddone = do "$fontdir/$donefile";
 247     if (!$olddone) {
 248         die "$fontdir $! $@ " unless $!==&ENOENT;
 249     } elsif ($olddone->{''} ne $foundryinfo) {
 250         our $repro_reported;
 251         print $reportfh "reprocessing fonts (rules updated)\n" or die $!
 252             unless $repro_reported++;
 253         $olddone = undef;
 254     }
 255     if (!$olddone) {
 256         $olddone = { };
 257         $changed = 1;
 258     }
 259     my $newdone = { '' => $foundryinfo };
 260     my %outfiles; # bitmask: 1 /*exists*/ | 2 /*wanted*/
 261     my $updated=0;
 262     my $reported=0;
 263     my $anypcfs=0;
 264
 265     my $logpath = "$fontdir/$logfile";
 266     unlink "$logpath" or $!==&ENOENT or die "$logpath $!";
 267     my $log = new IO::File $logpath, ">>" or die "$logpath $!";
 268
 269     if (!$wanted_parallel) {
 270         $wanted_parallel = Sys::CPU::cpu_count();
 271         printf $reportfh "parallelism: %d\n", $wanted_parallel if $verbose>=2;
 272     }
 273     $wanted_parallel = 1 if $wanted_parallel < 1;
 274
 275     our %inprogress;
 276
 277     my $await = sub {
 278         my $child = wait;
 279         die $! unless defined $child;
 280         my $job = $inprogress{$child};
 281         die $child unless $job;
 282
 283         my $dent = $job->{Dent};
 284         my $outdent = $job->{Outdent};
 285         my $stats = $job->{Stats};
 286         if ($?==0) {
 287             $updated++;
 288             $outfiles{$outdent} |= 3;
 289         } elsif ($?==2*256) {
 290         } else {
 291             die "update-xfonts-traditional: processing of".
 292                 " $fontdir/$dent [$child] failed ($?)\n";
 293         }
 294         $newdone->{$dent} = $stats;
 295         $changed = 1;
 296         delete $inprogress{$child};
 297     };
 298
 299     flush $reportfh or die $!;
 300     while (my $dent = scalar readdir FD) {
 301         if ($dent =~ m/^\Q$fontprefix\E.*\.new$/) {
 302             unlink "$fontdir/$dent" or $!==&ENOENT or die "$fontdir $dent $!";
 303             next;
 304         }
 305         next unless $dent =~ m/^[^.\/].*\.pcf\.gz$/;
 306         print $reportfh "processing $fontdir...\n" or die $!
 307             unless $reported++;
 308         if ($dent =~ m/^\Q$fontprefix/) {
 309             $outfiles{$dent} |= 1;
 310             next;
 311         }
 312         if (!stat "$fontdir/$dent") {
 313             die "$fontdir $dent $!" unless $!==&ENOENT;
 314             next;
 315         }
 316         die "$fontdir $dent" unless -f _;
 317         $anypcfs++;
 318
 319         my $stats = statsummary();
 320         my $tdone = $olddone->{$dent};
 321         my $outdent = $fontprefix.$dent;
 322         if (defined $tdone && $tdone eq $stats) {
 323             $outfiles{$outdent} |= 2;
 324             $newdone->{$dent} = $stats;
 325             next;
 326         }
 327
 328         $await->() while scalar keys %inprogress >= $wanted_parallel;
 329
 330         my $child = fork;  die unless defined $child;
 331         if (!$child) {
 332             my $r = processpcfgz("$fontdir/$dent",
 333                                  "$fontdir/$outdent.new",
 334                                  $log, $dent);
 335             my $rc;
 336             if ($r !~ m/^\d/) {
 337                 printf $log "%s: unchanged - %s\n", $dent, $r;
 338                 unlink "$fontdir/$outdent.new" or die "$fontdir $outdent $!";
 339                 $rc = 2;
 340             } else {
 341                 rename "$fontdir/$outdent.new", "$fontdir/$outdent"
 342                     or die "$fontdir $outdent $!";
 343                 $rc = 0;
 344             }
 345             $log->flush or die "$logpath $!";
 346             exit $rc;
 347         }
 348         $inprogress{$child} = {
 349             Dent => $dent,
 350             Outdent => $outdent,
 351             Stats => $stats,
 352         };
 353     }
 354     $await->() while scalar keys %inprogress;
 355
 356     my $affected=0;
 357     foreach my $olddent (keys %outfiles) {
 358         my $state = $outfiles{$olddent};
 359         if ($state & 2) {
 360             $affected++ if $state & 1;
 361             next;
 362         }
 363         unlink "$fontdir/$olddent" or die "$fontdir $olddent $!";
 364         $changed = 1;
 365         $updated++;
 366     }
 367     if (!stat "$fontdir/fonts.dir") {
 368         $!==&ENOENT or die "$fontdir $!";
 369     } else {
 370         $!=0; $?=0; system 'mkfontdir',$fontdir;
 371         die "$fontdir $? $!" if $? or $!;
 372     }
 373     if (!$anypcfs) {
 374         unlink "$logpath" or die "$fontdir $!";
 375         unlink "$fontdir/$donefile" or $!==&ENOENT or die "$fontdir $!";
 376     } elsif ($changed) {
 377         my $newdoneh = new IO::File "$fontdir/$donefile.new", 'w'
 378             or die "$fontdir $!";
 379         print $newdoneh Dumper($newdone) or die "$fontdir $!";
 380         close $newdoneh or die "$fontdir $!";
 381         rename "$fontdir/$donefile.new","$fontdir/$donefile"
 382             or die "$fontdir $!";
 383     }
 384     if ($reported || %$newdone || $affected || $updated) {
 385         printf " processed %s: %d pcfs, %d affected, %d updated.\n",
 386             $fontdir, (scalar keys %$newdone), $affected, $updated;
 387     }
 388 }
 389
 390 sub processfonttree ($) {
 391     my ($tree) = @_;
 392     find({ follow => 1,
 393            dangling_symlinks => 0,
 394            no_chdir => 1,
 395            wanted => sub {
 396                return unless -d _;
 397                processfontdir($File::Find::name);
 398            }},
 399          $tree);
 400 }
 401
 402 our $stdin = new IO::File '<&STDIN' or die $!;
 403 our $stdout = new IO::File '>&STDOUT' or die $!;
 404 our $stderr = new IO::File '>&STDERR' or die $!;
 405 $reportfh = $stdout;
 406
 407 our (@options)=(
 408     'R|rules-include=s@' => \@rulespath,
 409     'share-dir=s' => \$sharedir,
 410     'verbose|v+' => \$verbose,
 411     'j|parallel=i' => \$wanted_parallel,
 412     );
 413
 414 sub define_mode ($$) {
 415     my ($optname,$f) = @_;
 416     push @options, $optname, sub {
 417         die "only one mode may be specified\n" if defined $mode;
 418         $mode=$f;
 419     };
 420 }
 421
 422 define_mode('bdf-filter', sub {
 423     die "no arguments allowed with --bdf-filter\n" if @ARGV;
 424     $reportfh = $stderr;
 425     loadfoundries();
 426     my $r = processbdf($stdin,$stdout,$reportfh,'stdin');
 427     if ($r !~ m/^\d/) {
 428         print STDERR "stdin not processed: $r\n";
 429         exit 2;
 430     }
 431 });
 432
 433 define_mode('process-pcf', sub {
 434     die "need source and destination pcf.gz\n" if @ARGV!=2;
 435     loadfoundries();
 436     my $r = processpcfgz($ARGV[0],$ARGV[1],$reportfh,"pcf");
 437     if ($r !~ m/^\d/) {
 438         print STDERR "pcf not processed: $r\n";
 439         exit 2;
 440     }
 441 });
 442
 443 define_mode('process-fontdirs', sub {
 444     die "need font dir(s)\n" unless @ARGV;
 445     loadfoundries();
 446     foreach my $d (@ARGV) {
 447         processfontdir($d);
 448     }
 449 });
 450
 451 define_mode('process-fonttrees', sub {
 452     die "need font tree(s)\n" unless @ARGV;
 453     loadfoundries();
 454     foreach my $d (@ARGV) {
 455         processfonttree($d);
 456     }
 457 });
 458
 459 define_mode('update', sub {
 460     die "no arguments allowed with --postinst\n" unless !@ARGV;
 461     loadfoundries();
 462     foreach my $d (@fonttrees) {
 463         processfonttree($d);
 464     }
 465 });
 466
 467 Getopt::Long::Configure(qw(bundling));
 468 GetOptions(@options) or exit 127;
 469
 470 push @rulespath, "$sharedir/rules";
 471
 472 die "need a mode\n" unless $mode;
 473
 474 $mode->();