generate-board

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Carp;
   5 use Data::Dumper;
   6 use Math::GSL::Vector qw/:all/;
   7 use Math::GSL::Matrix qw/:all/;
   8 use Math::GSL::Const;
   9 use Math::GSL::BLAS qw/:all/;
  10 use Math::GSL::CBLAS qw/:all/;
  11 use Math::GSL::Machine qw/:all/;
  12
  13 use POSIX qw(M_PI);
  14
  15 BEGIN { unshift @INC, qw(.); }
  16
  17 use Parse;
  18
  19 our $xopts = '';
  20 our $bounding = 'Entire';
  21 our $facesf;
  22 our %vxname2pos; # $vxname2pos{VXNAME} = Math::GSL::Vector
  23 our %bb; # $r{Bounding...}[0..3] = points
  24 our $maxpaper = 'a3';
  25 my $a1sfactor = 1/sqrt(8);
  26
  27 sub TAU { M_PI * 2.0; }
  28 sub MM2PT { 72.0 / 25.4; }
  29
  30 our $mid;
  31
  32 our $a4_w = 595;
  33 our $a4_h = 842;
  34 our $a3_h = 1190;
  35 our $a1_w = 1684;
  36 our $a1_h = 2384;
  37
  38 our $max_printeredge = 5.50 * MM2PT;
  39 our $a1m_pasteedge = 3.5 * MM2PT; # along each edge
  40 our $preamble_from_boundings = '';
  41 our $top_adjuncts_dy_from_boundings = 0;
  42 our $bottom_adjuncts_dy_from_boundings = 0;
  43
  44 # ----- region names from plag, incl. reverse mapping -----
  45
  46 our %prs2region;
  47
  48 sub prep_region_rmap () {
  49   foreach my $rn (keys %region) {
  50     my $prs = plag_prs($rn);
  51     die if $prs2region{$prs};
  52     $prs2region{$prs} = $rn;
  53   }
  54 }
  55
  56 our $sre = qr{(?:(\")|(?=\w))(.*)\1$}; # 2 captures, $2 is the name
  57
  58 sub prs2r ($) {
  59   # bodgery for the sea and land
  60   return $c{Sea} if m/ \| / && !grep { !m{^$c{OuterfaceRe}$} } split / \| /, $_[0];
  61   $prs2region{$_[0]} // confess "@_ ?"
  62 }
  63 sub prs2rr ($) { $region{prs2r($_[0])} }
  64
  65 #----- file reader for plag output -----
  66
  67 sub read_faces () {
  68   # Sets
  69   #  $region{NAME}{Adj}[]{Ends}[]{VxName}
  70   #  $region{NAME}{Adj}[]{Ends}[]{Pos}
  71   #  $region{NAME}{Polygon}{Pos}
  72   #  $region{NAME}{Special}
  73   #
  74   # also incidentally
  75   #  $region{NAME}{Adj}[]{Ends}[]{Adjoins}
  76   #  $region{NAME}{Polygon}{Adjoins}
  77   # which should be ignored
  78
  79   open P, "<", $facesf or die $!;
  80   while (<P>) { last if m/^\&faces$/; }
  81   my $rr;
  82   my @edges;
  83   my $process_rr = sub {
  84     my $last_ai;
  85     if ($rr->{Name} eq $c{Sea}) {
  86       # We combined land and sea; now we must split them again
  87       # in fact, we just throw away all L entirely.
  88       # Here, when processing sea, we keep only vertices that
  89       # are part of the sea.
  90       @edges = grep {
  91         my $evxname = $_->{VxName};
  92         my @eregions = split / \| ?/, $evxname;
  93         grep { $_ eq $c{Sea} } @eregions
  94       } @edges;
  95     }
  96     $rr->{Polygon} = [ @edges ];
  97     if ($rr->{Name} ne $c{Sea}) {
  98       for my $ei (0..$#edges) {
  99         if (!defined $last_ai) {
 100           my $ai;
 101           for my $ai (0..$#{ $rr->{Adj} }) {
 102             next unless $rr->{Adj}[$ai]{Name} eq $edges[$ei]{Adjoins};
 103             $last_ai = $ai+1;
 104           }
 105           confess $edges[$ei]{Adjoins}.' ?' unless defined $last_ai;
 106         }
 107         my $ai = ($last_ai-1+@edges) % @edges;
 108         $last_ai = $ai;
 109         my $adj = $rr->{Adj}[$ai];
 110         confess Dumper($adj->{Name}, $edges[$ei]{Adjoins},
 111                        $rr, \@edges, $ei, $adj, $last_ai, $ai)." ?"
 112             unless $adj->{Name} eq $edges[$ei]{Adjoins};
 113
 114         for my $endi (0..1) {
 115           $adj->{Ends}[$endi] = $edges[ ($ei + $endi) % @edges ];
 116         }
 117       }
 118     }
 119     @edges = ();
 120     $rr = undef;
 121   };
 122   my $vxname;
 123   for (;;) {
 124     $!=0; $_=<P> // confess $!;
 125     last if m/^\&$/;
 126     if (m/^$sre$/) {
 127       my $new_face= $2;
 128       $process_rr->() if $rr;
 129       $rr= prs2rr($new_face);
 130     } elsif (m/^\s+$sre$/) {
 131       confess unless $rr;
 132       $vxname = $2;
 133       push @edges, { VxName => $vxname };
 134     } elsif (m/^\s+\^adjoins\s+$sre$/) {
 135       $edges[-1]{Adjoins} = prs2r($2);
 136     } elsif (m/^\s+\^\@([-e.0-9]+)\,([-e.0-9]+)$/) {
 137       my $pos = mkvec($1,$2);
 138       confess unless defined $vxname;
 139       $edges[-1]{Pos} = $pos;
 140       $vxname2pos{$vxname} = $pos;
 141     }
 142   }
 143   $process_rr->();
 144
 145   $region{$_}{Special} = 1 foreach @{ $c{SpecialRegions} };
 146 }
 147
 148 #----- geometry mangling -----
 149
 150 sub adj_ends ($) {
 151   my ($adj) = @_;
 152   map { $_->{Pos} } @{ $adj->{Ends} };
 153 }
 154
 155 sub calculate_centres () {
 156   # Sets
 157   #  $region{NAME}{Centre}
 158   foreach my $rr (values %region) {
 159     next if $rr->{Special};
 160     my $sum = Math::GSL::Vector->new(2);
 161     my $wsum = 0;
 162     foreach my $adj (@{ $rr->{Adj} }) {
 163       my @ends = adj_ends($adj);
 164       my $w = ($ends[1] - $ends[0])->norm();
 165       $sum += $w * $_ foreach @ends;
 166       $wsum += $w;
 167     }
 168     $rr->{Centre} = $sum * (0.5 / $wsum);
 169   }
 170 }
 171
 172 sub for_each_pos ($) {
 173   my ($f) = @_;
 174   my $call = sub {
 175     my ($pr,$rr,$why) = @_;
 176     return unless defined $$pr;
 177     $f->($pr,$rr,$why);
 178   };
 179   foreach my $rr (values %region) {
 180     $call->( \ $rr->{Centre}, $rr, $rr->{Name}." C" );
 181     foreach my $vertex (@{ $rr->{Polygon} }) {
 182       $call->( \ $vertex->{Pos}, $rr, $rr->{Name}." | ".$vertex->{Adjoins} );
 183     }
 184   }
 185 }
 186
 187 sub prvec ($) {
 188   my ($v) = @_;
 189   confess unless $v;
 190   sprintf "%g,%g", $v->get(0), $v->get(1);
 191 }
 192
 193 sub mkvec ($$) { Math::GSL::Vector->new(\@_) }
 194 sub vec2atan ($) { my ($dir) = @_; atan2 $dir->get(1), $dir->get(0); }
 195
 196 sub transform_coordinates () {
 197   # Adjusts coordinates in graph to be [0,0] .. top right (scaled)
 198   # until it's all in PostScript points
 199   my @or = map { $region{$_}{Centre} } @{ $c{OrientRegions} };
 200   my $dir = $or[1] - $or[0];
 201   my $theta = vec2atan($dir);
 202   my $rotateby = (90. - $c{OrientBearing}) * ((TAU)/360.) - $theta;
 203   my $s = sin($rotateby);
 204   my $c = cos($rotateby);
 205   my $transform = Math::GSL::Matrix->new(2,2);
 206   $transform->set_row(0, [  $c, -$s ]);
 207   $transform->set_row(1, [  $s,  $c ]);
 208   #  print STDERR "rotate was=",prvec($dir)," theta=$theta",
 209   #    " rotateby=$rotateby s=$s c=$c\n";
 210   my @lims;
 211   foreach my $topend (qw(0 1)) {
 212     my $v = $topend ? -$GSL_DBL_MAX : $GSL_DBL_MAX;
 213     $lims[$topend] = mkvec($v,$v);
 214   }
 215   for_each_pos(sub {
 216     my ($pr, $rr, $why) = @_;
 217     my $y = Math::GSL::Vector->new(2);
 218     gsl_blas_dgemv($CblasNoTrans,
 219                    1.0, $transform->raw,
 220                    $$pr->raw,
 221                    0, $y->raw)
 222         and confess;
 223     #print STDERR "gsl_blas_dgemv ",prvec($$pr)," => ",prvec($y),"\n";
 224     gsl_blas_dcopy($y->raw, $$pr->raw)
 225         and confess;
 226     foreach my $topend (qw(0 1)) {
 227       foreach my $xy (qw(0 1)) {
 228         my $now = $y->get($xy);
 229         my $lim = $lims[$topend]->get($xy);
 230         #print STDERR "?set $topend $xy $now $lim\n";
 231         next if $topend ? ($now <= $lim) : ($now >= $lim);
 232         $lims[$topend]->set([$xy], [$now]);
 233         #print STDERR "set $topend $xy $now\n";
 234       }
 235     }
 236   });
 237   #print STDERR "lims ",prvec($lims[0])," .. ",prvec($lims[1]),"\n";
 238   my $translate = -$lims[0];
 239   #print STDERR "translate ",prvec($translate),"\n";
 240   my $scale = $c{GraphScale} * MM2PT;
 241   for_each_pos(sub {
 242     my ($pr) = @_;
 243     gsl_vector_add($$pr->raw, $translate->raw) and confess;
 244     gsl_vector_scale($$pr->raw, $scale) and confess;
 245   });
 246   $mid = ($lims[1] - $lims[0]) * 0.5;
 247 }
 248
 249 sub adjust_sea() {
 250   # Adjusts the top and bottom edges of the sea
 251   my $poly = $region{$c{Sea}}{Polygon};
 252   my %occurs;
 253   foreach my $v (@$poly) {
 254     $occurs{$v->{VxName}}++
 255   }
 256   foreach my $v (@$poly) {
 257     $v->{SeaOccurs} = $occurs{$v->{VxName}};
 258   }
 259   #print STDERR " sea ".(scalar @$poly)."\n";
 260   my $occurs_m = sub {
 261     my ($ei) = @_;
 262     $poly->[($ei+@$poly) % @$poly]{SeaOccurs} > 1
 263   };
 264   for my $ei (0..$#$poly) {
 265     next if $occurs_m->($ei);
 266     next unless $occurs_m->($ei-1);
 267     next unless $occurs_m->($ei+1);
 268     #print STDERR " sea would adjust $poly->[$ei]{VxName}\n";
 269     # adjust coord outwards
 270   }
 271   for my $ei (0..$#$poly) {
 272     next unless $occurs_m->($ei);
 273     #print STDERR " sea occurs_m $ei $poly->[$ei]{VxName}\n";
 274     next unless $occurs_m->($ei-1);
 275     my $dleft = mkvec(-1000,0);
 276     foreach my $which (0,-1) {
 277       my $ej = ($ei +        $which + @$poly) % @$poly;
 278       my $ek = ($ei + +1 + 3*$which + @$poly) % @$poly;
 279       my $posj = \ $poly->[$ej]{Pos};
 280       my $posk = \ $poly->[$ek]{Pos};
 281       my $dout = $$posk - $$posj;
 282       #print STDERR " sea adj j=$ej ",prvec($$posj)," $poly->[$ej]{VxName}\n";
 283       #print STDERR " sea adj k=$ek ",prvec($$posk)," $poly->[$ek]{VxName}\n";
 284       if ($poly->[$ej]{VxName} =~ /Noorderzijlvest/) {
 285         #print STDERR " sea adj extra\n";
 286         $$posk = $$posj + 10 * mkvec(100,-50);
 287       }
 288       $$posj = $$posj + $dleft + $dout*10;
 289       $$posk = $$posk          + $dout*10;
 290     }
 291   }
 292 }
 293
 294 sub psvec ($) {
 295   my ($pos) = @_;
 296   sprintf "%20.6f %20.6f", $pos->get(0),$pos->get(1)
 297 }
 298
 299 sub face_path ($) {
 300   my ($rr) = @_;
 301   o("% $rr->{Name}\n");
 302   o("  newpath\n");
 303   my $xto = 'moveto';
 304   foreach my $vertex (@{ $rr->{Polygon} }) {
 305     my $pos = $vertex->{Pos};
 306     o(sprintf "    %s %s\n", psvec($pos), $xto);
 307     $xto = 'lineto';
 308   }
 309   o("    closepath\n");
 310 }
 311
 312 sub computeboundings() {
 313   $bb{Entire} = [ 0,0, $a4_h, $a4_w + $a3_h ];
 314   my $submargins = sub {
 315     my ($margin, $pr) = @_;
 316     my @p = @$pr;
 317     [ $p[0] + $margin,
 318       $p[1] + $margin,
 319       $p[2] - $margin,
 320       $p[3] - $margin ];
 321   };
 322   my $somepage = sub {
 323     my $id = shift @_;
 324     print STDERR "defining page Page$id\n";
 325     $bb{"Page$id"} = [ @_ ];
 326     $bb{"Printable$id"} = $submargins->($max_printeredge, $bb{"Page$id"});
 327   };
 328   my $pageb_a4 = sub {
 329     $somepage->('B', 0,0, $a4_h, $a4_w );
 330   };
 331   if ($maxpaper eq 'a3') {
 332     $pageb_a4->();
 333     my $mt_offset = $bb{PrintableB}[3] - $max_printeredge;
 334     $somepage->('MT', 0, $mt_offset, $a4_h, $mt_offset + $a3_h );
 335     $bb{PrintableAll} = [
 336                          @{ $bb{PrintableB} }[0..1],
 337                          @{ $bb{PrintableMT} }[2..3],
 338                         ];
 339   } elsif ($maxpaper eq 'a4') {
 340     $pageb_a4->();
 341     my $m_offset = $bb{PrintableB}[3] - $max_printeredge;
 342     $somepage->('M', 0, $m_offset, $a4_h, $m_offset + $a4_w );
 343     my $t_offset = $bb{PrintableM}[3] - $max_printeredge;
 344     $somepage->('T', 0, $t_offset, $a4_h, $t_offset + $a4_w );
 345     $bb{PrintableAll} = [
 346                          @{ $bb{PrintableB} }[0..1],
 347                          @{ $bb{PrintableT} }[2..3],
 348                         ];
 349   } elsif ($maxpaper =~ m/^a1/) {
 350     my $offx = ($a1_w - $bb{Entire}[2] * (1 + $a1sfactor)) / 3;
 351     my $offy = 0.5*($a1_h - $bb{Entire}[3]);
 352     $somepage->('P', -$offx,-$offy, $a1_w-$offx, $a1_h-$offy);
 353     my $hairs = 30 * MM2PT;
 354     my $hairsw = $bb{Entire}[2];
 355     my $hairsh = $bb{Entire}[3];
 356     my $surround = 5 * MM2PT;
 357     my $surroundw = $bb{Entire}[2] + $surround*2;
 358     my $surroundh = $bb{Entire}[3] + $surround*2;
 359     my @hrect = @{ $bb{Entire} };
 360     if ($maxpaper eq 'a1m') {
 361       @hrect = @{ $submargins->($a1m_pasteedge, \@hrect) };
 362       $bb{Cutout} = \@hrect;
 363     }
 364     my $w_stroke = $xopts =~ m/W/ ?
 365         ' gsave 3 setlinewidth stroke grestore '
 366         : '';
 367     $preamble_from_boundings = <<END;
 368          1 setlinewidth
 369          0 setgray
 370          /a1hairs {
 371              newpath moveto
 372              $hairs 0        rmoveto
 373              $hairs -2 mul 0 rlineto
 374              $hairs $hairs   rmoveto
 375              0 $hairs -2 mul rlineto
 376              stroke
 377          } def
 378          $hrect[0] $hrect[1] a1hairs
 379          $hrect[0] $hrect[3] a1hairs
 380          $hrect[2] $hrect[3] a1hairs
 381          $hrect[2] $hrect[1] a1hairs
 382          newpath
 383          -$surround -$surround moveto
 384           $surroundw 0         rlineto
 385           0 $surroundh         rlineto
 386           -$surroundw 0        rlineto
 387                  closepath $w_stroke clip
 388 END
 389     $top_adjuncts_dy_from_boundings = 35;
 390     $bottom_adjuncts_dy_from_boundings = -7;
 391   } else {
 392     confess;
 393   }
 394 }
 395
 396 sub showboundings () {
 397   return unless $xopts =~ m/B/;
 398   o(" gsave\n");
 399   my $bb = $bb{$bounding};
 400   o("  $bb->[0] neg $bb->[1] neg translate\n");
 401   my $i = 0;
 402   my $on = 2;
 403   my $off = 9;
 404   foreach my $bname (sort keys %bb) {
 405     o(sprintf "   1 %d %d setrgbcolor\n",
 406       !!($bname =~ m/^Page/),
 407       !!($bname =~ m/B$/),
 408      );
 409     o("    % $bname\n");
 410     o("    [ $on $off ] ".($i * ($on+$off))," setdash newpath\n");
 411     my @p = @{ $bb{$bname} };
 412     o("    $p[0] $p[1] moveto\n");
 413     o("    $p[2] $p[1] lineto\n");
 414     o("    $p[2] $p[3] lineto\n");
 415     o("    $p[0] $p[3] lineto\n");
 416     o("    closepath stroke\n");
 417     $i++;
 418   }
 419   o(" grestore");
 420 }
 421
 422 sub o_amble (@) {
 423   # CPerl-mode does a really awful thing with %s in the preamble
 424   # and postamble, causing constant useless flashing
 425   # So we write & in the here docs and transform them back:
 426   my ($t) = join '', @_;
 427   $t =~ s/^\&+/ '%' x length $& /mge;
 428   o($t);
 429 }
 430
 431 sub preamble() {
 432   my $bb = $bb{$bounding}; confess $bounding unless $bb;
 433   my $sz = [ $bb->[2] - $bb->[0], $bb->[3] - $bb->[1] ];
 434   o_amble(<<END);
 435 &!PS-Adobe-3.0
 436 &&BoundingBox 0 0 @$sz
 437 &&Pages: 1
 438 &&EndComments
 439 &&BeginProlog
 440 &&EndProlog
 441 &&BeginSetup
 442 << /PageSize [ @$sz ] >> setpagedevice
 443 /all {
 444   gsave
 445   $bb->[0] neg  $bb->[1] neg  translate
 446   $preamble_from_boundings
 447   board
 448   grestore
 449   showboundings
 450 } def
 451 /showboundings {
 452 END
 453   showboundings();
 454   o_amble(<<END);
 455 } def
 456 /board {
 457   gsave
 458   % adjustment to actual image placement within prinable areas etc.:
 459   34 -15 translate
 460 END
 461   if ($maxpaper eq 'a4') {
 462     o("0 -17 translate\n");
 463   }
 464 }
 465
 466 sub postamble () {
 467   o_amble(<<END);
 468   grestore
 469 } def % board
 470 &&EndSetup
 471 &&Page: 1
 472 &&BeginPageSetup
 473 /pgsave save def
 474 &&EndPageSetup
 475 all
 476 END
 477   if ($maxpaper =~ m/^a1/) {
 478     o(<<END);
 479   $a1_w 0 translate
 480   $a1sfactor dup scale
 481   $a1_w neg 0 translate
 482   1 1 3 { pop all 0 $a1_h 0.8 mul translate } for
 483 END
 484   }
 485   o_amble(<<END);
 486 pgsave restore
 487 showpage
 488 &&EOF
 489 END
 490 }
 491
 492 sub pscolour ($$$$) {
 493   my ($colourname, $cmykix,$rgbmul,$rgbadd) = @_;
 494   my $spec = $c{Colours}{$colourname};
 495   confess unless defined $spec;
 496
 497   # check that we have only one lighter/darker retain value for each one
 498   our %colour_occurred;
 499   $colour_occurred{$colourname}{$cmykix}{$rgbmul,$rgbadd} = 1;
 500   keys %{ $colour_occurred{$colourname}{$cmykix} } == 1 or confess;
 501
 502   my @r;
 503   my $rw;
 504   if ($spec =~ m/^[0-9a-f]+$/) {
 505     my $le = (length $spec)/3;
 506     my $re = ("(.{$le})") x 3;
 507     my @rgb = $spec =~ m/^$re$/;  @rgb or confess "$re ?";
 508     @rgb = map { hex($_) / (16**$le -1) } @rgb;
 509     foreach (@rgb) { $_ *= $rgbmul; $_ += $rgbadd; }
 510     @r = @rgb;
 511     $rw = 'setrgbcolor';
 512   } elsif ($spec =~ m/[CMYK]/) {
 513     my @specs = split /\//, $spec;
 514     if ($cmykix==1 && @specs==1) {
 515       $spec = $specs[0];
 516     } else {
 517       $spec = $specs[$cmykix];
 518       confess unless defined $spec;
 519     }
 520     my %cmyk;
 521     foreach (split /(?=[A-Z])/, $spec) {
 522       m/^([CMYK])([0-7](?:\.\d*)?|8)_?$/ or confess $_.' ?';
 523       confess if defined $cmyk{$1};
 524       $cmyk{$1} = $2 / 8.;
 525       #print STDERR " CMYK $1 $2\n";
 526     }
 527     @r = map { $cmyk{$_} // 0 } qw(C M Y K);
 528     $rw = 'setcmykcolor';
 529   } else {
 530     confess $spec.' ?';
 531   }
 532   my $r = join ' ',
 533       (map { sprintf "%.6f ", $_ } @r
 534       ),
 535           $rw;
 536   return $r;
 537 }
 538
 539 sub lighterpscolour ($$) {
 540   my ($colourname, $retain) = @_;
 541   #print STDERR "COLOUR LIGHTER $retain $colourname\n";
 542   pscolour($colourname, 0, $retain, 1-$retain);
 543 }
 544
 545 sub darkerpscolour ($$) {
 546   my ($colourname, $retain) = @_;
 547   #print STDERR "COLOUR DARKER $retain $colourname\n";
 548   pscolour($colourname, 2, $retain, 0);
 549 }
 550
 551 sub facepscolour ($) {
 552   my ($colourname) = @_;
 553   $xopts =~ m/W/ ? '1 setgray' :
 554       $colourname =~ m/land/ ? miscpscolour($colourname)
 555       : lighterpscolour($colourname, 0.75);
 556 }
 557
 558 sub miscpscolour ($) {
 559   my ($colourname) = @_;
 560   #print STDERR "COLOUR MISC $colourname\n";
 561   pscolour($colourname, 1, 1,0);
 562 }
 563
 564 sub seatrackedgepscolour () { darkerpscolour('cube', 0.25) }
 565
 566 sub fill_faces() {
 567   o("clippath ", facepscolour('land'), " fill\n");
 568   foreach my $rr (values %region) {
 569     next if $rr->{Name} =~ m/^L2?$/;
 570     face_path($rr);
 571     o(" ", facepscolour($rr->{Colour}), " eofill\n");
 572   }
 573 }
 574
 575 our $edge_lw = 5;
 576
 577 sub some_edge_faces (@) {
 578   o("$edge_lw setlinewidth 1 setlinejoin ",miscpscolour('edge'),"\n");
 579   foreach my $rr (@_) {
 580     next if $rr->{Name} =~ m/^L2?$/;
 581     face_path($rr);
 582     o("    stroke\n");
 583   }
 584 }
 585
 586 sub dashedwithhs ($$$) {
 587   my ($inner, $comment, $colour) = @_;
 588   my ($adj) = grep { $_->{Name} eq $c{Sea} } @{ $region{$inner}{Adj} };
 589   my $dash = 20;
 590   my (@pos) = adj_ends($adj);
 591   my $mid = 0.5 * ($pos[0] + $pos[1]);
 592   my $r = 0.5 * ($pos[1] - $pos[0])->norm();
 593   o(sprintf <<'END', $comment, facepscolour('sea'), psvec($mid), $r);
 594   %% %s
 595   %s %s %s 0 360 arc closepath fill
 596 END
 597   some_edge_faces(()); # just sets the colour
 598   o(sprintf <<END, map { psvec($_) } @pos);
 599   newpath %s moveto %s lineto
 600   [ $dash $dash ] $dash 0.5 mul setdash
 601   stroke
 602   [] 0 setdash
 603 END
 604   one_hs($colour, $mid);
 605 }
 606
 607 sub dashedwithhses() {
 608   dashedwithhs(
 609               $_->{Inner},
 610               $_->{Comment},
 611               $_->{Colour}
 612              ) foreach @{ $c{DashedHs} };
 613 }
 614
 615 sub edge_faces() {
 616   some_edge_faces($region{$c{Sea}});
 617   dashedwithhses();
 618   some_edge_faces(grep {
 619     my $n = $_->{Name};
 620     $n !~ m{^$c{OuterfaceRe}$} &&
 621     !grep { $n eq $_->{Inner} } @{ $c{DashedHs} }
 622   } values %region);
 623 }
 624
 625 our $hs_sz = 17 * MM2PT;
 626 our $hs_lw = 3;
 627
 628 our $text_sz = 18;
 629
 630 sub token_circle ($$$$;$$) {
 631   my ($what, $pos, $fillcolour, $edgecolour, $sz,$lw) = @_;
 632   $sz //= $hs_sz;
 633   $lw //= $hs_lw;
 634   o(sprintf <<END, $what, $fillcolour, psvec($pos), $sz/2, $edgecolour);
 635    %% %s
 636    newpath %s
 637      %s %f 0 360 arc closepath gsave fill grestore
 638      %s $lw setlinewidth stroke
 639 END
 640 }
 641
 642 sub one_hs ($$;$$) {
 643   my ($colour, $hspos, $sz, $lw) = @_;
 644   token_circle("HS - $colour",
 645                $hspos,
 646                darkerpscolour($colour, 0.75),
 647                miscpscolour('edge'),
 648               $sz,$lw);
 649 }
 650
 651 our $cube_sz = 6 * MM2PT;
 652 our $cube_gap = $cube_sz * 0.2;
 653 our $cube_lw = ($cube_sz * 0.1);
 654
 655 sub label_faces() {
 656   my $sz = $text_sz;
 657   my $shadow = $sz * 0.1;
 658   my $textc   = miscpscolour('text');
 659   my $shadowc = miscpscolour('textshadow');
 660   o(<<END);
 661   /wordsshow {
 662     $shadowc 0 10 359 {
 663       dup  cos $shadow mul
 664       exch sin $shadow mul
 665       words pop pop
 666     } bind for
 667     $textc 0 0 words pop pop
 668   } def
 669 END
 670   o("  /Helvetica-Bold findfont  $sz scalefont setfont\n");
 671   my %hs = map { $_ => 1 } @{ $c{HS} };
 672   foreach my $rr (values %region) {
 673     next if $rr->{Name} =~ m/^L\d?$/;
 674     my $words = $rr->{DisplayName};
 675     my $pos;
 676     if ($rr->{Name} eq $c{Sea}) {
 677       $pos = mkvec(90, 1280);
 678     } else {
 679       $pos = $rr->{Centre} + mkvec( 0, 0.5 * $sz * @$words );
 680     }
 681     if ($hs{$rr->{Name}}) {
 682       #print STDERR "adjust hs $rr->{Name}\n";
 683       $pos -= mkvec(0, -$hs_sz*
 684                     ( $rr->{Colour} eq 'green' ? 0.25 : 0.65 ));
 685       my $hspos = $pos - mkvec(0, $sz * @$words + $hs_sz/2 + $hs_lw
 686                                + $hs_sz*0.15);
 687       one_hs($rr->{Colour}, $hspos);
 688     }
 689     my $adjust = $c{TextAdjust}{$rr->{Name}};
 690     if ($adjust) {
 691       $pos += $sz * &mkvec(@$adjust);
 692     }
 693     my $w = $rr->{Water};
 694     $w = 2 if $rr->{Name} eq $c{Sea};
 695     if ($w) {
 696       #print STDERR " water $w in $rr->{Name}\n";
 697       my $down = water_cubes_sz(2) - water_cubes_sz(1) + $cube_gap;
 698       $pos -= mkvec(0, -0.5 * $down);
 699       my $cube_y = -($sz * @$words);
 700       if (grep { $_ eq $rr->{Name} } @{ $c{CubeAbove} }) {
 701         $pos -= mkvec(0,+$sz);
 702         $cube_y = 0;
 703         $down = 0;
 704       }
 705       o("  gsave\n");
 706       o("    ", psvec($pos), " translate\n");
 707       o("    0 ", $cube_y, " translate\n");
 708       o("    ", -0.5 * water_cubes_sz($w)," ", -$down, " translate\n");
 709       water_cubes($w, miscpscolour('edge'));
 710       o("  grestore\n");
 711     }
 712     o("  /words {\n");
 713     foreach my $word (@$words) {
 714       $pos += mkvec(0,-$sz);
 715       o("   ", psvec($pos), " moveto");
 716       o(<<END);
 717    2 copy rmoveto
 718    ($word) dup stringwidth pop     % word xw
 719      -0.5 mul 0 rmoveto             % word
 720      show
 721    0 -$sz rmoveto
 722 END
 723     }
 724     o(<<END);
 725   } bind def
 726   wordsshow
 727 END
 728   }
 729 }
 730
 731 sub water_cubes_sz($){
 732   my ($n) = @_;
 733   ($cube_sz + $cube_lw) * $n + ($cube_gap * ($n-1));
 734 }
 735
 736 sub water_cubes($$){
 737   my ($n, $edgecolour) = @_;
 738   my $s = $cube_sz;
 739   for my $i (0..$n-1) {
 740     o("  newpath  ", $i * ($cube_sz + $cube_lw + $cube_gap),"  0  moveto\n");
 741     o("          $s  0  rlineto\n");
 742     o("           0 $s  rlineto\n");
 743     o("         -$s  0  rlineto  closepath\n");
 744     o("  gsave ", miscpscolour('cube'), " fill grestore\n");
 745     o("  gsave ", $edgecolour, " ", $cube_lw,
 746       " setlinewidth stroke grestore \n");
 747   }
 748 }
 749
 750 my $deck_h = 89 * MM2PT;
 751
 752 sub decks(){
 753   my $lw = $edge_lw/2;
 754   o("  /deck1path {\n");
 755   my $w = 63 * MM2PT;
 756   my $h = $deck_h;
 757   my $r =  5 * MM2PT;
 758   o("      ",($w/2)," 0 moveto\n");
 759   my @p = ([ $w, 0 ],
 760            [ $w,$h ],
 761            [ 0, $h ],
 762            [ 0,  0 ]);
 763   foreach my $i (0..3) {
 764     o("    @{ $p[$i] }  @{ $p[($i + 1) % 4] }  $r  arct\n");
 765   }
 766   o("    closepath\n");
 767   o("  } bind def");
 768   o("  /deckpairpathx {\n"); # x because it leaves matrix changed
 769   o("    newpath         deck1path\n");
 770   o("    200 0 translate deck1path\n");
 771   o("  } bind def");
 772   o("  $lw setlinewidth ",miscpscolour('playerdeck'),"\n");
 773   o("  gsave 401 44 $bottom_adjuncts_dy_from_boundings add translate");
 774   o("     deckpairpathx stroke grestore");
 775   o("  $lw setlinewidth ",miscpscolour('dykefail'),"\n");
 776   o("  gsave 242 1363 $top_adjuncts_dy_from_boundings add translate ");
 777   o("     90 rotate deckpairpathx stroke grestore");
 778 }
 779
 780 sub sea_track(){
 781   o("% sea level track\n");
 782   o("  gsave 11 700 translate\n");
 783   my $track = $c{SeaTrack};
 784   my $token_sz = $hs_sz;
 785   my $dy = $token_sz * 1.25;
 786   my $dx = $token_sz * 1.25;
 787   my $linecolour = seatrackedgepscolour();
 788   my @pos;
 789   for my $i (0..$#$track) {
 790     $pos[$i] = mkvec(0, ($i - 0.5 * @$track) * $dy);
 791   }
 792   my $prepline = "$linecolour $hs_lw setlinewidth newpath";
 793   o("  $prepline\n");
 794   o("    ",psvec($pos[0])," moveto ",psvec($pos[-1])," lineto stroke\n");
 795   for my $pos (@pos) {
 796     token_circle("SL", $pos,
 797                  miscpscolour('cube'),
 798                  $linecolour);
 799   }
 800   my $last = 0;
 801   my $cubeedgecolour = seatrackedgepscolour();
 802   for my $i (0..$#pos) {
 803     my $differs = $track->[$i] != $last;
 804     $last = $track->[$i];
 805     next unless $differs;
 806     o("  $prepline\n");
 807     o("  gsave ",
 808       psvec($pos[$i] + mkvec(-0.0 * $token_sz, $dy/2))," translate\n");
 809
 810     my $t_sz = 24;
 811     my $shrink = ($hs_sz * 0.75 / $deck_h);
 812     o("    gsave % T M $i\n");
 813     o("      -43.5 -6.5 translate\n");
 814     o("      0.8 .8 scale \n");
 815     o("      ",0.6 * $dx, " ", -0.28 * $dy," translate\n");
 816     o("      gsave");
 817     o("        $shrink dup scale -90 rotate\n");
 818     o("        newpath ", ($hs_lw / $shrink)," setlinewidth\n");
 819     o("         deck1path stroke\n");
 820     o("      grestore");
 821     o("      /Helvetica-Bold findfont $t_sz scalefont setfont\n");
 822     o("      12 -21.5 moveto ($track->[$i]) show");
 823     o("    grestore\n");
 824
 825     if ($i > 0) {
 826       o("  0 -$dy moveto",
 827         " ",psvec(mkvec( $dx + $cube_sz, 0 )),
 828         " rlineto stroke\n");
 829     }
 830     o("  ",($token_sz * 0.6 + $cube_gap)," ",
 831       (-$dy * 0.5 - 0.5 * (water_cubes_sz(2))),
 832       " translate\n");
 833     my $bottom = int(($track->[$i+1] + 1) / 2);
 834     water_cubes($bottom, $cubeedgecolour);
 835     my $new_n = $track->[$i+1] - $bottom;
 836     o("  ", 0.5 * (water_cubes_sz($bottom) - water_cubes_sz($new_n)),
 837       "  ",       (water_cubes_sz(2)-water_cubes_sz(1)), " translate\n");
 838     water_cubes($new_n, $cubeedgecolour);
 839     o("  grestore\n");
 840   }
 841   o("  grestore\n");
 842 }
 843
 844 our $dyke_l = 25 * MM2PT;;
 845
 846 sub dykes(){
 847   my $l = $dyke_l;
 848   my $w = 5 * MM2PT;
 849   my $lw = $edge_lw * 0.50;
 850   my $l2 = $l/2;
 851   my $w2 = $w/2;
 852   o("  /dykepath {\n");
 853   o("            -$l2 -$w2 moveto\n");
 854   o("             $l2 -$w2 lineto\n");
 855   o("             $l2  $w2 lineto\n");
 856   o("            -$l2  $w2 lineto closepath\n");
 857   o("  } bind def\n");
 858   o("  /dyke {\n");
 859   o("    newpath dykepath\n");
 860   o("    gsave ",miscpscolour('dykefill')," fill grestore\n");
 861   o("    gsave ",miscpscolour('edge')," $lw setlinewidth stroke grestore\n");
 862   o("  } bind def\n");
 863   my $symbol_sz = $w * 1.50;
 864   my $t_sz = $symbol_sz * 1.0;
 865   my $t_at = sub {
 866     my ($ang) = @_;
 867     #print STDERR "ANG $ang\n";
 868     map { $t_sz * 0.5 * $_ } cos($ang), sin($ang);
 869   };
 870   my @t0 = $t_at->((TAU) *  0.25         );
 871   my @t1 = $t_at->((TAU) * (0.25 + 1./3) );
 872   my @t2 = $t_at->((TAU) * (0.25 + 2./3) );
 873   o("  /dtriangle {\n");
 874   o("    newpath @t0 moveto\n");
 875   o("            @t1 lineto\n");
 876   o("            @t2 lineto closepath\n");
 877   o("    gsave ",miscpscolour('dykeinit')," fill grestore\n");
 878   o("    gsave ",miscpscolour('edge')," $lw setlinewidth stroke grestore\n");
 879   o("  } bind def\n");
 880   foreach my $rr (values %region) {
 881     next if $rr->{Special};
 882     next if grep { $_->{Inner} eq $rr->{Name} } @{ $c{DashedHs} };
 883     next if $rr->{Colour} eq 'high';
 884     foreach my $adj (@{ $rr->{Adj} }) {
 885       my $neigh = $adj->{Name};
 886       o("  % dyke $rr->{Name} --- $neigh\n");
 887       next if $neigh lt $rr->{Name} && !$region{$neigh}{Special};
 888       next if $region{$neigh}{Colour} eq 'high';
 889       my @ends = adj_ends($adj);
 890       my $dirn = $ends[1] - $ends[0];
 891       my $angle = vec2atan($dirn);
 892       $angle = $angle * 360 / TAU;
 893       o("  gsave\n");
 894       o("    ", psvec( 0.5 * ($ends[0] + $ends[1]) )," translate\n");
 895       o("    $angle rotate\n");
 896       my $initial = $adj->{Dykes};
 897       for my $ys ($initial
 898                   ? [ map { $_ - 0.5 * ($initial-1) } 0..$initial-1 ]
 899                   : [0]) {
 900         foreach my $y (@$ys) {
 901           o("    gsave 0 ", $y * $w, " translate dyke ");
 902           o(" grestore\n");
 903         }
 904         my $nsymbols = $initial + !!$adj->{Deltawerk};
 905         o("   ", -0.5 * $symbol_sz * ($nsymbols-1)," 0 translate\n");
 906         my $trans = "  $symbol_sz 0 translate";
 907         if ($adj->{Deltawerk}) {
 908           one_hs('red', mkvec(0,0), $symbol_sz * 0.8, $lw);
 909           o($trans);
 910         }
 911         foreach my $i (1..$initial) {
 912           o(" gsave $angle neg rotate dtriangle grestore\n");
 913           o($trans);
 914         }
 915       }
 916       o("  grestore\n");
 917     }
 918   }
 919 }
 920
 921 sub hs_initial_1 ($$$;$$$) {
 922   my ($colour, $xi,$yi, $text, $text2, $fn) = @_;
 923   my $interval = $hs_sz * 1.75;
 924   my $demo_h = $hs_sz; #water_cubes_sz(3);
 925   my $demo_x0 = $hs_sz * 0.75 + $dyke_l * 0.60;
 926   my $demo_w = $demo_x0 + $dyke_l * 0.60;
 927   o("  % HS I $colour\n");
 928   o("  gsave\n");
 929   o("    550 1705 $top_adjuncts_dy_from_boundings add translate\n");
 930   o("    ", ($xi*$interval), " ", (($yi-1)*$interval), " translate\n");
 931   if ($fn) {
 932     o("  gsave\n");
 933     o("        $demo_h setlinewidth 0 0 moveto $demo_w 0 rlineto\n");
 934     o("        ", facepscolour($colour), " stroke grestore\n");
 935   }
 936   one_hs($colour, mkvec(0,0));
 937   if ($fn) {
 938     o("    /words {\n");
 939     o("      2 copy moveto                      ($text) show\n");
 940     o("      2 copy moveto 0 -$text_sz rmoveto ($text2) show\n");
 941     o("    } bind def\n");
 942     o("    gsave ".($hs_sz * 0.8)." $cube_gap translate wordsshow grestore\n");
 943     o("    $demo_x0 ",($hs_sz * -0.25)," translate\n");
 944     $fn->();
 945   }
 946   o("  grestore\n");
 947 }
 948
 949 sub hs_initial () {
 950   hs_initial_1('red',     0,0);
 951   hs_initial_1('purple',  0,1);
 952   hs_initial_1('green',   1,0, 'up to 6', 'fewer', sub {
 953     o("    ",(water_cubes_sz(1))," 0 translate\n");
 954     o("    0 ",(-water_cubes_sz(1) * 0.3)," translate\n");
 955     water_cubes(1, miscpscolour('edge'));
 956   });
 957   hs_initial_1('yellow',  1,1, 'up to 4', '', sub {
 958     o("    newpath dykepath\n");
 959     o("    gsave ",miscpscolour('edge')," stroke grestore\n");
 960     o("    gsave ",miscpscolour('dykehsadd')," fill grestore\n");
 961   });
 962 }
 963
 964 sub play_hint () {
 965   my $sz = 20;
 966   o("  gsave ",miscpscolour('hinttext'),
 967     " 260 1715 $top_adjuncts_dy_from_boundings add translate\n");
 968   o("  /Helvetica-Bold findfont $sz scalefont setfont\n");
 969   my @t = split /\n/, $c{PlayHint};
 970   foreach my $i (0..$#t) {
 971     my $t = $t[$i];
 972     $t =~ s/[\\()]/\\$&/g;
 973     o("  0 ",(-$i * $sz)," moveto ($t) show\n");
 974   }
 975   o("  grestore");
 976 }
 977
 978 #----- main program -----
 979
 980 $xopts = shift @ARGV if $ARGV[0] =~ s/^-X//;
 981 $bounding = $1 if $xopts =~ s/b(\w+)//;
 982 $maxpaper = $1 if $xopts =~ s/p(\w+)//;
 983 $maxpaper =~ m/^a[134]$|^a1m$/ or confess;
 984
 985 ($facesf, @ARGV) = @ARGV or die;
 986 parse_input_graph();
 987 prep_region_rmap();
 988 read_faces();
 989 calculate_centres();
 990 transform_coordinates();
 991 adjust_sea();
 992
 993 computeboundings();
 994 preamble();
 995 fill_faces();
 996 edge_faces();
 997 dykes();
 998 label_faces();
 999 decks();
1000 sea_track();
1001 hs_initial();
1002 play_hint();
1003 postamble();
1004
1005 print STDERR Dumper(\%region) if $ENV{'GENERATE_BOARD_DUP'};
1006
1007 # Local variables:
1008 # cperl-indent-level: 2
1009 # End.