Parse.pm

   1
   2 package Parse;
   3
   4 use strict;
   5 use Carp;
   6 use Graph;
   7
   8 use Exporter;
   9
  10 our @ISA = qw(Exporter);
  11 our @EXPORT = qw(parse_input_graph o plag_prs %region %c);
  12
  13 our %c;
  14 require 'misc-data.pl';
  15
  16 our %region;
  17 # $region{NAME}{Colour}
  18 # $region{NAME}{Water}
  19 # $region{NAME}{Name}
  20 # $region{NAME}{L} # line number
  21 # $region{NAME}{Adj}[]{Name}
  22 # $region{NAME}{Adj}[]{DisplayName}[]
  23 # $region{NAME}{Adj}[]{Pattern}
  24 # $region{NAME}{Adj}[]{Regexp}
  25 # $region{NAME}{Adj}[]{Dikes}
  26 # $region{NAME}{Adj}[]{L}
  27
  28 our %adj;
  29 # $adj{EARLIER}{LATER}{Dikes}
  30 # $adj{EARLIER}{LATER}{L}[]
  31 # $adj{EARLIER}{LATER}{T}[]
  32
  33 sub read_in () {
  34   my $ccolour;
  35   my $cregion;
  36
  37   while (<>) {
  38     next if m{^\s*\#};
  39     next unless m{\S};
  40     s{\s+$}{} or confess;
  41     if (m{^\w+}) {
  42       $ccolour = $&;
  43       next;
  44     }
  45     if (my ($name, $water) = m{^\t(\S.*\w|L2?)(?: \[(\d+)\])?$}) {
  46       confess unless defined $ccolour;
  47       my $dname = $c{DisplayNames}{$name} // $name;
  48       $name =~ s{/}{}g;
  49       confess "$name ?" if $region{$name};
  50       $region{$name}{Colour} = $ccolour;
  51       $region{$name}{Water} = $water;
  52       $region{$name}{L} = $.;
  53       if ($dname =~ m{/}) {
  54         $dname =~ s{(?<!-)/(?! )}{-/}g;
  55         $region{$name}{DisplayName} = [ grep m/./, split m{ */ *}, $dname ];
  56       } else {
  57         $region{$name}{DisplayName} = [ split m{(?<=-)| }, $dname ];
  58       }
  59       $cregion = $name;
  60       next;
  61     }
  62     if (my ($aref, $adikes) = m{^\t\t(\S.*[A-Za-z.]|L2?)(?: (\+\+?))?$}) {
  63       my $adj = { Dikes => (length $adikes // 0), L => $. };
  64       if ($aref =~ m{\.}) {
  65         $adj->{Pattern} = $aref;
  66         $aref =~ s{\-}{[^- ]*-}g;
  67         $aref =~ s{\.+}{
  68             length $& eq 1 ? qr{[^- ]* ?} :
  69             length $& eq 2 ? qr{.*}       : confess "$aref"
  70         }ge;
  71         $adj->{Regexp} = $aref;
  72       } else {
  73         $adj->{Name} = $aref;
  74       }
  75       push @{ $region{$cregion}{Adj} }, $adj;
  76       next;
  77     }
  78     confess "$_ ?";
  79   }
  80 }
  81
  82 sub unique_aref ($$) {
  83   my ($ra, $adja) = @_;
  84   my $re = $adja->{Regexp};
  85   return $adja->{Name} unless defined $re;
  86   my @cands;
  87   foreach my $rb (sort keys %region) {
  88     #print STDERR "?? $ra -> $re $rb ?\n";
  89     foreach my $adjb (@{ $region{$rb}{Adj} }) {
  90       my $adjbn = $adjb->{Name};
  91       next unless defined $adjbn;
  92       #print STDERR "?? $ra -> $re $rb ?? $adjbn\n";
  93       next unless $adjbn eq $ra;
  94       push @cands, [ $rb, "$region{$rb}{L},$adjb->{L}" ];
  95     }
  96   }
  97   my @found = grep { $_->[0] =~ m{^$re$} } @cands;
  98   my $pr = sub {
  99     join ' / ', map { "$_->[0] ($_->[1])" } @_;
 100   };
 101   confess "$adja->{L} $adja->{Pattern} /$re/ | ".$pr->(@cands)
 102       ." | ".$pr->(@found)." | ?"
 103       unless @found==1;
 104   my $r = $found[0][0];
 105   #print STDERR "resolve $ra -> $adja->{Pattern} = $r\n";
 106   return $r;
 107 }
 108
 109 sub region_cmp {
 110   ($a eq 'L' ) <=> ($b eq 'L' ) or
 111   ($a eq 'L2') <=> ($b eq 'L2') or
 112   ($a eq 'NZ') <=> ($b eq 'NZ') or
 113    $a          cmp  $b
 114 }
 115
 116 sub resolve_arefs () {
 117   #print Dumper(\%region);
 118   foreach my $ra (sort keys %region) {
 119     foreach my $adj (@{ $region{$ra}{Adj} }) {
 120       next if defined $adj->{Name};
 121       $adj->{ProspectiveName} = unique_aref $ra, $adj;
 122     }
 123   }
 124   foreach my $ra (sort keys %region) {
 125     foreach my $adj (@{ $region{$ra}{Adj} }) {
 126       $adj->{Name} //= $adj->{ProspectiveName};
 127     }
 128   }
 129   foreach my $ra (sort keys %region) {
 130     foreach my $adj (@{ $region{$ra}{Adj} }) {
 131       confess unless $adj->{Name} eq unique_aref $ra, $adj;
 132     }
 133   }
 134 }
 135
 136 sub adjacencies () {
 137   foreach my $ra (sort keys %region) {
 138     my $adjs = $region{$ra}{Adj};
 139     foreach my $adji (0..$#$adjs) {
 140       my $adja = $adjs->[$adji];
 141       my $rb = $adja->{Name};
 142       my ($r0,$r1) = sort region_cmp ($ra,$rb);
 143       push @{ $adj{$r0}{$r1}{L} }, $adja->{L};
 144       push @{ $adj{$r0}{$r1}{T} }, substr($ra,0,1)."#".$adji;
 145       my $e = $adj{$r0}{$r1};
 146       $e->{Dikes} //= $adja->{Dikes};
 147       confess "$r0 - $r1 | @{ $e->{L} } | $e->{Dikes} $adja->{Dikes} ?"
 148           unless $e->{Dikes} == $adja->{Dikes};
 149     }
 150   }
 151   my $ndikes = 0;
 152   foreach my $r0 (sort keys %adj) {
 153     foreach my $r1 (sort keys %{ $adj{$r0} }) {
 154       my $e = $adj{$r0}{$r1};
 155       confess "$r0 / $r1 : @{ $e->{L} } ?" unless @{ $e->{L} } == 2;
 156       $ndikes += $e->{Dikes};
 157     }
 158   }
 159   #print STDERR "total $ndikes dikes\n";
 160 }
 161
 162 sub names () {
 163   foreach my $r (sort keys %region) {
 164     $region{$r}{Name} = $r;
 165   }
 166 }
 167
 168 sub edge_id_to_other_id ($$) {
 169   my ($ra, $adjia) = @_;
 170   my $adjsa = $region{$ra}{Adj};
 171   my $adja = $adjsa->[$adjia];
 172   my $rb = $adja->{Name};
 173   my $adjsb = $region{$rb}{Adj};
 174   foreach my $adjib (0..$#$adjsb) {
 175     my $adjb = $adjsb->[$adjib];
 176     next unless $adjb->{Name} eq $ra;
 177     # $adjb is the same edge seen from the other side
 178     return ($rb, $adjib);
 179   }
 180   confess "$ra $adjia ?";
 181 }
 182
 183 sub o { print @_ or die $!; }
 184
 185 sub plag_prs ($) {
 186     my ($t) = @_;
 187     $t = $` if $t =~ m/\n/;
 188     $t =~ s/ //g;
 189     $t =~ s/-//g;
 190     return "$t";
 191 }
 192
 193 sub parse_input_graph () {
 194   read_in();
 195   resolve_arefs();
 196   adjacencies();
 197   names();
 198 }
 199
 200 1;