generate-board

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Carp;
   5 use Data::Dumper;
   6 use Math::GSL::Vector qw/:all/;
   7 use Math::GSL::Matrix qw/:all/;
   8 use Math::GSL::Const;
   9 use Math::GSL::BLAS qw/:all/;
  10 use Math::GSL::CBLAS qw/:all/;
  11 use Math::GSL::Machine qw/:all/;
  12
  13 use POSIX qw(M_PI);
  14
  15 BEGIN { unshift @INC, qw(.); }
  16
  17 use Parse;
  18
  19 our $xopts = '';
  20 our $bounding = 'Entire';
  21 our $facesf;
  22 our %vxname2pos; # $vxname2pos{VXNAME} = Math::GSL::Vector
  23 our %bb; # $r{Bounding...}[0..3] = points
  24 our $maxpaper = 'a3';
  25
  26 sub TAU { M_PI * 2.0; }
  27 sub MM2PT { 72.0 / 25.4; }
  28
  29 our $mid;
  30
  31 our $a4_w = 595;
  32 our $a4_h = 842;
  33 our $a3_h = 1190;
  34
  35 our $max_printeredge = 5.50 * MM2PT;
  36
  37
  38 # ----- region names from plag, incl. reverse mapping -----
  39
  40 our %prs2region;
  41
  42 sub prep_region_rmap () {
  43   foreach my $rn (keys %region) {
  44     my $prs = plag_prs($rn);
  45     die if $prs2region{$prs};
  46     $prs2region{$prs} = $rn;
  47   }
  48 }
  49
  50 our $sre = qr{(?:(\")|(?=\w))(.*)\1$}; # 2 captures, $2 is the name
  51
  52 sub prs2r ($) {
  53   # bodgery for the sea and land
  54   return 'NZ' if m/ \| / && !grep { !m{^(?:NZ|L2?)$} } split / \| /, $_[0];
  55   $prs2region{$_[0]} // confess "@_ ?"
  56 }
  57 sub prs2rr ($) { $region{prs2r($_[0])} }
  58
  59 #----- file reader for plag output -----
  60
  61 sub read_faces () {
  62   # Sets
  63   #  $region{NAME}{Adj}[]{Ends}[]{VxName}
  64   #  $region{NAME}{Adj}[]{Ends}[]{Pos}
  65   #  $region{NAME}{Polygon}{Pos}
  66   #  $region{NAME}{Special}
  67   #
  68   # also incidentally
  69   #  $region{NAME}{Adj}[]{Ends}[]{Adjoins}
  70   #  $region{NAME}{Polygon}{Adjoins}
  71   # which should be ignored
  72
  73   open P, "<", $facesf or die $!;
  74   while (<P>) { last if m/^\&faces$/; }
  75   my $rr;
  76   my @edges;
  77   my $process_rr = sub {
  78     my $last_ai;
  79     if ($rr->{Name} eq 'NZ') {
  80       # We combined L and NZ; now we must split them again
  81       # in fact, we just throw away L and L2 entirely.
  82       # Here, when processing NZ, we keep only vertices that
  83       # are part of NZ.
  84       @edges = grep {
  85         my $evxname = $_->{VxName};
  86         my @eregions = split / \| ?/, $evxname;
  87         grep { $_ eq 'NZ' } @eregions
  88       } @edges;
  89     }
  90     $rr->{Polygon} = [ @edges ];
  91     if ($rr->{Name} ne 'NZ') {
  92       for my $ei (0..$#edges) {
  93         if (!defined $last_ai) {
  94           my $ai;
  95           for my $ai (0..$#{ $rr->{Adj} }) {
  96             next unless $rr->{Adj}[$ai]{Name} eq $edges[$ei]{Adjoins};
  97             $last_ai = $ai+1;
  98           }
  99           confess $edges[$ei]{Adjoins}.' ?' unless defined $last_ai;
 100         }
 101         my $ai = ($last_ai-1+@edges) % @edges;
 102         $last_ai = $ai;
 103         my $adj = $rr->{Adj}[$ai];
 104         confess Dumper($adj->{Name}, $edges[$ei]{Adjoins},
 105                        $rr, \@edges, $ei, $adj, $last_ai, $ai)." ?"
 106             unless $adj->{Name} eq $edges[$ei]{Adjoins};
 107
 108         for my $endi (0..1) {
 109           $adj->{Ends}[$endi] = $edges[ ($ei + $endi) % @edges ];
 110         }
 111       }
 112     }
 113     @edges = ();
 114     $rr = undef;
 115   };
 116   my $vxname;
 117   for (;;) {
 118     $!=0; $_=<P> // confess $!;
 119     last if m/^\&$/;
 120     if (m/^$sre$/) {
 121       my $new_face= $2;
 122       $process_rr->() if $rr;
 123       $rr= prs2rr($new_face);
 124     } elsif (m/^\s+$sre$/) {
 125       confess unless $rr;
 126       $vxname = $2;
 127       push @edges, { VxName => $vxname };
 128     } elsif (m/^\s+\^adjoins\s+$sre$/) {
 129       $edges[-1]{Adjoins} = prs2r($2);
 130     } elsif (m/^\s+\^\@([-e.0-9]+)\,([-e.0-9]+)$/) {
 131       my $pos = mkvec($1,$2);
 132       confess unless defined $vxname;
 133       $edges[-1]{Pos} = $pos;
 134       $vxname2pos{$vxname} = $pos;
 135     }
 136   }
 137   $process_rr->();
 138
 139   $region{$_}{Special} = 1 foreach qw(NZ L L2);
 140 }
 141
 142 #----- geometry mangling -----
 143
 144 sub adj_ends ($) {
 145   my ($adj) = @_;
 146   map { $_->{Pos} } @{ $adj->{Ends} };
 147 }
 148
 149 sub calculate_centres () {
 150   # Sets
 151   #  $region{NAME}{Centre}
 152   foreach my $rr (values %region) {
 153     next if $rr->{Special};
 154     my $sum = Math::GSL::Vector->new(2);
 155     my $wsum = 0;
 156     foreach my $adj (@{ $rr->{Adj} }) {
 157       my @ends = adj_ends($adj);
 158       my $w = ($ends[1] - $ends[0])->norm();
 159       $sum += $w * $_ foreach @ends;
 160       $wsum += $w;
 161     }
 162     $rr->{Centre} = $sum * (0.5 / $wsum);
 163   }
 164 }
 165
 166 sub for_each_pos ($) {
 167   my ($f) = @_;
 168   my $call = sub {
 169     my ($pr,$rr,$why) = @_;
 170     return unless defined $$pr;
 171     $f->($pr,$rr,$why);
 172   };
 173   foreach my $rr (values %region) {
 174     $call->( \ $rr->{Centre}, $rr, $rr->{Name}." C" );
 175     foreach my $vertex (@{ $rr->{Polygon} }) {
 176       $call->( \ $vertex->{Pos}, $rr, $rr->{Name}." | ".$vertex->{Adjoins} );
 177     }
 178   }
 179 }
 180
 181 sub prvec ($) {
 182   my ($v) = @_;
 183   confess unless $v;
 184   sprintf "%g,%g", $v->get(0), $v->get(1);
 185 }
 186
 187 sub mkvec ($$) { Math::GSL::Vector->new(\@_) }
 188 sub vec2atan ($) { my ($dir) = @_; atan2 $dir->get(1), $dir->get(0); }
 189
 190 sub transform_coordinates () {
 191   # Adjusts coordinates in graph to be [0,0] .. top right (scaled)
 192   # until it's all in PostScript points
 193   my @or = map { $region{$_}{Centre} } @{ $c{OrientRegions} };
 194   my $dir = $or[1] - $or[0];
 195   my $theta = vec2atan($dir);
 196   my $rotateby = (90. - $c{OrientBearing}) * ((TAU)/360.) - $theta;
 197   my $s = sin($rotateby);
 198   my $c = cos($rotateby);
 199   my $transform = Math::GSL::Matrix->new(2,2);
 200   $transform->set_row(0, [  $c, -$s ]);
 201   $transform->set_row(1, [  $s,  $c ]);
 202   #  print STDERR "rotate was=",prvec($dir)," theta=$theta",
 203   #    " rotateby=$rotateby s=$s c=$c\n";
 204   my @lims;
 205   foreach my $topend (qw(0 1)) {
 206     my $v = $topend ? -$GSL_DBL_MAX : $GSL_DBL_MAX;
 207     $lims[$topend] = mkvec($v,$v);
 208   }
 209   for_each_pos(sub {
 210     my ($pr, $rr, $why) = @_;
 211     my $y = Math::GSL::Vector->new(2);
 212     gsl_blas_dgemv($CblasNoTrans,
 213                    1.0, $transform->raw,
 214                    $$pr->raw,
 215                    0, $y->raw)
 216         and confess;
 217     #print STDERR "gsl_blas_dgemv ",prvec($$pr)," => ",prvec($y),"\n";
 218     gsl_blas_dcopy($y->raw, $$pr->raw)
 219         and confess;
 220     foreach my $topend (qw(0 1)) {
 221       foreach my $xy (qw(0 1)) {
 222         my $now = $y->get($xy);
 223         my $lim = $lims[$topend]->get($xy);
 224         #print STDERR "?set $topend $xy $now $lim\n";
 225         next if $topend ? ($now <= $lim) : ($now >= $lim);
 226         $lims[$topend]->set([$xy], [$now]);
 227         #print STDERR "set $topend $xy $now\n";
 228       }
 229     }
 230   });
 231   #print STDERR "lims ",prvec($lims[0])," .. ",prvec($lims[1]),"\n";
 232   my $translate = -$lims[0];
 233   #print STDERR "translate ",prvec($translate),"\n";
 234   my $scale = $c{GraphScale} * MM2PT;
 235   for_each_pos(sub {
 236     my ($pr) = @_;
 237     gsl_vector_add($$pr->raw, $translate->raw) and confess;
 238     gsl_vector_scale($$pr->raw, $scale) and confess;
 239   });
 240   $mid = ($lims[1] - $lims[0]) * 0.5;
 241 }
 242
 243 sub adjust_nz() {
 244   my $poly = $region{NZ}{Polygon};
 245   my %occurs;
 246   foreach my $v (@$poly) {
 247     $occurs{$v->{VxName}}++
 248   }
 249   foreach my $v (@$poly) {
 250     $v->{NZ_Occurs} = $occurs{$v->{VxName}};
 251   }
 252   #print STDERR " nz ".(scalar @$poly)."\n";
 253   my $occurs_m = sub {
 254     my ($ei) = @_;
 255     $poly->[($ei+@$poly) % @$poly]{NZ_Occurs} > 1
 256   };
 257   for my $ei (0..$#$poly) {
 258     next if $occurs_m->($ei);
 259     next unless $occurs_m->($ei-1);
 260     next unless $occurs_m->($ei+1);
 261     #print STDERR " nz would adjust $poly->[$ei]{VxName}\n";
 262     # adjust coord outwards
 263   }
 264   for my $ei (0..$#$poly) {
 265     next unless $occurs_m->($ei);
 266     #print STDERR " nz occurs_m $ei $poly->[$ei]{VxName}\n";
 267     next unless $occurs_m->($ei-1);
 268     my $dleft = mkvec(-1000,0);
 269     foreach my $which (0,-1) {
 270       my $ej = ($ei +        $which + @$poly) % @$poly;
 271       my $ek = ($ei + +1 + 3*$which + @$poly) % @$poly;
 272       my $posj = \ $poly->[$ej]{Pos};
 273       my $posk = \ $poly->[$ek]{Pos};
 274       my $dout = $$posk - $$posj;
 275       #print STDERR " nz adj j=$ej ",prvec($$posj)," $poly->[$ej]{VxName}\n";
 276       #print STDERR " nz adj k=$ek ",prvec($$posk)," $poly->[$ek]{VxName}\n";
 277       if ($poly->[$ej]{VxName} =~ /Noorderzijlvest/) {
 278         #print STDERR " nz adj extra\n";
 279         $$posk = $$posj + 10 * mkvec(100,-50);
 280       }
 281       $$posj = $$posj + $dleft + $dout*10;
 282       $$posk = $$posk          + $dout*10;
 283     }
 284   }
 285 }
 286
 287 sub psvec ($) {
 288   my ($pos) = @_;
 289   sprintf "%20.6f %20.6f", $pos->get(0),$pos->get(1)
 290 }
 291
 292 sub face_path ($) {
 293   my ($rr) = @_;
 294   o("% $rr->{Name}\n");
 295   o("  newpath\n");
 296   my $xto = 'moveto';
 297   foreach my $vertex (@{ $rr->{Polygon} }) {
 298     my $pos = $vertex->{Pos};
 299     o(sprintf "    %s %s\n", psvec($pos), $xto);
 300     $xto = 'lineto';
 301   }
 302   o("    closepath\n");
 303 }
 304
 305 sub computeboundings() {
 306   $bb{Entire} = [ 0,0, $a4_h, $a4_w + $a3_h ];
 307   $bb{PageB} = [ 0,0, $a4_h, $a4_w ];
 308   my $page2minprintable = sub {
 309     my (@p) = @{ $_[0] };
 310     [ $p[0] + $max_printeredge,
 311       $p[1] + $max_printeredge,
 312       $p[2] - $max_printeredge,
 313       $p[3] - $max_printeredge ];
 314   };
 315   $bb{PrintableB} = $page2minprintable->($bb{PageB});
 316   my $somepage = sub {
 317     my $id = shift @_;
 318     $bb{"Page$id"} = [ @_ ];
 319     $bb{"Printable$id"} = $page2minprintable->($bb{"Page$id"});
 320   };
 321   if ($maxpaper eq 'a3') {
 322     my $mt_offset = $bb{PrintableB}[3] - $max_printeredge;
 323     $somepage->('MT', 0, $mt_offset, $a4_h, $mt_offset + $a3_h );
 324     $bb{PrintableAll} = [
 325                          @{ $bb{PrintableB} }[0..1],
 326                          @{ $bb{PrintableMT} }[2..3],
 327                         ];
 328   } elsif ($maxpaper eq 'a4') {
 329     my $m_offset = $bb{PrintableB}[3] - $max_printeredge;
 330     $somepage->('M', 0, $m_offset, $a4_h, $m_offset + $a4_w );
 331     my $t_offset = $bb{PrintableM}[3] - $max_printeredge;
 332     $somepage->('T', 0, $t_offset, $a4_h, $t_offset + $a4_w );
 333   } else {
 334     confess;
 335   }
 336 }
 337
 338 sub showboundings () {
 339   return unless $xopts =~ m/B/;
 340   o("  grestore gsave\n");
 341   my $i = 0;
 342   my $on = 2;
 343   my $off = 9;
 344   foreach my $bname (sort keys %bb) {
 345     o(sprintf "   1 %d %d setrgbcolor\n",
 346       !!($bname =~ m/^Page/),
 347       !!($bname =~ m/B$/),
 348      );
 349     o("    % $bname\n");
 350     o("    [ $on $off ] ".($i * ($on+$off))," setdash newpath\n");
 351     my @p = @{ $bb{$bname} };
 352     o("    $p[0] $p[1] moveto\n");
 353     o("    $p[2] $p[1] lineto\n");
 354     o("    $p[2] $p[3] lineto\n");
 355     o("    $p[0] $p[3] lineto\n");
 356     o("    closepath stroke\n");
 357     $i++;
 358   }
 359 }
 360
 361 sub o_amble (@) {
 362   # CPerl-mode does a really awful thing with %s in the preamble
 363   # and postamble, causing constant useless flashing
 364   # So we write & in the here docs and transform them back:
 365   my ($t) = join '', @_;
 366   $t =~ s/^\&+/ '%' x length $& /mge;
 367   o($t);
 368 }
 369
 370 sub preamble() {
 371   my $bb = $bb{$bounding}; confess $bounding unless $bb;
 372   my $sz = [ $bb->[2] - $bb->[0], $bb->[3] - $bb->[1] ];
 373   o_amble(<<END);
 374 &!PS-Adobe-3.0
 375 &&BoundingBox @$bb
 376 &&Pages: 1
 377 &&EndComments
 378 &&BeginProlog
 379 &&EndProlog
 380 &&BeginSetup
 381 << /PageSize [ @$sz ] >> setpagedevice
 382 /board {
 383   gsave
 384   34 -15 translate
 385 END
 386   if ($maxpaper eq 'a4') {
 387     o("0 -17 translate\n");
 388   }
 389   # xxx split into pages
 390 }
 391
 392 sub postamble () {
 393   o_amble(<<END);
 394   grestore
 395 } bind def
 396 &&EndSetup
 397 &&Page: 1
 398 &&BeginPageSetup
 399 /pgsave save def
 400 &&EndPageSetup
 401 board
 402 pgsave restore
 403 showpage
 404 &&EOF
 405 END
 406 }
 407
 408 sub pscolour ($$$$) {
 409   my ($colourname, $cmykix,$rgbmul,$rgbadd) = @_;
 410   my $spec = $c{Colours}{$colourname};
 411   confess unless defined $spec;
 412
 413   # check that we have only one lighter/darker retain value for each one
 414   our %colour_occurred;
 415   $colour_occurred{$colourname}{$cmykix}{$rgbmul,$rgbadd} = 1;
 416   keys %{ $colour_occurred{$colourname}{$cmykix} } == 1 or confess;
 417
 418   my @r;
 419   my $rw;
 420   if ($spec =~ m/^[0-9a-f]+$/) {
 421     my $le = (length $spec)/3;
 422     my $re = ("(.{$le})") x 3;
 423     my @rgb = $spec =~ m/^$re$/;  @rgb or confess "$re ?";
 424     @rgb = map { hex($_) / (16**$le -1) } @rgb;
 425     foreach (@rgb) { $_ *= $rgbmul; $_ += $rgbadd; }
 426     @r = @rgb;
 427     $rw = 'setrgbcolor';
 428   } elsif ($spec =~ m/[CMYK]/) {
 429     my @specs = split /\//, $spec;
 430     if ($cmykix==1 && @specs==1) {
 431       $spec = $specs[0];
 432     } else {
 433       $spec = $specs[$cmykix];
 434       confess unless defined $spec;
 435     }
 436     my %cmyk;
 437     foreach (split /(?=[A-Z])/, $spec) {
 438       m/^([CMYK])([0-7](?:\.\d*)?|8)_?$/ or confess $_.' ?';
 439       confess if defined $cmyk{$1};
 440       $cmyk{$1} = $2 / 8.;
 441       #print STDERR " CMYK $1 $2\n";
 442     }
 443     @r = map { $cmyk{$_} // 0 } qw(C M Y K);
 444     $rw = 'setcmykcolor';
 445   } else {
 446     confess $spec.' ?';
 447   }
 448   my $r = join ' ',
 449       (map { sprintf "%.6f ", $_ } @r
 450       ),
 451           $rw;
 452   return $r;
 453 }
 454
 455 sub lighterpscolour ($$) {
 456   my ($colourname, $retain) = @_;
 457   #print STDERR "COLOUR LIGHTER $retain $colourname\n";
 458   pscolour($colourname, 0, $retain, 1-$retain);
 459 }
 460
 461 sub darkerpscolour ($$) {
 462   my ($colourname, $retain) = @_;
 463   #print STDERR "COLOUR DARKER $retain $colourname\n";
 464   pscolour($colourname, 2, $retain, 0);
 465 }
 466
 467 sub facepscolour ($) {
 468   my ($colourname) = @_;
 469   $xopts =~ m/W/ ? '1 setgray' : lighterpscolour($colourname, 0.75);
 470 }
 471
 472 sub miscpscolour ($) {
 473   my ($colourname) = @_;
 474   #print STDERR "COLOUR MISC $colourname\n";
 475   pscolour($colourname, 1, 1,0);
 476 }
 477
 478 sub seatrackedgepscolour () { darkerpscolour('cube', 0.25) }
 479
 480 sub fill_faces() {
 481   o("clippath ", facepscolour('land'), " fill\n");
 482   foreach my $rr (values %region) {
 483     next if $rr->{Name} =~ m/^L2?$/;
 484     face_path($rr);
 485     o(" ", facepscolour($rr->{Colour}), " eofill\n");
 486   }
 487 }
 488
 489 our $edge_lw = 5;
 490
 491 sub some_edge_faces (@) {
 492   o("$edge_lw setlinewidth 1 setlinejoin ",miscpscolour('edge'),"\n");
 493   foreach my $rr (@_) {
 494     next if $rr->{Name} =~ m/^L2?$/;
 495     face_path($rr);
 496     o("    stroke\n");
 497   }
 498 }
 499
 500 sub afsluitdijk() {
 501   my ($adj) = grep { $_->{Name} eq 'NZ' } @{ $region{'ZZ'}{Adj} };
 502   my $dash = 20;
 503   my (@pos) = adj_ends($adj);
 504   my $mid = 0.5 * ($pos[0] + $pos[1]);
 505   my $r = 0.5 * ($pos[1] - $pos[0])->norm();
 506   o(sprintf <<'END', facepscolour('sea'), psvec($mid), $r);
 507   %% Afsluitdijk
 508   %s %s %s 0 360 arc closepath fill
 509 END
 510   some_edge_faces(()); # just sets the colour
 511   o(sprintf <<END, map { psvec($_) } @pos);
 512   newpath %s moveto %s lineto
 513   [ $dash $dash ] $dash 0.5 mul setdash
 514   stroke
 515   [] 0 setdash
 516 END
 517   one_hs('purple', $mid);
 518 }
 519
 520 sub edge_faces() {
 521   some_edge_faces($region{'NZ'});
 522   afsluitdijk();
 523   some_edge_faces(grep {
 524     $_->{Name} !~ m{^(?:L2?|NZ|ZZ)$}
 525   } values %region);
 526 }
 527
 528 our $hs_sz = 17 * MM2PT;
 529 our $hs_lw = 3;
 530
 531 our $text_sz = 18;
 532
 533 sub token_circle ($$$$;$$) {
 534   my ($what, $pos, $fillcolour, $edgecolour, $sz,$lw) = @_;
 535   $sz //= $hs_sz;
 536   $lw //= $hs_lw;
 537   o(sprintf <<END, $what, $fillcolour, psvec($pos), $sz/2, $edgecolour);
 538    %% %s
 539    newpath %s
 540      %s %f 0 360 arc closepath gsave fill grestore
 541      %s $lw setlinewidth stroke
 542 END
 543 }
 544
 545 sub one_hs ($$;$$) {
 546   my ($colour, $hspos, $sz, $lw) = @_;
 547   token_circle("HS - $colour",
 548                $hspos,
 549                darkerpscolour($colour, 0.75),
 550                miscpscolour('edge'),
 551               $sz,$lw);
 552 }
 553
 554 our $cube_sz = 6 * MM2PT;
 555 our $cube_gap = $cube_sz * 0.2;
 556 our $cube_lw = ($cube_sz * 0.1);
 557
 558 sub label_faces() {
 559   my $sz = $text_sz;
 560   my $shadow = $sz * 0.1;
 561   my $textc   = miscpscolour('text');
 562   my $shadowc = miscpscolour('textshadow');
 563   o(<<END);
 564   /wordsshow {
 565     $shadowc 0 10 359 {
 566       dup  cos $shadow mul
 567       exch sin $shadow mul
 568       words pop pop
 569     } bind for
 570     $textc 0 0 words pop pop
 571   } def
 572 END
 573   o("  /Helvetica-Bold findfont  $sz scalefont setfont\n");
 574   my %hs = map { $_ => 1 } @{ $c{HS} };
 575   foreach my $rr (values %region) {
 576     next if $rr->{Name} =~ m/^L\d?$/;
 577     my $words = $rr->{DisplayName};
 578     my $pos;
 579     if ($rr->{Name} eq 'NZ') {
 580       $pos = mkvec(90, 1280);
 581     } else {
 582       $pos = $rr->{Centre} + mkvec( 0, 0.5 * $sz * @$words );
 583     }
 584     if ($hs{$rr->{Name}}) {
 585       #print STDERR "adjust hs $rr->{Name}\n";
 586       $pos -= mkvec(0, -$hs_sz*
 587                     ( $rr->{Colour} eq 'green' ? 0.25 : 0.65 ));
 588       my $hspos = $pos - mkvec(0, $sz * @$words + $hs_sz/2 + $hs_lw
 589                                + $hs_sz*0.15);
 590       one_hs($rr->{Colour}, $hspos);
 591     }
 592     my $adjust = $c{TextAdjust}{$rr->{Name}};
 593     if ($adjust) {
 594       $pos += $sz * &mkvec(@$adjust);
 595     }
 596     my $w = $rr->{Water};
 597     $w = 2 if $rr->{Special} || $rr->{Name} eq 'ZZ';
 598     if ($w) {
 599       #print STDERR " water $w in $rr->{Name}\n";
 600       my $down = water_cubes_sz(2) - water_cubes_sz(1) + $cube_gap;
 601       $pos -= mkvec(0, -0.5 * $down);
 602       my $cube_y = -($sz * @$words);
 603       if ($rr->{Name} eq 'Wieringermeer') {
 604         $pos -= mkvec(0,+$sz);
 605         $cube_y = 0;
 606         $down = 0;
 607       }
 608       o("  gsave\n");
 609       o("    ", psvec($pos), " translate\n");
 610       o("    0 ", $cube_y, " translate\n");
 611       o("    ", -0.5 * water_cubes_sz($w)," ", -$down, " translate\n");
 612       water_cubes($w, miscpscolour('edge'));
 613       o("  grestore\n");
 614     }
 615     o("  /words {\n");
 616     foreach my $word (@$words) {
 617       $pos += mkvec(0,-$sz);
 618       o("   ", psvec($pos), " moveto");
 619       o(<<END);
 620    2 copy rmoveto
 621    ($word) dup stringwidth pop     % word xw
 622      -0.5 mul 0 rmoveto             % word
 623      show
 624    0 -$sz rmoveto
 625 END
 626     }
 627     o(<<END);
 628   } bind def
 629   wordsshow
 630 END
 631   }
 632 }
 633
 634 sub water_cubes_sz($){
 635   my ($n) = @_;
 636   ($cube_sz + $cube_lw) * $n + ($cube_gap * ($n-1));
 637 }
 638
 639 sub water_cubes($$){
 640   my ($n, $edgecolour) = @_;
 641   my $s = $cube_sz;
 642   for my $i (0..$n-1) {
 643     o("  newpath  ", $i * ($cube_sz + $cube_lw + $cube_gap),"  0  moveto\n");
 644     o("          $s  0  rlineto\n");
 645     o("           0 $s  rlineto\n");
 646     o("         -$s  0  rlineto  closepath\n");
 647     o("  gsave ", miscpscolour('cube'), " fill grestore\n");
 648     o("  gsave ", $edgecolour, " ", $cube_lw,
 649       " setlinewidth stroke grestore \n");
 650   }
 651 }
 652
 653 my $deck_h = 89 * MM2PT;
 654
 655 sub decks(){
 656   my $lw = $edge_lw/2;
 657   o("  /deck1path {\n");
 658   my $w = 63 * MM2PT;
 659   my $h = $deck_h;
 660   my $r =  5 * MM2PT;
 661   o("      ",($w/2)," 0 moveto\n");
 662   my @p = ([ $w, 0 ],
 663            [ $w,$h ],
 664            [ 0, $h ],
 665            [ 0,  0 ]);
 666   foreach my $i (0..3) {
 667     o("    @{ $p[$i] }  @{ $p[($i + 1) % 4] }  $r  arct\n");
 668   }
 669   o("    closepath\n");
 670   o("  } bind def");
 671   o("  /deckpairpathx {\n"); # x because it leaves matrix changed
 672   o("    newpath         deck1path\n");
 673   o("    200 0 translate deck1path\n");
 674   o("  } bind def");
 675   o("  $lw setlinewidth ",miscpscolour('playerdeck'),"\n");
 676   o("  gsave 401 44 translate deckpairpathx stroke grestore");
 677   o("  $lw setlinewidth ",miscpscolour('dykefail'),"\n");
 678   o("  gsave 242 1363 translate 90 rotate deckpairpathx stroke grestore");
 679 }
 680
 681 sub sea_track(){
 682   o("% sea level track\n");
 683   o("  gsave 11 700 translate\n");
 684   my $track = $c{SeaTrack};
 685   my $token_sz = $hs_sz;
 686   my $dy = $token_sz * 1.25;
 687   my $dx = $token_sz * 1.25;
 688   my $linecolour = seatrackedgepscolour();
 689   my @pos;
 690   for my $i (0..$#$track) {
 691     $pos[$i] = mkvec(0, ($i - 0.5 * @$track) * $dy);
 692   }
 693   my $prepline = "$linecolour $hs_lw setlinewidth newpath";
 694   o("  $prepline\n");
 695   o("    ",psvec($pos[0])," moveto ",psvec($pos[-1])," lineto stroke\n");
 696   for my $pos (@pos) {
 697     token_circle("SL", $pos,
 698                  miscpscolour('cube'),
 699                  $linecolour);
 700   }
 701   my $last = 0;
 702   my $cubeedgecolour = seatrackedgepscolour();
 703   for my $i (0..$#pos) {
 704     my $differs = $track->[$i] != $last;
 705     $last = $track->[$i];
 706     next unless $differs;
 707     o("  $prepline\n");
 708     o("  gsave ",
 709       psvec($pos[$i] + mkvec(-0.0 * $token_sz, $dy/2))," translate\n");
 710
 711     my $t_sz = 24;
 712     my $shrink = ($hs_sz * 0.75 / $deck_h);
 713     o("    gsave % T M $i\n");
 714     o("      -43.5 -6.5 translate\n");
 715     o("      0.8 .8 scale \n");
 716     o("      ",0.6 * $dx, " ", -0.28 * $dy," translate\n");
 717     o("      gsave");
 718     o("        $shrink dup scale -90 rotate\n");
 719     o("        newpath ", ($hs_lw / $shrink)," setlinewidth\n");
 720     o("         deck1path stroke\n");
 721     o("      grestore");
 722     o("      /Helvetica-Bold findfont $t_sz scalefont setfont\n");
 723     o("      12 -21.5 moveto ($track->[$i]) show");
 724     o("    grestore\n");
 725
 726     if ($i > 0) {
 727       o("  0 -$dy moveto",
 728         " ",psvec(mkvec( $dx + $cube_sz, 0 )),
 729         " rlineto stroke\n");
 730     }
 731     o("  ",($token_sz * 0.6 + $cube_gap)," ",
 732       (-$dy * 0.5 - 0.5 * (water_cubes_sz(2))),
 733       " translate\n");
 734     my $bottom = int(($track->[$i+1] + 1) / 2);
 735     water_cubes($bottom, $cubeedgecolour);
 736     my $new_n = $track->[$i+1] - $bottom;
 737     o("  ", 0.5 * (water_cubes_sz($bottom) - water_cubes_sz($new_n)),
 738       "  ",       (water_cubes_sz(2)-water_cubes_sz(1)), " translate\n");
 739     water_cubes($new_n, $cubeedgecolour);
 740     o("  grestore\n");
 741   }
 742   o("  grestore\n");
 743 }
 744
 745 our $dyke_l = 25 * MM2PT;;
 746
 747 sub dykes(){
 748   my $l = $dyke_l;
 749   my $w = 5 * MM2PT;
 750   my $lw = $edge_lw * 0.50;
 751   my $l2 = $l/2;
 752   my $w2 = $w/2;
 753   o("  /dykepath {\n");
 754   o("            -$l2 -$w2 moveto\n");
 755   o("             $l2 -$w2 lineto\n");
 756   o("             $l2  $w2 lineto\n");
 757   o("            -$l2  $w2 lineto closepath\n");
 758   o("  } bind def\n");
 759   o("  /dyke {\n");
 760   o("    newpath dykepath\n");
 761   o("    gsave ",miscpscolour('dykefill')," fill grestore\n");
 762   o("    gsave ",miscpscolour('edge')," $lw setlinewidth stroke grestore\n");
 763   o("  } bind def\n");
 764   my $symbol_sz = $w * 1.50;
 765   my $t_sz = $symbol_sz * 1.0;
 766   my $t_at = sub {
 767     my ($ang) = @_;
 768     #print STDERR "ANG $ang\n";
 769     map { $t_sz * 0.5 * $_ } cos($ang), sin($ang);
 770   };
 771   my @t0 = $t_at->((TAU) *  0.25         );
 772   my @t1 = $t_at->((TAU) * (0.25 + 1./3) );
 773   my @t2 = $t_at->((TAU) * (0.25 + 2./3) );
 774   o("  /dtriangle {\n");
 775   o("    newpath @t0 moveto\n");
 776   o("            @t1 lineto\n");
 777   o("            @t2 lineto closepath\n");
 778   o("    gsave ",miscpscolour('dykeinit')," fill grestore\n");
 779   o("    gsave ",miscpscolour('edge')," $lw setlinewidth stroke grestore\n");
 780   o("  } bind def\n");
 781   foreach my $rr (values %region) {
 782     next if $rr->{Special};
 783     next if $rr->{Name} eq 'ZZ';
 784     next if $rr->{Colour} eq 'high';
 785     foreach my $adj (@{ $rr->{Adj} }) {
 786       my $neigh = $adj->{Name};
 787       o("  % dyke $rr->{Name} --- $neigh\n");
 788       next if $neigh lt $rr->{Name} && !$region{$neigh}{Special};
 789       next if $region{$neigh}{Colour} eq 'high';
 790       my @ends = adj_ends($adj);
 791       my $dirn = $ends[1] - $ends[0];
 792       my $angle = vec2atan($dirn);
 793       $angle = $angle * 360 / TAU;
 794       o("  gsave\n");
 795       o("    ", psvec( 0.5 * ($ends[0] + $ends[1]) )," translate\n");
 796       o("    $angle rotate\n");
 797       my $initial = $adj->{Dykes};
 798       for my $ys ($initial
 799                   ? [ map { $_ - 0.5 * ($initial-1) } 0..$initial-1 ]
 800                   : [0]) {
 801         foreach my $y (@$ys) {
 802           o("    gsave 0 ", $y * $w, " translate dyke ");
 803           o(" grestore\n");
 804         }
 805         my $nsymbols = $initial + !!$adj->{Deltawerk};
 806         o("   ", -0.5 * $symbol_sz * ($nsymbols-1)," 0 translate\n");
 807         my $trans = "  $symbol_sz 0 translate";
 808         if ($adj->{Deltawerk}) {
 809           one_hs('red', mkvec(0,0), $symbol_sz * 0.8, $lw);
 810           o($trans);
 811         }
 812         foreach my $i (1..$initial) {
 813           o(" gsave $angle neg rotate dtriangle grestore\n");
 814           o($trans);
 815         }
 816       }
 817       o("  grestore\n");
 818     }
 819   }
 820 }
 821
 822 sub hs_initial_1 ($$$;$$$) {
 823   my ($colour, $xi,$yi, $text, $text2, $fn) = @_;
 824   my $interval = $hs_sz * 1.75;
 825   my $demo_h = $hs_sz; #water_cubes_sz(3);
 826   my $demo_x0 = $hs_sz * 0.75 + $dyke_l * 0.60;
 827   my $demo_w = $demo_x0 + $dyke_l * 0.60;
 828   o("  % HS I $colour\n");
 829   o("  gsave\n");
 830   o("    550 1705 translate\n");
 831   o("    ", ($xi*$interval), " ", (($yi-1)*$interval), " translate\n");
 832   if ($fn) {
 833     o("  gsave\n");
 834     o("        $demo_h setlinewidth 0 0 moveto $demo_w 0 rlineto\n");
 835     o("        ", facepscolour($colour), " stroke grestore\n");
 836   }
 837   one_hs($colour, mkvec(0,0));
 838   if ($fn) {
 839     o("    /words {\n");
 840     o("      2 copy moveto                      ($text) show\n");
 841     o("      2 copy moveto 0 -$text_sz rmoveto ($text2) show\n");
 842     o("    } bind def\n");
 843     o("    gsave ".($hs_sz * 0.8)." $cube_gap translate wordsshow grestore\n");
 844     o("    $demo_x0 ",($hs_sz * -0.25)," translate\n");
 845     $fn->();
 846   }
 847   o("  grestore\n");
 848 }
 849
 850 sub hs_initial () {
 851   hs_initial_1('red',     0,0);
 852   hs_initial_1('purple',  0,1);
 853   hs_initial_1('green',   1,0, 'up to 6', 'fewer', sub {
 854     o("    ",(water_cubes_sz(1))," 0 translate\n");
 855     o("    0 ",(-water_cubes_sz(1) * 0.3)," translate\n");
 856     water_cubes(1, miscpscolour('edge'));
 857   });
 858   hs_initial_1('yellow',  1,1, 'up to 4', '', sub {
 859     o("    newpath dykepath\n");
 860     o("    gsave ",miscpscolour('edge')," stroke grestore\n");
 861     o("    gsave ",miscpscolour('dykehsadd')," fill grestore\n");
 862   });
 863 }
 864
 865 sub play_hint () {
 866   my $sz = 20;
 867   o("  gsave ",miscpscolour('hinttext')," 260 1715 translate\n");
 868   o("  /Helvetica-Bold findfont $sz scalefont setfont\n");
 869   my @t = split /\n/, $c{PlayHint};
 870   foreach my $i (0..$#t) {
 871     my $t = $t[$i];
 872     $t =~ s/[\\()]/\\$&/g;
 873     o("  0 ",(-$i * $sz)," moveto ($t) show\n");
 874   }
 875   o("  grestore");
 876 }
 877
 878 #----- main program -----
 879
 880 $xopts = shift @ARGV if $ARGV[0] =~ s/^-X//;
 881 $bounding = $1 if $xopts =~ s/b(\w+)//;
 882 $maxpaper = $1 if $xopts =~ s/p(\w+)//;
 883 $maxpaper =~ m/^a[134]$/ or confess;
 884
 885 ($facesf, @ARGV) = @ARGV or die;
 886 parse_input_graph();
 887 prep_region_rmap();
 888 read_faces();
 889 calculate_centres();
 890 transform_coordinates();
 891 adjust_nz();
 892
 893 computeboundings();
 894 preamble();
 895 fill_faces();
 896 edge_faces();
 897 dykes();
 898 label_faces();
 899 decks();
 900 sea_track();
 901 hs_initial();
 902 play_hint();
 903 showboundings();
 904 postamble();
 905
 906 print STDERR Dumper(\%region) if $ENV{'GENERATE_BOARD_DUP'};
 907
 908 # Local variables:
 909 # cperl-indent-level: 2
 910 # End.