-#!/bin/bash
-set -e
-base=/var/named
-conf=$base/conf
-etcfile=/etc/named/zones-rgc
-
-check=true
-install=false
-hostdelg=false
-hostzone=false
-progress=true
-usage=true
-
-while [ $# -gt 0 ]
-do
- case "$1" in
- -f) usage=false; check=false; install=true ;;
- -y) usage=false; check=true; install=true ;;
- -n) usage=false; check=true; install=false ;;
- -h) hostdelg=true; hostzone=false ;;
- -z) hostdelg=true; hostzone=true ;;
- -q) progress=false ;;
- *) echo >&2 "$0: usage: $0 [-y|-f] [-h|-z] [-q]"; exit 3 ;;
- esac
- shift
-done
-
-if $usage
-then
- cat <<END >&2
-usage: named-conf-regen -f|-y|-n [-h|-z]
+#!/usr/bin/perl -w
+
+use strict;
+use IO::File;
+use Data::Dumper;
+use POSIX;
+
+use vars qw($quis
+ $mode $doall
+ $etcfile $where
+ $debug $needglue $localonly $repeat $verbosity);
+
+$quis= $0; $quis =~ s,.*/,,;
+
+$mode= '';
+$doall= 0;
+$etcfile= "/etc/bind/chiark-conf-gen.zones";
+$where= '<built-in>';
+$debug= 0;
+$needglue= 1;
+$localonly= 0;
+$verbosity= 2;
+$repeat= 0;
+
+use vars qw($dig_owner $dig_type $dig_rdata);
+
+while (@ARGV && $ARGV[0] =~ m/^\-/) {
+ $_= shift @ARGV;
+ if (s/^\-\-//) {
+ last if m/^$/;
+ if (m/^(yes|no|force)$/) { m/^./; $mode= $&; }
+ elsif (m/^all$/) { $doall=1; }
+ elsif (m/^config$/) { $etcfile= loarg(); $where= '--config option'; }
+ elsif (m/^glueless$/) { $needglue=0; }
+ elsif (m/^localonly$/) { $localonly=1; }
+ elsif (m/^quiet$/) { $verbosity--; }
+ elsif (m/^repeat$/) { $repeat=1; }
+ elsif (m/^verbose$/) { $verbosity++; }
+ else { usageerr("unknown option --$_"); }
+ } else {
+ s/^\-//;
+ last if m/^$/;
+ while (m/^./) {
+ if (s/^[ynf]//) { $mode=$&; }
+ elsif (s/^A//) { $doall=1; }
+ elsif (s/^C//) { $etcfile= soarg(); $where= '-C option'; }
+ elsif (s/^D//) { $debug++; }
+ elsif (s/^g//) { $needglue=0; }
+ elsif (s/^l//) { $localonly=1; }
+ elsif (s/^q//) { $verbosity--; }
+ elsif (s/^r//) { $repeat=1; }
+ elsif (s/^v//) { $verbosity++; }
+ else { usageerr("unknown option -$&"); }
+ }
+ }
+}
+
+sub loarg() { usageerr("missing option value") if !@ARGV; return shift @ARGV; }
+sub soarg() { my ($rv); $rv=$_; $_=''; return length $rv ? $rv : loarg(); }
+
+usageerr("-q may be specified at most twice") if $verbosity<0;
+usageerr("-v may be specified at most once") if $verbosity>3;
+usageerr("-D may be specified at most twice") if $debug>2;
+usageerr("must specify either -f|-y|-n or zones (and not both)")
+ if !!$mode == !!@ARGV;
+
+sub usageerr ($) {
+ die <<END;
+$_[0]
+
+usage: chiark-named-conf [options] -f|-y|-n|<zone>...
operation modes:
- -f install without checking } but you must then
- -y check and install } ndc reload
- -n check only
+ -f --force install without checking
+ -y --yes check and install
+ -n --no check only (configured zones)
+ <zone> ... check only (specified zones, even unconfigured ones)
additional options:
- -h check output from host -C
- -z check output from host -C and host -val
-END
- exit 1
-fi
-
-beginfile () {
- if $install
- then
- exec >$conf/$1.new
- else
- exec >/dev/null
- fi
- currentfile=$1
-}
-
-endfile () {
- exec >/dev/null
- files="$files $currentfile"
-}
-
-installfiles () {
- if $install
- then
- cd $conf
- for f in $files
- do
- mv -f $f.new $f
- done
- fi
-}
-
-warnings=0
-
-warning () {
- echo >&2 "$zone $style: $*"
- warnings=$[$warnings+1]
-}
-
-equlines () {
- if [ "x`echo \" $2\" | wc -l`" != "x`echo \" $3\" | wc -l`" ]
- then
- warning "$1 >$2|$3<"
- fi
-}
-
-checkhostout () {
- set +e
- hostout="`host $1 \"$zone\" 2>&1 >/dev/null $2 | egrep -v \
-'^ \!\!\! .* SOA primary .* is not advertised via NS$'`"
- set -e
- if [ "x$hostout" = x ]; then return; fi
- if $hostfirstwarn
- then
- warning "warnings from host:"
- hostfirstwarn=false
- fi
- echo >&2 "$hostout"
-}
-
-progress () {
- if $progress
- then
- echo -n "$zone $style " >&2
- echo -ne '\r' >&2
- fi
-}
-
-cd $base/primary
-zones="*_db"
-
-beginfile primary.zones
-for f in $zones
-do
- zone="`echo $f | sed -e 's/_db$//'`"
- cat <<END
-zone "$zone" {
- type master;
- file "primary/$f";
-};
-END
-done
-endfile
-
-myname=''
-
-beginfile secondary.zones
-exec <$etcfile
-while read style zone servers
-do
- names=''
- case "$style" in
- myname)
- myname=$zone
- continue
- ;;
- secondary)
- progress
- file="slave/$zone"
- if $check
- then
- rectype=SOA
- set -e; soa="`host -t soa $zone.`"; set +e
- soaname="`echo \" $soa\" | expand | sed -e '
- s/^ [^ ][^ ]* *SOA *//; s/ .*$//; q
- '`"
- equlines SOA "$soaname" ''
- fi
- ;;
- backup|unoff)
- progress
- rectype=NS
- file="slave/$zone"
- ;;
- '#'|'')
- continue
- ;;
- *)
- echo >&2 "$etcfile: $style"
- exit 3
- esac
-
- if $check
- then
- set -e; ns="`host -t ns $zone.`"; set +e
- nsnames="`echo \" $ns\" | expand | tr A-Z a-z | sed -n '
- 1s/^ //
- s/^[^ ][^ ]* *ns *\([0-9a-z][-.0-9a-z]*\)$/\1/p
- '`"
- equlines NS "$nsnames" "$ns"
- nsnames="`echo $nsnames | tr '
-' ' '`"
-
- if [ "x$myname" != x ]
- then
- meadvert=false
- for ns in $nsnames
- do
- if [ "x$myname" = "x$ns" ]
- then
- meadvert=true
- fi
- done
- fi
-
- case "$style" in
- secondary) names="$soaname" ;;
- unoff|backup) names="$nsnames" ;;
- esac
-
- case "$style" in
- secondary|backup)
- if [ $meadvert = false ]
- then
- warning "$myname unlisted NS $nsnames"
- fi
- ;;
- unoff)
- if $meadvert = false
- then
- warning "$myname advertised NS $nsnames"
- fi
- ;;
- esac
-
- addrs=''
- for ns in $names
- do
- set -e; a="`host -t a \"$ns\".`"; set +e
- taddrs="`echo \" $a\" | expand | sed -n '
- 1s/^ //
- s/^[^ ][^ ]* *A *\([0-9][.0-9]*\)/\1/p
- '`"
- equlines "A $ns" "$a" "$taddrs"
- addrs="$addrs $taddrs"
- done
- fi
-
- cat <<END
-zone "$zone" {
- type slave;
- file "$file";
- masters {
-END
- for server in $servers
- do
- echo " $server;"
- if $check
- then
- notfound=true
- for addr in $addrs
- do
- if [ "x$addr" = "x$server" ]
- then
- notfound=false
- fi
- done
- if $notfound
- then
- warning "server $server? but $rectype $names" $addrs
- fi
- fi
- done
- cat <<END
- };
-};
+ -A --all report on zones marked ? (ones we know are broken)
+ -D debug $quis (does not help debug your DNS config)
+ -g --glueless do not warn about any glueless referrals (not recommended)
+ -l --localonly full checks only on zones which we primary
+ -q --quiet no output for OK zones
+ -r --repeat repeat warnings for all sources of imperfect data
+ -v --verbose extra verbose info about each zone
+ -C|--config <DIR/FILE use FILE as default config and DIR as default dir
+
+chiark-named-conf is Copyright 2002 Ian Jackson. It is Free software, under
+the GNU General Public License, and you are welcome to change it and/or
+distribute copies under certain conditions. There is ABSOLUTELY NO WARRANTY.
END
- hostfirstwarn=true
- if $hostdelg
- then
- checkhostout -C
- fi
- if $hostzone
- then
- checkhostout -val localhost
- fi
-done
-endfile
-
-if [ $warnings != 0 ]
-then
- echo >&2 "$warnings warnings "
-fi
-
-installfiles
+}
+
+cfg_fail("config filename $etcfile should not be directory")
+ if $etcfile =~ m,/$,;
+
+use vars qw($default_dir);
+$default_dir= $etcfile =~ m,^.*/, ? $& : './';
+
+use vars qw($slave_dir $slave_prefix $slave_suffix);
+$slave_dir= 'slave';
+$slave_prefix= '';
+$slave_suffix= '';
+
+use vars qw(@self_ns @self_soa @self_addr @forbid_addr @conv_glueless);
+@self_ns= @self_soa= @self_addr= @forbid_addr= ();
+@conv_glueless= qw(in-addr.arpa ip6.arpa ip6.int);
+
+use vars qw(%zone_cfg @zone_cfg_list);
+%zone_cfg= ();
+@zone_cfg_list= ();
+
+use vars qw($output $default_output %output_contents);
+$output= '';
+$default_output= '';
+%output_contents= ();
+
+use vars qw($check $install);
+$check= $mode !~ m/^f/;
+$install= $mode =~ m/^[yf]/;
+
+read_config($etcfile);
+debug_dump('@zone_cfg_list %zone_cfg');
+process_zones($mode ? @zone_cfg_list : @ARGV);
+debug_dump('%output_contents');
+output_files() if $install;
+
+exit 0;
+
+#-------------------- configuration reading
+
+sub cfg_fail ($) { die "$quis: $where:\n $_[0]\n"; }
+
+sub read_config ($) {
+ my ($if) = @_;
+ my ($fh,$z,@self,$before,
+ $mod,$dir,$prefix,$suffix,$subfile,$lprefix,$lsuffix,$zf);
+ local ($_);
+
+ $fh= new IO::File $if,'r' or cfg_fail("open $if:\n $!");
+ $before= '';
+ for (;;) {
+ if (!defined($_= <$fh>)) {
+ cfg_fail("read config file $if:\n $!") if $fh->error();
+ last;
+ }
+ chomp; s/\s+$//;
+ if (s/\\$//) { $before.= $_; next; }
+ $_= $before.$_;
+ $before= '';
+ s/^\s+//;
+ $where= "$if:$.";
+ next if m/^\#/;
+ last if m/^end$/;
+ next unless m/\S/;
+ if (m/^self(\-ns|\-soa|)\s+(\S.*\S)/) {
+ @self= split /\s+/, $2;
+ @self_ns= @self if $1 ne '-soa';
+ @self_soa= @self if $1 ne '-ns';
+ } elsif (m/^serverless\-glueless\s+(\S.*\S)/) {
+ @conv_glueless= split /\s+/, $1;
+ } elsif (m/^self\-addr\s+([0-9. \t]+)/) {
+ @self_addr= split /\s+/, $1;
+ } elsif (m/^forbid\-addr(?:\s+([0-9. \t]+))?/) {
+ @forbid_addr= defined $1 ? split /\s+/, $1 : ();
+ } elsif (m,^
+ primary\-dir ([*?]?)
+ \s+ (\S+)/([^/ \t]*)
+ (?: \s+ ([^/ \t]*) (?: (/.+) )?
+ )?
+ $,x) {
+ ($mod, $dir, $prefix, $suffix, $subfile) =
+ ($1,qualify($2),$3,$4,$5);
+ $suffix= '' if !defined $suffix;
+ $subfile= '' if !defined $subfile;
+ $suffix= '_db' if !length $suffix && !length $subfile;
+ if (-d "$dir/$prefix") { $dir.='/'; $dir.=$prefix; $prefix=''; }
+ opendir D, $dir or cfg_fail("open primary-dir $dir:\n $!");
+ $lprefix= length $prefix; $lsuffix= length $suffix;
+ while (defined($_= readdir D)) {
+ next if m/^\./ && !$lprefix;
+ next unless length > $lprefix+$lsuffix;
+ next unless substr($_,0,$lprefix) eq $prefix;
+ next unless substr($_,length($_)-$lsuffix) eq $suffix;
+ $z= substr($_,$lprefix,length($_)-($lprefix+$lsuffix));
+ $zf= $dir.'/'.$prefix.$z.$suffix.$subfile;
+ if (!stat $zf) {
+ next if length $subfile && $! == &ENOENT;
+ cfg_fail("cannot stat zonefile $zf:\n $!");
+ }
+ -f _ or cfg_fail("zonefile $zf is not a plain file");
+ zone_conf($z,'primary','p',$mod,$zf);
+ }
+ closedir D or cfg_fail("close primary-dir $dir:\n $!");
+ } elsif (m/^primary([*?]?)\s+(\S+)\s+(\S+)$/) {
+ zone_conf($2,'primary','p',$1,qualify($3));
+ } elsif (m/^published([*?]?)\s+(\S+)\s+([0-9.\t]+)$/) {
+ zone_conf($2,'published','s',$1,'',$3);
+ } elsif (m/^stealth([*?]?)\s+(\S+)\s+([0-9. \t]+)$/) {
+ zone_conf($2,'stealth','u',$1,'',split /\s+/, $3);
+ } elsif (m/^slave\-dir\s+(\S+)(?:(?:\s+(\S+))\s+(\S+))?$/) {
+ ($slave_dir, $slave_prefix, $slave_suffix) = (qualify($1),$2,$3);
+ $slave_prefix='' if !defined $slave_prefix;
+ $slave_suffix='' if !defined $slave_suffix;
+ } elsif (m/^output\s+bind8\+(\S+)$/) {
+ cfg_fail("default output may not apply to only some zones")
+ if @zone_cfg_list && length $default_output;
+ set_output(qualify($1));
+ } elsif (m/^include\s+(\S+)$/) {
+ read_config($1);
+ } else {
+ cfg_fail("unknown configuration directive".
+ " or incorrect syntax or arguments:\n".
+ " \`$_'");
+ }
+ }
+ $fh->close or cfg_fail("close config file $if:\n $!");
+}
+
+sub qualify ($) {
+ my ($i) = @_;
+ $i= "$default_dir$i" unless $i =~ m,^/,;
+ return $i;
+}
+
+sub zone_conf ($$$$$@) {
+ my ($zone,$style,$sabbr,$mod,$file,@servers) = @_;
+ my ($sfx,$aref);
+ $file= qualify("$slave_dir/$slave_prefix".$zone.$slave_suffix)
+ unless length $file;
+ if (!length $output) {
+ $default_output= qualify('chiark-conf-gen.bind8')
+ unless length $default_output;
+ set_output($default_output);
+ }
+ cfg_fail("redefined zone $zone\n".
+ " earlier definition $zone_cfg{$zone}{'where'}")
+ if exists $zone_cfg{$zone};
+ $zone_cfg{$zone}{'where'}= $where;
+ $zone_cfg{$zone}{'file'}= $file;
+ $zone_cfg{$zone}{'style_p'}= $style.$mod;
+ $zone_cfg{$zone}{'s'}= $sabbr.$mod; # p)rimary s)econdary u)npub f)oreign
+ $zone_cfg{$zone}{'servers'}= [ @servers ];
+ foreach $sfx (qw(self_soa self_ns self_addr forbid_addr conv_glueless)) {
+ { no strict 'refs'; $aref= [ @$sfx ]; }
+ @$aref or cfg_fail("failed to specify $sfx before zone")
+ if $sfx =~ m/^self/;
+ $zone_cfg{$zone}{$sfx}= $aref;
+ }
+ $zone_cfg{$zone}{'output'}= $output;
+ push @zone_cfg_list, $zone;
+}
+
+sub set_output($) {
+ my ($newout) = @_;
+ $output= $newout;
+ $output_contents{$output}= '';
+}
+
+
+#-------------------- checking
+
+use vars qw($zone $cfg $warnings %zone_warnings);
+$warnings= 0;
+
+sub progress ($$) {
+ my ($minv,$m) = @_;
+ return if $verbosity < $minv;
+ print "$m\n";
+}
+
+sub verbose ($) { progress(3, ' ' . $_[0]); }
+
+sub process_zones (@) {
+ my (@zones) = @_;
+ local ($zone,$cfg);
+
+ foreach $zone (@zones) {
+ zone_reset();
+ $cfg= $zone_cfg{$zone} || {
+ 'style_p' => 'foreign',
+ 's' => 'f',
+ 'servers' => [ ],
+ };
+ progress(1, sprintf "%-20s %s", $zone, $$cfg{'style_p'});
+ if ($check && ($doall || $cfg->{'s'} !~ m/\?/)) {
+ eval {
+ if ($localonly && $cfg->{'s'} =~ m/f/) {
+ zone_warning("foreign zone specified with -l",'');
+ } elsif ($localonly && $cfg->{'s'} !~ m/p/) {
+ zone_check_local();
+ } else {
+ zone_check_full();
+ }
+ };
+ zone_warning("checks failed: $@",'') if length $@;
+ }
+ $output_contents{$$cfg{'output'}} .= zone_output()
+ if $install;
+ }
+ if ($warnings) {
+ printf STDERR ("%s: %d warning(s) in %d zone(s);".
+ " %d zone(s) checked ok.\n",
+ $quis,
+ $warnings,
+ scalar(keys %zone_warnings),
+ scalar(@zones - keys %zone_warnings));
+ } else {
+ progress(1, sprintf "%d zone(s) checked ok", scalar @zones);
+ }
+}
+
+use vars qw(%delgs); # $delgs{$nameserver_list} = [ $whosaidandwhy ]
+use vars qw(%auths); # $auths{$nameserver_list} = [ $whosaidandwhy ]
+use vars qw(%glue); # $glue{$name}{$addr_list} = [ $whosaidandwhy ]
+use vars qw(%soas); # $soa{"$serial $origin"} = [ $whosaidandwhy ]
+use vars qw(%addr_is_ok %warned);
+use vars qw($delg_to_us);
+use vars qw(@to_check); # ($addr,$whyask,$name_if_auth,$glueless_ok, ...)
+use vars qw(@to_check_soa); # ($addr,$whyask,$name,$is_ns, ...)
+
+sub zone_warning ($$) {
+ my ($w,$o) = @_;
+ my ($wk);
+
+ return 0 if !$repeat && $warned{$w}++;
+
+ $w =~ s/\n$//;
+ $w =~ s,\n, // ,g;
+
+ $w .= " ($o)" if length $o;
+ print STDERR "$zone: warning: $w\n" or die $!;
+ $warnings++;
+ $zone_warnings{$zone}++;
+ return 1;
+}
+
+sub zone_warnmore ($) {
+ print STDERR "$zone: $_[0]\n" or die $!;
+}
+
+sub zone_check_full () {
+ zone_investigate();
+ zone_consistency();
+ zone_servers_ok();
+}
+
+sub zone_reset() {
+ %delgs= %auths= %glue= %soas= %warned= %addr_is_ok= ();
+ $delg_to_us= 0;
+ @to_check= @to_check_soa= ();
+}
+
+sub zone_investigate() {
+ my ($super_zone, @start_nsnames, $start_ww,
+ $start_ns, @start_ns_addrs, $s, $wa, $name_if_auth,
+ %nsrrset_checked, %soa_checked, $addr, $glueless_ok,
+ $rcode, $name, $is_ns);
+
+ if ($cfg->{'s'} !~ m/\*/) {
+ $super_zone= $zone;
+ for (;;) {
+ debug_trace("zone $zone superzone $super_zone");
+ $super_zone eq '.'
+ and die "no superzone ? ($super_zone)\n";
+ $super_zone =~ s/^[^.]+\.//
+ or $super_zone= '.';
+ ($rcode,@start_nsnames)=
+ lookup($super_zone,'ns-','06',"superzone search");
+ last if !$rcode;
+ }
+ $start_ww= "server for $super_zone";
+ } else {
+ ($rcode,@start_nsnames)=
+ lookup($zone,'ns-','0',"initial nameserver search");
+ $start_ww= "nameserver for $zone";
+ }
+ for $start_ns (@start_nsnames) {
+ $start_ns= lc $start_ns;
+ ($rcode,@start_ns_addrs)= lookup($start_ns,'a','0',"$start_ww");
+ foreach $addr (@start_ns_addrs) {
+ push @to_check, $addr, "$start_ns, $start_ww", undef, 0;
+ }
+ }
+ for (;;) {
+ # We do these in order so that we always do NS RRset checks on
+ # nameservers that came from other NS RRsets first; otherwise
+ # we might set nsrrset_checked due to a glueless_ok check,
+ # and then not check for gluefulness later.
+ debug_dump('@to_check @to_check_soa');
+ if (($addr,$wa,$name_if_auth,$glueless_ok,@to_check) = @to_check) {
+ push @to_check_soa, $addr, $wa, $name_if_auth, 1,
+ if defined $name_if_auth;
+ next if $nsrrset_checked{$addr}++;
+ zone_check_nsrrset($addr, $wa, $name_if_auth, $glueless_ok);
+ } elsif (($addr,$wa,$name,$is_ns,@to_check_soa) = @to_check_soa) {
+ next if $soa_checked{$addr}++;
+ zone_check_soa($addr,$wa,$name,$is_ns);
+ } else {
+ last;
+ }
+ }
+}
+
+sub zone_check_nsrrset ($$$$) {
+ my ($uaddr,$wa, $name_if_auth, $glueless_ok) = @_;
+ my (@s, $s, $a, %s2g, @glue, $glue, $delgs_or_auths, $wwn, $ww);
+ my ($rcode);
+ $ww= "[$uaddr] $wa";
+ verbose("checking delegation by $ww");
+ dig(sub {
+ if ($dig_type eq 'ns' && $dig_owner eq $zone) {
+ $s2g{lc $dig_rdata} = [ ];
+ } elsif ($dig_type eq 'a' && exists $s2g{$dig_owner}) {
+ $wwn= "in glue from $ww";
+ zone_server_queue($dig_rdata,$dig_owner,$wwn,"NS [$uaddr]",0);
+ push @{ $s2g{$dig_owner} }, $dig_rdata;
+ }
+ },
+ $zone,'ns',$uaddr);
+ if (!%s2g) {
+ zone_warning("unable to find NS RRset at [$uaddr]", $wa);
+ return;
+ } elsif (keys %s2g == 1) {
+ zone_warning("only one nameserver ". (join '', keys %s2g),
+ $ww);
+ }
+ @s= sort keys %s2g;
+ foreach $s (@s) {
+ zone_ns_name($s,$ww);
+ @glue= @{ $s2g{$s} };
+ if (!@glue) {
+ zone_warning("glueless NS $s", $ww)
+ unless $glueless_ok || !$needglue ||
+ grep { has_suffix_of($zone,".$_"); }
+ @{ $cfg->{'conv_glueless'} };
+ ($rcode,@glue)= lookup($s,'a','0',"glueless NS from $ww");
+ foreach $a (@glue) {
+ $wwn= "glueless NS from $ww";
+ zone_server_queue($a,$s,$wwn,"NS [$uaddr]",0);
+ }
+ }
+ $glue= join ' ', sort @glue;
+ push @{ $glue{$s}{$glue} }, $ww;
+ }
+ $s= join ' ', @s;
+ $delgs_or_auths= defined($name_if_auth) ? \%auths : \%delgs;
+ push @{ $delgs_or_auths->{$s} }, $ww;
+}
+
+sub zone_ns_name ($$) {
+ my ($name,$ww) = @_;
+ my ($cg);
+ $delg_to_us=1 if grep { $name eq $_ } @{ $cfg->{'self_ns'} };
+ foreach $cg (@{ $cfg->{'conv_glueless'} }) {
+ zone_warning("nameserver $name in serverless-glueless".
+ " namespace area $cg",
+ $ww)
+ if has_suffix_of(".$name",".$cg");
+ }
+ zone_warning("published server, as $name, but configured as stealth",
+ $ww)
+ if $cfg->{'s'} =~ m/u/ &&
+ grep { $_ eq $name }
+ @{ $cfg->{'self_ns'} }, @{ $cfg->{'self_soa'} };
+}
+
+sub zone_server_queue ($$$$$) {
+ my ($addr,$name,$wwn,$wwq,$is_soa) = @_;
+ zone_server_addr($addr,$name,$wwn,$wwq,$is_soa);
+ push @to_check, $addr, "$name, $wwn", $name, $is_soa;
+}
+
+sub zone_server_addr ($$$$$) {
+ my ($addr,$name,$ww,$wwq,$is_soa) = @_;
+ debug_trace("zone_server_addr ".join '|',@_);
+ $addr_is_ok{$addr}= "$name ($wwq)"
+ if $is_soa || $cfg->{'s'} =~ m/u/;
+ zone_warning("forbidden nameserver address [$addr] $name",$ww)
+ if grep { $_ eq $addr } @{ $cfg->{'forbid_addr'} };
+
+ my ($name_is_self, $addr_is_self);
+ $name_is_self= grep { $_ eq $name }
+ @{ $cfg->{$is_soa ? 'self_soa' : 'self_ns'} };
+ $addr_is_self= grep { $_ eq $addr }
+ @{ $cfg->{'self_addr'} };
+ if ($name_is_self && !$addr_is_self) {
+ zone_warning("our $name supplied with wrong address [$addr]", $ww);
+ }
+ if (!$name_is_self && $addr_is_self) {
+ zone_warning("we [$addr] are named in ".
+ ($is_soa ? "SOA" : "NS").
+ " by wrong name $name",
+ $ww);
+ }
+ if (!$name_is_self && !$addr_is_self &&
+ $is_soa && $cfg->{'s'} =~ m/p/) {
+ zone_warning("SOA ORIGIN $name is not us (".
+ (join ' ', @{ $cfg->{'self_soa'} }).")", $ww);
+ }
+ $delg_to_us=1 if $addr_is_self && !$is_soa;
+}
+
+sub zone_check_soa ($$$$) {
+ my ($uaddr,$wa,$name,$is_ns) = @_;
+ my ($lame,$serial,$origin,$got,$rcode,@soa_addrs,$soa_addr,$ww,$wwn);
+ verbose("checking service at [$uaddr] $name");
+ $lame= 'dead or lame';
+ $ww= "[$uaddr] $wa";
+ dig(sub {
+ if ($dig_type eq 'flags:') {
+ $lame= $dig_rdata =~ m/ aa / ? '' : 'lame';
+ } elsif ($dig_type eq 'soa' && $dig_owner eq $zone && !$lame) {
+ die "several SOAs ? $ww" if defined $origin;
+ $got= $dig_rdata;
+ $got =~ m/^(\d+) (\S+)$/ or die "$got ?";
+ ($serial,$origin) = ($1,$2);
+ }
+ },
+ $zone,'soa',$uaddr);
+ $lame= 'broken' if !$lame && !defined $origin;
+ if ($lame) { zone_warning("$lame server [$uaddr]",$wa); return; }
+ progress(2, sprintf "%-16s %46s has %s%s",
+ $zone, "$name [$uaddr]", $serial, $is_ns ? '' : '*');
+ push @{ $soas{$got} }, $ww;
+ ($rcode,@soa_addrs)= lookup($origin,'a','0',"SOA ORIGIN");
+ $wwn= "SOA ORIGIN from $ww";
+ foreach $soa_addr (@soa_addrs) {
+ zone_server_queue($soa_addr,$origin,$wwn,"SOA [$uaddr]",1);
+ }
+}
+
+sub zone_consistency() {
+ my ($d, $org_ser, $origin, $a, $h, $self_soa, $wa);
+ zone_consistency_set('delegations',\%delgs);
+ foreach $d (keys %delgs) { delete $auths{$d}; }
+ zone_consistency_set('zone nameserver rrset',\%auths);
+ foreach $h (keys %glue) {
+ zone_consistency_set("glue for $h", $glue{$h});
+ }
+ zone_consistency_set("serial number and/or SOA ORIGIN",\%soas);
+ $self_soa= $cfg->{'self_soa'};
+}
+
+sub zone_servers_ok () {
+ my ($showok,%fs);
+ if (%addr_is_ok) {
+ $showok= 0;
+ foreach $a (@{ $cfg->{'servers'} }) {
+ next if exists $addr_is_ok{$a};
+ zone_warning("we slave from [$a]",'')
+ and $showok=1;
+ }
+ if ($showok) {
+ foreach $a (keys %addr_is_ok) {
+ zone_warnmore("permitted master [$a] $addr_is_ok{$a}");
+ }
+ }
+ }
+ if ($cfg->{'s'} =~ m/s/ && !$delg_to_us) {
+ zone_warning("we are supposedly published secondary,".
+ " but not listed as a nameserver",'');
+ map { $fs{$_}=1 } keys(%delgs), keys(%auths);
+ zone_warnmore("servers are: ". join ' ', sort keys %fs);
+ }
+}
+
+sub zone_consistency_set ($%) {
+ my ($msg,$set) = @_;
+ my ($d,$o);
+ if (keys(%$set) > 1) {
+ zone_warning("inconsistent $msg:",'');
+ foreach $d (keys %$set) {
+ foreach $o (@{ $set->{$d} }) { zone_warnmore(" $d from $o"); }
+ }
+ }
+}
+
+sub zone_check_local () {
+ zone_servers_simplefind();
+ zone_servers_ok();
+}
+
+sub zone_servers_simplefind () {
+ my ($rcode,@nsnames,$ns,@soas,$origin);
+
+ ($rcode,@nsnames)= lookup($zone,'ns-','0',"zone's servers");
+ foreach $ns (@nsnames) {
+ zone_ns_name($ns,"NS");
+ zone_server_simple($ns,'NS',0);
+ }
+ $delgs{join ' ', sort @nsnames} = [ "zone's servers" ];
+
+ ($rcode,@soas)= lookup($zone,'soa','0',"SOA ORIGIN");
+ die "multiple SOA RRs in set! @soas ?" if @soas!=1;
+ $soas[0] =~ m/^(\S+)\s/ or die "SOA ? $_";
+ zone_server_simple(domain_canon($1,"lookup $zone SOA"),'SOA',1);
+}
+
+sub zone_server_simple ($$$) {
+ my ($name,$ww,$is_soa) = @_;
+ my ($rcode,@addrs,$addr);
+ ($rcode,@addrs)= lookup($name,'a','0', "server - ".
+ ($is_soa ? "SOA ORIGIN" : "NS"));
+ foreach $addr (@addrs) { zone_server_addr($addr,$name,$ww,$ww,$is_soa); }
+}
+
+#-------------------- outputting
+
+sub zone_output () {
+ my ($o,$m);
+
+ $o= "zone \"$zone\" {\n";
+ if ($$cfg{'s'} =~ m/p/) {
+ $o.= " type master;\n";
+ } else {
+ $o.= " type slave;\n".
+ " masters {\n";
+ foreach $m (@{ $$cfg{'servers'} }) { $o.= " $m;\n"; }
+ $o.= " };\n";
+ }
+ $o.= " file \"$$cfg{'file'}\";\n";
+ $o.= "};\n";
+ return $o;
+}
+
+sub output_files () {
+ my ($fn,$ofn,$mfn,$l,$dir, $maxmode,$h,@to_install);
+
+ foreach $ofn (keys %output_contents) {
+ $fn= $ofn; $mfn= "output file $fn";
+ for (;;) {
+ if (!lstat $fn) {
+ $! == &ENOENT or die "$quis: stat $mfn:\n $!\n";
+ $maxmode= 0666;
+ last;
+ } elsif (-f _) {
+ $maxmode= (stat _)[2];
+ last;
+ } elsif (-l _) {
+ defined($l= readlink $fn)
+ or die "$quis: readlink $mfn:\n $!\n";
+ $dir= $fn =~ m,^.*/, ? $& : './';
+ $fn= "$dir$l" unless $l =~ m,^/,;
+ $mfn= "output file $fn (symlink target of $ofn)";
+ } else {
+ die "$quis: output file $mfn exists but is not a file".
+ " (or symlink to one)";
+ }
+ }
+ unlink "$fn.new" or $! == &ENOENT or
+ die "$quis: cannot clear out old .new version of $mfn:\n $!";
+ $h= new IO::File "$fn.new",'w',$maxmode
+ or die("$quis: create .new version of $mfn:\n $!");
+ print $h
+ "# generated by $quis, do not edit\n",
+ $output_contents{$ofn}
+ or die "$quis: write data to .new version of $mfn:\n $!";
+ $h->close
+ or die "$quis: close .new version of $mfn:\n $!";
+ push @to_install, $fn,$mfn;
+ }
+
+ while (($fn,$mfn, @to_install) = @to_install) {
+ rename "$fn.new",$fn
+ or die "$quis: install new version of $mfn:\n $!";
+ }
+}
+
+#-------------------- general utilities
+
+sub debug_dump ($) {
+ my ($vn);
+ return unless $debug>1;
+ local $Data::Dumper::Terse=1;
+ foreach $vn (split /\s+/, $_[0]) {
+ print "$vn := ", eval "Dumper(\\$vn)";
+ }
+}
+
+sub debug_trace ($) {
+ return unless $debug;
+ print "D $_[0]\n";
+}
+
+sub has_suffix_of ($$) {
+ my ($whole,$suffix) = @_;
+ debug_trace("has_suffix_of $whole $suffix");
+ return 0 if length $whole < length $suffix;
+ return 0 if substr($whole, length($whole) - length($suffix)) ne $suffix;
+ debug_trace("has_suffix_of $whole $suffix YES");
+ return 1;
+}
+
+sub lookup ($$$$) {
+ my ($domain,$type,$okrcodes,$w) = @_;
+ my ($c,$h,@result);
+ debug_trace("lookup ==> (->$okrcodes) $domain $type");
+ $h= new IO::Handle;
+
+ defined($c= open $h, "-|") or die "$quis: fork adnshost:\n $!\n";
+ if (!$c) {
+ exec 'adnshost','-Fi','+Do','+Dt','+Dc','-Cf',"-t$type",
+ '-',"$domain";
+ die "$quis: exec adnshost:\n $!\n";
+ }
+ @result= $h->getlines();
+ $h->error and die "$quis: read from adnshost:\n $!\n";
+ chomp @result;
+ $!=0; $h->close;
+ die "$quis: lookup -t$type $domain $okrcodes ($w) failed $? $! @result\n"
+ if $! or $?&255 or $?>1536 or index($okrcodes,$?>>8)<0;
+ debug_trace("lookup <== $? @result");
+ return ($?,@result);
+}
+
+sub dig (&$$$) {
+ my ($eachrr, $qowner,$qtype,$qaddr) = @_;
+ # also pseudo-rr with type `flags:'
+ my ($h,$inmid,$irdata,$c,$digwhy);
+ local ($_);
+
+ debug_trace("dig ==> \@$qaddr $qowner $qtype");
+
+ $h= new IO::Handle;
+ defined($c= open $h, "-|") or die "$quis: fork dig:\n $!\n";
+ if (!$c) {
+ open STDERR, ">&STDOUT" or die $!;
+ exec ('dig',
+ '+nodef','+nosea','+nodebug','+norecurse',
+ "\@$qaddr",'-t',$qtype,$qowner);
+ die "$quis: exec dig:\n $!\n";
+ }
+ $inmid='';
+ for (;;) {
+ if (!defined($_= $h->getline())) {
+ $h->error() and die "$quis: read from dig:\n $!\n";
+ last;
+ }
+ chomp;
+ if (length $inmid) {
+ s/^\s+/ / or die "$inmid // $_ ?";
+ s/\;.*$//;
+ $_= $inmid.$_;
+ $inmid='';
+ s/$/ \(/ unless s/\s*\)\s*$//;
+ }
+ if (s/\s*\(\s*$//) { $inmid= $_; next; }
+ $digwhy= "dig $qowner $qtype $qaddr \`$_'";
+ if (m/^\;\; flags\:( [-0-9a-z ]+)\;/) {
+ $dig_owner=''; $dig_type='flags:'; $dig_rdata= "$1 ";
+ debug_trace("dig f: $dig_rdata");
+ &$eachrr;
+ } elsif (m/^\;/) {
+ } elsif (!m/\S/) {
+ } elsif (m/^([-.0-9a-z]+)\s+\d\w+\s+in\s+([a-z]+)\s+(\S.*)/i) {
+ $dig_owner=domain_canon($1,$digwhy); $dig_type=lc $2; $irdata=$3;
+ if ($dig_type eq 'a') {
+ $irdata =~ m/^[.0-9]+$/ or die "$irdata ?";
+ $dig_rdata= $&;
+ } elsif ($dig_type eq 'ns') {
+ $irdata =~ m/^[-.0-9a-z]+$/i or die "bad nameserver $irdata ?";
+ $dig_rdata= domain_canon($irdata,$digwhy);
+ } elsif ($dig_type eq 'soa') {
+ $irdata =~ m/^([-.0-9a-z]+)\s+.*\s+(\d+)(?:\s+\d\w+){4}$/i
+ or die "bad SOA $irdata ?";
+ $dig_rdata= $2.' '.domain_canon($1,$digwhy);
+ } else {
+ debug_trace("ignoring uknown RR type $dig_type");
+ next;
+ }
+ debug_trace("dig $dig_owner $dig_type $dig_rdata");
+ &$eachrr;
+ } else {
+ debug_trace("ignoring unknown dig output $_");
+ }
+ }
+ $h->close;
+ debug_trace("dig <== gave $?");
+}
+
+sub domain_canon ($$) {
+ my ($i,$w) = @_;
+ $i =~ s/(.)\.$/$1/;
+ return '.' if $i eq '.';
+ die "domain $i ($w) ?" unless $i =~ m/^[0-9a-z]/i;
+ return lc $i;
+}