generate-board

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Carp;
   5 use Data::Dumper;
   6 use Math::GSL::Vector qw/:all/;
   7 use Math::GSL::Matrix qw/:all/;
   8 use Math::GSL::Const;
   9 use Math::GSL::BLAS qw/:all/;
  10 use Math::GSL::CBLAS qw/:all/;
  11 use Math::GSL::Machine qw/:all/;
  12
  13 use POSIX qw(M_PI);
  14
  15 BEGIN { unshift @INC, qw(.); }
  16
  17 use Parse;
  18
  19 our $xopts = '';
  20 our $bounding = 'Entire';
  21 our $facesf;
  22 our %vxname2pos; # $vxname2pos{VXNAME} = Math::GSL::Vector
  23 our %bb; # $r{Bounding...}[0..3] = points
  24
  25 sub TAU { M_PI * 2.0; }
  26 sub MM2PT { 72.0 / 25.4; }
  27
  28 our $mid;
  29
  30 our $a4_w = 595;
  31 our $a4_h = 842;
  32 our $a3_h = 1190;
  33
  34 our $max_printeredge = 5.50 * MM2PT;
  35
  36
  37 # ----- region names from plag, incl. reverse mapping -----
  38
  39 our %prs2region;
  40
  41 sub prep_region_rmap () {
  42   foreach my $rn (keys %region) {
  43     my $prs = plag_prs($rn);
  44     die if $prs2region{$prs};
  45     $prs2region{$prs} = $rn;
  46   }
  47 }
  48
  49 our $sre = qr{(?:(\")|(?=\w))(.*)\1$}; # 2 captures, $2 is the name
  50
  51 sub prs2r ($) {
  52   # bodgery for the sea and land
  53   return 'NZ' if m/ \| / && !grep { !m{^(?:NZ|L2?)$} } split / \| /, $_[0];
  54   $prs2region{$_[0]} // confess "@_ ?"
  55 }
  56 sub prs2rr ($) { $region{prs2r($_[0])} }
  57
  58 #----- file reader for plag output -----
  59
  60 sub read_faces () {
  61   # Sets
  62   #  $region{NAME}{Adj}[]{Ends}[]{VxName}
  63   #  $region{NAME}{Adj}[]{Ends}[]{Pos}
  64   #  $region{NAME}{Polygon}{Pos}
  65   #  $region{NAME}{Special}
  66   #
  67   # also incidentally
  68   #  $region{NAME}{Adj}[]{Ends}[]{Adjoins}
  69   #  $region{NAME}{Polygon}{Adjoins}
  70   # which should be ignored
  71
  72   open P, "<", $facesf or die $!;
  73   while (<P>) { last if m/^\&faces$/; }
  74   my $rr;
  75   my @edges;
  76   my $process_rr = sub {
  77     my $last_ai;
  78     if ($rr->{Name} eq 'NZ') {
  79       # We combined L and NZ; now we must split them again
  80       # in fact, we just throw away L and L2 entirely.
  81       # Here, when processing NZ, we keep only vertices that
  82       # are part of NZ.
  83       @edges = grep {
  84         my $evxname = $_->{VxName};
  85         my @eregions = split / \| ?/, $evxname;
  86         grep { $_ eq 'NZ' } @eregions
  87       } @edges;
  88     }
  89     $rr->{Polygon} = [ @edges ];
  90     if ($rr->{Name} ne 'NZ') {
  91       for my $ei (0..$#edges) {
  92         if (!defined $last_ai) {
  93           my $ai;
  94           for my $ai (0..$#{ $rr->{Adj} }) {
  95             next unless $rr->{Adj}[$ai]{Name} eq $edges[$ei]{Adjoins};
  96             $last_ai = $ai+1;
  97           }
  98           confess $edges[$ei]{Adjoins}.' ?' unless defined $last_ai;
  99         }
 100         my $ai = ($last_ai-1+@edges) % @edges;
 101         $last_ai = $ai;
 102         my $adj = $rr->{Adj}[$ai];
 103         confess Dumper($adj->{Name}, $edges[$ei]{Adjoins},
 104                        $rr, \@edges, $ei, $adj, $last_ai, $ai)." ?"
 105             unless $adj->{Name} eq $edges[$ei]{Adjoins};
 106
 107         for my $endi (0..1) {
 108           $adj->{Ends}[$endi] = $edges[ ($ei + $endi) % @edges ];
 109         }
 110       }
 111     }
 112     @edges = ();
 113     $rr = undef;
 114   };
 115   my $vxname;
 116   for (;;) {
 117     $!=0; $_=<P> // confess $!;
 118     last if m/^\&$/;
 119     if (m/^$sre$/) {
 120       my $new_face= $2;
 121       $process_rr->() if $rr;
 122       $rr= prs2rr($new_face);
 123     } elsif (m/^\s+$sre$/) {
 124       confess unless $rr;
 125       $vxname = $2;
 126       push @edges, { VxName => $vxname };
 127     } elsif (m/^\s+\^adjoins\s+$sre$/) {
 128       $edges[-1]{Adjoins} = prs2r($2);
 129     } elsif (m/^\s+\^\@([-e.0-9]+)\,([-e.0-9]+)$/) {
 130       my $pos = mkvec($1,$2);
 131       confess unless defined $vxname;
 132       $edges[-1]{Pos} = $pos;
 133       $vxname2pos{$vxname} = $pos;
 134     }
 135   }
 136   $process_rr->();
 137
 138   $region{$_}{Special} = 1 foreach qw(NZ L L2);
 139 }
 140
 141 #----- geometry mangling -----
 142
 143 sub adj_ends ($) {
 144   my ($adj) = @_;
 145   map { $_->{Pos} } @{ $adj->{Ends} };
 146 }
 147
 148 sub calculate_centres () {
 149   # Sets
 150   #  $region{NAME}{Centre}
 151   foreach my $rr (values %region) {
 152     next if $rr->{Special};
 153     my $sum = Math::GSL::Vector->new(2);
 154     my $wsum = 0;
 155     foreach my $adj (@{ $rr->{Adj} }) {
 156       my @ends = adj_ends($adj);
 157       my $w = ($ends[1] - $ends[0])->norm();
 158       $sum += $w * $_ foreach @ends;
 159       $wsum += $w;
 160     }
 161     $rr->{Centre} = $sum * (0.5 / $wsum);
 162   }
 163 }
 164
 165 sub for_each_pos ($) {
 166   my ($f) = @_;
 167   my $call = sub {
 168     my ($pr,$rr,$why) = @_;
 169     return unless defined $$pr;
 170     $f->($pr,$rr,$why);
 171   };
 172   foreach my $rr (values %region) {
 173     $call->( \ $rr->{Centre}, $rr, $rr->{Name}." C" );
 174     foreach my $vertex (@{ $rr->{Polygon} }) {
 175       $call->( \ $vertex->{Pos}, $rr, $rr->{Name}." | ".$vertex->{Adjoins} );
 176     }
 177   }
 178 }
 179
 180 sub prvec ($) {
 181   my ($v) = @_;
 182   confess unless $v;
 183   sprintf "%g,%g", $v->get(0), $v->get(1);
 184 }
 185
 186 sub mkvec ($$) { Math::GSL::Vector->new(\@_) }
 187 sub vec2atan ($) { my ($dir) = @_; atan2 $dir->get(1), $dir->get(0); }
 188
 189 sub transform_coordinates () {
 190   # Adjusts coordinates in graph to be [0,0] .. top right (scaled)
 191   # until it's all in PostScript points
 192   my @or = map { $region{$_}{Centre} } @{ $c{OrientRegions} };
 193   my $dir = $or[1] - $or[0];
 194   my $theta = vec2atan($dir);
 195   my $rotateby = (90. - $c{OrientBearing}) * ((TAU)/360.) - $theta;
 196   my $s = sin($rotateby);
 197   my $c = cos($rotateby);
 198   my $transform = Math::GSL::Matrix->new(2,2);
 199   $transform->set_row(0, [  $c, -$s ]);
 200   $transform->set_row(1, [  $s,  $c ]);
 201   print STDERR "rotate was=",prvec($dir)," theta=$theta",
 202       " rotateby=$rotateby s=$s c=$c\n";
 203   my @lims;
 204   foreach my $topend (qw(0 1)) {
 205     my $v = $topend ? -$GSL_DBL_MAX : $GSL_DBL_MAX;
 206     $lims[$topend] = mkvec($v,$v);
 207   }
 208   for_each_pos(sub {
 209     my ($pr, $rr, $why) = @_;
 210     my $y = Math::GSL::Vector->new(2);
 211     gsl_blas_dgemv($CblasNoTrans,
 212                    1.0, $transform->raw,
 213                    $$pr->raw,
 214                    0, $y->raw)
 215         and confess;
 216     #print STDERR "gsl_blas_dgemv ",prvec($$pr)," => ",prvec($y),"\n";
 217     gsl_blas_dcopy($y->raw, $$pr->raw)
 218         and confess;
 219     foreach my $topend (qw(0 1)) {
 220       foreach my $xy (qw(0 1)) {
 221         my $now = $y->get($xy);
 222         my $lim = $lims[$topend]->get($xy);
 223         #print STDERR "?set $topend $xy $now $lim\n";
 224         next if $topend ? ($now <= $lim) : ($now >= $lim);
 225         $lims[$topend]->set([$xy], [$now]);
 226         #print STDERR "set $topend $xy $now\n";
 227       }
 228     }
 229   });
 230   print STDERR "lims ",prvec($lims[0])," .. ",prvec($lims[1]),"\n";
 231   my $translate = -$lims[0];
 232   print STDERR "translate ",prvec($translate),"\n";
 233   my $scale = $c{GraphScale} * MM2PT;
 234   for_each_pos(sub {
 235     my ($pr) = @_;
 236     gsl_vector_add($$pr->raw, $translate->raw) and confess;
 237     gsl_vector_scale($$pr->raw, $scale) and confess;
 238   });
 239   $mid = ($lims[1] - $lims[0]) * 0.5;
 240 }
 241
 242 sub adjust_nz() {
 243   my $poly = $region{NZ}{Polygon};
 244   my %occurs;
 245   foreach my $v (@$poly) {
 246     $occurs{$v->{VxName}}++
 247   }
 248   foreach my $v (@$poly) {
 249     $v->{NZ_Occurs} = $occurs{$v->{VxName}};
 250   }
 251   print STDERR " nz ".(scalar @$poly)."\n";
 252   my $occurs_m = sub {
 253     my ($ei) = @_;
 254     $poly->[($ei+@$poly) % @$poly]{NZ_Occurs} > 1
 255   };
 256   for my $ei (0..$#$poly) {
 257     next if $occurs_m->($ei);
 258     next unless $occurs_m->($ei-1);
 259     next unless $occurs_m->($ei+1);
 260     print STDERR " nz would adjust $poly->[$ei]{VxName}\n";
 261     # adjust coord outwards
 262   }
 263   for my $ei (0..$#$poly) {
 264     next unless $occurs_m->($ei);
 265     print STDERR " nz occurs_m $ei $poly->[$ei]{VxName}\n";
 266     next unless $occurs_m->($ei-1);
 267     my $dleft = mkvec(-1000,0);
 268     foreach my $which (0,-1) {
 269       my $ej = ($ei +        $which + @$poly) % @$poly;
 270       my $ek = ($ei + +1 + 3*$which + @$poly) % @$poly;
 271       my $posj = \ $poly->[$ej]{Pos};
 272       my $posk = \ $poly->[$ek]{Pos};
 273       my $dout = $$posk - $$posj;
 274       print STDERR " nz adj j=$ej ",prvec($$posj)," $poly->[$ej]{VxName}\n";
 275       print STDERR " nz adj k=$ek ",prvec($$posk)," $poly->[$ek]{VxName}\n";
 276       if ($poly->[$ej]{VxName} =~ /Noorderzijlvest/) {
 277         print STDERR " nz adj extra\n";
 278         $$posk = $$posj + 10 * mkvec(100,-50);
 279       }
 280       $$posj = $$posj + $dleft + $dout*10;
 281       $$posk = $$posk          + $dout*10;
 282     }
 283   }
 284 }
 285
 286 sub psvec ($) {
 287   my ($pos) = @_;
 288   sprintf "%20.6f %20.6f", $pos->get(0),$pos->get(1)
 289 }
 290
 291 sub face_path ($) {
 292   my ($rr) = @_;
 293   o("% $rr->{Name}\n");
 294   o("  newpath\n");
 295   my $xto = 'moveto';
 296   foreach my $vertex (@{ $rr->{Polygon} }) {
 297     my $pos = $vertex->{Pos};
 298     o(sprintf "    %s %s\n", psvec($pos), $xto);
 299     $xto = 'lineto';
 300   }
 301   o("    closepath\n");
 302 }
 303
 304 sub computeboundings() {
 305   $bb{Entire} = [ 0,0, $a4_h, $a4_w + $a3_h ];
 306   $bb{PageB} = [ 0,0, $a4_h, $a4_w ];
 307   my $page2minprintable = sub {
 308     my (@p) = @{ $_[0] };
 309     [ $p[0] + $max_printeredge,
 310       $p[1] + $max_printeredge,
 311       $p[2] - $max_printeredge,
 312       $p[3] - $max_printeredge ];
 313   };
 314   $bb{PrintableB} = $page2minprintable->($bb{PageB});
 315   my $mt_offset = $bb{PrintableB}[3] - $max_printeredge;
 316   $bb{PageMT} = [ 0, $mt_offset, $a4_h, $mt_offset + $a3_h ];
 317   $bb{PrintableMT} = $page2minprintable->($bb{PageMT});
 318   $bb{PrintableAll} = [
 319                       @{ $bb{PrintableB} }[0..1],
 320                       @{ $bb{PrintableMT} }[2..3],
 321                      ];
 322 }
 323
 324 sub showboundings () {
 325   return unless $xopts =~ m/B/;
 326   o("  grestore gsave\n");
 327   my $i = 0;
 328   my $on = 2;
 329   my $off = 9;
 330   foreach my $bname (sort keys %bb) {
 331     o(sprintf "   1 %d %d setrgbcolor\n",
 332       !!($bname =~ m/^Page/),
 333       !!($bname =~ m/B$/),
 334      );
 335     o("    % $bname\n");
 336     o("    [ $on $off ] ".($i * ($on+$off))," setdash newpath\n");
 337     my @p = @{ $bb{$bname} };
 338     o("    $p[0] $p[1] moveto\n");
 339     o("    $p[2] $p[1] lineto\n");
 340     o("    $p[2] $p[3] lineto\n");
 341     o("    $p[0] $p[3] lineto\n");
 342     o("    closepath stroke\n");
 343     $i++;
 344   }
 345 }
 346
 347 sub o_amble (@) {
 348   # CPerl-mode does a really awful thing with %s in the preamble
 349   # and postamble, causing constant useless flashing
 350   # So we write & in the here docs and transform them back:
 351   my ($t) = join '', @_;
 352   $t =~ s/^\&+/ '%' x length $& /mge;
 353   o($t);
 354 }
 355
 356 sub preamble() {
 357   my $bb = $bb{$bounding}; confess $bounding unless $bb;
 358   my $sz = [ $bb->[2] - $bb->[0], $bb->[3] - $bb->[1] ];
 359   o_amble(<<END);
 360 &!PS-Adobe-3.0
 361 &&BoundingBox @$bb
 362 &&Pages: 1
 363 &&EndComments
 364 &&BeginProlog
 365 &&EndProlog
 366 &&BeginSetup
 367 << /PageSize [ @$sz ] >> setpagedevice
 368 /board {
 369   gsave
 370   34 -15 translate
 371 END
 372   # xxx split into pages
 373 }
 374
 375 sub postamble () {
 376   o_amble(<<END);
 377   grestore
 378 } bind def
 379 &&EndSetup
 380 &&Page: 1
 381 &&BeginPageSetup
 382 /pgsave save def
 383 &&EndPageSetup
 384 board
 385 pgsave restore
 386 showpage
 387 &&EOF
 388 END
 389 }
 390
 391 sub pscolour ($;$) {
 392   my ($spec, $adj1) = @_;
 393   confess unless defined $spec;
 394   my $le = (length $spec)/3;
 395   my $re = ("(.{$le})") x 3;
 396   my @rgb = $spec =~ m/^$re$/;  @rgb or confess "$re ?";
 397   @rgb = map { hex($_) / (16**$le -1) } @rgb;
 398   $adj1 //= sub { };
 399   $adj1->(@rgb);
 400   my $r = join ' ',
 401       (map { sprintf "%.6f ", $_ } @rgb
 402       ),
 403            'setrgbcolor';
 404   return $r;
 405 }
 406
 407 sub lighterpscolour ($$) {
 408   my ($colourname, $retain) = @_;
 409   pscolour($c{Colours}{$colourname},
 410            sub { $_ = 1.0 - $retain * (1.0 - $_) foreach @_ })
 411 }
 412
 413 sub darkerpscolour ($$) {
 414   my ($colourname, $retain) = @_;
 415   pscolour($c{Colours}{$colourname},
 416            sub { $_ = $retain * $_ foreach @_ })
 417 }
 418
 419 sub facepscolour ($) {
 420   my ($colourname) = @_;
 421   $xopts =~ m/W/ ? '1 setgray' : lighterpscolour($colourname, 0.75);
 422 }
 423
 424 sub miscpscolour ($) {
 425   my ($colourname) = @_;
 426   pscolour($c{Colours}{$colourname});
 427 }
 428
 429 sub cubeedgepscolour () {  '0 setgray ' }
 430 sub seatrackedgepscolour () { darkerpscolour('cube', 0.25) }
 431 # xxx ^ combine these - which one ?
 432
 433 sub fill_faces() {
 434   o("clippath ", facepscolour('land'), " fill\n");
 435   foreach my $rr (values %region) {
 436     next if $rr->{Name} =~ m/^L2?$/;
 437     face_path($rr);
 438     o(" ", facepscolour($rr->{Colour}), " eofill\n");
 439   }
 440 }
 441
 442 our $edge_lw = 5;
 443
 444 sub some_edge_faces (@) {
 445   o("$edge_lw setlinewidth 1 setlinejoin 0 setgray\n");
 446   foreach my $rr (@_) {
 447     next if $rr->{Name} =~ m/^L2?$/;
 448     face_path($rr);
 449     o("    stroke\n");
 450   }
 451 }
 452
 453 sub afsluitdijk() {
 454   my ($adj) = grep { $_->{Name} eq 'NZ' } @{ $region{'ZZ'}{Adj} };
 455   my $dash = 20;
 456   my (@pos) = adj_ends($adj);
 457   my $mid = 0.5 * ($pos[0] + $pos[1]);
 458   my $r = 0.5 * ($pos[1] - $pos[0])->norm();
 459   o(sprintf <<'END', facepscolour('sea'), psvec($mid), $r);
 460   %% Afsluitdijk
 461   %s %s %s 0 360 arc closepath fill
 462 END
 463   some_edge_faces(()); # just sets the colour
 464   o(sprintf <<END, map { psvec($_) } @pos);
 465   newpath %s moveto %s lineto
 466   [ $dash $dash ] $dash 0.5 mul setdash
 467   stroke
 468   [] 0 setdash
 469 END
 470   one_hs('purple', $mid);
 471 }
 472
 473 sub edge_faces() {
 474   some_edge_faces($region{'NZ'});
 475   afsluitdijk();
 476   some_edge_faces(grep {
 477     $_->{Name} !~ m{^(?:L2?|NZ|ZZ)$}
 478   } values %region);
 479 }
 480
 481 our $hs_sz = 17 * MM2PT;
 482 our $hs_lw = 3;
 483
 484 our $text_sz = 18;
 485
 486 sub token_circle ($$$$;$$) {
 487   my ($what, $pos, $fillcolour, $edgecolour, $sz,$lw) = @_;
 488   $sz //= $hs_sz;
 489   $lw //= $hs_lw;
 490   o(sprintf <<END, $what, $fillcolour, psvec($pos), $sz/2, $edgecolour);
 491    %% %s
 492    newpath %s
 493      %s %f 0 360 arc closepath gsave fill grestore
 494      %s $lw setlinewidth stroke
 495 END
 496 }
 497
 498 sub one_hs ($$;$$) {
 499   my ($colour, $hspos, $sz, $lw) = @_;
 500   token_circle("HS - $colour",
 501                $hspos,
 502                darkerpscolour($colour, 0.75),
 503                '0 setgray',
 504               $sz,$lw);
 505 }
 506
 507 our $cube_sz = 6 * MM2PT;
 508 our $cube_gap = $cube_sz * 0.2;
 509 our $cube_lw = ($cube_sz * 0.1);
 510
 511 sub label_faces() {
 512   my $sz = $text_sz;
 513   my $shadow = $sz * 0.1;
 514   o(<<END);
 515   /wordsshow {
 516     0 setgray 0 10 359 {
 517       dup  cos $shadow mul
 518       exch sin $shadow mul
 519       words pop pop
 520     } bind for
 521     1 setgray 0 0 words pop pop
 522   } def
 523 END
 524   o("  /Helvetica-Bold findfont  $sz scalefont setfont\n");
 525   my %hs = map { $_ => 1 } @{ $c{HS} };
 526   foreach my $rr (values %region) {
 527     next if $rr->{Name} =~ m/^L\d?$/;
 528     my $words = $rr->{DisplayName};
 529     my $pos;
 530     if ($rr->{Name} eq 'NZ') {
 531       $pos = mkvec(90, 1280);
 532     } else {
 533       $pos = $rr->{Centre} + mkvec( 0, 0.5 * $sz * @$words );
 534     }
 535     if ($hs{$rr->{Name}}) {
 536       print STDERR "adjust hs $rr->{Name}\n";
 537       $pos -= mkvec(0, -$hs_sz*
 538                     ( $rr->{Colour} eq 'green' ? 0.25 : 0.65 ));
 539       my $hspos = $pos - mkvec(0, $sz * @$words + $hs_sz/2 + $hs_lw
 540                                + $hs_sz*0.15);
 541       one_hs($rr->{Colour}, $hspos);
 542     }
 543     my $adjust = $c{TextAdjust}{$rr->{Name}};
 544     if ($adjust) {
 545       $pos += $sz * &mkvec(@$adjust);
 546     }
 547     my $w = $rr->{Water};
 548     $w = 2 if $rr->{Special} || $rr->{Name} eq 'ZZ';
 549     if ($w) {
 550       print STDERR " water $w in $rr->{Name}\n";
 551       my $down = water_cubes_sz(2) - water_cubes_sz(1) + $cube_gap;
 552       $pos -= mkvec(0, -0.5 * $down);
 553       my $cube_y = -($sz * @$words);
 554       if ($rr->{Name} eq 'Wieringermeer') {
 555         $pos -= mkvec(0,+$sz);
 556         $cube_y = 0;
 557         $down = 0;
 558       }
 559       o("  gsave\n");
 560       o("    ", psvec($pos), " translate\n");
 561       o("    0 ", $cube_y, " translate\n");
 562       o("    ", -0.5 * water_cubes_sz($w)," ", -$down, " translate\n");
 563       water_cubes($w);
 564       o("  grestore\n");
 565     }
 566     o("  /words {\n");
 567     foreach my $word (@$words) {
 568       $pos += mkvec(0,-$sz);
 569       o("   ", psvec($pos), " moveto");
 570       o(<<END);
 571    2 copy rmoveto
 572    ($word) dup stringwidth pop     % word xw
 573      -0.5 mul 0 rmoveto             % word
 574      show
 575    0 -$sz rmoveto
 576 END
 577     }
 578     o(<<END);
 579   } bind def
 580   wordsshow
 581 END
 582   }
 583 }
 584
 585 sub water_cubes_sz($){
 586   my ($n) = @_;
 587   ($cube_sz + $cube_lw) * $n + ($cube_gap * ($n-1));
 588 }
 589
 590 sub water_cubes($){
 591   my ($n) = @_;
 592   my $s = $cube_sz;
 593   for my $i (0..$n-1) {
 594     o("  newpath  ", $i * ($cube_sz + $cube_lw + $cube_gap),"  0  moveto\n");
 595     o("          $s  0  rlineto\n");
 596     o("           0 $s  rlineto\n");
 597     o("         -$s  0  rlineto  closepath\n");
 598     o("  gsave ", miscpscolour('cube'), " fill grestore\n");
 599     o("  gsave ", cubeedgepscolour(), $cube_lw,
 600       " setlinewidth stroke grestore \n");
 601   }
 602 }
 603
 604 my $deck_h = 89 * MM2PT;
 605
 606 sub decks(){
 607   my $lw = $edge_lw/2;
 608   o("  /deck1path {\n");
 609   my $w = 63 * MM2PT;
 610   my $h = $deck_h;
 611   my $r =  5 * MM2PT;
 612   o("      ",($w/2)," 0 moveto\n");
 613   my @p = ([ $w, 0 ],
 614            [ $w,$h ],
 615            [ 0, $h ],
 616            [ 0,  0 ]);
 617   foreach my $i (0..3) {
 618     o("    @{ $p[$i] }  @{ $p[($i + 1) % 4] }  $r  arct\n");
 619   }
 620   o("    closepath\n");
 621   o("  } bind def");
 622   o("  /deckpairpathx {\n"); # x because it leaves matrix changed
 623   o("    newpath         deck1path\n");
 624   o("    200 0 translate deck1path\n");
 625   o("  } bind def");
 626   o("  $lw setlinewidth 1 setgray\n");
 627   o("  gsave 401 44 translate deckpairpathx stroke grestore");
 628   o("  $lw setlinewidth ",miscpscolour('dykefail'),"\n");
 629   o("  gsave 242 1363 translate 90 rotate deckpairpathx stroke grestore");
 630 }
 631
 632 sub sea_track(){
 633   o("% sea level track\n");
 634   o("  gsave 11 700 translate\n");
 635   my $track = $c{SeaTrack};
 636   my $token_sz = $hs_sz;
 637   my $dy = $token_sz * 1.25;
 638   my $dx = $token_sz * 1.25;
 639   my $linecolour = seatrackedgepscolour();
 640   my @pos;
 641   for my $i (0..$#$track) {
 642     $pos[$i] = mkvec(0, ($i - 0.5 * @$track) * $dy);
 643   }
 644   my $prepline = "$linecolour $hs_lw setlinewidth newpath";
 645   o("  $prepline\n");
 646   o("    ",psvec($pos[0])," moveto ",psvec($pos[-1])," lineto stroke\n");
 647   for my $pos (@pos) {
 648     token_circle("SL", $pos,
 649                  miscpscolour('cube'),
 650                  $linecolour);
 651   }
 652   my $last = 0;
 653   for my $i (0..$#pos) {
 654     my $differs = $track->[$i] != $last;
 655     $last = $track->[$i];
 656     next unless $differs;
 657     o("  $prepline\n");
 658     o("  gsave ",
 659       psvec($pos[$i] + mkvec(-0.0 * $token_sz, $dy/2))," translate\n");
 660
 661     my $t_sz = 24;
 662     my $shrink = ($hs_sz * 0.75 / $deck_h);
 663     o("    gsave % T M $i\n");
 664     o("      -43.5 -6.5 translate\n");
 665     o("      0.8 .8 scale \n");
 666     o("      ",0.6 * $dx, " ", -0.28 * $dy," translate\n");
 667     o("      gsave");
 668     o("        $shrink dup scale -90 rotate\n");
 669     o("        newpath ", ($hs_lw / $shrink)," setlinewidth\n");
 670     o("         deck1path stroke\n");
 671     o("      grestore");
 672     o("      /Helvetica-Bold findfont $t_sz scalefont setfont\n");
 673     o("      12 -21.5 moveto ($track->[$i]) show");
 674     o("    grestore\n");
 675
 676     if ($i > 0) {
 677       o("  0 -$dy moveto",
 678         " ",psvec(mkvec( $dx + $cube_sz, 0 )),
 679         " rlineto stroke\n");
 680     }
 681     o("  ",($token_sz * 0.6 + $cube_gap)," ",
 682       (-$dy * 0.5 - 0.5 * (water_cubes_sz(2))),
 683       " translate\n");
 684     my $bottom = int(($track->[$i+1] + 1) / 2);
 685     water_cubes($bottom);
 686     my $new_n = $track->[$i+1] - $bottom;
 687     o("  ", 0.5 * (water_cubes_sz($bottom) - water_cubes_sz($new_n)),
 688       "  ",       (water_cubes_sz(2)-water_cubes_sz(1)), " translate\n");
 689     water_cubes($new_n);
 690     o("  grestore\n");
 691   }
 692   o("  grestore\n");
 693 }
 694
 695 our $dyke_l = 25 * MM2PT;;
 696
 697 sub dykes(){
 698   my $l = $dyke_l;
 699   my $w = 5 * MM2PT;
 700   my $lw = $edge_lw * 0.50;
 701   my $l2 = $l/2;
 702   my $w2 = $w/2;
 703   o("  /dykepath {\n");
 704   o("            -$l2 -$w2 moveto\n");
 705   o("             $l2 -$w2 lineto\n");
 706   o("             $l2  $w2 lineto\n");
 707   o("            -$l2  $w2 lineto closepath\n");
 708   o("  } bind def\n");
 709   o("  /dyke {\n");
 710   o("    newpath dykepath\n");
 711   o("    gsave 0.50 setgray fill grestore\n");
 712   o("    gsave 0.00 setgray $lw setlinewidth stroke grestore\n");
 713   o("  } bind def\n");
 714   my $symbol_sz = $w * 1.50;
 715   my $t_sz = $symbol_sz * 1.0;
 716   my $t_at = sub {
 717     my ($ang) = @_;
 718     print STDERR "ANG $ang\n";
 719     map { $t_sz * 0.5 * $_ } cos($ang), sin($ang);
 720   };
 721   my @t0 = $t_at->((TAU) *  0.25         );
 722   my @t1 = $t_at->((TAU) * (0.25 + 1./3) );
 723   my @t2 = $t_at->((TAU) * (0.25 + 2./3) );
 724   o("  /dtriangle {\n");
 725   o("    newpath @t0 moveto\n");
 726   o("            @t1 lineto\n");
 727   o("            @t2 lineto closepath\n");
 728   o("    gsave ",miscpscolour('dykeinit')," fill grestore\n");
 729   o("    gsave 0 setgray $lw setlinewidth stroke grestore\n");
 730   o("  } bind def\n");
 731   foreach my $rr (values %region) {
 732     next if $rr->{Special};
 733     next if $rr->{Name} eq 'ZZ';
 734     next if $rr->{Colour} eq 'high';
 735     foreach my $adj (@{ $rr->{Adj} }) {
 736       my $neigh = $adj->{Name};
 737       o("  % dyke $rr->{Name} --- $neigh\n");
 738       next if $neigh lt $rr->{Name} && !$region{$neigh}{Special};
 739       next if $region{$neigh}{Colour} eq 'high';
 740       my @ends = adj_ends($adj);
 741       my $dirn = $ends[1] - $ends[0];
 742       my $angle = vec2atan($dirn);
 743       $angle = $angle * 360 / TAU;
 744       o("  gsave\n");
 745       o("    ", psvec( 0.5 * ($ends[0] + $ends[1]) )," translate\n");
 746       o("    $angle rotate\n");
 747       my $initial = $adj->{Dykes};
 748       for my $ys ($initial
 749                   ? [ map { $_ - 0.5 * ($initial-1) } 0..$initial-1 ]
 750                   : [0]) {
 751         foreach my $y (@$ys) {
 752           o("    gsave 0 ", $y * $w, " translate dyke ");
 753           o(" grestore\n");
 754         }
 755         my $nsymbols = $initial + !!$adj->{Deltawerk};
 756         o("   ", -0.5 * $symbol_sz * ($nsymbols-1)," 0 translate\n");
 757         my $trans = "  $symbol_sz 0 translate";
 758         if ($adj->{Deltawerk}) {
 759           one_hs('red', mkvec(0,0), $symbol_sz * 0.8, $lw);
 760           o($trans);
 761         }
 762         foreach my $i (1..$initial) {
 763           o(" gsave $angle neg rotate dtriangle grestore\n");
 764           o($trans);
 765         }
 766       }
 767       o("  grestore\n");
 768     }
 769   }
 770 }
 771
 772 sub hs_initial_1 ($$$;$$$) {
 773   my ($colour, $xi,$yi, $text, $text2, $fn) = @_;
 774   my $interval = $hs_sz * 1.75;
 775   my $demo_h = $hs_sz; #water_cubes_sz(3);
 776   my $demo_x0 = $hs_sz * 0.75 + $dyke_l * 0.60;
 777   my $demo_w = $demo_x0 + $dyke_l * 0.60;
 778   o("  % HS I $colour\n");
 779   o("  gsave\n");
 780   o("    550 1705 translate\n");
 781   o("    ", ($xi*$interval), " ", (($yi-1)*$interval), " translate\n");
 782   if ($fn) {
 783     o("  gsave");
 784     o("        $demo_h setlinewidth 0 0 moveto $demo_w 0 rlineto\n");
 785     o("        ", facepscolour($colour), " stroke grestore\n");
 786   }
 787   one_hs($colour, mkvec(0,0));
 788   if ($fn) {
 789     o("    /words {");
 790     o("      2 copy moveto                      ($text) show");
 791     o("      2 copy moveto 0 -$text_sz rmoveto ($text2) show");
 792     o("    } bind def");
 793     o("    gsave ".($hs_sz * 0.8)." $cube_gap translate wordsshow grestore\n");
 794     o("    $demo_x0 ",($hs_sz * -0.25)," translate\n");
 795     $fn->();
 796   }
 797   o("  grestore\n");
 798 }
 799
 800 sub hs_initial () {
 801   hs_initial_1('red',     0,0);
 802   hs_initial_1('purple',  0,1);
 803   hs_initial_1('green',   1,0, 'up to 6', 'fewer', sub {
 804     o("    ",(water_cubes_sz(1))," 0 translate\n");
 805     o("    0 ",(-water_cubes_sz(1) * 0.3)," translate\n");
 806     water_cubes(1);
 807   });
 808   hs_initial_1('yellow',  1,1, 'up to 4', '', sub {
 809     o("    newpath dykepath\n");
 810     o("    gsave 0.50 setgray fill grestore\n");
 811     o("    gsave ",miscpscolour('dykehsadd')," fill grestore\n");
 812   });
 813 }
 814
 815 sub play_hint () {
 816   my $sz = 20;
 817   o("  gsave 0 setgray 260 1715 translate");
 818   o("  /Helvetica-Bold findfont $sz scalefont setfont");
 819   my @t = split /\n/, $c{PlayHint};
 820   foreach my $i (0..$#t) {
 821     my $t = $t[$i];
 822     $t =~ s/[\\()]/\\$&/g;
 823     o("  0 ",(-$i * $sz)," moveto ($t) show");
 824   }
 825   o("  grestore");
 826 }
 827
 828 #----- main program -----
 829
 830 $xopts = shift @ARGV if $ARGV[0] =~ s/^-X//;
 831 $bounding = $1 if $xopts =~ s/b(\w+)//;
 832
 833 ($facesf, @ARGV) = @ARGV or die;
 834 parse_input_graph();
 835 prep_region_rmap();
 836 read_faces();
 837 calculate_centres();
 838 transform_coordinates();
 839 adjust_nz();
 840
 841 computeboundings();
 842 preamble();
 843 fill_faces();
 844 edge_faces();
 845 dykes();
 846 label_faces();
 847 decks();
 848 sea_track();
 849 hs_initial();
 850 play_hint();
 851 showboundings();
 852 postamble();
 853
 854 print STDERR Dumper(\%region) if $ENV{'GENERATE_BOARD_DUP'};
 855
 856 # Local variables:
 857 # cperl-indent-level: 2
 858 # End.