generate-board

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Carp;
   5 use Data::Dumper;
   6 use Math::GSL::Vector qw/:all/;
   7 use Math::GSL::Matrix qw/:all/;
   8 use Math::GSL::Const;
   9 use Math::GSL::BLAS qw/:all/;
  10 use Math::GSL::CBLAS qw/:all/;
  11 use Math::GSL::Machine qw/:all/;
  12
  13 use POSIX qw(M_PI);
  14
  15 BEGIN { unshift @INC, qw(.); }
  16
  17 use Parse;
  18
  19 our $xopts = '';
  20 our $bounding = 'Entire';
  21 our $facesf;
  22 our %vxname2pos; # $vxname2pos{VXNAME} = Math::GSL::Vector
  23 our %bb; # $r{Bounding...}[0..3] = points
  24 our $maxpaper = 'a3';
  25
  26 sub TAU { M_PI * 2.0; }
  27 sub MM2PT { 72.0 / 25.4; }
  28
  29 our $mid;
  30
  31 our $a4_w = 595;
  32 our $a4_h = 842;
  33 our $a3_h = 1190;
  34
  35 our $max_printeredge = 5.50 * MM2PT;
  36
  37
  38 # ----- region names from plag, incl. reverse mapping -----
  39
  40 our %prs2region;
  41
  42 sub prep_region_rmap () {
  43   foreach my $rn (keys %region) {
  44     my $prs = plag_prs($rn);
  45     die if $prs2region{$prs};
  46     $prs2region{$prs} = $rn;
  47   }
  48 }
  49
  50 our $sre = qr{(?:(\")|(?=\w))(.*)\1$}; # 2 captures, $2 is the name
  51
  52 sub prs2r ($) {
  53   # bodgery for the sea and land
  54   return 'NZ' if m/ \| / && !grep { !m{^(?:NZ|L2?)$} } split / \| /, $_[0];
  55   $prs2region{$_[0]} // confess "@_ ?"
  56 }
  57 sub prs2rr ($) { $region{prs2r($_[0])} }
  58
  59 #----- file reader for plag output -----
  60
  61 sub read_faces () {
  62   # Sets
  63   #  $region{NAME}{Adj}[]{Ends}[]{VxName}
  64   #  $region{NAME}{Adj}[]{Ends}[]{Pos}
  65   #  $region{NAME}{Polygon}{Pos}
  66   #  $region{NAME}{Special}
  67   #
  68   # also incidentally
  69   #  $region{NAME}{Adj}[]{Ends}[]{Adjoins}
  70   #  $region{NAME}{Polygon}{Adjoins}
  71   # which should be ignored
  72
  73   open P, "<", $facesf or die $!;
  74   while (<P>) { last if m/^\&faces$/; }
  75   my $rr;
  76   my @edges;
  77   my $process_rr = sub {
  78     my $last_ai;
  79     if ($rr->{Name} eq 'NZ') {
  80       # We combined L and NZ; now we must split them again
  81       # in fact, we just throw away L and L2 entirely.
  82       # Here, when processing NZ, we keep only vertices that
  83       # are part of NZ.
  84       @edges = grep {
  85         my $evxname = $_->{VxName};
  86         my @eregions = split / \| ?/, $evxname;
  87         grep { $_ eq 'NZ' } @eregions
  88       } @edges;
  89     }
  90     $rr->{Polygon} = [ @edges ];
  91     if ($rr->{Name} ne 'NZ') {
  92       for my $ei (0..$#edges) {
  93         if (!defined $last_ai) {
  94           my $ai;
  95           for my $ai (0..$#{ $rr->{Adj} }) {
  96             next unless $rr->{Adj}[$ai]{Name} eq $edges[$ei]{Adjoins};
  97             $last_ai = $ai+1;
  98           }
  99           confess $edges[$ei]{Adjoins}.' ?' unless defined $last_ai;
 100         }
 101         my $ai = ($last_ai-1+@edges) % @edges;
 102         $last_ai = $ai;
 103         my $adj = $rr->{Adj}[$ai];
 104         confess Dumper($adj->{Name}, $edges[$ei]{Adjoins},
 105                        $rr, \@edges, $ei, $adj, $last_ai, $ai)." ?"
 106             unless $adj->{Name} eq $edges[$ei]{Adjoins};
 107
 108         for my $endi (0..1) {
 109           $adj->{Ends}[$endi] = $edges[ ($ei + $endi) % @edges ];
 110         }
 111       }
 112     }
 113     @edges = ();
 114     $rr = undef;
 115   };
 116   my $vxname;
 117   for (;;) {
 118     $!=0; $_=<P> // confess $!;
 119     last if m/^\&$/;
 120     if (m/^$sre$/) {
 121       my $new_face= $2;
 122       $process_rr->() if $rr;
 123       $rr= prs2rr($new_face);
 124     } elsif (m/^\s+$sre$/) {
 125       confess unless $rr;
 126       $vxname = $2;
 127       push @edges, { VxName => $vxname };
 128     } elsif (m/^\s+\^adjoins\s+$sre$/) {
 129       $edges[-1]{Adjoins} = prs2r($2);
 130     } elsif (m/^\s+\^\@([-e.0-9]+)\,([-e.0-9]+)$/) {
 131       my $pos = mkvec($1,$2);
 132       confess unless defined $vxname;
 133       $edges[-1]{Pos} = $pos;
 134       $vxname2pos{$vxname} = $pos;
 135     }
 136   }
 137   $process_rr->();
 138
 139   $region{$_}{Special} = 1 foreach qw(NZ L L2);
 140 }
 141
 142 #----- geometry mangling -----
 143
 144 sub adj_ends ($) {
 145   my ($adj) = @_;
 146   map { $_->{Pos} } @{ $adj->{Ends} };
 147 }
 148
 149 sub calculate_centres () {
 150   # Sets
 151   #  $region{NAME}{Centre}
 152   foreach my $rr (values %region) {
 153     next if $rr->{Special};
 154     my $sum = Math::GSL::Vector->new(2);
 155     my $wsum = 0;
 156     foreach my $adj (@{ $rr->{Adj} }) {
 157       my @ends = adj_ends($adj);
 158       my $w = ($ends[1] - $ends[0])->norm();
 159       $sum += $w * $_ foreach @ends;
 160       $wsum += $w;
 161     }
 162     $rr->{Centre} = $sum * (0.5 / $wsum);
 163   }
 164 }
 165
 166 sub for_each_pos ($) {
 167   my ($f) = @_;
 168   my $call = sub {
 169     my ($pr,$rr,$why) = @_;
 170     return unless defined $$pr;
 171     $f->($pr,$rr,$why);
 172   };
 173   foreach my $rr (values %region) {
 174     $call->( \ $rr->{Centre}, $rr, $rr->{Name}." C" );
 175     foreach my $vertex (@{ $rr->{Polygon} }) {
 176       $call->( \ $vertex->{Pos}, $rr, $rr->{Name}." | ".$vertex->{Adjoins} );
 177     }
 178   }
 179 }
 180
 181 sub prvec ($) {
 182   my ($v) = @_;
 183   confess unless $v;
 184   sprintf "%g,%g", $v->get(0), $v->get(1);
 185 }
 186
 187 sub mkvec ($$) { Math::GSL::Vector->new(\@_) }
 188 sub vec2atan ($) { my ($dir) = @_; atan2 $dir->get(1), $dir->get(0); }
 189
 190 sub transform_coordinates () {
 191   # Adjusts coordinates in graph to be [0,0] .. top right (scaled)
 192   # until it's all in PostScript points
 193   my @or = map { $region{$_}{Centre} } @{ $c{OrientRegions} };
 194   my $dir = $or[1] - $or[0];
 195   my $theta = vec2atan($dir);
 196   my $rotateby = (90. - $c{OrientBearing}) * ((TAU)/360.) - $theta;
 197   my $s = sin($rotateby);
 198   my $c = cos($rotateby);
 199   my $transform = Math::GSL::Matrix->new(2,2);
 200   $transform->set_row(0, [  $c, -$s ]);
 201   $transform->set_row(1, [  $s,  $c ]);
 202   #  print STDERR "rotate was=",prvec($dir)," theta=$theta",
 203   #    " rotateby=$rotateby s=$s c=$c\n";
 204   my @lims;
 205   foreach my $topend (qw(0 1)) {
 206     my $v = $topend ? -$GSL_DBL_MAX : $GSL_DBL_MAX;
 207     $lims[$topend] = mkvec($v,$v);
 208   }
 209   for_each_pos(sub {
 210     my ($pr, $rr, $why) = @_;
 211     my $y = Math::GSL::Vector->new(2);
 212     gsl_blas_dgemv($CblasNoTrans,
 213                    1.0, $transform->raw,
 214                    $$pr->raw,
 215                    0, $y->raw)
 216         and confess;
 217     #print STDERR "gsl_blas_dgemv ",prvec($$pr)," => ",prvec($y),"\n";
 218     gsl_blas_dcopy($y->raw, $$pr->raw)
 219         and confess;
 220     foreach my $topend (qw(0 1)) {
 221       foreach my $xy (qw(0 1)) {
 222         my $now = $y->get($xy);
 223         my $lim = $lims[$topend]->get($xy);
 224         #print STDERR "?set $topend $xy $now $lim\n";
 225         next if $topend ? ($now <= $lim) : ($now >= $lim);
 226         $lims[$topend]->set([$xy], [$now]);
 227         #print STDERR "set $topend $xy $now\n";
 228       }
 229     }
 230   });
 231   #print STDERR "lims ",prvec($lims[0])," .. ",prvec($lims[1]),"\n";
 232   my $translate = -$lims[0];
 233   #print STDERR "translate ",prvec($translate),"\n";
 234   my $scale = $c{GraphScale} * MM2PT;
 235   for_each_pos(sub {
 236     my ($pr) = @_;
 237     gsl_vector_add($$pr->raw, $translate->raw) and confess;
 238     gsl_vector_scale($$pr->raw, $scale) and confess;
 239   });
 240   $mid = ($lims[1] - $lims[0]) * 0.5;
 241 }
 242
 243 sub adjust_nz() {
 244   my $poly = $region{NZ}{Polygon};
 245   my %occurs;
 246   foreach my $v (@$poly) {
 247     $occurs{$v->{VxName}}++
 248   }
 249   foreach my $v (@$poly) {
 250     $v->{NZ_Occurs} = $occurs{$v->{VxName}};
 251   }
 252   #print STDERR " nz ".(scalar @$poly)."\n";
 253   my $occurs_m = sub {
 254     my ($ei) = @_;
 255     $poly->[($ei+@$poly) % @$poly]{NZ_Occurs} > 1
 256   };
 257   for my $ei (0..$#$poly) {
 258     next if $occurs_m->($ei);
 259     next unless $occurs_m->($ei-1);
 260     next unless $occurs_m->($ei+1);
 261     #print STDERR " nz would adjust $poly->[$ei]{VxName}\n";
 262     # adjust coord outwards
 263   }
 264   for my $ei (0..$#$poly) {
 265     next unless $occurs_m->($ei);
 266     #print STDERR " nz occurs_m $ei $poly->[$ei]{VxName}\n";
 267     next unless $occurs_m->($ei-1);
 268     my $dleft = mkvec(-1000,0);
 269     foreach my $which (0,-1) {
 270       my $ej = ($ei +        $which + @$poly) % @$poly;
 271       my $ek = ($ei + +1 + 3*$which + @$poly) % @$poly;
 272       my $posj = \ $poly->[$ej]{Pos};
 273       my $posk = \ $poly->[$ek]{Pos};
 274       my $dout = $$posk - $$posj;
 275       #print STDERR " nz adj j=$ej ",prvec($$posj)," $poly->[$ej]{VxName}\n";
 276       #print STDERR " nz adj k=$ek ",prvec($$posk)," $poly->[$ek]{VxName}\n";
 277       if ($poly->[$ej]{VxName} =~ /Noorderzijlvest/) {
 278         #print STDERR " nz adj extra\n";
 279         $$posk = $$posj + 10 * mkvec(100,-50);
 280       }
 281       $$posj = $$posj + $dleft + $dout*10;
 282       $$posk = $$posk          + $dout*10;
 283     }
 284   }
 285 }
 286
 287 sub psvec ($) {
 288   my ($pos) = @_;
 289   sprintf "%20.6f %20.6f", $pos->get(0),$pos->get(1)
 290 }
 291
 292 sub face_path ($) {
 293   my ($rr) = @_;
 294   o("% $rr->{Name}\n");
 295   o("  newpath\n");
 296   my $xto = 'moveto';
 297   foreach my $vertex (@{ $rr->{Polygon} }) {
 298     my $pos = $vertex->{Pos};
 299     o(sprintf "    %s %s\n", psvec($pos), $xto);
 300     $xto = 'lineto';
 301   }
 302   o("    closepath\n");
 303 }
 304
 305 sub computeboundings() {
 306   $bb{Entire} = [ 0,0, $a4_h, $a4_w + $a3_h ];
 307   $bb{PageB} = [ 0,0, $a4_h, $a4_w ];
 308   my $page2minprintable = sub {
 309     my (@p) = @{ $_[0] };
 310     [ $p[0] + $max_printeredge,
 311       $p[1] + $max_printeredge,
 312       $p[2] - $max_printeredge,
 313       $p[3] - $max_printeredge ];
 314   };
 315   $bb{PrintableB} = $page2minprintable->($bb{PageB});
 316   my $mt_offset = $bb{PrintableB}[3] - $max_printeredge;
 317   $bb{PageMT} = [ 0, $mt_offset, $a4_h, $mt_offset + $a3_h ];
 318   $bb{PrintableMT} = $page2minprintable->($bb{PageMT});
 319   $bb{PrintableAll} = [
 320                       @{ $bb{PrintableB} }[0..1],
 321                       @{ $bb{PrintableMT} }[2..3],
 322                      ];
 323 }
 324
 325 sub showboundings () {
 326   return unless $xopts =~ m/B/;
 327   o("  grestore gsave\n");
 328   my $i = 0;
 329   my $on = 2;
 330   my $off = 9;
 331   foreach my $bname (sort keys %bb) {
 332     o(sprintf "   1 %d %d setrgbcolor\n",
 333       !!($bname =~ m/^Page/),
 334       !!($bname =~ m/B$/),
 335      );
 336     o("    % $bname\n");
 337     o("    [ $on $off ] ".($i * ($on+$off))," setdash newpath\n");
 338     my @p = @{ $bb{$bname} };
 339     o("    $p[0] $p[1] moveto\n");
 340     o("    $p[2] $p[1] lineto\n");
 341     o("    $p[2] $p[3] lineto\n");
 342     o("    $p[0] $p[3] lineto\n");
 343     o("    closepath stroke\n");
 344     $i++;
 345   }
 346 }
 347
 348 sub o_amble (@) {
 349   # CPerl-mode does a really awful thing with %s in the preamble
 350   # and postamble, causing constant useless flashing
 351   # So we write & in the here docs and transform them back:
 352   my ($t) = join '', @_;
 353   $t =~ s/^\&+/ '%' x length $& /mge;
 354   o($t);
 355 }
 356
 357 sub preamble() {
 358   my $bb = $bb{$bounding}; confess $bounding unless $bb;
 359   my $sz = [ $bb->[2] - $bb->[0], $bb->[3] - $bb->[1] ];
 360   o_amble(<<END);
 361 &!PS-Adobe-3.0
 362 &&BoundingBox @$bb
 363 &&Pages: 1
 364 &&EndComments
 365 &&BeginProlog
 366 &&EndProlog
 367 &&BeginSetup
 368 << /PageSize [ @$sz ] >> setpagedevice
 369 /board {
 370   gsave
 371   34 -15 translate
 372 END
 373   # xxx split into pages
 374 }
 375
 376 sub postamble () {
 377   o_amble(<<END);
 378   grestore
 379 } bind def
 380 &&EndSetup
 381 &&Page: 1
 382 &&BeginPageSetup
 383 /pgsave save def
 384 &&EndPageSetup
 385 board
 386 pgsave restore
 387 showpage
 388 &&EOF
 389 END
 390 }
 391
 392 sub pscolour ($$$$) {
 393   my ($colourname, $cmykix,$rgbmul,$rgbadd) = @_;
 394   my $spec = $c{Colours}{$colourname};
 395   confess unless defined $spec;
 396
 397   # check that we have only one lighter/darker retain value for each one
 398   our %colour_occurred;
 399   $colour_occurred{$colourname}{$cmykix}{$rgbmul,$rgbadd} = 1;
 400   keys %{ $colour_occurred{$colourname}{$cmykix} } == 1 or confess;
 401
 402   my @r;
 403   my $rw;
 404   if ($spec =~ m/^[0-9a-f]+$/) {
 405     my $le = (length $spec)/3;
 406     my $re = ("(.{$le})") x 3;
 407     my @rgb = $spec =~ m/^$re$/;  @rgb or confess "$re ?";
 408     @rgb = map { hex($_) / (16**$le -1) } @rgb;
 409     foreach (@rgb) { $_ *= $rgbmul; $_ += $rgbadd; }
 410     @r = @rgb;
 411     $rw = 'setrgbcolor';
 412   } elsif ($spec =~ m/[CMYK]/) {
 413     my @specs = split /\//, $spec;
 414     if ($cmykix==1 && @specs==1) {
 415       $spec = $specs[0];
 416     } else {
 417       $spec = $specs[$cmykix];
 418       confess unless defined $spec;
 419     }
 420     my %cmyk;
 421     foreach (split /(?=[A-Z])/, $spec) {
 422       m/^([CMYK])([0-7](?:\.\d*)?|8)_?$/ or confess $_.' ?';
 423       confess if defined $cmyk{$1};
 424       $cmyk{$1} = $2 / 8.;
 425       #print STDERR " CMYK $1 $2\n";
 426     }
 427     @r = map { $cmyk{$_} // 0 } qw(C M Y K);
 428     $rw = 'setcmykcolor';
 429   } else {
 430     confess $spec.' ?';
 431   }
 432   my $r = join ' ',
 433       (map { sprintf "%.6f ", $_ } @r
 434       ),
 435           $rw;
 436   return $r;
 437 }
 438
 439 sub lighterpscolour ($$) {
 440   my ($colourname, $retain) = @_;
 441   #print STDERR "COLOUR LIGHTER $retain $colourname\n";
 442   pscolour($colourname, 0, $retain, 1-$retain);
 443 }
 444
 445 sub darkerpscolour ($$) {
 446   my ($colourname, $retain) = @_;
 447   #print STDERR "COLOUR DARKER $retain $colourname\n";
 448   pscolour($colourname, 2, $retain, 0);
 449 }
 450
 451 sub facepscolour ($) {
 452   my ($colourname) = @_;
 453   $xopts =~ m/W/ ? '1 setgray' : lighterpscolour($colourname, 0.75);
 454 }
 455
 456 sub miscpscolour ($) {
 457   my ($colourname) = @_;
 458   #print STDERR "COLOUR MISC $colourname\n";
 459   pscolour($colourname, 1, 1,0);
 460 }
 461
 462 sub seatrackedgepscolour () { darkerpscolour('cube', 0.25) }
 463
 464 sub fill_faces() {
 465   o("clippath ", facepscolour('land'), " fill\n");
 466   foreach my $rr (values %region) {
 467     next if $rr->{Name} =~ m/^L2?$/;
 468     face_path($rr);
 469     o(" ", facepscolour($rr->{Colour}), " eofill\n");
 470   }
 471 }
 472
 473 our $edge_lw = 5;
 474
 475 sub some_edge_faces (@) {
 476   o("$edge_lw setlinewidth 1 setlinejoin ",miscpscolour('edge'),"\n");
 477   foreach my $rr (@_) {
 478     next if $rr->{Name} =~ m/^L2?$/;
 479     face_path($rr);
 480     o("    stroke\n");
 481   }
 482 }
 483
 484 sub afsluitdijk() {
 485   my ($adj) = grep { $_->{Name} eq 'NZ' } @{ $region{'ZZ'}{Adj} };
 486   my $dash = 20;
 487   my (@pos) = adj_ends($adj);
 488   my $mid = 0.5 * ($pos[0] + $pos[1]);
 489   my $r = 0.5 * ($pos[1] - $pos[0])->norm();
 490   o(sprintf <<'END', facepscolour('sea'), psvec($mid), $r);
 491   %% Afsluitdijk
 492   %s %s %s 0 360 arc closepath fill
 493 END
 494   some_edge_faces(()); # just sets the colour
 495   o(sprintf <<END, map { psvec($_) } @pos);
 496   newpath %s moveto %s lineto
 497   [ $dash $dash ] $dash 0.5 mul setdash
 498   stroke
 499   [] 0 setdash
 500 END
 501   one_hs('purple', $mid);
 502 }
 503
 504 sub edge_faces() {
 505   some_edge_faces($region{'NZ'});
 506   afsluitdijk();
 507   some_edge_faces(grep {
 508     $_->{Name} !~ m{^(?:L2?|NZ|ZZ)$}
 509   } values %region);
 510 }
 511
 512 our $hs_sz = 17 * MM2PT;
 513 our $hs_lw = 3;
 514
 515 our $text_sz = 18;
 516
 517 sub token_circle ($$$$;$$) {
 518   my ($what, $pos, $fillcolour, $edgecolour, $sz,$lw) = @_;
 519   $sz //= $hs_sz;
 520   $lw //= $hs_lw;
 521   o(sprintf <<END, $what, $fillcolour, psvec($pos), $sz/2, $edgecolour);
 522    %% %s
 523    newpath %s
 524      %s %f 0 360 arc closepath gsave fill grestore
 525      %s $lw setlinewidth stroke
 526 END
 527 }
 528
 529 sub one_hs ($$;$$) {
 530   my ($colour, $hspos, $sz, $lw) = @_;
 531   token_circle("HS - $colour",
 532                $hspos,
 533                darkerpscolour($colour, 0.75),
 534                miscpscolour('edge'),
 535               $sz,$lw);
 536 }
 537
 538 our $cube_sz = 6 * MM2PT;
 539 our $cube_gap = $cube_sz * 0.2;
 540 our $cube_lw = ($cube_sz * 0.1);
 541
 542 sub label_faces() {
 543   my $sz = $text_sz;
 544   my $shadow = $sz * 0.1;
 545   my $textc   = miscpscolour('text');
 546   my $shadowc = miscpscolour('textshadow');
 547   o(<<END);
 548   /wordsshow {
 549     $shadowc 0 10 359 {
 550       dup  cos $shadow mul
 551       exch sin $shadow mul
 552       words pop pop
 553     } bind for
 554     $textc 0 0 words pop pop
 555   } def
 556 END
 557   o("  /Helvetica-Bold findfont  $sz scalefont setfont\n");
 558   my %hs = map { $_ => 1 } @{ $c{HS} };
 559   foreach my $rr (values %region) {
 560     next if $rr->{Name} =~ m/^L\d?$/;
 561     my $words = $rr->{DisplayName};
 562     my $pos;
 563     if ($rr->{Name} eq 'NZ') {
 564       $pos = mkvec(90, 1280);
 565     } else {
 566       $pos = $rr->{Centre} + mkvec( 0, 0.5 * $sz * @$words );
 567     }
 568     if ($hs{$rr->{Name}}) {
 569       #print STDERR "adjust hs $rr->{Name}\n";
 570       $pos -= mkvec(0, -$hs_sz*
 571                     ( $rr->{Colour} eq 'green' ? 0.25 : 0.65 ));
 572       my $hspos = $pos - mkvec(0, $sz * @$words + $hs_sz/2 + $hs_lw
 573                                + $hs_sz*0.15);
 574       one_hs($rr->{Colour}, $hspos);
 575     }
 576     my $adjust = $c{TextAdjust}{$rr->{Name}};
 577     if ($adjust) {
 578       $pos += $sz * &mkvec(@$adjust);
 579     }
 580     my $w = $rr->{Water};
 581     $w = 2 if $rr->{Special} || $rr->{Name} eq 'ZZ';
 582     if ($w) {
 583       #print STDERR " water $w in $rr->{Name}\n";
 584       my $down = water_cubes_sz(2) - water_cubes_sz(1) + $cube_gap;
 585       $pos -= mkvec(0, -0.5 * $down);
 586       my $cube_y = -($sz * @$words);
 587       if ($rr->{Name} eq 'Wieringermeer') {
 588         $pos -= mkvec(0,+$sz);
 589         $cube_y = 0;
 590         $down = 0;
 591       }
 592       o("  gsave\n");
 593       o("    ", psvec($pos), " translate\n");
 594       o("    0 ", $cube_y, " translate\n");
 595       o("    ", -0.5 * water_cubes_sz($w)," ", -$down, " translate\n");
 596       water_cubes($w, miscpscolour('edge'));
 597       o("  grestore\n");
 598     }
 599     o("  /words {\n");
 600     foreach my $word (@$words) {
 601       $pos += mkvec(0,-$sz);
 602       o("   ", psvec($pos), " moveto");
 603       o(<<END);
 604    2 copy rmoveto
 605    ($word) dup stringwidth pop     % word xw
 606      -0.5 mul 0 rmoveto             % word
 607      show
 608    0 -$sz rmoveto
 609 END
 610     }
 611     o(<<END);
 612   } bind def
 613   wordsshow
 614 END
 615   }
 616 }
 617
 618 sub water_cubes_sz($){
 619   my ($n) = @_;
 620   ($cube_sz + $cube_lw) * $n + ($cube_gap * ($n-1));
 621 }
 622
 623 sub water_cubes($$){
 624   my ($n, $edgecolour) = @_;
 625   my $s = $cube_sz;
 626   for my $i (0..$n-1) {
 627     o("  newpath  ", $i * ($cube_sz + $cube_lw + $cube_gap),"  0  moveto\n");
 628     o("          $s  0  rlineto\n");
 629     o("           0 $s  rlineto\n");
 630     o("         -$s  0  rlineto  closepath\n");
 631     o("  gsave ", miscpscolour('cube'), " fill grestore\n");
 632     o("  gsave ", $edgecolour, " ", $cube_lw,
 633       " setlinewidth stroke grestore \n");
 634   }
 635 }
 636
 637 my $deck_h = 89 * MM2PT;
 638
 639 sub decks(){
 640   my $lw = $edge_lw/2;
 641   o("  /deck1path {\n");
 642   my $w = 63 * MM2PT;
 643   my $h = $deck_h;
 644   my $r =  5 * MM2PT;
 645   o("      ",($w/2)," 0 moveto\n");
 646   my @p = ([ $w, 0 ],
 647            [ $w,$h ],
 648            [ 0, $h ],
 649            [ 0,  0 ]);
 650   foreach my $i (0..3) {
 651     o("    @{ $p[$i] }  @{ $p[($i + 1) % 4] }  $r  arct\n");
 652   }
 653   o("    closepath\n");
 654   o("  } bind def");
 655   o("  /deckpairpathx {\n"); # x because it leaves matrix changed
 656   o("    newpath         deck1path\n");
 657   o("    200 0 translate deck1path\n");
 658   o("  } bind def");
 659   o("  $lw setlinewidth ",miscpscolour('playerdeck'),"\n");
 660   o("  gsave 401 44 translate deckpairpathx stroke grestore");
 661   o("  $lw setlinewidth ",miscpscolour('dykefail'),"\n");
 662   o("  gsave 242 1363 translate 90 rotate deckpairpathx stroke grestore");
 663 }
 664
 665 sub sea_track(){
 666   o("% sea level track\n");
 667   o("  gsave 11 700 translate\n");
 668   my $track = $c{SeaTrack};
 669   my $token_sz = $hs_sz;
 670   my $dy = $token_sz * 1.25;
 671   my $dx = $token_sz * 1.25;
 672   my $linecolour = seatrackedgepscolour();
 673   my @pos;
 674   for my $i (0..$#$track) {
 675     $pos[$i] = mkvec(0, ($i - 0.5 * @$track) * $dy);
 676   }
 677   my $prepline = "$linecolour $hs_lw setlinewidth newpath";
 678   o("  $prepline\n");
 679   o("    ",psvec($pos[0])," moveto ",psvec($pos[-1])," lineto stroke\n");
 680   for my $pos (@pos) {
 681     token_circle("SL", $pos,
 682                  miscpscolour('cube'),
 683                  $linecolour);
 684   }
 685   my $last = 0;
 686   my $cubeedgecolour = seatrackedgepscolour();
 687   for my $i (0..$#pos) {
 688     my $differs = $track->[$i] != $last;
 689     $last = $track->[$i];
 690     next unless $differs;
 691     o("  $prepline\n");
 692     o("  gsave ",
 693       psvec($pos[$i] + mkvec(-0.0 * $token_sz, $dy/2))," translate\n");
 694
 695     my $t_sz = 24;
 696     my $shrink = ($hs_sz * 0.75 / $deck_h);
 697     o("    gsave % T M $i\n");
 698     o("      -43.5 -6.5 translate\n");
 699     o("      0.8 .8 scale \n");
 700     o("      ",0.6 * $dx, " ", -0.28 * $dy," translate\n");
 701     o("      gsave");
 702     o("        $shrink dup scale -90 rotate\n");
 703     o("        newpath ", ($hs_lw / $shrink)," setlinewidth\n");
 704     o("         deck1path stroke\n");
 705     o("      grestore");
 706     o("      /Helvetica-Bold findfont $t_sz scalefont setfont\n");
 707     o("      12 -21.5 moveto ($track->[$i]) show");
 708     o("    grestore\n");
 709
 710     if ($i > 0) {
 711       o("  0 -$dy moveto",
 712         " ",psvec(mkvec( $dx + $cube_sz, 0 )),
 713         " rlineto stroke\n");
 714     }
 715     o("  ",($token_sz * 0.6 + $cube_gap)," ",
 716       (-$dy * 0.5 - 0.5 * (water_cubes_sz(2))),
 717       " translate\n");
 718     my $bottom = int(($track->[$i+1] + 1) / 2);
 719     water_cubes($bottom, $cubeedgecolour);
 720     my $new_n = $track->[$i+1] - $bottom;
 721     o("  ", 0.5 * (water_cubes_sz($bottom) - water_cubes_sz($new_n)),
 722       "  ",       (water_cubes_sz(2)-water_cubes_sz(1)), " translate\n");
 723     water_cubes($new_n, $cubeedgecolour);
 724     o("  grestore\n");
 725   }
 726   o("  grestore\n");
 727 }
 728
 729 our $dyke_l = 25 * MM2PT;;
 730
 731 sub dykes(){
 732   my $l = $dyke_l;
 733   my $w = 5 * MM2PT;
 734   my $lw = $edge_lw * 0.50;
 735   my $l2 = $l/2;
 736   my $w2 = $w/2;
 737   o("  /dykepath {\n");
 738   o("            -$l2 -$w2 moveto\n");
 739   o("             $l2 -$w2 lineto\n");
 740   o("             $l2  $w2 lineto\n");
 741   o("            -$l2  $w2 lineto closepath\n");
 742   o("  } bind def\n");
 743   o("  /dyke {\n");
 744   o("    newpath dykepath\n");
 745   o("    gsave ",miscpscolour('dykefill')," fill grestore\n");
 746   o("    gsave ",miscpscolour('edge')," $lw setlinewidth stroke grestore\n");
 747   o("  } bind def\n");
 748   my $symbol_sz = $w * 1.50;
 749   my $t_sz = $symbol_sz * 1.0;
 750   my $t_at = sub {
 751     my ($ang) = @_;
 752     #print STDERR "ANG $ang\n";
 753     map { $t_sz * 0.5 * $_ } cos($ang), sin($ang);
 754   };
 755   my @t0 = $t_at->((TAU) *  0.25         );
 756   my @t1 = $t_at->((TAU) * (0.25 + 1./3) );
 757   my @t2 = $t_at->((TAU) * (0.25 + 2./3) );
 758   o("  /dtriangle {\n");
 759   o("    newpath @t0 moveto\n");
 760   o("            @t1 lineto\n");
 761   o("            @t2 lineto closepath\n");
 762   o("    gsave ",miscpscolour('dykeinit')," fill grestore\n");
 763   o("    gsave ",miscpscolour('edge')," $lw setlinewidth stroke grestore\n");
 764   o("  } bind def\n");
 765   foreach my $rr (values %region) {
 766     next if $rr->{Special};
 767     next if $rr->{Name} eq 'ZZ';
 768     next if $rr->{Colour} eq 'high';
 769     foreach my $adj (@{ $rr->{Adj} }) {
 770       my $neigh = $adj->{Name};
 771       o("  % dyke $rr->{Name} --- $neigh\n");
 772       next if $neigh lt $rr->{Name} && !$region{$neigh}{Special};
 773       next if $region{$neigh}{Colour} eq 'high';
 774       my @ends = adj_ends($adj);
 775       my $dirn = $ends[1] - $ends[0];
 776       my $angle = vec2atan($dirn);
 777       $angle = $angle * 360 / TAU;
 778       o("  gsave\n");
 779       o("    ", psvec( 0.5 * ($ends[0] + $ends[1]) )," translate\n");
 780       o("    $angle rotate\n");
 781       my $initial = $adj->{Dykes};
 782       for my $ys ($initial
 783                   ? [ map { $_ - 0.5 * ($initial-1) } 0..$initial-1 ]
 784                   : [0]) {
 785         foreach my $y (@$ys) {
 786           o("    gsave 0 ", $y * $w, " translate dyke ");
 787           o(" grestore\n");
 788         }
 789         my $nsymbols = $initial + !!$adj->{Deltawerk};
 790         o("   ", -0.5 * $symbol_sz * ($nsymbols-1)," 0 translate\n");
 791         my $trans = "  $symbol_sz 0 translate";
 792         if ($adj->{Deltawerk}) {
 793           one_hs('red', mkvec(0,0), $symbol_sz * 0.8, $lw);
 794           o($trans);
 795         }
 796         foreach my $i (1..$initial) {
 797           o(" gsave $angle neg rotate dtriangle grestore\n");
 798           o($trans);
 799         }
 800       }
 801       o("  grestore\n");
 802     }
 803   }
 804 }
 805
 806 sub hs_initial_1 ($$$;$$$) {
 807   my ($colour, $xi,$yi, $text, $text2, $fn) = @_;
 808   my $interval = $hs_sz * 1.75;
 809   my $demo_h = $hs_sz; #water_cubes_sz(3);
 810   my $demo_x0 = $hs_sz * 0.75 + $dyke_l * 0.60;
 811   my $demo_w = $demo_x0 + $dyke_l * 0.60;
 812   o("  % HS I $colour\n");
 813   o("  gsave\n");
 814   o("    550 1705 translate\n");
 815   o("    ", ($xi*$interval), " ", (($yi-1)*$interval), " translate\n");
 816   if ($fn) {
 817     o("  gsave\n");
 818     o("        $demo_h setlinewidth 0 0 moveto $demo_w 0 rlineto\n");
 819     o("        ", facepscolour($colour), " stroke grestore\n");
 820   }
 821   one_hs($colour, mkvec(0,0));
 822   if ($fn) {
 823     o("    /words {\n");
 824     o("      2 copy moveto                      ($text) show\n");
 825     o("      2 copy moveto 0 -$text_sz rmoveto ($text2) show\n");
 826     o("    } bind def\n");
 827     o("    gsave ".($hs_sz * 0.8)." $cube_gap translate wordsshow grestore\n");
 828     o("    $demo_x0 ",($hs_sz * -0.25)," translate\n");
 829     $fn->();
 830   }
 831   o("  grestore\n");
 832 }
 833
 834 sub hs_initial () {
 835   hs_initial_1('red',     0,0);
 836   hs_initial_1('purple',  0,1);
 837   hs_initial_1('green',   1,0, 'up to 6', 'fewer', sub {
 838     o("    ",(water_cubes_sz(1))," 0 translate\n");
 839     o("    0 ",(-water_cubes_sz(1) * 0.3)," translate\n");
 840     water_cubes(1, miscpscolour('edge'));
 841   });
 842   hs_initial_1('yellow',  1,1, 'up to 4', '', sub {
 843     o("    newpath dykepath\n");
 844     o("    gsave ",miscpscolour('edge')," stroke grestore\n");
 845     o("    gsave ",miscpscolour('dykehsadd')," fill grestore\n");
 846   });
 847 }
 848
 849 sub play_hint () {
 850   my $sz = 20;
 851   o("  gsave ",miscpscolour('hinttext')," 260 1715 translate\n");
 852   o("  /Helvetica-Bold findfont $sz scalefont setfont\n");
 853   my @t = split /\n/, $c{PlayHint};
 854   foreach my $i (0..$#t) {
 855     my $t = $t[$i];
 856     $t =~ s/[\\()]/\\$&/g;
 857     o("  0 ",(-$i * $sz)," moveto ($t) show\n");
 858   }
 859   o("  grestore");
 860 }
 861
 862 #----- main program -----
 863
 864 $xopts = shift @ARGV if $ARGV[0] =~ s/^-X//;
 865 $bounding = $1 if $xopts =~ s/b(\w+)//;
 866 $maxpaper = $1 if $xopts =~ s/p(\w+)//;
 867 $maxpaper =~ m/^a[134]$/ or confess;
 868
 869 ($facesf, @ARGV) = @ARGV or die;
 870 parse_input_graph();
 871 prep_region_rmap();
 872 read_faces();
 873 calculate_centres();
 874 transform_coordinates();
 875 adjust_nz();
 876
 877 computeboundings();
 878 preamble();
 879 fill_faces();
 880 edge_faces();
 881 dykes();
 882 label_faces();
 883 decks();
 884 sea_track();
 885 hs_initial();
 886 play_hint();
 887 showboundings();
 888 postamble();
 889
 890 print STDERR Dumper(\%region) if $ENV{'GENERATE_BOARD_DUP'};
 891
 892 # Local variables:
 893 # cperl-indent-level: 2
 894 # End.