generate-board

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Carp;
   5 use Data::Dumper;
   6 use Math::GSL::Vector qw/:all/;
   7 use Math::GSL::Matrix qw/:all/;
   8 use Math::GSL::Const;
   9 use Math::GSL::BLAS qw/:all/;
  10 use Math::GSL::CBLAS qw/:all/;
  11 use Math::GSL::Machine qw/:all/;
  12
  13 use POSIX qw(M_PI);
  14
  15 BEGIN { unshift @INC, qw(.); }
  16
  17 use Parse;
  18
  19 our $xopts = '';
  20 our $bounding = 'Entire';
  21 our $facesf;
  22 our %vxname2pos; # $vxname2pos{VXNAME} = Math::GSL::Vector
  23 our %bb; # $r{Bounding...}[0..3] = points
  24 our $maxpaper = 'a3';
  25
  26 sub TAU { M_PI * 2.0; }
  27 sub MM2PT { 72.0 / 25.4; }
  28
  29 our $mid;
  30
  31 our $a4_w = 595;
  32 our $a4_h = 842;
  33 our $a3_h = 1190;
  34 our $a1_w = 1684;
  35 our $a1_h = 2384;
  36
  37 our $max_printeredge = 5.50 * MM2PT;
  38 our $a1m_pasteedge = 3.5 * MM2PT; # along each edge
  39 our $preamble_from_boundings = '';
  40
  41 # ----- region names from plag, incl. reverse mapping -----
  42
  43 our %prs2region;
  44
  45 sub prep_region_rmap () {
  46   foreach my $rn (keys %region) {
  47     my $prs = plag_prs($rn);
  48     die if $prs2region{$prs};
  49     $prs2region{$prs} = $rn;
  50   }
  51 }
  52
  53 our $sre = qr{(?:(\")|(?=\w))(.*)\1$}; # 2 captures, $2 is the name
  54
  55 sub prs2r ($) {
  56   # bodgery for the sea and land
  57   return 'NZ' if m/ \| / && !grep { !m{^(?:NZ|L2?)$} } split / \| /, $_[0];
  58   $prs2region{$_[0]} // confess "@_ ?"
  59 }
  60 sub prs2rr ($) { $region{prs2r($_[0])} }
  61
  62 #----- file reader for plag output -----
  63
  64 sub read_faces () {
  65   # Sets
  66   #  $region{NAME}{Adj}[]{Ends}[]{VxName}
  67   #  $region{NAME}{Adj}[]{Ends}[]{Pos}
  68   #  $region{NAME}{Polygon}{Pos}
  69   #  $region{NAME}{Special}
  70   #
  71   # also incidentally
  72   #  $region{NAME}{Adj}[]{Ends}[]{Adjoins}
  73   #  $region{NAME}{Polygon}{Adjoins}
  74   # which should be ignored
  75
  76   open P, "<", $facesf or die $!;
  77   while (<P>) { last if m/^\&faces$/; }
  78   my $rr;
  79   my @edges;
  80   my $process_rr = sub {
  81     my $last_ai;
  82     if ($rr->{Name} eq 'NZ') {
  83       # We combined L and NZ; now we must split them again
  84       # in fact, we just throw away L and L2 entirely.
  85       # Here, when processing NZ, we keep only vertices that
  86       # are part of NZ.
  87       @edges = grep {
  88         my $evxname = $_->{VxName};
  89         my @eregions = split / \| ?/, $evxname;
  90         grep { $_ eq 'NZ' } @eregions
  91       } @edges;
  92     }
  93     $rr->{Polygon} = [ @edges ];
  94     if ($rr->{Name} ne 'NZ') {
  95       for my $ei (0..$#edges) {
  96         if (!defined $last_ai) {
  97           my $ai;
  98           for my $ai (0..$#{ $rr->{Adj} }) {
  99             next unless $rr->{Adj}[$ai]{Name} eq $edges[$ei]{Adjoins};
 100             $last_ai = $ai+1;
 101           }
 102           confess $edges[$ei]{Adjoins}.' ?' unless defined $last_ai;
 103         }
 104         my $ai = ($last_ai-1+@edges) % @edges;
 105         $last_ai = $ai;
 106         my $adj = $rr->{Adj}[$ai];
 107         confess Dumper($adj->{Name}, $edges[$ei]{Adjoins},
 108                        $rr, \@edges, $ei, $adj, $last_ai, $ai)." ?"
 109             unless $adj->{Name} eq $edges[$ei]{Adjoins};
 110
 111         for my $endi (0..1) {
 112           $adj->{Ends}[$endi] = $edges[ ($ei + $endi) % @edges ];
 113         }
 114       }
 115     }
 116     @edges = ();
 117     $rr = undef;
 118   };
 119   my $vxname;
 120   for (;;) {
 121     $!=0; $_=<P> // confess $!;
 122     last if m/^\&$/;
 123     if (m/^$sre$/) {
 124       my $new_face= $2;
 125       $process_rr->() if $rr;
 126       $rr= prs2rr($new_face);
 127     } elsif (m/^\s+$sre$/) {
 128       confess unless $rr;
 129       $vxname = $2;
 130       push @edges, { VxName => $vxname };
 131     } elsif (m/^\s+\^adjoins\s+$sre$/) {
 132       $edges[-1]{Adjoins} = prs2r($2);
 133     } elsif (m/^\s+\^\@([-e.0-9]+)\,([-e.0-9]+)$/) {
 134       my $pos = mkvec($1,$2);
 135       confess unless defined $vxname;
 136       $edges[-1]{Pos} = $pos;
 137       $vxname2pos{$vxname} = $pos;
 138     }
 139   }
 140   $process_rr->();
 141
 142   $region{$_}{Special} = 1 foreach qw(NZ L L2);
 143 }
 144
 145 #----- geometry mangling -----
 146
 147 sub adj_ends ($) {
 148   my ($adj) = @_;
 149   map { $_->{Pos} } @{ $adj->{Ends} };
 150 }
 151
 152 sub calculate_centres () {
 153   # Sets
 154   #  $region{NAME}{Centre}
 155   foreach my $rr (values %region) {
 156     next if $rr->{Special};
 157     my $sum = Math::GSL::Vector->new(2);
 158     my $wsum = 0;
 159     foreach my $adj (@{ $rr->{Adj} }) {
 160       my @ends = adj_ends($adj);
 161       my $w = ($ends[1] - $ends[0])->norm();
 162       $sum += $w * $_ foreach @ends;
 163       $wsum += $w;
 164     }
 165     $rr->{Centre} = $sum * (0.5 / $wsum);
 166   }
 167 }
 168
 169 sub for_each_pos ($) {
 170   my ($f) = @_;
 171   my $call = sub {
 172     my ($pr,$rr,$why) = @_;
 173     return unless defined $$pr;
 174     $f->($pr,$rr,$why);
 175   };
 176   foreach my $rr (values %region) {
 177     $call->( \ $rr->{Centre}, $rr, $rr->{Name}." C" );
 178     foreach my $vertex (@{ $rr->{Polygon} }) {
 179       $call->( \ $vertex->{Pos}, $rr, $rr->{Name}." | ".$vertex->{Adjoins} );
 180     }
 181   }
 182 }
 183
 184 sub prvec ($) {
 185   my ($v) = @_;
 186   confess unless $v;
 187   sprintf "%g,%g", $v->get(0), $v->get(1);
 188 }
 189
 190 sub mkvec ($$) { Math::GSL::Vector->new(\@_) }
 191 sub vec2atan ($) { my ($dir) = @_; atan2 $dir->get(1), $dir->get(0); }
 192
 193 sub transform_coordinates () {
 194   # Adjusts coordinates in graph to be [0,0] .. top right (scaled)
 195   # until it's all in PostScript points
 196   my @or = map { $region{$_}{Centre} } @{ $c{OrientRegions} };
 197   my $dir = $or[1] - $or[0];
 198   my $theta = vec2atan($dir);
 199   my $rotateby = (90. - $c{OrientBearing}) * ((TAU)/360.) - $theta;
 200   my $s = sin($rotateby);
 201   my $c = cos($rotateby);
 202   my $transform = Math::GSL::Matrix->new(2,2);
 203   $transform->set_row(0, [  $c, -$s ]);
 204   $transform->set_row(1, [  $s,  $c ]);
 205   #  print STDERR "rotate was=",prvec($dir)," theta=$theta",
 206   #    " rotateby=$rotateby s=$s c=$c\n";
 207   my @lims;
 208   foreach my $topend (qw(0 1)) {
 209     my $v = $topend ? -$GSL_DBL_MAX : $GSL_DBL_MAX;
 210     $lims[$topend] = mkvec($v,$v);
 211   }
 212   for_each_pos(sub {
 213     my ($pr, $rr, $why) = @_;
 214     my $y = Math::GSL::Vector->new(2);
 215     gsl_blas_dgemv($CblasNoTrans,
 216                    1.0, $transform->raw,
 217                    $$pr->raw,
 218                    0, $y->raw)
 219         and confess;
 220     #print STDERR "gsl_blas_dgemv ",prvec($$pr)," => ",prvec($y),"\n";
 221     gsl_blas_dcopy($y->raw, $$pr->raw)
 222         and confess;
 223     foreach my $topend (qw(0 1)) {
 224       foreach my $xy (qw(0 1)) {
 225         my $now = $y->get($xy);
 226         my $lim = $lims[$topend]->get($xy);
 227         #print STDERR "?set $topend $xy $now $lim\n";
 228         next if $topend ? ($now <= $lim) : ($now >= $lim);
 229         $lims[$topend]->set([$xy], [$now]);
 230         #print STDERR "set $topend $xy $now\n";
 231       }
 232     }
 233   });
 234   #print STDERR "lims ",prvec($lims[0])," .. ",prvec($lims[1]),"\n";
 235   my $translate = -$lims[0];
 236   #print STDERR "translate ",prvec($translate),"\n";
 237   my $scale = $c{GraphScale} * MM2PT;
 238   for_each_pos(sub {
 239     my ($pr) = @_;
 240     gsl_vector_add($$pr->raw, $translate->raw) and confess;
 241     gsl_vector_scale($$pr->raw, $scale) and confess;
 242   });
 243   $mid = ($lims[1] - $lims[0]) * 0.5;
 244 }
 245
 246 sub adjust_nz() {
 247   my $poly = $region{NZ}{Polygon};
 248   my %occurs;
 249   foreach my $v (@$poly) {
 250     $occurs{$v->{VxName}}++
 251   }
 252   foreach my $v (@$poly) {
 253     $v->{NZ_Occurs} = $occurs{$v->{VxName}};
 254   }
 255   #print STDERR " nz ".(scalar @$poly)."\n";
 256   my $occurs_m = sub {
 257     my ($ei) = @_;
 258     $poly->[($ei+@$poly) % @$poly]{NZ_Occurs} > 1
 259   };
 260   for my $ei (0..$#$poly) {
 261     next if $occurs_m->($ei);
 262     next unless $occurs_m->($ei-1);
 263     next unless $occurs_m->($ei+1);
 264     #print STDERR " nz would adjust $poly->[$ei]{VxName}\n";
 265     # adjust coord outwards
 266   }
 267   for my $ei (0..$#$poly) {
 268     next unless $occurs_m->($ei);
 269     #print STDERR " nz occurs_m $ei $poly->[$ei]{VxName}\n";
 270     next unless $occurs_m->($ei-1);
 271     my $dleft = mkvec(-1000,0);
 272     foreach my $which (0,-1) {
 273       my $ej = ($ei +        $which + @$poly) % @$poly;
 274       my $ek = ($ei + +1 + 3*$which + @$poly) % @$poly;
 275       my $posj = \ $poly->[$ej]{Pos};
 276       my $posk = \ $poly->[$ek]{Pos};
 277       my $dout = $$posk - $$posj;
 278       #print STDERR " nz adj j=$ej ",prvec($$posj)," $poly->[$ej]{VxName}\n";
 279       #print STDERR " nz adj k=$ek ",prvec($$posk)," $poly->[$ek]{VxName}\n";
 280       if ($poly->[$ej]{VxName} =~ /Noorderzijlvest/) {
 281         #print STDERR " nz adj extra\n";
 282         $$posk = $$posj + 10 * mkvec(100,-50);
 283       }
 284       $$posj = $$posj + $dleft + $dout*10;
 285       $$posk = $$posk          + $dout*10;
 286     }
 287   }
 288 }
 289
 290 sub psvec ($) {
 291   my ($pos) = @_;
 292   sprintf "%20.6f %20.6f", $pos->get(0),$pos->get(1)
 293 }
 294
 295 sub face_path ($) {
 296   my ($rr) = @_;
 297   o("% $rr->{Name}\n");
 298   o("  newpath\n");
 299   my $xto = 'moveto';
 300   foreach my $vertex (@{ $rr->{Polygon} }) {
 301     my $pos = $vertex->{Pos};
 302     o(sprintf "    %s %s\n", psvec($pos), $xto);
 303     $xto = 'lineto';
 304   }
 305   o("    closepath\n");
 306 }
 307
 308 sub computeboundings() {
 309   $bb{Entire} = [ 0,0, $a4_h, $a4_w + $a3_h ];
 310   my $submargins = sub {
 311     my ($margin, $pr) = @_;
 312     my @p = @$pr;
 313     [ $p[0] + $margin,
 314       $p[1] + $margin,
 315       $p[2] - $margin,
 316       $p[3] - $margin ];
 317   };
 318   my $somepage = sub {
 319     my $id = shift @_;
 320     print STDERR "defining page Page$id\n";
 321     $bb{"Page$id"} = [ @_ ];
 322     $bb{"Printable$id"} = $submargins->($max_printeredge, $bb{"Page$id"});
 323   };
 324   my $pageb_a4 = sub {
 325     $somepage->('B', 0,0, $a4_h, $a4_w );
 326   };
 327   if ($maxpaper eq 'a3') {
 328     $pageb_a4->();
 329     my $mt_offset = $bb{PrintableB}[3] - $max_printeredge;
 330     $somepage->('MT', 0, $mt_offset, $a4_h, $mt_offset + $a3_h );
 331     $bb{PrintableAll} = [
 332                          @{ $bb{PrintableB} }[0..1],
 333                          @{ $bb{PrintableMT} }[2..3],
 334                         ];
 335   } elsif ($maxpaper eq 'a4') {
 336     $pageb_a4->();
 337     my $m_offset = $bb{PrintableB}[3] - $max_printeredge;
 338     $somepage->('M', 0, $m_offset, $a4_h, $m_offset + $a4_w );
 339     my $t_offset = $bb{PrintableM}[3] - $max_printeredge;
 340     $somepage->('T', 0, $t_offset, $a4_h, $t_offset + $a4_w );
 341     $bb{PrintableAll} = [
 342                          @{ $bb{PrintableB} }[0..1],
 343                          @{ $bb{PrintableT} }[2..3],
 344                         ];
 345   } elsif ($maxpaper =~ m/^a1/) {
 346     my $surround = 5 * MM2PT;
 347     my $surroundw = $bb{Entire}[2] + $surround*2;
 348     my $surroundh = $bb{Entire}[3] + $surround*2;
 349     $somepage->('P', 0,0, $a1_w, $a1_h);
 350     my $offx = 0.5*($bb{PageP}[2] - $bb{Entire}[2]);
 351     my $offy = 0.5*($bb{PageP}[3] - $bb{Entire}[3]);
 352     $bb{Entire}[0] += $offx;  $bb{Entire}[1] += $offy;
 353     $bb{Entire}[2] += $offx;  $bb{Entire}[3] += $offy;
 354     $preamble_from_boundings = <<END;
 355          $offx $offy translate
 356          -$surround -$surround moveto
 357           $surroundw 0         rlineto
 358           0 $surroundh         rlineto
 359           -$surroundw 0        rlineto
 360                  closepath clip
 361 END
 362     if ($maxpaper eq 'a1m') {
 363       $bb{Cutout} = $submargins->($a1m_pasteedge, $bb{Entire});
 364     }
 365   } else {
 366     confess;
 367   }
 368 }
 369
 370 sub showboundings () {
 371   return unless $xopts =~ m/B/;
 372   o("  grestore gsave\n");
 373   my $i = 0;
 374   my $on = 2;
 375   my $off = 9;
 376   foreach my $bname (sort keys %bb) {
 377     o(sprintf "   1 %d %d setrgbcolor\n",
 378       !!($bname =~ m/^Page/),
 379       !!($bname =~ m/B$/),
 380      );
 381     o("    % $bname\n");
 382     o("    [ $on $off ] ".($i * ($on+$off))," setdash newpath\n");
 383     my @p = @{ $bb{$bname} };
 384     o("    $p[0] $p[1] moveto\n");
 385     o("    $p[2] $p[1] lineto\n");
 386     o("    $p[2] $p[3] lineto\n");
 387     o("    $p[0] $p[3] lineto\n");
 388     o("    closepath stroke\n");
 389     $i++;
 390   }
 391 }
 392
 393 sub o_amble (@) {
 394   # CPerl-mode does a really awful thing with %s in the preamble
 395   # and postamble, causing constant useless flashing
 396   # So we write & in the here docs and transform them back:
 397   my ($t) = join '', @_;
 398   $t =~ s/^\&+/ '%' x length $& /mge;
 399   o($t);
 400 }
 401
 402 sub preamble() {
 403   my $bb = $bb{$bounding}; confess $bounding unless $bb;
 404   my $sz = [ $bb->[2] - $bb->[0], $bb->[3] - $bb->[1] ];
 405   o_amble(<<END);
 406 &!PS-Adobe-3.0
 407 &&BoundingBox @$bb
 408 &&Pages: 1
 409 &&EndComments
 410 &&BeginProlog
 411 &&EndProlog
 412 &&BeginSetup
 413 << /PageSize [ @$sz ] >> setpagedevice
 414 /board {
 415   gsave
 416 $preamble_from_boundings
 417   34 -15 translate
 418 END
 419   if ($maxpaper eq 'a4') {
 420     o("0 -17 translate\n");
 421   }
 422   # xxx split into pages
 423 }
 424
 425 sub postamble () {
 426   o_amble(<<END);
 427   grestore
 428 } bind def
 429 &&EndSetup
 430 &&Page: 1
 431 &&BeginPageSetup
 432 /pgsave save def
 433 &&EndPageSetup
 434 board
 435 pgsave restore
 436 showpage
 437 &&EOF
 438 END
 439 }
 440
 441 sub pscolour ($$$$) {
 442   my ($colourname, $cmykix,$rgbmul,$rgbadd) = @_;
 443   my $spec = $c{Colours}{$colourname};
 444   confess unless defined $spec;
 445
 446   # check that we have only one lighter/darker retain value for each one
 447   our %colour_occurred;
 448   $colour_occurred{$colourname}{$cmykix}{$rgbmul,$rgbadd} = 1;
 449   keys %{ $colour_occurred{$colourname}{$cmykix} } == 1 or confess;
 450
 451   my @r;
 452   my $rw;
 453   if ($spec =~ m/^[0-9a-f]+$/) {
 454     my $le = (length $spec)/3;
 455     my $re = ("(.{$le})") x 3;
 456     my @rgb = $spec =~ m/^$re$/;  @rgb or confess "$re ?";
 457     @rgb = map { hex($_) / (16**$le -1) } @rgb;
 458     foreach (@rgb) { $_ *= $rgbmul; $_ += $rgbadd; }
 459     @r = @rgb;
 460     $rw = 'setrgbcolor';
 461   } elsif ($spec =~ m/[CMYK]/) {
 462     my @specs = split /\//, $spec;
 463     if ($cmykix==1 && @specs==1) {
 464       $spec = $specs[0];
 465     } else {
 466       $spec = $specs[$cmykix];
 467       confess unless defined $spec;
 468     }
 469     my %cmyk;
 470     foreach (split /(?=[A-Z])/, $spec) {
 471       m/^([CMYK])([0-7](?:\.\d*)?|8)_?$/ or confess $_.' ?';
 472       confess if defined $cmyk{$1};
 473       $cmyk{$1} = $2 / 8.;
 474       #print STDERR " CMYK $1 $2\n";
 475     }
 476     @r = map { $cmyk{$_} // 0 } qw(C M Y K);
 477     $rw = 'setcmykcolor';
 478   } else {
 479     confess $spec.' ?';
 480   }
 481   my $r = join ' ',
 482       (map { sprintf "%.6f ", $_ } @r
 483       ),
 484           $rw;
 485   return $r;
 486 }
 487
 488 sub lighterpscolour ($$) {
 489   my ($colourname, $retain) = @_;
 490   #print STDERR "COLOUR LIGHTER $retain $colourname\n";
 491   pscolour($colourname, 0, $retain, 1-$retain);
 492 }
 493
 494 sub darkerpscolour ($$) {
 495   my ($colourname, $retain) = @_;
 496   #print STDERR "COLOUR DARKER $retain $colourname\n";
 497   pscolour($colourname, 2, $retain, 0);
 498 }
 499
 500 sub facepscolour ($) {
 501   my ($colourname) = @_;
 502   $xopts =~ m/W/ ? '1 setgray' : lighterpscolour($colourname, 0.75);
 503 }
 504
 505 sub miscpscolour ($) {
 506   my ($colourname) = @_;
 507   #print STDERR "COLOUR MISC $colourname\n";
 508   pscolour($colourname, 1, 1,0);
 509 }
 510
 511 sub seatrackedgepscolour () { darkerpscolour('cube', 0.25) }
 512
 513 sub fill_faces() {
 514   o("clippath ", facepscolour('land'), " fill\n");
 515   foreach my $rr (values %region) {
 516     next if $rr->{Name} =~ m/^L2?$/;
 517     face_path($rr);
 518     o(" ", facepscolour($rr->{Colour}), " eofill\n");
 519   }
 520 }
 521
 522 our $edge_lw = 5;
 523
 524 sub some_edge_faces (@) {
 525   o("$edge_lw setlinewidth 1 setlinejoin ",miscpscolour('edge'),"\n");
 526   foreach my $rr (@_) {
 527     next if $rr->{Name} =~ m/^L2?$/;
 528     face_path($rr);
 529     o("    stroke\n");
 530   }
 531 }
 532
 533 sub afsluitdijk() {
 534   my ($adj) = grep { $_->{Name} eq 'NZ' } @{ $region{'ZZ'}{Adj} };
 535   my $dash = 20;
 536   my (@pos) = adj_ends($adj);
 537   my $mid = 0.5 * ($pos[0] + $pos[1]);
 538   my $r = 0.5 * ($pos[1] - $pos[0])->norm();
 539   o(sprintf <<'END', facepscolour('sea'), psvec($mid), $r);
 540   %% Afsluitdijk
 541   %s %s %s 0 360 arc closepath fill
 542 END
 543   some_edge_faces(()); # just sets the colour
 544   o(sprintf <<END, map { psvec($_) } @pos);
 545   newpath %s moveto %s lineto
 546   [ $dash $dash ] $dash 0.5 mul setdash
 547   stroke
 548   [] 0 setdash
 549 END
 550   one_hs('purple', $mid);
 551 }
 552
 553 sub edge_faces() {
 554   some_edge_faces($region{'NZ'});
 555   afsluitdijk();
 556   some_edge_faces(grep {
 557     $_->{Name} !~ m{^(?:L2?|NZ|ZZ)$}
 558   } values %region);
 559 }
 560
 561 our $hs_sz = 17 * MM2PT;
 562 our $hs_lw = 3;
 563
 564 our $text_sz = 18;
 565
 566 sub token_circle ($$$$;$$) {
 567   my ($what, $pos, $fillcolour, $edgecolour, $sz,$lw) = @_;
 568   $sz //= $hs_sz;
 569   $lw //= $hs_lw;
 570   o(sprintf <<END, $what, $fillcolour, psvec($pos), $sz/2, $edgecolour);
 571    %% %s
 572    newpath %s
 573      %s %f 0 360 arc closepath gsave fill grestore
 574      %s $lw setlinewidth stroke
 575 END
 576 }
 577
 578 sub one_hs ($$;$$) {
 579   my ($colour, $hspos, $sz, $lw) = @_;
 580   token_circle("HS - $colour",
 581                $hspos,
 582                darkerpscolour($colour, 0.75),
 583                miscpscolour('edge'),
 584               $sz,$lw);
 585 }
 586
 587 our $cube_sz = 6 * MM2PT;
 588 our $cube_gap = $cube_sz * 0.2;
 589 our $cube_lw = ($cube_sz * 0.1);
 590
 591 sub label_faces() {
 592   my $sz = $text_sz;
 593   my $shadow = $sz * 0.1;
 594   my $textc   = miscpscolour('text');
 595   my $shadowc = miscpscolour('textshadow');
 596   o(<<END);
 597   /wordsshow {
 598     $shadowc 0 10 359 {
 599       dup  cos $shadow mul
 600       exch sin $shadow mul
 601       words pop pop
 602     } bind for
 603     $textc 0 0 words pop pop
 604   } def
 605 END
 606   o("  /Helvetica-Bold findfont  $sz scalefont setfont\n");
 607   my %hs = map { $_ => 1 } @{ $c{HS} };
 608   foreach my $rr (values %region) {
 609     next if $rr->{Name} =~ m/^L\d?$/;
 610     my $words = $rr->{DisplayName};
 611     my $pos;
 612     if ($rr->{Name} eq 'NZ') {
 613       $pos = mkvec(90, 1280);
 614     } else {
 615       $pos = $rr->{Centre} + mkvec( 0, 0.5 * $sz * @$words );
 616     }
 617     if ($hs{$rr->{Name}}) {
 618       #print STDERR "adjust hs $rr->{Name}\n";
 619       $pos -= mkvec(0, -$hs_sz*
 620                     ( $rr->{Colour} eq 'green' ? 0.25 : 0.65 ));
 621       my $hspos = $pos - mkvec(0, $sz * @$words + $hs_sz/2 + $hs_lw
 622                                + $hs_sz*0.15);
 623       one_hs($rr->{Colour}, $hspos);
 624     }
 625     my $adjust = $c{TextAdjust}{$rr->{Name}};
 626     if ($adjust) {
 627       $pos += $sz * &mkvec(@$adjust);
 628     }
 629     my $w = $rr->{Water};
 630     $w = 2 if $rr->{Special} || $rr->{Name} eq 'ZZ';
 631     if ($w) {
 632       #print STDERR " water $w in $rr->{Name}\n";
 633       my $down = water_cubes_sz(2) - water_cubes_sz(1) + $cube_gap;
 634       $pos -= mkvec(0, -0.5 * $down);
 635       my $cube_y = -($sz * @$words);
 636       if ($rr->{Name} eq 'Wieringermeer') {
 637         $pos -= mkvec(0,+$sz);
 638         $cube_y = 0;
 639         $down = 0;
 640       }
 641       o("  gsave\n");
 642       o("    ", psvec($pos), " translate\n");
 643       o("    0 ", $cube_y, " translate\n");
 644       o("    ", -0.5 * water_cubes_sz($w)," ", -$down, " translate\n");
 645       water_cubes($w, miscpscolour('edge'));
 646       o("  grestore\n");
 647     }
 648     o("  /words {\n");
 649     foreach my $word (@$words) {
 650       $pos += mkvec(0,-$sz);
 651       o("   ", psvec($pos), " moveto");
 652       o(<<END);
 653    2 copy rmoveto
 654    ($word) dup stringwidth pop     % word xw
 655      -0.5 mul 0 rmoveto             % word
 656      show
 657    0 -$sz rmoveto
 658 END
 659     }
 660     o(<<END);
 661   } bind def
 662   wordsshow
 663 END
 664   }
 665 }
 666
 667 sub water_cubes_sz($){
 668   my ($n) = @_;
 669   ($cube_sz + $cube_lw) * $n + ($cube_gap * ($n-1));
 670 }
 671
 672 sub water_cubes($$){
 673   my ($n, $edgecolour) = @_;
 674   my $s = $cube_sz;
 675   for my $i (0..$n-1) {
 676     o("  newpath  ", $i * ($cube_sz + $cube_lw + $cube_gap),"  0  moveto\n");
 677     o("          $s  0  rlineto\n");
 678     o("           0 $s  rlineto\n");
 679     o("         -$s  0  rlineto  closepath\n");
 680     o("  gsave ", miscpscolour('cube'), " fill grestore\n");
 681     o("  gsave ", $edgecolour, " ", $cube_lw,
 682       " setlinewidth stroke grestore \n");
 683   }
 684 }
 685
 686 my $deck_h = 89 * MM2PT;
 687
 688 sub decks(){
 689   my $lw = $edge_lw/2;
 690   o("  /deck1path {\n");
 691   my $w = 63 * MM2PT;
 692   my $h = $deck_h;
 693   my $r =  5 * MM2PT;
 694   o("      ",($w/2)," 0 moveto\n");
 695   my @p = ([ $w, 0 ],
 696            [ $w,$h ],
 697            [ 0, $h ],
 698            [ 0,  0 ]);
 699   foreach my $i (0..3) {
 700     o("    @{ $p[$i] }  @{ $p[($i + 1) % 4] }  $r  arct\n");
 701   }
 702   o("    closepath\n");
 703   o("  } bind def");
 704   o("  /deckpairpathx {\n"); # x because it leaves matrix changed
 705   o("    newpath         deck1path\n");
 706   o("    200 0 translate deck1path\n");
 707   o("  } bind def");
 708   o("  $lw setlinewidth ",miscpscolour('playerdeck'),"\n");
 709   o("  gsave 401 44 translate deckpairpathx stroke grestore");
 710   o("  $lw setlinewidth ",miscpscolour('dykefail'),"\n");
 711   o("  gsave 242 1363 translate 90 rotate deckpairpathx stroke grestore");
 712 }
 713
 714 sub sea_track(){
 715   o("% sea level track\n");
 716   o("  gsave 11 700 translate\n");
 717   my $track = $c{SeaTrack};
 718   my $token_sz = $hs_sz;
 719   my $dy = $token_sz * 1.25;
 720   my $dx = $token_sz * 1.25;
 721   my $linecolour = seatrackedgepscolour();
 722   my @pos;
 723   for my $i (0..$#$track) {
 724     $pos[$i] = mkvec(0, ($i - 0.5 * @$track) * $dy);
 725   }
 726   my $prepline = "$linecolour $hs_lw setlinewidth newpath";
 727   o("  $prepline\n");
 728   o("    ",psvec($pos[0])," moveto ",psvec($pos[-1])," lineto stroke\n");
 729   for my $pos (@pos) {
 730     token_circle("SL", $pos,
 731                  miscpscolour('cube'),
 732                  $linecolour);
 733   }
 734   my $last = 0;
 735   my $cubeedgecolour = seatrackedgepscolour();
 736   for my $i (0..$#pos) {
 737     my $differs = $track->[$i] != $last;
 738     $last = $track->[$i];
 739     next unless $differs;
 740     o("  $prepline\n");
 741     o("  gsave ",
 742       psvec($pos[$i] + mkvec(-0.0 * $token_sz, $dy/2))," translate\n");
 743
 744     my $t_sz = 24;
 745     my $shrink = ($hs_sz * 0.75 / $deck_h);
 746     o("    gsave % T M $i\n");
 747     o("      -43.5 -6.5 translate\n");
 748     o("      0.8 .8 scale \n");
 749     o("      ",0.6 * $dx, " ", -0.28 * $dy," translate\n");
 750     o("      gsave");
 751     o("        $shrink dup scale -90 rotate\n");
 752     o("        newpath ", ($hs_lw / $shrink)," setlinewidth\n");
 753     o("         deck1path stroke\n");
 754     o("      grestore");
 755     o("      /Helvetica-Bold findfont $t_sz scalefont setfont\n");
 756     o("      12 -21.5 moveto ($track->[$i]) show");
 757     o("    grestore\n");
 758
 759     if ($i > 0) {
 760       o("  0 -$dy moveto",
 761         " ",psvec(mkvec( $dx + $cube_sz, 0 )),
 762         " rlineto stroke\n");
 763     }
 764     o("  ",($token_sz * 0.6 + $cube_gap)," ",
 765       (-$dy * 0.5 - 0.5 * (water_cubes_sz(2))),
 766       " translate\n");
 767     my $bottom = int(($track->[$i+1] + 1) / 2);
 768     water_cubes($bottom, $cubeedgecolour);
 769     my $new_n = $track->[$i+1] - $bottom;
 770     o("  ", 0.5 * (water_cubes_sz($bottom) - water_cubes_sz($new_n)),
 771       "  ",       (water_cubes_sz(2)-water_cubes_sz(1)), " translate\n");
 772     water_cubes($new_n, $cubeedgecolour);
 773     o("  grestore\n");
 774   }
 775   o("  grestore\n");
 776 }
 777
 778 our $dyke_l = 25 * MM2PT;;
 779
 780 sub dykes(){
 781   my $l = $dyke_l;
 782   my $w = 5 * MM2PT;
 783   my $lw = $edge_lw * 0.50;
 784   my $l2 = $l/2;
 785   my $w2 = $w/2;
 786   o("  /dykepath {\n");
 787   o("            -$l2 -$w2 moveto\n");
 788   o("             $l2 -$w2 lineto\n");
 789   o("             $l2  $w2 lineto\n");
 790   o("            -$l2  $w2 lineto closepath\n");
 791   o("  } bind def\n");
 792   o("  /dyke {\n");
 793   o("    newpath dykepath\n");
 794   o("    gsave ",miscpscolour('dykefill')," fill grestore\n");
 795   o("    gsave ",miscpscolour('edge')," $lw setlinewidth stroke grestore\n");
 796   o("  } bind def\n");
 797   my $symbol_sz = $w * 1.50;
 798   my $t_sz = $symbol_sz * 1.0;
 799   my $t_at = sub {
 800     my ($ang) = @_;
 801     #print STDERR "ANG $ang\n";
 802     map { $t_sz * 0.5 * $_ } cos($ang), sin($ang);
 803   };
 804   my @t0 = $t_at->((TAU) *  0.25         );
 805   my @t1 = $t_at->((TAU) * (0.25 + 1./3) );
 806   my @t2 = $t_at->((TAU) * (0.25 + 2./3) );
 807   o("  /dtriangle {\n");
 808   o("    newpath @t0 moveto\n");
 809   o("            @t1 lineto\n");
 810   o("            @t2 lineto closepath\n");
 811   o("    gsave ",miscpscolour('dykeinit')," fill grestore\n");
 812   o("    gsave ",miscpscolour('edge')," $lw setlinewidth stroke grestore\n");
 813   o("  } bind def\n");
 814   foreach my $rr (values %region) {
 815     next if $rr->{Special};
 816     next if $rr->{Name} eq 'ZZ';
 817     next if $rr->{Colour} eq 'high';
 818     foreach my $adj (@{ $rr->{Adj} }) {
 819       my $neigh = $adj->{Name};
 820       o("  % dyke $rr->{Name} --- $neigh\n");
 821       next if $neigh lt $rr->{Name} && !$region{$neigh}{Special};
 822       next if $region{$neigh}{Colour} eq 'high';
 823       my @ends = adj_ends($adj);
 824       my $dirn = $ends[1] - $ends[0];
 825       my $angle = vec2atan($dirn);
 826       $angle = $angle * 360 / TAU;
 827       o("  gsave\n");
 828       o("    ", psvec( 0.5 * ($ends[0] + $ends[1]) )," translate\n");
 829       o("    $angle rotate\n");
 830       my $initial = $adj->{Dykes};
 831       for my $ys ($initial
 832                   ? [ map { $_ - 0.5 * ($initial-1) } 0..$initial-1 ]
 833                   : [0]) {
 834         foreach my $y (@$ys) {
 835           o("    gsave 0 ", $y * $w, " translate dyke ");
 836           o(" grestore\n");
 837         }
 838         my $nsymbols = $initial + !!$adj->{Deltawerk};
 839         o("   ", -0.5 * $symbol_sz * ($nsymbols-1)," 0 translate\n");
 840         my $trans = "  $symbol_sz 0 translate";
 841         if ($adj->{Deltawerk}) {
 842           one_hs('red', mkvec(0,0), $symbol_sz * 0.8, $lw);
 843           o($trans);
 844         }
 845         foreach my $i (1..$initial) {
 846           o(" gsave $angle neg rotate dtriangle grestore\n");
 847           o($trans);
 848         }
 849       }
 850       o("  grestore\n");
 851     }
 852   }
 853 }
 854
 855 sub hs_initial_1 ($$$;$$$) {
 856   my ($colour, $xi,$yi, $text, $text2, $fn) = @_;
 857   my $interval = $hs_sz * 1.75;
 858   my $demo_h = $hs_sz; #water_cubes_sz(3);
 859   my $demo_x0 = $hs_sz * 0.75 + $dyke_l * 0.60;
 860   my $demo_w = $demo_x0 + $dyke_l * 0.60;
 861   o("  % HS I $colour\n");
 862   o("  gsave\n");
 863   o("    550 1705 translate\n");
 864   o("    ", ($xi*$interval), " ", (($yi-1)*$interval), " translate\n");
 865   if ($fn) {
 866     o("  gsave\n");
 867     o("        $demo_h setlinewidth 0 0 moveto $demo_w 0 rlineto\n");
 868     o("        ", facepscolour($colour), " stroke grestore\n");
 869   }
 870   one_hs($colour, mkvec(0,0));
 871   if ($fn) {
 872     o("    /words {\n");
 873     o("      2 copy moveto                      ($text) show\n");
 874     o("      2 copy moveto 0 -$text_sz rmoveto ($text2) show\n");
 875     o("    } bind def\n");
 876     o("    gsave ".($hs_sz * 0.8)." $cube_gap translate wordsshow grestore\n");
 877     o("    $demo_x0 ",($hs_sz * -0.25)," translate\n");
 878     $fn->();
 879   }
 880   o("  grestore\n");
 881 }
 882
 883 sub hs_initial () {
 884   hs_initial_1('red',     0,0);
 885   hs_initial_1('purple',  0,1);
 886   hs_initial_1('green',   1,0, 'up to 6', 'fewer', sub {
 887     o("    ",(water_cubes_sz(1))," 0 translate\n");
 888     o("    0 ",(-water_cubes_sz(1) * 0.3)," translate\n");
 889     water_cubes(1, miscpscolour('edge'));
 890   });
 891   hs_initial_1('yellow',  1,1, 'up to 4', '', sub {
 892     o("    newpath dykepath\n");
 893     o("    gsave ",miscpscolour('edge')," stroke grestore\n");
 894     o("    gsave ",miscpscolour('dykehsadd')," fill grestore\n");
 895   });
 896 }
 897
 898 sub play_hint () {
 899   my $sz = 20;
 900   o("  gsave ",miscpscolour('hinttext')," 260 1715 translate\n");
 901   o("  /Helvetica-Bold findfont $sz scalefont setfont\n");
 902   my @t = split /\n/, $c{PlayHint};
 903   foreach my $i (0..$#t) {
 904     my $t = $t[$i];
 905     $t =~ s/[\\()]/\\$&/g;
 906     o("  0 ",(-$i * $sz)," moveto ($t) show\n");
 907   }
 908   o("  grestore");
 909 }
 910
 911 #----- main program -----
 912
 913 $xopts = shift @ARGV if $ARGV[0] =~ s/^-X//;
 914 $bounding = $1 if $xopts =~ s/b(\w+)//;
 915 $maxpaper = $1 if $xopts =~ s/p(\w+)//;
 916 $maxpaper =~ m/^a[134]$|^a1m$/ or confess;
 917
 918 ($facesf, @ARGV) = @ARGV or die;
 919 parse_input_graph();
 920 prep_region_rmap();
 921 read_faces();
 922 calculate_centres();
 923 transform_coordinates();
 924 adjust_nz();
 925
 926 computeboundings();
 927 preamble();
 928 fill_faces();
 929 edge_faces();
 930 dykes();
 931 label_faces();
 932 decks();
 933 sea_track();
 934 hs_initial();
 935 play_hint();
 936 showboundings();
 937 postamble();
 938
 939 print STDERR Dumper(\%region) if $ENV{'GENERATE_BOARD_DUP'};
 940
 941 # Local variables:
 942 # cperl-indent-level: 2
 943 # End.