generate-board

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Carp;
   5 use Data::Dumper;
   6 use Math::GSL::Vector qw/:all/;
   7 use Math::GSL::Matrix qw/:all/;
   8 use Math::GSL::Const;
   9 use Math::GSL::BLAS qw/:all/;
  10 use Math::GSL::CBLAS qw/:all/;
  11 use Math::GSL::Machine qw/:all/;
  12
  13 use POSIX qw(M_PI);
  14
  15 BEGIN { unshift @INC, qw(.); }
  16
  17 use Parse;
  18
  19 our $xopts = '';
  20 our $bounding = 'Entire';
  21 our $facesf;
  22 our %vxname2pos; # $vxname2pos{VXNAME} = Math::GSL::Vector
  23 our %bb; # $r{Bounding...}[0..3] = points
  24 our $maxpaper = 'a3';
  25
  26 sub TAU { M_PI * 2.0; }
  27 sub MM2PT { 72.0 / 25.4; }
  28
  29 our $mid;
  30
  31 our $a4_w = 595;
  32 our $a4_h = 842;
  33 our $a3_h = 1190;
  34 our $a1_w = 1684;
  35 our $a1_h = 2384;
  36
  37 our $max_printeredge = 5.50 * MM2PT;
  38 our $a1m_pasteedge = 3.5 * MM2PT; # along each edge
  39 our $preamble_from_boundings = '';
  40 our $top_adjuncts_dy_from_boundings = 0;
  41 our $bottom_adjuncts_dy_from_boundings = 0;
  42
  43 # ----- region names from plag, incl. reverse mapping -----
  44
  45 our %prs2region;
  46
  47 sub prep_region_rmap () {
  48   foreach my $rn (keys %region) {
  49     my $prs = plag_prs($rn);
  50     die if $prs2region{$prs};
  51     $prs2region{$prs} = $rn;
  52   }
  53 }
  54
  55 our $sre = qr{(?:(\")|(?=\w))(.*)\1$}; # 2 captures, $2 is the name
  56
  57 sub prs2r ($) {
  58   # bodgery for the sea and land
  59   return 'NZ' if m/ \| / && !grep { !m{^(?:NZ|L2?)$} } split / \| /, $_[0];
  60   $prs2region{$_[0]} // confess "@_ ?"
  61 }
  62 sub prs2rr ($) { $region{prs2r($_[0])} }
  63
  64 #----- file reader for plag output -----
  65
  66 sub read_faces () {
  67   # Sets
  68   #  $region{NAME}{Adj}[]{Ends}[]{VxName}
  69   #  $region{NAME}{Adj}[]{Ends}[]{Pos}
  70   #  $region{NAME}{Polygon}{Pos}
  71   #  $region{NAME}{Special}
  72   #
  73   # also incidentally
  74   #  $region{NAME}{Adj}[]{Ends}[]{Adjoins}
  75   #  $region{NAME}{Polygon}{Adjoins}
  76   # which should be ignored
  77
  78   open P, "<", $facesf or die $!;
  79   while (<P>) { last if m/^\&faces$/; }
  80   my $rr;
  81   my @edges;
  82   my $process_rr = sub {
  83     my $last_ai;
  84     if ($rr->{Name} eq 'NZ') {
  85       # We combined L and NZ; now we must split them again
  86       # in fact, we just throw away L and L2 entirely.
  87       # Here, when processing NZ, we keep only vertices that
  88       # are part of NZ.
  89       @edges = grep {
  90         my $evxname = $_->{VxName};
  91         my @eregions = split / \| ?/, $evxname;
  92         grep { $_ eq 'NZ' } @eregions
  93       } @edges;
  94     }
  95     $rr->{Polygon} = [ @edges ];
  96     if ($rr->{Name} ne 'NZ') {
  97       for my $ei (0..$#edges) {
  98         if (!defined $last_ai) {
  99           my $ai;
 100           for my $ai (0..$#{ $rr->{Adj} }) {
 101             next unless $rr->{Adj}[$ai]{Name} eq $edges[$ei]{Adjoins};
 102             $last_ai = $ai+1;
 103           }
 104           confess $edges[$ei]{Adjoins}.' ?' unless defined $last_ai;
 105         }
 106         my $ai = ($last_ai-1+@edges) % @edges;
 107         $last_ai = $ai;
 108         my $adj = $rr->{Adj}[$ai];
 109         confess Dumper($adj->{Name}, $edges[$ei]{Adjoins},
 110                        $rr, \@edges, $ei, $adj, $last_ai, $ai)." ?"
 111             unless $adj->{Name} eq $edges[$ei]{Adjoins};
 112
 113         for my $endi (0..1) {
 114           $adj->{Ends}[$endi] = $edges[ ($ei + $endi) % @edges ];
 115         }
 116       }
 117     }
 118     @edges = ();
 119     $rr = undef;
 120   };
 121   my $vxname;
 122   for (;;) {
 123     $!=0; $_=<P> // confess $!;
 124     last if m/^\&$/;
 125     if (m/^$sre$/) {
 126       my $new_face= $2;
 127       $process_rr->() if $rr;
 128       $rr= prs2rr($new_face);
 129     } elsif (m/^\s+$sre$/) {
 130       confess unless $rr;
 131       $vxname = $2;
 132       push @edges, { VxName => $vxname };
 133     } elsif (m/^\s+\^adjoins\s+$sre$/) {
 134       $edges[-1]{Adjoins} = prs2r($2);
 135     } elsif (m/^\s+\^\@([-e.0-9]+)\,([-e.0-9]+)$/) {
 136       my $pos = mkvec($1,$2);
 137       confess unless defined $vxname;
 138       $edges[-1]{Pos} = $pos;
 139       $vxname2pos{$vxname} = $pos;
 140     }
 141   }
 142   $process_rr->();
 143
 144   $region{$_}{Special} = 1 foreach qw(NZ L L2);
 145 }
 146
 147 #----- geometry mangling -----
 148
 149 sub adj_ends ($) {
 150   my ($adj) = @_;
 151   map { $_->{Pos} } @{ $adj->{Ends} };
 152 }
 153
 154 sub calculate_centres () {
 155   # Sets
 156   #  $region{NAME}{Centre}
 157   foreach my $rr (values %region) {
 158     next if $rr->{Special};
 159     my $sum = Math::GSL::Vector->new(2);
 160     my $wsum = 0;
 161     foreach my $adj (@{ $rr->{Adj} }) {
 162       my @ends = adj_ends($adj);
 163       my $w = ($ends[1] - $ends[0])->norm();
 164       $sum += $w * $_ foreach @ends;
 165       $wsum += $w;
 166     }
 167     $rr->{Centre} = $sum * (0.5 / $wsum);
 168   }
 169 }
 170
 171 sub for_each_pos ($) {
 172   my ($f) = @_;
 173   my $call = sub {
 174     my ($pr,$rr,$why) = @_;
 175     return unless defined $$pr;
 176     $f->($pr,$rr,$why);
 177   };
 178   foreach my $rr (values %region) {
 179     $call->( \ $rr->{Centre}, $rr, $rr->{Name}." C" );
 180     foreach my $vertex (@{ $rr->{Polygon} }) {
 181       $call->( \ $vertex->{Pos}, $rr, $rr->{Name}." | ".$vertex->{Adjoins} );
 182     }
 183   }
 184 }
 185
 186 sub prvec ($) {
 187   my ($v) = @_;
 188   confess unless $v;
 189   sprintf "%g,%g", $v->get(0), $v->get(1);
 190 }
 191
 192 sub mkvec ($$) { Math::GSL::Vector->new(\@_) }
 193 sub vec2atan ($) { my ($dir) = @_; atan2 $dir->get(1), $dir->get(0); }
 194
 195 sub transform_coordinates () {
 196   # Adjusts coordinates in graph to be [0,0] .. top right (scaled)
 197   # until it's all in PostScript points
 198   my @or = map { $region{$_}{Centre} } @{ $c{OrientRegions} };
 199   my $dir = $or[1] - $or[0];
 200   my $theta = vec2atan($dir);
 201   my $rotateby = (90. - $c{OrientBearing}) * ((TAU)/360.) - $theta;
 202   my $s = sin($rotateby);
 203   my $c = cos($rotateby);
 204   my $transform = Math::GSL::Matrix->new(2,2);
 205   $transform->set_row(0, [  $c, -$s ]);
 206   $transform->set_row(1, [  $s,  $c ]);
 207   #  print STDERR "rotate was=",prvec($dir)," theta=$theta",
 208   #    " rotateby=$rotateby s=$s c=$c\n";
 209   my @lims;
 210   foreach my $topend (qw(0 1)) {
 211     my $v = $topend ? -$GSL_DBL_MAX : $GSL_DBL_MAX;
 212     $lims[$topend] = mkvec($v,$v);
 213   }
 214   for_each_pos(sub {
 215     my ($pr, $rr, $why) = @_;
 216     my $y = Math::GSL::Vector->new(2);
 217     gsl_blas_dgemv($CblasNoTrans,
 218                    1.0, $transform->raw,
 219                    $$pr->raw,
 220                    0, $y->raw)
 221         and confess;
 222     #print STDERR "gsl_blas_dgemv ",prvec($$pr)," => ",prvec($y),"\n";
 223     gsl_blas_dcopy($y->raw, $$pr->raw)
 224         and confess;
 225     foreach my $topend (qw(0 1)) {
 226       foreach my $xy (qw(0 1)) {
 227         my $now = $y->get($xy);
 228         my $lim = $lims[$topend]->get($xy);
 229         #print STDERR "?set $topend $xy $now $lim\n";
 230         next if $topend ? ($now <= $lim) : ($now >= $lim);
 231         $lims[$topend]->set([$xy], [$now]);
 232         #print STDERR "set $topend $xy $now\n";
 233       }
 234     }
 235   });
 236   #print STDERR "lims ",prvec($lims[0])," .. ",prvec($lims[1]),"\n";
 237   my $translate = -$lims[0];
 238   #print STDERR "translate ",prvec($translate),"\n";
 239   my $scale = $c{GraphScale} * MM2PT;
 240   for_each_pos(sub {
 241     my ($pr) = @_;
 242     gsl_vector_add($$pr->raw, $translate->raw) and confess;
 243     gsl_vector_scale($$pr->raw, $scale) and confess;
 244   });
 245   $mid = ($lims[1] - $lims[0]) * 0.5;
 246 }
 247
 248 sub adjust_nz() {
 249   my $poly = $region{NZ}{Polygon};
 250   my %occurs;
 251   foreach my $v (@$poly) {
 252     $occurs{$v->{VxName}}++
 253   }
 254   foreach my $v (@$poly) {
 255     $v->{NZ_Occurs} = $occurs{$v->{VxName}};
 256   }
 257   #print STDERR " nz ".(scalar @$poly)."\n";
 258   my $occurs_m = sub {
 259     my ($ei) = @_;
 260     $poly->[($ei+@$poly) % @$poly]{NZ_Occurs} > 1
 261   };
 262   for my $ei (0..$#$poly) {
 263     next if $occurs_m->($ei);
 264     next unless $occurs_m->($ei-1);
 265     next unless $occurs_m->($ei+1);
 266     #print STDERR " nz would adjust $poly->[$ei]{VxName}\n";
 267     # adjust coord outwards
 268   }
 269   for my $ei (0..$#$poly) {
 270     next unless $occurs_m->($ei);
 271     #print STDERR " nz occurs_m $ei $poly->[$ei]{VxName}\n";
 272     next unless $occurs_m->($ei-1);
 273     my $dleft = mkvec(-1000,0);
 274     foreach my $which (0,-1) {
 275       my $ej = ($ei +        $which + @$poly) % @$poly;
 276       my $ek = ($ei + +1 + 3*$which + @$poly) % @$poly;
 277       my $posj = \ $poly->[$ej]{Pos};
 278       my $posk = \ $poly->[$ek]{Pos};
 279       my $dout = $$posk - $$posj;
 280       #print STDERR " nz adj j=$ej ",prvec($$posj)," $poly->[$ej]{VxName}\n";
 281       #print STDERR " nz adj k=$ek ",prvec($$posk)," $poly->[$ek]{VxName}\n";
 282       if ($poly->[$ej]{VxName} =~ /Noorderzijlvest/) {
 283         #print STDERR " nz adj extra\n";
 284         $$posk = $$posj + 10 * mkvec(100,-50);
 285       }
 286       $$posj = $$posj + $dleft + $dout*10;
 287       $$posk = $$posk          + $dout*10;
 288     }
 289   }
 290 }
 291
 292 sub psvec ($) {
 293   my ($pos) = @_;
 294   sprintf "%20.6f %20.6f", $pos->get(0),$pos->get(1)
 295 }
 296
 297 sub face_path ($) {
 298   my ($rr) = @_;
 299   o("% $rr->{Name}\n");
 300   o("  newpath\n");
 301   my $xto = 'moveto';
 302   foreach my $vertex (@{ $rr->{Polygon} }) {
 303     my $pos = $vertex->{Pos};
 304     o(sprintf "    %s %s\n", psvec($pos), $xto);
 305     $xto = 'lineto';
 306   }
 307   o("    closepath\n");
 308 }
 309
 310 sub computeboundings() {
 311   $bb{Entire} = [ 0,0, $a4_h, $a4_w + $a3_h ];
 312   my $submargins = sub {
 313     my ($margin, $pr) = @_;
 314     my @p = @$pr;
 315     [ $p[0] + $margin,
 316       $p[1] + $margin,
 317       $p[2] - $margin,
 318       $p[3] - $margin ];
 319   };
 320   my $somepage = sub {
 321     my $id = shift @_;
 322     print STDERR "defining page Page$id\n";
 323     $bb{"Page$id"} = [ @_ ];
 324     $bb{"Printable$id"} = $submargins->($max_printeredge, $bb{"Page$id"});
 325   };
 326   my $pageb_a4 = sub {
 327     $somepage->('B', 0,0, $a4_h, $a4_w );
 328   };
 329   if ($maxpaper eq 'a3') {
 330     $pageb_a4->();
 331     my $mt_offset = $bb{PrintableB}[3] - $max_printeredge;
 332     $somepage->('MT', 0, $mt_offset, $a4_h, $mt_offset + $a3_h );
 333     $bb{PrintableAll} = [
 334                          @{ $bb{PrintableB} }[0..1],
 335                          @{ $bb{PrintableMT} }[2..3],
 336                         ];
 337   } elsif ($maxpaper eq 'a4') {
 338     $pageb_a4->();
 339     my $m_offset = $bb{PrintableB}[3] - $max_printeredge;
 340     $somepage->('M', 0, $m_offset, $a4_h, $m_offset + $a4_w );
 341     my $t_offset = $bb{PrintableM}[3] - $max_printeredge;
 342     $somepage->('T', 0, $t_offset, $a4_h, $t_offset + $a4_w );
 343     $bb{PrintableAll} = [
 344                          @{ $bb{PrintableB} }[0..1],
 345                          @{ $bb{PrintableT} }[2..3],
 346                         ];
 347   } elsif ($maxpaper =~ m/^a1/) {
 348     my $offx = 0.5*($a1_w - $bb{Entire}[2]);
 349     my $offy = 0.5*($a1_h - $bb{Entire}[3]);
 350     $somepage->('P', -$offx,-$offy, $a1_w-$offx, $a1_h-$offy);
 351     my $hairs = 30 * MM2PT;
 352     my $hairsw = $bb{Entire}[2];
 353     my $hairsh = $bb{Entire}[3];
 354     my $surround = 5 * MM2PT;
 355     my $surroundw = $bb{Entire}[2] + $surround*2;
 356     my $surroundh = $bb{Entire}[3] + $surround*2;
 357     my @hrect = @{ $bb{Entire} };
 358     if ($maxpaper eq 'a1m') {
 359       @hrect = @{ $submargins->($a1m_pasteedge, \@hrect) };
 360       $bb{Cutout} = \@hrect;
 361     }
 362     my $w_stroke = $xopts =~ m/W/ ?
 363         ' gsave 3 setlinewidth stroke grestore '
 364         : '';
 365     $preamble_from_boundings = <<END;
 366          1 setlinewidth
 367          0 setgray
 368          /a1hairs {
 369              newpath moveto
 370              $hairs 0        rmoveto
 371              $hairs -2 mul 0 rlineto
 372              $hairs $hairs   rmoveto
 373              0 $hairs -2 mul rlineto
 374              stroke
 375          } def
 376          $hrect[0] $hrect[1] a1hairs
 377          $hrect[0] $hrect[3] a1hairs
 378          $hrect[2] $hrect[3] a1hairs
 379          $hrect[2] $hrect[1] a1hairs
 380          newpath
 381          -$surround -$surround moveto
 382           $surroundw 0         rlineto
 383           0 $surroundh         rlineto
 384           -$surroundw 0        rlineto
 385                  closepath $w_stroke clip
 386 END
 387     $top_adjuncts_dy_from_boundings = 35;
 388     $bottom_adjuncts_dy_from_boundings = -7;
 389   } else {
 390     confess;
 391   }
 392 }
 393
 394 sub showboundings () {
 395   return unless $xopts =~ m/B/;
 396   o("  grestore gsave\n");
 397   my $bb = $bb{$bounding};
 398   o("  $bb->[0] neg $bb->[1] neg translate\n");
 399   my $i = 0;
 400   my $on = 2;
 401   my $off = 9;
 402   foreach my $bname (sort keys %bb) {
 403     o(sprintf "   1 %d %d setrgbcolor\n",
 404       !!($bname =~ m/^Page/),
 405       !!($bname =~ m/B$/),
 406      );
 407     o("    % $bname\n");
 408     o("    [ $on $off ] ".($i * ($on+$off))," setdash newpath\n");
 409     my @p = @{ $bb{$bname} };
 410     o("    $p[0] $p[1] moveto\n");
 411     o("    $p[2] $p[1] lineto\n");
 412     o("    $p[2] $p[3] lineto\n");
 413     o("    $p[0] $p[3] lineto\n");
 414     o("    closepath stroke\n");
 415     $i++;
 416   }
 417 }
 418
 419 sub o_amble (@) {
 420   # CPerl-mode does a really awful thing with %s in the preamble
 421   # and postamble, causing constant useless flashing
 422   # So we write & in the here docs and transform them back:
 423   my ($t) = join '', @_;
 424   $t =~ s/^\&+/ '%' x length $& /mge;
 425   o($t);
 426 }
 427
 428 sub preamble() {
 429   my $bb = $bb{$bounding}; confess $bounding unless $bb;
 430   my $sz = [ $bb->[2] - $bb->[0], $bb->[3] - $bb->[1] ];
 431   o_amble(<<END);
 432 &!PS-Adobe-3.0
 433 &&BoundingBox 0 0 @$sz
 434 &&Pages: 1
 435 &&EndComments
 436 &&BeginProlog
 437 &&EndProlog
 438 &&BeginSetup
 439 << /PageSize [ @$sz ] >> setpagedevice
 440 /board {
 441   gsave
 442   $bb->[0] neg  $bb->[1] neg  translate
 443   $preamble_from_boundings
 444
 445   % adjustment to actual image placement within prinable areas etc.:
 446   34 -15 translate
 447 END
 448   if ($maxpaper eq 'a4') {
 449     o("0 -17 translate\n");
 450   }
 451 }
 452
 453 sub postamble () {
 454   o_amble(<<END);
 455   grestore
 456 } bind def
 457 &&EndSetup
 458 &&Page: 1
 459 &&BeginPageSetup
 460 /pgsave save def
 461 &&EndPageSetup
 462 board
 463 pgsave restore
 464 showpage
 465 &&EOF
 466 END
 467 }
 468
 469 sub pscolour ($$$$) {
 470   my ($colourname, $cmykix,$rgbmul,$rgbadd) = @_;
 471   my $spec = $c{Colours}{$colourname};
 472   confess unless defined $spec;
 473
 474   # check that we have only one lighter/darker retain value for each one
 475   our %colour_occurred;
 476   $colour_occurred{$colourname}{$cmykix}{$rgbmul,$rgbadd} = 1;
 477   keys %{ $colour_occurred{$colourname}{$cmykix} } == 1 or confess;
 478
 479   my @r;
 480   my $rw;
 481   if ($spec =~ m/^[0-9a-f]+$/) {
 482     my $le = (length $spec)/3;
 483     my $re = ("(.{$le})") x 3;
 484     my @rgb = $spec =~ m/^$re$/;  @rgb or confess "$re ?";
 485     @rgb = map { hex($_) / (16**$le -1) } @rgb;
 486     foreach (@rgb) { $_ *= $rgbmul; $_ += $rgbadd; }
 487     @r = @rgb;
 488     $rw = 'setrgbcolor';
 489   } elsif ($spec =~ m/[CMYK]/) {
 490     my @specs = split /\//, $spec;
 491     if ($cmykix==1 && @specs==1) {
 492       $spec = $specs[0];
 493     } else {
 494       $spec = $specs[$cmykix];
 495       confess unless defined $spec;
 496     }
 497     my %cmyk;
 498     foreach (split /(?=[A-Z])/, $spec) {
 499       m/^([CMYK])([0-7](?:\.\d*)?|8)_?$/ or confess $_.' ?';
 500       confess if defined $cmyk{$1};
 501       $cmyk{$1} = $2 / 8.;
 502       #print STDERR " CMYK $1 $2\n";
 503     }
 504     @r = map { $cmyk{$_} // 0 } qw(C M Y K);
 505     $rw = 'setcmykcolor';
 506   } else {
 507     confess $spec.' ?';
 508   }
 509   my $r = join ' ',
 510       (map { sprintf "%.6f ", $_ } @r
 511       ),
 512           $rw;
 513   return $r;
 514 }
 515
 516 sub lighterpscolour ($$) {
 517   my ($colourname, $retain) = @_;
 518   #print STDERR "COLOUR LIGHTER $retain $colourname\n";
 519   pscolour($colourname, 0, $retain, 1-$retain);
 520 }
 521
 522 sub darkerpscolour ($$) {
 523   my ($colourname, $retain) = @_;
 524   #print STDERR "COLOUR DARKER $retain $colourname\n";
 525   pscolour($colourname, 2, $retain, 0);
 526 }
 527
 528 sub facepscolour ($) {
 529   my ($colourname) = @_;
 530   $xopts =~ m/W/ ? '1 setgray' :
 531       $colourname =~ m/land/ ? miscpscolour($colourname)
 532       : lighterpscolour($colourname, 0.75);
 533 }
 534
 535 sub miscpscolour ($) {
 536   my ($colourname) = @_;
 537   #print STDERR "COLOUR MISC $colourname\n";
 538   pscolour($colourname, 1, 1,0);
 539 }
 540
 541 sub seatrackedgepscolour () { darkerpscolour('cube', 0.25) }
 542
 543 sub fill_faces() {
 544   o("clippath ", facepscolour('land'), " fill\n");
 545   foreach my $rr (values %region) {
 546     next if $rr->{Name} =~ m/^L2?$/;
 547     face_path($rr);
 548     o(" ", facepscolour($rr->{Colour}), " eofill\n");
 549   }
 550 }
 551
 552 our $edge_lw = 5;
 553
 554 sub some_edge_faces (@) {
 555   o("$edge_lw setlinewidth 1 setlinejoin ",miscpscolour('edge'),"\n");
 556   foreach my $rr (@_) {
 557     next if $rr->{Name} =~ m/^L2?$/;
 558     face_path($rr);
 559     o("    stroke\n");
 560   }
 561 }
 562
 563 sub afsluitdijk() {
 564   my ($adj) = grep { $_->{Name} eq 'NZ' } @{ $region{'ZZ'}{Adj} };
 565   my $dash = 20;
 566   my (@pos) = adj_ends($adj);
 567   my $mid = 0.5 * ($pos[0] + $pos[1]);
 568   my $r = 0.5 * ($pos[1] - $pos[0])->norm();
 569   o(sprintf <<'END', facepscolour('sea'), psvec($mid), $r);
 570   %% Afsluitdijk
 571   %s %s %s 0 360 arc closepath fill
 572 END
 573   some_edge_faces(()); # just sets the colour
 574   o(sprintf <<END, map { psvec($_) } @pos);
 575   newpath %s moveto %s lineto
 576   [ $dash $dash ] $dash 0.5 mul setdash
 577   stroke
 578   [] 0 setdash
 579 END
 580   one_hs('purple', $mid);
 581 }
 582
 583 sub edge_faces() {
 584   some_edge_faces($region{'NZ'});
 585   afsluitdijk();
 586   some_edge_faces(grep {
 587     $_->{Name} !~ m{^(?:L2?|NZ|ZZ)$}
 588   } values %region);
 589 }
 590
 591 our $hs_sz = 17 * MM2PT;
 592 our $hs_lw = 3;
 593
 594 our $text_sz = 18;
 595
 596 sub token_circle ($$$$;$$) {
 597   my ($what, $pos, $fillcolour, $edgecolour, $sz,$lw) = @_;
 598   $sz //= $hs_sz;
 599   $lw //= $hs_lw;
 600   o(sprintf <<END, $what, $fillcolour, psvec($pos), $sz/2, $edgecolour);
 601    %% %s
 602    newpath %s
 603      %s %f 0 360 arc closepath gsave fill grestore
 604      %s $lw setlinewidth stroke
 605 END
 606 }
 607
 608 sub one_hs ($$;$$) {
 609   my ($colour, $hspos, $sz, $lw) = @_;
 610   token_circle("HS - $colour",
 611                $hspos,
 612                darkerpscolour($colour, 0.75),
 613                miscpscolour('edge'),
 614               $sz,$lw);
 615 }
 616
 617 our $cube_sz = 6 * MM2PT;
 618 our $cube_gap = $cube_sz * 0.2;
 619 our $cube_lw = ($cube_sz * 0.1);
 620
 621 sub label_faces() {
 622   my $sz = $text_sz;
 623   my $shadow = $sz * 0.1;
 624   my $textc   = miscpscolour('text');
 625   my $shadowc = miscpscolour('textshadow');
 626   o(<<END);
 627   /wordsshow {
 628     $shadowc 0 10 359 {
 629       dup  cos $shadow mul
 630       exch sin $shadow mul
 631       words pop pop
 632     } bind for
 633     $textc 0 0 words pop pop
 634   } def
 635 END
 636   o("  /Helvetica-Bold findfont  $sz scalefont setfont\n");
 637   my %hs = map { $_ => 1 } @{ $c{HS} };
 638   foreach my $rr (values %region) {
 639     next if $rr->{Name} =~ m/^L\d?$/;
 640     my $words = $rr->{DisplayName};
 641     my $pos;
 642     if ($rr->{Name} eq 'NZ') {
 643       $pos = mkvec(90, 1280);
 644     } else {
 645       $pos = $rr->{Centre} + mkvec( 0, 0.5 * $sz * @$words );
 646     }
 647     if ($hs{$rr->{Name}}) {
 648       #print STDERR "adjust hs $rr->{Name}\n";
 649       $pos -= mkvec(0, -$hs_sz*
 650                     ( $rr->{Colour} eq 'green' ? 0.25 : 0.65 ));
 651       my $hspos = $pos - mkvec(0, $sz * @$words + $hs_sz/2 + $hs_lw
 652                                + $hs_sz*0.15);
 653       one_hs($rr->{Colour}, $hspos);
 654     }
 655     my $adjust = $c{TextAdjust}{$rr->{Name}};
 656     if ($adjust) {
 657       $pos += $sz * &mkvec(@$adjust);
 658     }
 659     my $w = $rr->{Water};
 660     $w = 2 if $rr->{Special} || $rr->{Name} eq 'ZZ';
 661     if ($w) {
 662       #print STDERR " water $w in $rr->{Name}\n";
 663       my $down = water_cubes_sz(2) - water_cubes_sz(1) + $cube_gap;
 664       $pos -= mkvec(0, -0.5 * $down);
 665       my $cube_y = -($sz * @$words);
 666       if ($rr->{Name} eq 'Wieringermeer') {
 667         $pos -= mkvec(0,+$sz);
 668         $cube_y = 0;
 669         $down = 0;
 670       }
 671       o("  gsave\n");
 672       o("    ", psvec($pos), " translate\n");
 673       o("    0 ", $cube_y, " translate\n");
 674       o("    ", -0.5 * water_cubes_sz($w)," ", -$down, " translate\n");
 675       water_cubes($w, miscpscolour('edge'));
 676       o("  grestore\n");
 677     }
 678     o("  /words {\n");
 679     foreach my $word (@$words) {
 680       $pos += mkvec(0,-$sz);
 681       o("   ", psvec($pos), " moveto");
 682       o(<<END);
 683    2 copy rmoveto
 684    ($word) dup stringwidth pop     % word xw
 685      -0.5 mul 0 rmoveto             % word
 686      show
 687    0 -$sz rmoveto
 688 END
 689     }
 690     o(<<END);
 691   } bind def
 692   wordsshow
 693 END
 694   }
 695 }
 696
 697 sub water_cubes_sz($){
 698   my ($n) = @_;
 699   ($cube_sz + $cube_lw) * $n + ($cube_gap * ($n-1));
 700 }
 701
 702 sub water_cubes($$){
 703   my ($n, $edgecolour) = @_;
 704   my $s = $cube_sz;
 705   for my $i (0..$n-1) {
 706     o("  newpath  ", $i * ($cube_sz + $cube_lw + $cube_gap),"  0  moveto\n");
 707     o("          $s  0  rlineto\n");
 708     o("           0 $s  rlineto\n");
 709     o("         -$s  0  rlineto  closepath\n");
 710     o("  gsave ", miscpscolour('cube'), " fill grestore\n");
 711     o("  gsave ", $edgecolour, " ", $cube_lw,
 712       " setlinewidth stroke grestore \n");
 713   }
 714 }
 715
 716 my $deck_h = 89 * MM2PT;
 717
 718 sub decks(){
 719   my $lw = $edge_lw/2;
 720   o("  /deck1path {\n");
 721   my $w = 63 * MM2PT;
 722   my $h = $deck_h;
 723   my $r =  5 * MM2PT;
 724   o("      ",($w/2)," 0 moveto\n");
 725   my @p = ([ $w, 0 ],
 726            [ $w,$h ],
 727            [ 0, $h ],
 728            [ 0,  0 ]);
 729   foreach my $i (0..3) {
 730     o("    @{ $p[$i] }  @{ $p[($i + 1) % 4] }  $r  arct\n");
 731   }
 732   o("    closepath\n");
 733   o("  } bind def");
 734   o("  /deckpairpathx {\n"); # x because it leaves matrix changed
 735   o("    newpath         deck1path\n");
 736   o("    200 0 translate deck1path\n");
 737   o("  } bind def");
 738   o("  $lw setlinewidth ",miscpscolour('playerdeck'),"\n");
 739   o("  gsave 401 44 $bottom_adjuncts_dy_from_boundings add translate");
 740   o("     deckpairpathx stroke grestore");
 741   o("  $lw setlinewidth ",miscpscolour('dykefail'),"\n");
 742   o("  gsave 242 1363 $top_adjuncts_dy_from_boundings add translate ");
 743   o("     90 rotate deckpairpathx stroke grestore");
 744 }
 745
 746 sub sea_track(){
 747   o("% sea level track\n");
 748   o("  gsave 11 700 translate\n");
 749   my $track = $c{SeaTrack};
 750   my $token_sz = $hs_sz;
 751   my $dy = $token_sz * 1.25;
 752   my $dx = $token_sz * 1.25;
 753   my $linecolour = seatrackedgepscolour();
 754   my @pos;
 755   for my $i (0..$#$track) {
 756     $pos[$i] = mkvec(0, ($i - 0.5 * @$track) * $dy);
 757   }
 758   my $prepline = "$linecolour $hs_lw setlinewidth newpath";
 759   o("  $prepline\n");
 760   o("    ",psvec($pos[0])," moveto ",psvec($pos[-1])," lineto stroke\n");
 761   for my $pos (@pos) {
 762     token_circle("SL", $pos,
 763                  miscpscolour('cube'),
 764                  $linecolour);
 765   }
 766   my $last = 0;
 767   my $cubeedgecolour = seatrackedgepscolour();
 768   for my $i (0..$#pos) {
 769     my $differs = $track->[$i] != $last;
 770     $last = $track->[$i];
 771     next unless $differs;
 772     o("  $prepline\n");
 773     o("  gsave ",
 774       psvec($pos[$i] + mkvec(-0.0 * $token_sz, $dy/2))," translate\n");
 775
 776     my $t_sz = 24;
 777     my $shrink = ($hs_sz * 0.75 / $deck_h);
 778     o("    gsave % T M $i\n");
 779     o("      -43.5 -6.5 translate\n");
 780     o("      0.8 .8 scale \n");
 781     o("      ",0.6 * $dx, " ", -0.28 * $dy," translate\n");
 782     o("      gsave");
 783     o("        $shrink dup scale -90 rotate\n");
 784     o("        newpath ", ($hs_lw / $shrink)," setlinewidth\n");
 785     o("         deck1path stroke\n");
 786     o("      grestore");
 787     o("      /Helvetica-Bold findfont $t_sz scalefont setfont\n");
 788     o("      12 -21.5 moveto ($track->[$i]) show");
 789     o("    grestore\n");
 790
 791     if ($i > 0) {
 792       o("  0 -$dy moveto",
 793         " ",psvec(mkvec( $dx + $cube_sz, 0 )),
 794         " rlineto stroke\n");
 795     }
 796     o("  ",($token_sz * 0.6 + $cube_gap)," ",
 797       (-$dy * 0.5 - 0.5 * (water_cubes_sz(2))),
 798       " translate\n");
 799     my $bottom = int(($track->[$i+1] + 1) / 2);
 800     water_cubes($bottom, $cubeedgecolour);
 801     my $new_n = $track->[$i+1] - $bottom;
 802     o("  ", 0.5 * (water_cubes_sz($bottom) - water_cubes_sz($new_n)),
 803       "  ",       (water_cubes_sz(2)-water_cubes_sz(1)), " translate\n");
 804     water_cubes($new_n, $cubeedgecolour);
 805     o("  grestore\n");
 806   }
 807   o("  grestore\n");
 808 }
 809
 810 our $dyke_l = 25 * MM2PT;;
 811
 812 sub dykes(){
 813   my $l = $dyke_l;
 814   my $w = 5 * MM2PT;
 815   my $lw = $edge_lw * 0.50;
 816   my $l2 = $l/2;
 817   my $w2 = $w/2;
 818   o("  /dykepath {\n");
 819   o("            -$l2 -$w2 moveto\n");
 820   o("             $l2 -$w2 lineto\n");
 821   o("             $l2  $w2 lineto\n");
 822   o("            -$l2  $w2 lineto closepath\n");
 823   o("  } bind def\n");
 824   o("  /dyke {\n");
 825   o("    newpath dykepath\n");
 826   o("    gsave ",miscpscolour('dykefill')," fill grestore\n");
 827   o("    gsave ",miscpscolour('edge')," $lw setlinewidth stroke grestore\n");
 828   o("  } bind def\n");
 829   my $symbol_sz = $w * 1.50;
 830   my $t_sz = $symbol_sz * 1.0;
 831   my $t_at = sub {
 832     my ($ang) = @_;
 833     #print STDERR "ANG $ang\n";
 834     map { $t_sz * 0.5 * $_ } cos($ang), sin($ang);
 835   };
 836   my @t0 = $t_at->((TAU) *  0.25         );
 837   my @t1 = $t_at->((TAU) * (0.25 + 1./3) );
 838   my @t2 = $t_at->((TAU) * (0.25 + 2./3) );
 839   o("  /dtriangle {\n");
 840   o("    newpath @t0 moveto\n");
 841   o("            @t1 lineto\n");
 842   o("            @t2 lineto closepath\n");
 843   o("    gsave ",miscpscolour('dykeinit')," fill grestore\n");
 844   o("    gsave ",miscpscolour('edge')," $lw setlinewidth stroke grestore\n");
 845   o("  } bind def\n");
 846   foreach my $rr (values %region) {
 847     next if $rr->{Special};
 848     next if $rr->{Name} eq 'ZZ';
 849     next if $rr->{Colour} eq 'high';
 850     foreach my $adj (@{ $rr->{Adj} }) {
 851       my $neigh = $adj->{Name};
 852       o("  % dyke $rr->{Name} --- $neigh\n");
 853       next if $neigh lt $rr->{Name} && !$region{$neigh}{Special};
 854       next if $region{$neigh}{Colour} eq 'high';
 855       my @ends = adj_ends($adj);
 856       my $dirn = $ends[1] - $ends[0];
 857       my $angle = vec2atan($dirn);
 858       $angle = $angle * 360 / TAU;
 859       o("  gsave\n");
 860       o("    ", psvec( 0.5 * ($ends[0] + $ends[1]) )," translate\n");
 861       o("    $angle rotate\n");
 862       my $initial = $adj->{Dykes};
 863       for my $ys ($initial
 864                   ? [ map { $_ - 0.5 * ($initial-1) } 0..$initial-1 ]
 865                   : [0]) {
 866         foreach my $y (@$ys) {
 867           o("    gsave 0 ", $y * $w, " translate dyke ");
 868           o(" grestore\n");
 869         }
 870         my $nsymbols = $initial + !!$adj->{Deltawerk};
 871         o("   ", -0.5 * $symbol_sz * ($nsymbols-1)," 0 translate\n");
 872         my $trans = "  $symbol_sz 0 translate";
 873         if ($adj->{Deltawerk}) {
 874           one_hs('red', mkvec(0,0), $symbol_sz * 0.8, $lw);
 875           o($trans);
 876         }
 877         foreach my $i (1..$initial) {
 878           o(" gsave $angle neg rotate dtriangle grestore\n");
 879           o($trans);
 880         }
 881       }
 882       o("  grestore\n");
 883     }
 884   }
 885 }
 886
 887 sub hs_initial_1 ($$$;$$$) {
 888   my ($colour, $xi,$yi, $text, $text2, $fn) = @_;
 889   my $interval = $hs_sz * 1.75;
 890   my $demo_h = $hs_sz; #water_cubes_sz(3);
 891   my $demo_x0 = $hs_sz * 0.75 + $dyke_l * 0.60;
 892   my $demo_w = $demo_x0 + $dyke_l * 0.60;
 893   o("  % HS I $colour\n");
 894   o("  gsave\n");
 895   o("    550 1705 $top_adjuncts_dy_from_boundings add translate\n");
 896   o("    ", ($xi*$interval), " ", (($yi-1)*$interval), " translate\n");
 897   if ($fn) {
 898     o("  gsave\n");
 899     o("        $demo_h setlinewidth 0 0 moveto $demo_w 0 rlineto\n");
 900     o("        ", facepscolour($colour), " stroke grestore\n");
 901   }
 902   one_hs($colour, mkvec(0,0));
 903   if ($fn) {
 904     o("    /words {\n");
 905     o("      2 copy moveto                      ($text) show\n");
 906     o("      2 copy moveto 0 -$text_sz rmoveto ($text2) show\n");
 907     o("    } bind def\n");
 908     o("    gsave ".($hs_sz * 0.8)." $cube_gap translate wordsshow grestore\n");
 909     o("    $demo_x0 ",($hs_sz * -0.25)," translate\n");
 910     $fn->();
 911   }
 912   o("  grestore\n");
 913 }
 914
 915 sub hs_initial () {
 916   hs_initial_1('red',     0,0);
 917   hs_initial_1('purple',  0,1);
 918   hs_initial_1('green',   1,0, 'up to 6', 'fewer', sub {
 919     o("    ",(water_cubes_sz(1))," 0 translate\n");
 920     o("    0 ",(-water_cubes_sz(1) * 0.3)," translate\n");
 921     water_cubes(1, miscpscolour('edge'));
 922   });
 923   hs_initial_1('yellow',  1,1, 'up to 4', '', sub {
 924     o("    newpath dykepath\n");
 925     o("    gsave ",miscpscolour('edge')," stroke grestore\n");
 926     o("    gsave ",miscpscolour('dykehsadd')," fill grestore\n");
 927   });
 928 }
 929
 930 sub play_hint () {
 931   my $sz = 20;
 932   o("  gsave ",miscpscolour('hinttext'),
 933     " 260 1715 $top_adjuncts_dy_from_boundings add translate\n");
 934   o("  /Helvetica-Bold findfont $sz scalefont setfont\n");
 935   my @t = split /\n/, $c{PlayHint};
 936   foreach my $i (0..$#t) {
 937     my $t = $t[$i];
 938     $t =~ s/[\\()]/\\$&/g;
 939     o("  0 ",(-$i * $sz)," moveto ($t) show\n");
 940   }
 941   o("  grestore");
 942 }
 943
 944 #----- main program -----
 945
 946 $xopts = shift @ARGV if $ARGV[0] =~ s/^-X//;
 947 $bounding = $1 if $xopts =~ s/b(\w+)//;
 948 $maxpaper = $1 if $xopts =~ s/p(\w+)//;
 949 $maxpaper =~ m/^a[134]$|^a1m$/ or confess;
 950
 951 ($facesf, @ARGV) = @ARGV or die;
 952 parse_input_graph();
 953 prep_region_rmap();
 954 read_faces();
 955 calculate_centres();
 956 transform_coordinates();
 957 adjust_nz();
 958
 959 computeboundings();
 960 preamble();
 961 fill_faces();
 962 edge_faces();
 963 dykes();
 964 label_faces();
 965 decks();
 966 sea_track();
 967 hs_initial();
 968 play_hint();
 969 showboundings();
 970 postamble();
 971
 972 print STDERR Dumper(\%region) if $ENV{'GENERATE_BOARD_DUP'};
 973
 974 # Local variables:
 975 # cperl-indent-level: 2
 976 # End.