ipif/udptunnel-vpn-config.m4

   1 m4_dnl udptunnel-vpn-config.m4: macros for udptunnel-reconf et al
   2
   3 m4_dnl This is free software; you can redistribute it and/or modify it
   4 m4_dnl under the terms of the GNU General Public License as published by
   5 m4_dnl the Free Software Foundation; either version 2 of the License, or
   6 m4_dnl (at your option) any later version.
   7 m4_dnl
   8 m4_dnl This program is distributed in the hope that it will be useful, but
   9 m4_dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  10 m4_dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11 m4_dnl General Public License for more details.
  12 m4_dnl
  13 m4_dnl You should have received a copy of the GNU General Public License
  14 m4_dnl along with userv-utils; if not, write to the Free Software
  15 m4_dnl Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  16 m4_dnl
  17 m4_dnl $Id$
  18
  19 m4_define(V_JUNK,1)m4_divert(V_JUNK)
  20 m4_define(V_VARIABLE,2)
  21 m4_define(V_ACTIVES,3)
  22 m4_define(V_PASSIVES,4)
  23 m4_changequote([,])
  24
  25 m4_define(V_WARGS, [
  26  m4_define([$1], [m4_ifelse($][#,$2,[$3],
  27   [# ]m4___file__:m4___line__[: wrong number of args to $1])])])
  28
  29 V_WARGS([SET], 2, [V_SET([V_$1], [$2])])
  30 m4_define(V_YES, [m4_define([V_SET],[m4_define($][@)])])
  31 m4_define(V_NO, [m4_define([V_SET], [])])
  32
  33 m4_define(V_ACTPA, [
  34  V_WARGS($1, 1, [m4_divert(V_$1S)$][1 m4_dnl
  35  m4_divert(V_JUNK)m4_ifelse($][1,V_site,
  36   [V_YES],
  37   [V_NO]
  38 )])])
  39
  40 m4_dnl   V_WARGS(, 2, [m4_divert(V_PASSIVES)$1 m4_dnl
  41 m4_dnl   m4_divert(V_JUNK)m4_ifelse([$1],V_site, [$2])])
  42
  43 m4_divert(V_JUNK)
  44
  45 V_YES
  46 m4_include(V_defaults)
  47
  48 V_WARGS(SITE, 1, [m4_ifelse([$1],V_site, [V_YES], [V_NO])])
  49 V_YES
  50 m4_include(V_sites)
  51 m4_undefine([SITE])
  52
  53 V_ACTPA(ACTIVE)
  54 V_ACTPA(PASSIVE)
  55 V_YES
  56 m4_include(V_tunnels)
  57
  58 V_YES
  59 m4_include(V_global)
  60
  61 m4_divert(V_VARIABLE)
  62 WHVARIABLE
  63 m4_divert(V_JUNK)
  64
  65 m4_define(V_WANTED, V_[]WANTED)
  66 m4_divert(0)
  67 m4_undivert(V_WANTED)
  68 m4_divert(-1)
  69 m4_undivert(V_JUNK)
  70 m4_undivert(V_ACTIVES)
  71 m4_undivert(V_PASSIVES)
  72 m4_undivert(V_VARIABLE)