generate-board

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Carp;
   5 use Data::Dumper;
   6 use Math::GSL::Vector qw/:all/;
   7 use Math::GSL::Matrix qw/:all/;
   8 use Math::GSL::Const;
   9 use Math::GSL::BLAS qw/:all/;
  10 use Math::GSL::CBLAS qw/:all/;
  11 use Math::GSL::Machine qw/:all/;
  12
  13 use POSIX qw(M_PI);
  14
  15 BEGIN { unshift @INC, qw(.); }
  16
  17 use Parse;
  18
  19 our $xopts = '';
  20 our $bounding = 'Entire';
  21 our $facesf;
  22 our %vxname2pos; # $vxname2pos{VXNAME} = Math::GSL::Vector
  23 our %bb; # $r{Bounding...}[0..3] = points
  24 our $maxpaper = 'a3';
  25 my $a1sfactor = 1/sqrt(8);
  26
  27 sub TAU { M_PI * 2.0; }
  28 sub MM2PT { 72.0 / 25.4; }
  29
  30 our $mid;
  31
  32 our $a4_w = 595;
  33 our $a4_h = 842;
  34 our $a3_h = 1190;
  35 our $a1_w = 1684;
  36 our $a1_h = 2384;
  37
  38 our $max_printeredge = 5.50 * MM2PT;
  39 our $a1m_pasteedge = 3.5 * MM2PT; # along each edge
  40 our $preamble_from_boundings = '';
  41 our $top_adjuncts_dy_from_boundings = 0;
  42 our $bottom_adjuncts_dy_from_boundings = 0;
  43
  44 # ----- region names from plag, incl. reverse mapping -----
  45
  46 our %prs2region;
  47
  48 sub prep_region_rmap () {
  49   foreach my $rn (keys %region) {
  50     my $prs = plag_prs($rn);
  51     die if $prs2region{$prs};
  52     $prs2region{$prs} = $rn;
  53   }
  54 }
  55
  56 our $sre = qr{(?:(\")|(?=\w))(.*)\1$}; # 2 captures, $2 is the name
  57
  58 sub prs2r ($) {
  59   # bodgery for the sea and land
  60   return 'NZ' if m/ \| / && !grep { !m{^(?:NZ|L2?)$} } split / \| /, $_[0];
  61   $prs2region{$_[0]} // confess "@_ ?"
  62 }
  63 sub prs2rr ($) { $region{prs2r($_[0])} }
  64
  65 #----- file reader for plag output -----
  66
  67 sub read_faces () {
  68   # Sets
  69   #  $region{NAME}{Adj}[]{Ends}[]{VxName}
  70   #  $region{NAME}{Adj}[]{Ends}[]{Pos}
  71   #  $region{NAME}{Polygon}{Pos}
  72   #  $region{NAME}{Special}
  73   #
  74   # also incidentally
  75   #  $region{NAME}{Adj}[]{Ends}[]{Adjoins}
  76   #  $region{NAME}{Polygon}{Adjoins}
  77   # which should be ignored
  78
  79   open P, "<", $facesf or die $!;
  80   while (<P>) { last if m/^\&faces$/; }
  81   my $rr;
  82   my @edges;
  83   my $process_rr = sub {
  84     my $last_ai;
  85     if ($rr->{Name} eq 'NZ') {
  86       # We combined L and NZ; now we must split them again
  87       # in fact, we just throw away L and L2 entirely.
  88       # Here, when processing NZ, we keep only vertices that
  89       # are part of NZ.
  90       @edges = grep {
  91         my $evxname = $_->{VxName};
  92         my @eregions = split / \| ?/, $evxname;
  93         grep { $_ eq 'NZ' } @eregions
  94       } @edges;
  95     }
  96     $rr->{Polygon} = [ @edges ];
  97     if ($rr->{Name} ne 'NZ') {
  98       for my $ei (0..$#edges) {
  99         if (!defined $last_ai) {
 100           my $ai;
 101           for my $ai (0..$#{ $rr->{Adj} }) {
 102             next unless $rr->{Adj}[$ai]{Name} eq $edges[$ei]{Adjoins};
 103             $last_ai = $ai+1;
 104           }
 105           confess $edges[$ei]{Adjoins}.' ?' unless defined $last_ai;
 106         }
 107         my $ai = ($last_ai-1+@edges) % @edges;
 108         $last_ai = $ai;
 109         my $adj = $rr->{Adj}[$ai];
 110         confess Dumper($adj->{Name}, $edges[$ei]{Adjoins},
 111                        $rr, \@edges, $ei, $adj, $last_ai, $ai)." ?"
 112             unless $adj->{Name} eq $edges[$ei]{Adjoins};
 113
 114         for my $endi (0..1) {
 115           $adj->{Ends}[$endi] = $edges[ ($ei + $endi) % @edges ];
 116         }
 117       }
 118     }
 119     @edges = ();
 120     $rr = undef;
 121   };
 122   my $vxname;
 123   for (;;) {
 124     $!=0; $_=<P> // confess $!;
 125     last if m/^\&$/;
 126     if (m/^$sre$/) {
 127       my $new_face= $2;
 128       $process_rr->() if $rr;
 129       $rr= prs2rr($new_face);
 130     } elsif (m/^\s+$sre$/) {
 131       confess unless $rr;
 132       $vxname = $2;
 133       push @edges, { VxName => $vxname };
 134     } elsif (m/^\s+\^adjoins\s+$sre$/) {
 135       $edges[-1]{Adjoins} = prs2r($2);
 136     } elsif (m/^\s+\^\@([-e.0-9]+)\,([-e.0-9]+)$/) {
 137       my $pos = mkvec($1,$2);
 138       confess unless defined $vxname;
 139       $edges[-1]{Pos} = $pos;
 140       $vxname2pos{$vxname} = $pos;
 141     }
 142   }
 143   $process_rr->();
 144
 145   $region{$_}{Special} = 1 foreach qw(NZ L L2);
 146 }
 147
 148 #----- geometry mangling -----
 149
 150 sub adj_ends ($) {
 151   my ($adj) = @_;
 152   map { $_->{Pos} } @{ $adj->{Ends} };
 153 }
 154
 155 sub calculate_centres () {
 156   # Sets
 157   #  $region{NAME}{Centre}
 158   foreach my $rr (values %region) {
 159     next if $rr->{Special};
 160     my $sum = Math::GSL::Vector->new(2);
 161     my $wsum = 0;
 162     foreach my $adj (@{ $rr->{Adj} }) {
 163       my @ends = adj_ends($adj);
 164       my $w = ($ends[1] - $ends[0])->norm();
 165       $sum += $w * $_ foreach @ends;
 166       $wsum += $w;
 167     }
 168     $rr->{Centre} = $sum * (0.5 / $wsum);
 169   }
 170 }
 171
 172 sub for_each_pos ($) {
 173   my ($f) = @_;
 174   my $call = sub {
 175     my ($pr,$rr,$why) = @_;
 176     return unless defined $$pr;
 177     $f->($pr,$rr,$why);
 178   };
 179   foreach my $rr (values %region) {
 180     $call->( \ $rr->{Centre}, $rr, $rr->{Name}." C" );
 181     foreach my $vertex (@{ $rr->{Polygon} }) {
 182       $call->( \ $vertex->{Pos}, $rr, $rr->{Name}." | ".$vertex->{Adjoins} );
 183     }
 184   }
 185 }
 186
 187 sub prvec ($) {
 188   my ($v) = @_;
 189   confess unless $v;
 190   sprintf "%g,%g", $v->get(0), $v->get(1);
 191 }
 192
 193 sub mkvec ($$) { Math::GSL::Vector->new(\@_) }
 194 sub vec2atan ($) { my ($dir) = @_; atan2 $dir->get(1), $dir->get(0); }
 195
 196 sub transform_coordinates () {
 197   # Adjusts coordinates in graph to be [0,0] .. top right (scaled)
 198   # until it's all in PostScript points
 199   my @or = map { $region{$_}{Centre} } @{ $c{OrientRegions} };
 200   my $dir = $or[1] - $or[0];
 201   my $theta = vec2atan($dir);
 202   my $rotateby = (90. - $c{OrientBearing}) * ((TAU)/360.) - $theta;
 203   my $s = sin($rotateby);
 204   my $c = cos($rotateby);
 205   my $transform = Math::GSL::Matrix->new(2,2);
 206   $transform->set_row(0, [  $c, -$s ]);
 207   $transform->set_row(1, [  $s,  $c ]);
 208   #  print STDERR "rotate was=",prvec($dir)," theta=$theta",
 209   #    " rotateby=$rotateby s=$s c=$c\n";
 210   my @lims;
 211   foreach my $topend (qw(0 1)) {
 212     my $v = $topend ? -$GSL_DBL_MAX : $GSL_DBL_MAX;
 213     $lims[$topend] = mkvec($v,$v);
 214   }
 215   for_each_pos(sub {
 216     my ($pr, $rr, $why) = @_;
 217     my $y = Math::GSL::Vector->new(2);
 218     gsl_blas_dgemv($CblasNoTrans,
 219                    1.0, $transform->raw,
 220                    $$pr->raw,
 221                    0, $y->raw)
 222         and confess;
 223     #print STDERR "gsl_blas_dgemv ",prvec($$pr)," => ",prvec($y),"\n";
 224     gsl_blas_dcopy($y->raw, $$pr->raw)
 225         and confess;
 226     foreach my $topend (qw(0 1)) {
 227       foreach my $xy (qw(0 1)) {
 228         my $now = $y->get($xy);
 229         my $lim = $lims[$topend]->get($xy);
 230         #print STDERR "?set $topend $xy $now $lim\n";
 231         next if $topend ? ($now <= $lim) : ($now >= $lim);
 232         $lims[$topend]->set([$xy], [$now]);
 233         #print STDERR "set $topend $xy $now\n";
 234       }
 235     }
 236   });
 237   #print STDERR "lims ",prvec($lims[0])," .. ",prvec($lims[1]),"\n";
 238   my $translate = -$lims[0];
 239   #print STDERR "translate ",prvec($translate),"\n";
 240   my $scale = $c{GraphScale} * MM2PT;
 241   for_each_pos(sub {
 242     my ($pr) = @_;
 243     gsl_vector_add($$pr->raw, $translate->raw) and confess;
 244     gsl_vector_scale($$pr->raw, $scale) and confess;
 245   });
 246   $mid = ($lims[1] - $lims[0]) * 0.5;
 247 }
 248
 249 sub adjust_nz() {
 250   my $poly = $region{NZ}{Polygon};
 251   my %occurs;
 252   foreach my $v (@$poly) {
 253     $occurs{$v->{VxName}}++
 254   }
 255   foreach my $v (@$poly) {
 256     $v->{NZ_Occurs} = $occurs{$v->{VxName}};
 257   }
 258   #print STDERR " nz ".(scalar @$poly)."\n";
 259   my $occurs_m = sub {
 260     my ($ei) = @_;
 261     $poly->[($ei+@$poly) % @$poly]{NZ_Occurs} > 1
 262   };
 263   for my $ei (0..$#$poly) {
 264     next if $occurs_m->($ei);
 265     next unless $occurs_m->($ei-1);
 266     next unless $occurs_m->($ei+1);
 267     #print STDERR " nz would adjust $poly->[$ei]{VxName}\n";
 268     # adjust coord outwards
 269   }
 270   for my $ei (0..$#$poly) {
 271     next unless $occurs_m->($ei);
 272     #print STDERR " nz occurs_m $ei $poly->[$ei]{VxName}\n";
 273     next unless $occurs_m->($ei-1);
 274     my $dleft = mkvec(-1000,0);
 275     foreach my $which (0,-1) {
 276       my $ej = ($ei +        $which + @$poly) % @$poly;
 277       my $ek = ($ei + +1 + 3*$which + @$poly) % @$poly;
 278       my $posj = \ $poly->[$ej]{Pos};
 279       my $posk = \ $poly->[$ek]{Pos};
 280       my $dout = $$posk - $$posj;
 281       #print STDERR " nz adj j=$ej ",prvec($$posj)," $poly->[$ej]{VxName}\n";
 282       #print STDERR " nz adj k=$ek ",prvec($$posk)," $poly->[$ek]{VxName}\n";
 283       if ($poly->[$ej]{VxName} =~ /Noorderzijlvest/) {
 284         #print STDERR " nz adj extra\n";
 285         $$posk = $$posj + 10 * mkvec(100,-50);
 286       }
 287       $$posj = $$posj + $dleft + $dout*10;
 288       $$posk = $$posk          + $dout*10;
 289     }
 290   }
 291 }
 292
 293 sub psvec ($) {
 294   my ($pos) = @_;
 295   sprintf "%20.6f %20.6f", $pos->get(0),$pos->get(1)
 296 }
 297
 298 sub face_path ($) {
 299   my ($rr) = @_;
 300   o("% $rr->{Name}\n");
 301   o("  newpath\n");
 302   my $xto = 'moveto';
 303   foreach my $vertex (@{ $rr->{Polygon} }) {
 304     my $pos = $vertex->{Pos};
 305     o(sprintf "    %s %s\n", psvec($pos), $xto);
 306     $xto = 'lineto';
 307   }
 308   o("    closepath\n");
 309 }
 310
 311 sub computeboundings() {
 312   $bb{Entire} = [ 0,0, $a4_h, $a4_w + $a3_h ];
 313   my $submargins = sub {
 314     my ($margin, $pr) = @_;
 315     my @p = @$pr;
 316     [ $p[0] + $margin,
 317       $p[1] + $margin,
 318       $p[2] - $margin,
 319       $p[3] - $margin ];
 320   };
 321   my $somepage = sub {
 322     my $id = shift @_;
 323     print STDERR "defining page Page$id\n";
 324     $bb{"Page$id"} = [ @_ ];
 325     $bb{"Printable$id"} = $submargins->($max_printeredge, $bb{"Page$id"});
 326   };
 327   my $pageb_a4 = sub {
 328     $somepage->('B', 0,0, $a4_h, $a4_w );
 329   };
 330   if ($maxpaper eq 'a3') {
 331     $pageb_a4->();
 332     my $mt_offset = $bb{PrintableB}[3] - $max_printeredge;
 333     $somepage->('MT', 0, $mt_offset, $a4_h, $mt_offset + $a3_h );
 334     $bb{PrintableAll} = [
 335                          @{ $bb{PrintableB} }[0..1],
 336                          @{ $bb{PrintableMT} }[2..3],
 337                         ];
 338   } elsif ($maxpaper eq 'a4') {
 339     $pageb_a4->();
 340     my $m_offset = $bb{PrintableB}[3] - $max_printeredge;
 341     $somepage->('M', 0, $m_offset, $a4_h, $m_offset + $a4_w );
 342     my $t_offset = $bb{PrintableM}[3] - $max_printeredge;
 343     $somepage->('T', 0, $t_offset, $a4_h, $t_offset + $a4_w );
 344     $bb{PrintableAll} = [
 345                          @{ $bb{PrintableB} }[0..1],
 346                          @{ $bb{PrintableT} }[2..3],
 347                         ];
 348   } elsif ($maxpaper =~ m/^a1/) {
 349     my $offx = ($a1_w - $bb{Entire}[2] * (1 + $a1sfactor)) / 3;
 350     my $offy = 0.5*($a1_h - $bb{Entire}[3]);
 351     $somepage->('P', -$offx,-$offy, $a1_w-$offx, $a1_h-$offy);
 352     my $hairs = 30 * MM2PT;
 353     my $hairsw = $bb{Entire}[2];
 354     my $hairsh = $bb{Entire}[3];
 355     my $surround = 5 * MM2PT;
 356     my $surroundw = $bb{Entire}[2] + $surround*2;
 357     my $surroundh = $bb{Entire}[3] + $surround*2;
 358     my @hrect = @{ $bb{Entire} };
 359     if ($maxpaper eq 'a1m') {
 360       @hrect = @{ $submargins->($a1m_pasteedge, \@hrect) };
 361       $bb{Cutout} = \@hrect;
 362     }
 363     my $w_stroke = $xopts =~ m/W/ ?
 364         ' gsave 3 setlinewidth stroke grestore '
 365         : '';
 366     $preamble_from_boundings = <<END;
 367          1 setlinewidth
 368          0 setgray
 369          /a1hairs {
 370              newpath moveto
 371              $hairs 0        rmoveto
 372              $hairs -2 mul 0 rlineto
 373              $hairs $hairs   rmoveto
 374              0 $hairs -2 mul rlineto
 375              stroke
 376          } def
 377          $hrect[0] $hrect[1] a1hairs
 378          $hrect[0] $hrect[3] a1hairs
 379          $hrect[2] $hrect[3] a1hairs
 380          $hrect[2] $hrect[1] a1hairs
 381          newpath
 382          -$surround -$surround moveto
 383           $surroundw 0         rlineto
 384           0 $surroundh         rlineto
 385           -$surroundw 0        rlineto
 386                  closepath $w_stroke clip
 387 END
 388     $top_adjuncts_dy_from_boundings = 35;
 389     $bottom_adjuncts_dy_from_boundings = -7;
 390   } else {
 391     confess;
 392   }
 393 }
 394
 395 sub showboundings () {
 396   return unless $xopts =~ m/B/;
 397   o(" gsave\n");
 398   my $bb = $bb{$bounding};
 399   o("  $bb->[0] neg $bb->[1] neg translate\n");
 400   my $i = 0;
 401   my $on = 2;
 402   my $off = 9;
 403   foreach my $bname (sort keys %bb) {
 404     o(sprintf "   1 %d %d setrgbcolor\n",
 405       !!($bname =~ m/^Page/),
 406       !!($bname =~ m/B$/),
 407      );
 408     o("    % $bname\n");
 409     o("    [ $on $off ] ".($i * ($on+$off))," setdash newpath\n");
 410     my @p = @{ $bb{$bname} };
 411     o("    $p[0] $p[1] moveto\n");
 412     o("    $p[2] $p[1] lineto\n");
 413     o("    $p[2] $p[3] lineto\n");
 414     o("    $p[0] $p[3] lineto\n");
 415     o("    closepath stroke\n");
 416     $i++;
 417   }
 418   o(" grestore");
 419 }
 420
 421 sub o_amble (@) {
 422   # CPerl-mode does a really awful thing with %s in the preamble
 423   # and postamble, causing constant useless flashing
 424   # So we write & in the here docs and transform them back:
 425   my ($t) = join '', @_;
 426   $t =~ s/^\&+/ '%' x length $& /mge;
 427   o($t);
 428 }
 429
 430 sub preamble() {
 431   my $bb = $bb{$bounding}; confess $bounding unless $bb;
 432   my $sz = [ $bb->[2] - $bb->[0], $bb->[3] - $bb->[1] ];
 433   o_amble(<<END);
 434 &!PS-Adobe-3.0
 435 &&BoundingBox 0 0 @$sz
 436 &&Pages: 1
 437 &&EndComments
 438 &&BeginProlog
 439 &&EndProlog
 440 &&BeginSetup
 441 << /PageSize [ @$sz ] >> setpagedevice
 442 /all {
 443   gsave
 444   $bb->[0] neg  $bb->[1] neg  translate
 445   $preamble_from_boundings
 446   board
 447   grestore
 448   showboundings
 449 } def
 450 /showboundings {
 451 END
 452   showboundings();
 453   o_amble(<<END);
 454 } def
 455 /board {
 456   gsave
 457   % adjustment to actual image placement within prinable areas etc.:
 458   34 -15 translate
 459 END
 460   if ($maxpaper eq 'a4') {
 461     o("0 -17 translate\n");
 462   }
 463 }
 464
 465 sub postamble () {
 466   o_amble(<<END);
 467   grestore
 468 } def % board
 469 &&EndSetup
 470 &&Page: 1
 471 &&BeginPageSetup
 472 /pgsave save def
 473 &&EndPageSetup
 474 all
 475 END
 476   if ($maxpaper =~ m/^a1/) {
 477     o(<<END);
 478   $a1_w 0 translate
 479   $a1sfactor dup scale
 480   $a1_w neg 0 translate
 481   1 1 3 { pop all 0 $a1_h 0.8 mul translate } for
 482 END
 483   }
 484   o_amble(<<END);
 485 pgsave restore
 486 showpage
 487 &&EOF
 488 END
 489 }
 490
 491 sub pscolour ($$$$) {
 492   my ($colourname, $cmykix,$rgbmul,$rgbadd) = @_;
 493   my $spec = $c{Colours}{$colourname};
 494   confess unless defined $spec;
 495
 496   # check that we have only one lighter/darker retain value for each one
 497   our %colour_occurred;
 498   $colour_occurred{$colourname}{$cmykix}{$rgbmul,$rgbadd} = 1;
 499   keys %{ $colour_occurred{$colourname}{$cmykix} } == 1 or confess;
 500
 501   my @r;
 502   my $rw;
 503   if ($spec =~ m/^[0-9a-f]+$/) {
 504     my $le = (length $spec)/3;
 505     my $re = ("(.{$le})") x 3;
 506     my @rgb = $spec =~ m/^$re$/;  @rgb or confess "$re ?";
 507     @rgb = map { hex($_) / (16**$le -1) } @rgb;
 508     foreach (@rgb) { $_ *= $rgbmul; $_ += $rgbadd; }
 509     @r = @rgb;
 510     $rw = 'setrgbcolor';
 511   } elsif ($spec =~ m/[CMYK]/) {
 512     my @specs = split /\//, $spec;
 513     if ($cmykix==1 && @specs==1) {
 514       $spec = $specs[0];
 515     } else {
 516       $spec = $specs[$cmykix];
 517       confess unless defined $spec;
 518     }
 519     my %cmyk;
 520     foreach (split /(?=[A-Z])/, $spec) {
 521       m/^([CMYK])([0-7](?:\.\d*)?|8)_?$/ or confess $_.' ?';
 522       confess if defined $cmyk{$1};
 523       $cmyk{$1} = $2 / 8.;
 524       #print STDERR " CMYK $1 $2\n";
 525     }
 526     @r = map { $cmyk{$_} // 0 } qw(C M Y K);
 527     $rw = 'setcmykcolor';
 528   } else {
 529     confess $spec.' ?';
 530   }
 531   my $r = join ' ',
 532       (map { sprintf "%.6f ", $_ } @r
 533       ),
 534           $rw;
 535   return $r;
 536 }
 537
 538 sub lighterpscolour ($$) {
 539   my ($colourname, $retain) = @_;
 540   #print STDERR "COLOUR LIGHTER $retain $colourname\n";
 541   pscolour($colourname, 0, $retain, 1-$retain);
 542 }
 543
 544 sub darkerpscolour ($$) {
 545   my ($colourname, $retain) = @_;
 546   #print STDERR "COLOUR DARKER $retain $colourname\n";
 547   pscolour($colourname, 2, $retain, 0);
 548 }
 549
 550 sub facepscolour ($) {
 551   my ($colourname) = @_;
 552   $xopts =~ m/W/ ? '1 setgray' :
 553       $colourname =~ m/land/ ? miscpscolour($colourname)
 554       : lighterpscolour($colourname, 0.75);
 555 }
 556
 557 sub miscpscolour ($) {
 558   my ($colourname) = @_;
 559   #print STDERR "COLOUR MISC $colourname\n";
 560   pscolour($colourname, 1, 1,0);
 561 }
 562
 563 sub seatrackedgepscolour () { darkerpscolour('cube', 0.25) }
 564
 565 sub fill_faces() {
 566   o("clippath ", facepscolour('land'), " fill\n");
 567   foreach my $rr (values %region) {
 568     next if $rr->{Name} =~ m/^L2?$/;
 569     face_path($rr);
 570     o(" ", facepscolour($rr->{Colour}), " eofill\n");
 571   }
 572 }
 573
 574 our $edge_lw = 5;
 575
 576 sub some_edge_faces (@) {
 577   o("$edge_lw setlinewidth 1 setlinejoin ",miscpscolour('edge'),"\n");
 578   foreach my $rr (@_) {
 579     next if $rr->{Name} =~ m/^L2?$/;
 580     face_path($rr);
 581     o("    stroke\n");
 582   }
 583 }
 584
 585 sub afsluitdijk() {
 586   my ($adj) = grep { $_->{Name} eq 'NZ' } @{ $region{'ZZ'}{Adj} };
 587   my $dash = 20;
 588   my (@pos) = adj_ends($adj);
 589   my $mid = 0.5 * ($pos[0] + $pos[1]);
 590   my $r = 0.5 * ($pos[1] - $pos[0])->norm();
 591   o(sprintf <<'END', facepscolour('sea'), psvec($mid), $r);
 592   %% Afsluitdijk
 593   %s %s %s 0 360 arc closepath fill
 594 END
 595   some_edge_faces(()); # just sets the colour
 596   o(sprintf <<END, map { psvec($_) } @pos);
 597   newpath %s moveto %s lineto
 598   [ $dash $dash ] $dash 0.5 mul setdash
 599   stroke
 600   [] 0 setdash
 601 END
 602   one_hs('purple', $mid);
 603 }
 604
 605 sub edge_faces() {
 606   some_edge_faces($region{'NZ'});
 607   afsluitdijk();
 608   some_edge_faces(grep {
 609     $_->{Name} !~ m{^(?:L2?|NZ|ZZ)$}
 610   } values %region);
 611 }
 612
 613 our $hs_sz = 17 * MM2PT;
 614 our $hs_lw = 3;
 615
 616 our $text_sz = 18;
 617
 618 sub token_circle ($$$$;$$) {
 619   my ($what, $pos, $fillcolour, $edgecolour, $sz,$lw) = @_;
 620   $sz //= $hs_sz;
 621   $lw //= $hs_lw;
 622   o(sprintf <<END, $what, $fillcolour, psvec($pos), $sz/2, $edgecolour);
 623    %% %s
 624    newpath %s
 625      %s %f 0 360 arc closepath gsave fill grestore
 626      %s $lw setlinewidth stroke
 627 END
 628 }
 629
 630 sub one_hs ($$;$$) {
 631   my ($colour, $hspos, $sz, $lw) = @_;
 632   token_circle("HS - $colour",
 633                $hspos,
 634                darkerpscolour($colour, 0.75),
 635                miscpscolour('edge'),
 636               $sz,$lw);
 637 }
 638
 639 our $cube_sz = 6 * MM2PT;
 640 our $cube_gap = $cube_sz * 0.2;
 641 our $cube_lw = ($cube_sz * 0.1);
 642
 643 sub label_faces() {
 644   my $sz = $text_sz;
 645   my $shadow = $sz * 0.1;
 646   my $textc   = miscpscolour('text');
 647   my $shadowc = miscpscolour('textshadow');
 648   o(<<END);
 649   /wordsshow {
 650     $shadowc 0 10 359 {
 651       dup  cos $shadow mul
 652       exch sin $shadow mul
 653       words pop pop
 654     } bind for
 655     $textc 0 0 words pop pop
 656   } def
 657 END
 658   o("  /Helvetica-Bold findfont  $sz scalefont setfont\n");
 659   my %hs = map { $_ => 1 } @{ $c{HS} };
 660   foreach my $rr (values %region) {
 661     next if $rr->{Name} =~ m/^L\d?$/;
 662     my $words = $rr->{DisplayName};
 663     my $pos;
 664     if ($rr->{Name} eq 'NZ') {
 665       $pos = mkvec(90, 1280);
 666     } else {
 667       $pos = $rr->{Centre} + mkvec( 0, 0.5 * $sz * @$words );
 668     }
 669     if ($hs{$rr->{Name}}) {
 670       #print STDERR "adjust hs $rr->{Name}\n";
 671       $pos -= mkvec(0, -$hs_sz*
 672                     ( $rr->{Colour} eq 'green' ? 0.25 : 0.65 ));
 673       my $hspos = $pos - mkvec(0, $sz * @$words + $hs_sz/2 + $hs_lw
 674                                + $hs_sz*0.15);
 675       one_hs($rr->{Colour}, $hspos);
 676     }
 677     my $adjust = $c{TextAdjust}{$rr->{Name}};
 678     if ($adjust) {
 679       $pos += $sz * &mkvec(@$adjust);
 680     }
 681     my $w = $rr->{Water};
 682     $w = 2 if $rr->{Special} || $rr->{Name} eq 'ZZ';
 683     if ($w) {
 684       #print STDERR " water $w in $rr->{Name}\n";
 685       my $down = water_cubes_sz(2) - water_cubes_sz(1) + $cube_gap;
 686       $pos -= mkvec(0, -0.5 * $down);
 687       my $cube_y = -($sz * @$words);
 688       if ($rr->{Name} eq 'Wieringermeer') {
 689         $pos -= mkvec(0,+$sz);
 690         $cube_y = 0;
 691         $down = 0;
 692       }
 693       o("  gsave\n");
 694       o("    ", psvec($pos), " translate\n");
 695       o("    0 ", $cube_y, " translate\n");
 696       o("    ", -0.5 * water_cubes_sz($w)," ", -$down, " translate\n");
 697       water_cubes($w, miscpscolour('edge'));
 698       o("  grestore\n");
 699     }
 700     o("  /words {\n");
 701     foreach my $word (@$words) {
 702       $pos += mkvec(0,-$sz);
 703       o("   ", psvec($pos), " moveto");
 704       o(<<END);
 705    2 copy rmoveto
 706    ($word) dup stringwidth pop     % word xw
 707      -0.5 mul 0 rmoveto             % word
 708      show
 709    0 -$sz rmoveto
 710 END
 711     }
 712     o(<<END);
 713   } bind def
 714   wordsshow
 715 END
 716   }
 717 }
 718
 719 sub water_cubes_sz($){
 720   my ($n) = @_;
 721   ($cube_sz + $cube_lw) * $n + ($cube_gap * ($n-1));
 722 }
 723
 724 sub water_cubes($$){
 725   my ($n, $edgecolour) = @_;
 726   my $s = $cube_sz;
 727   for my $i (0..$n-1) {
 728     o("  newpath  ", $i * ($cube_sz + $cube_lw + $cube_gap),"  0  moveto\n");
 729     o("          $s  0  rlineto\n");
 730     o("           0 $s  rlineto\n");
 731     o("         -$s  0  rlineto  closepath\n");
 732     o("  gsave ", miscpscolour('cube'), " fill grestore\n");
 733     o("  gsave ", $edgecolour, " ", $cube_lw,
 734       " setlinewidth stroke grestore \n");
 735   }
 736 }
 737
 738 my $deck_h = 89 * MM2PT;
 739
 740 sub decks(){
 741   my $lw = $edge_lw/2;
 742   o("  /deck1path {\n");
 743   my $w = 63 * MM2PT;
 744   my $h = $deck_h;
 745   my $r =  5 * MM2PT;
 746   o("      ",($w/2)," 0 moveto\n");
 747   my @p = ([ $w, 0 ],
 748            [ $w,$h ],
 749            [ 0, $h ],
 750            [ 0,  0 ]);
 751   foreach my $i (0..3) {
 752     o("    @{ $p[$i] }  @{ $p[($i + 1) % 4] }  $r  arct\n");
 753   }
 754   o("    closepath\n");
 755   o("  } bind def");
 756   o("  /deckpairpathx {\n"); # x because it leaves matrix changed
 757   o("    newpath         deck1path\n");
 758   o("    200 0 translate deck1path\n");
 759   o("  } bind def");
 760   o("  $lw setlinewidth ",miscpscolour('playerdeck'),"\n");
 761   o("  gsave 401 44 $bottom_adjuncts_dy_from_boundings add translate");
 762   o("     deckpairpathx stroke grestore");
 763   o("  $lw setlinewidth ",miscpscolour('dykefail'),"\n");
 764   o("  gsave 242 1363 $top_adjuncts_dy_from_boundings add translate ");
 765   o("     90 rotate deckpairpathx stroke grestore");
 766 }
 767
 768 sub sea_track(){
 769   o("% sea level track\n");
 770   o("  gsave 11 700 translate\n");
 771   my $track = $c{SeaTrack};
 772   my $token_sz = $hs_sz;
 773   my $dy = $token_sz * 1.25;
 774   my $dx = $token_sz * 1.25;
 775   my $linecolour = seatrackedgepscolour();
 776   my @pos;
 777   for my $i (0..$#$track) {
 778     $pos[$i] = mkvec(0, ($i - 0.5 * @$track) * $dy);
 779   }
 780   my $prepline = "$linecolour $hs_lw setlinewidth newpath";
 781   o("  $prepline\n");
 782   o("    ",psvec($pos[0])," moveto ",psvec($pos[-1])," lineto stroke\n");
 783   for my $pos (@pos) {
 784     token_circle("SL", $pos,
 785                  miscpscolour('cube'),
 786                  $linecolour);
 787   }
 788   my $last = 0;
 789   my $cubeedgecolour = seatrackedgepscolour();
 790   for my $i (0..$#pos) {
 791     my $differs = $track->[$i] != $last;
 792     $last = $track->[$i];
 793     next unless $differs;
 794     o("  $prepline\n");
 795     o("  gsave ",
 796       psvec($pos[$i] + mkvec(-0.0 * $token_sz, $dy/2))," translate\n");
 797
 798     my $t_sz = 24;
 799     my $shrink = ($hs_sz * 0.75 / $deck_h);
 800     o("    gsave % T M $i\n");
 801     o("      -43.5 -6.5 translate\n");
 802     o("      0.8 .8 scale \n");
 803     o("      ",0.6 * $dx, " ", -0.28 * $dy," translate\n");
 804     o("      gsave");
 805     o("        $shrink dup scale -90 rotate\n");
 806     o("        newpath ", ($hs_lw / $shrink)," setlinewidth\n");
 807     o("         deck1path stroke\n");
 808     o("      grestore");
 809     o("      /Helvetica-Bold findfont $t_sz scalefont setfont\n");
 810     o("      12 -21.5 moveto ($track->[$i]) show");
 811     o("    grestore\n");
 812
 813     if ($i > 0) {
 814       o("  0 -$dy moveto",
 815         " ",psvec(mkvec( $dx + $cube_sz, 0 )),
 816         " rlineto stroke\n");
 817     }
 818     o("  ",($token_sz * 0.6 + $cube_gap)," ",
 819       (-$dy * 0.5 - 0.5 * (water_cubes_sz(2))),
 820       " translate\n");
 821     my $bottom = int(($track->[$i+1] + 1) / 2);
 822     water_cubes($bottom, $cubeedgecolour);
 823     my $new_n = $track->[$i+1] - $bottom;
 824     o("  ", 0.5 * (water_cubes_sz($bottom) - water_cubes_sz($new_n)),
 825       "  ",       (water_cubes_sz(2)-water_cubes_sz(1)), " translate\n");
 826     water_cubes($new_n, $cubeedgecolour);
 827     o("  grestore\n");
 828   }
 829   o("  grestore\n");
 830 }
 831
 832 our $dyke_l = 25 * MM2PT;;
 833
 834 sub dykes(){
 835   my $l = $dyke_l;
 836   my $w = 5 * MM2PT;
 837   my $lw = $edge_lw * 0.50;
 838   my $l2 = $l/2;
 839   my $w2 = $w/2;
 840   o("  /dykepath {\n");
 841   o("            -$l2 -$w2 moveto\n");
 842   o("             $l2 -$w2 lineto\n");
 843   o("             $l2  $w2 lineto\n");
 844   o("            -$l2  $w2 lineto closepath\n");
 845   o("  } bind def\n");
 846   o("  /dyke {\n");
 847   o("    newpath dykepath\n");
 848   o("    gsave ",miscpscolour('dykefill')," fill grestore\n");
 849   o("    gsave ",miscpscolour('edge')," $lw setlinewidth stroke grestore\n");
 850   o("  } bind def\n");
 851   my $symbol_sz = $w * 1.50;
 852   my $t_sz = $symbol_sz * 1.0;
 853   my $t_at = sub {
 854     my ($ang) = @_;
 855     #print STDERR "ANG $ang\n";
 856     map { $t_sz * 0.5 * $_ } cos($ang), sin($ang);
 857   };
 858   my @t0 = $t_at->((TAU) *  0.25         );
 859   my @t1 = $t_at->((TAU) * (0.25 + 1./3) );
 860   my @t2 = $t_at->((TAU) * (0.25 + 2./3) );
 861   o("  /dtriangle {\n");
 862   o("    newpath @t0 moveto\n");
 863   o("            @t1 lineto\n");
 864   o("            @t2 lineto closepath\n");
 865   o("    gsave ",miscpscolour('dykeinit')," fill grestore\n");
 866   o("    gsave ",miscpscolour('edge')," $lw setlinewidth stroke grestore\n");
 867   o("  } bind def\n");
 868   foreach my $rr (values %region) {
 869     next if $rr->{Special};
 870     next if $rr->{Name} eq 'ZZ';
 871     next if $rr->{Colour} eq 'high';
 872     foreach my $adj (@{ $rr->{Adj} }) {
 873       my $neigh = $adj->{Name};
 874       o("  % dyke $rr->{Name} --- $neigh\n");
 875       next if $neigh lt $rr->{Name} && !$region{$neigh}{Special};
 876       next if $region{$neigh}{Colour} eq 'high';
 877       my @ends = adj_ends($adj);
 878       my $dirn = $ends[1] - $ends[0];
 879       my $angle = vec2atan($dirn);
 880       $angle = $angle * 360 / TAU;
 881       o("  gsave\n");
 882       o("    ", psvec( 0.5 * ($ends[0] + $ends[1]) )," translate\n");
 883       o("    $angle rotate\n");
 884       my $initial = $adj->{Dykes};
 885       for my $ys ($initial
 886                   ? [ map { $_ - 0.5 * ($initial-1) } 0..$initial-1 ]
 887                   : [0]) {
 888         foreach my $y (@$ys) {
 889           o("    gsave 0 ", $y * $w, " translate dyke ");
 890           o(" grestore\n");
 891         }
 892         my $nsymbols = $initial + !!$adj->{Deltawerk};
 893         o("   ", -0.5 * $symbol_sz * ($nsymbols-1)," 0 translate\n");
 894         my $trans = "  $symbol_sz 0 translate";
 895         if ($adj->{Deltawerk}) {
 896           one_hs('red', mkvec(0,0), $symbol_sz * 0.8, $lw);
 897           o($trans);
 898         }
 899         foreach my $i (1..$initial) {
 900           o(" gsave $angle neg rotate dtriangle grestore\n");
 901           o($trans);
 902         }
 903       }
 904       o("  grestore\n");
 905     }
 906   }
 907 }
 908
 909 sub hs_initial_1 ($$$;$$$) {
 910   my ($colour, $xi,$yi, $text, $text2, $fn) = @_;
 911   my $interval = $hs_sz * 1.75;
 912   my $demo_h = $hs_sz; #water_cubes_sz(3);
 913   my $demo_x0 = $hs_sz * 0.75 + $dyke_l * 0.60;
 914   my $demo_w = $demo_x0 + $dyke_l * 0.60;
 915   o("  % HS I $colour\n");
 916   o("  gsave\n");
 917   o("    550 1705 $top_adjuncts_dy_from_boundings add translate\n");
 918   o("    ", ($xi*$interval), " ", (($yi-1)*$interval), " translate\n");
 919   if ($fn) {
 920     o("  gsave\n");
 921     o("        $demo_h setlinewidth 0 0 moveto $demo_w 0 rlineto\n");
 922     o("        ", facepscolour($colour), " stroke grestore\n");
 923   }
 924   one_hs($colour, mkvec(0,0));
 925   if ($fn) {
 926     o("    /words {\n");
 927     o("      2 copy moveto                      ($text) show\n");
 928     o("      2 copy moveto 0 -$text_sz rmoveto ($text2) show\n");
 929     o("    } bind def\n");
 930     o("    gsave ".($hs_sz * 0.8)." $cube_gap translate wordsshow grestore\n");
 931     o("    $demo_x0 ",($hs_sz * -0.25)," translate\n");
 932     $fn->();
 933   }
 934   o("  grestore\n");
 935 }
 936
 937 sub hs_initial () {
 938   hs_initial_1('red',     0,0);
 939   hs_initial_1('purple',  0,1);
 940   hs_initial_1('green',   1,0, 'up to 6', 'fewer', sub {
 941     o("    ",(water_cubes_sz(1))," 0 translate\n");
 942     o("    0 ",(-water_cubes_sz(1) * 0.3)," translate\n");
 943     water_cubes(1, miscpscolour('edge'));
 944   });
 945   hs_initial_1('yellow',  1,1, 'up to 4', '', sub {
 946     o("    newpath dykepath\n");
 947     o("    gsave ",miscpscolour('edge')," stroke grestore\n");
 948     o("    gsave ",miscpscolour('dykehsadd')," fill grestore\n");
 949   });
 950 }
 951
 952 sub play_hint () {
 953   my $sz = 20;
 954   o("  gsave ",miscpscolour('hinttext'),
 955     " 260 1715 $top_adjuncts_dy_from_boundings add translate\n");
 956   o("  /Helvetica-Bold findfont $sz scalefont setfont\n");
 957   my @t = split /\n/, $c{PlayHint};
 958   foreach my $i (0..$#t) {
 959     my $t = $t[$i];
 960     $t =~ s/[\\()]/\\$&/g;
 961     o("  0 ",(-$i * $sz)," moveto ($t) show\n");
 962   }
 963   o("  grestore");
 964 }
 965
 966 #----- main program -----
 967
 968 $xopts = shift @ARGV if $ARGV[0] =~ s/^-X//;
 969 $bounding = $1 if $xopts =~ s/b(\w+)//;
 970 $maxpaper = $1 if $xopts =~ s/p(\w+)//;
 971 $maxpaper =~ m/^a[134]$|^a1m$/ or confess;
 972
 973 ($facesf, @ARGV) = @ARGV or die;
 974 parse_input_graph();
 975 prep_region_rmap();
 976 read_faces();
 977 calculate_centres();
 978 transform_coordinates();
 979 adjust_nz();
 980
 981 computeboundings();
 982 preamble();
 983 fill_faces();
 984 edge_faces();
 985 dykes();
 986 label_faces();
 987 decks();
 988 sea_track();
 989 hs_initial();
 990 play_hint();
 991 postamble();
 992
 993 print STDERR Dumper(\%region) if $ENV{'GENERATE_BOARD_DUP'};
 994
 995 # Local variables:
 996 # cperl-indent-level: 2
 997 # End.