chiark / gitweb /
ba36757a41a33b4504e38dbd4bd9b34a38c460d4
[chiark-utils.git] / scripts / named-conf
1 #!/usr/bin/perl -w
2
3 use strict;
4 use IO::File;
5 use Data::Dumper;
6 use POSIX;
7
8 use vars qw($quis
9             $mode $doall
10             $etcfile $where
11             $debug $needglue $localonly $repeat $verbosity);
12
13 $quis= $0; $quis =~ s,.*/,,;
14
15 $mode= '';
16 $doall= 0;
17 $etcfile= "/etc/bind/chiark-conf-gen.zones";
18 $where= '<built-in>';
19 $debug= 0;
20 $needglue= 1;
21 $localonly= 0;
22 $verbosity= 2;
23 $repeat= 0;
24
25 use vars qw($dig_owner $dig_type $dig_rdata);
26
27 while (@ARGV && $ARGV[0] =~ m/^\-/) {
28     $_= shift @ARGV;
29     if (s/^\-\-//) {
30         last if m/^$/;
31         if (m/^(yes|no|force)$/) { m/^./; $mode= $&; }
32         elsif (m/^all$/) { $doall=1; }
33         elsif (m/^config$/) { $etcfile= loarg(); $where= '--config option'; }
34         elsif (m/^glueless$/) { $needglue=0; }
35         elsif (m/^localonly$/) { $localonly=1; }
36         elsif (m/^quiet$/) { $verbosity--; }
37         elsif (m/^repeat$/) { $repeat=1; }
38         elsif (m/^verbose$/) { $verbosity++; }
39         else { usageerr("unknown option --$_"); }
40     } else {
41         s/^\-//;
42         last if m/^$/;
43         while (m/^./) {
44             if (s/^[ynf]//) { $mode=$&; }
45             elsif (s/^A//) { $doall=1; }
46             elsif (s/^C//) { $etcfile= soarg(); $where= '-C option'; }
47             elsif (s/^D//) { $debug++; }
48             elsif (s/^g//) { $needglue=0; }
49             elsif (s/^l//) { $localonly=1; }
50             elsif (s/^q//) { $verbosity--; }
51             elsif (s/^r//) { $repeat=1; }
52             elsif (s/^v//) { $verbosity++; }
53             else { usageerr("unknown option -$&"); }
54         }
55     }
56 }
57
58 sub loarg() { usageerr("missing option value") if !@ARGV; return shift @ARGV; }
59 sub soarg() { my ($rv); $rv=$_; $_=''; return length $rv ? $rv : loarg(); }
60
61 usageerr("-q may be specified at most twice") if $verbosity<0;
62 usageerr("-v may be specified at most once") if $verbosity>3;
63 usageerr("-D may be specified at most twice") if $debug>2;
64 usageerr("must specify either -f|-y|-n or zones (and not both)")
65     if !!$mode == !!@ARGV;
66
67 sub usageerr ($) {
68     die <<END;
69 $_[0]
70
71 usage: chiark-named-conf [options] -f|-y|-n|<zone>...
72 operation modes:
73  -f --force   install without checking
74  -y --yes     check and install
75  -n --no      check only (configured zones)
76  <zone> ...   check only (specified zones, even unconfigured ones)
77 additional options:
78  -A --all       report on zones marked ? (ones we know are broken)
79  -D             debug $quis (does not help debug your DNS config)
80  -g --glueless  do not warn about any glueless referrals (not recommended)
81  -l --localonly full checks only on zones which we primary
82  -q --quiet     no output for OK zones
83  -r --repeat    repeat warnings for all sources of imperfect data
84  -v --verbose   extra verbose info about each zone
85  -C|--config <DIR/FILE  use FILE as default config and DIR as default dir
86
87 chiark-named-conf is Copyright 2002 Ian Jackson.  It is Free software, under
88 the GNU General Public License, and you are welcome to change it and/or
89 distribute copies under certain conditions.  There is ABSOLUTELY NO WARRANTY.
90 END
91 }
92
93 cfg_fail("config filename $etcfile should not be directory")
94     if $etcfile =~ m,/$,;
95
96 use vars qw($default_dir);
97 $default_dir= $etcfile =~ m,^.*/, ? $& : './';
98
99 use vars qw($slave_dir $slave_prefix $slave_suffix);
100 $slave_dir= 'slave';
101 $slave_prefix= '';
102 $slave_suffix= '';
103
104 use vars qw(@self_ns @self_soa @self_addr @forbid_addr @conv_glueless);
105 @self_ns= @self_soa= @self_addr= @forbid_addr= ();
106 @conv_glueless= qw(in-addr.arpa ip6.arpa ip6.int);
107
108 use vars qw(%zone_cfg @zone_cfg_list);
109 %zone_cfg= ();
110 @zone_cfg_list= ();
111
112 use vars qw($output $default_output %output_contents);
113 $output= '';
114 $default_output= '';
115 %output_contents= ();
116
117 use vars qw($check $install);
118 $check= $mode !~ m/^f/;
119 $install= $mode =~ m/^[yf]/;
120
121 read_config($etcfile);
122 debug_dump('@zone_cfg_list %zone_cfg');
123 process_zones($mode ? @zone_cfg_list : @ARGV);
124 debug_dump('%output_contents');
125 output_files() if $install;
126
127 exit 0;
128
129 #-------------------- configuration reading
130
131 sub cfg_fail ($) { die "$quis: $where:\n $_[0]\n"; }
132
133 sub read_config ($) {
134     my ($if) = @_;
135     my ($fh,$z,@self,$before,
136         $mod,$dir,$prefix,$suffix,$subfile,$lprefix,$lsuffix,$zf);
137     local ($_);
138
139     $fh= new IO::File $if,'r' or cfg_fail("open $if:\n $!");
140     $before= '';
141     for (;;) {
142         if (!defined($_= <$fh>)) {
143             cfg_fail("read config file $if:\n $!") if $fh->error();
144             last;
145         }
146         chomp; s/\s+$//;
147         if (s/\\$//) { $before.= $_; next; }
148         $_= $before.$_;
149         $before= '';
150         s/^\s+//;
151         $where= "$if:$.";
152         next if m/^\#/;
153         last if m/^end$/;
154         next unless m/\S/;
155         if (m/^self(\-ns|\-soa|)\s+(\S.*\S)/) {
156             @self= split /\s+/, $2;
157             @self_ns= @self if $1 ne '-soa';
158             @self_soa= @self if $1 ne '-ns';
159         } elsif (m/^serverless\-glueless\s+(\S.*\S)/) {
160             @conv_glueless= split /\s+/, $1;
161         } elsif (m/^self\-addr\s+([0-9. \t]+)/) {
162             @self_addr= split /\s+/, $1;
163         } elsif (m/^forbid\-addr(?:\s+([0-9. \t]+))?/) {
164             @forbid_addr= defined $1 ? split /\s+/, $1 : ();
165         } elsif (m,^
166                  primary\-dir ([*?]?)
167                  \s+ (\S+)/([^/ \t]*)
168                  (?: \s+ ([^/ \t]*) (?: (/.+) )?
169                   )?
170                  $,x) {
171             ($mod, $dir, $prefix, $suffix, $subfile) =
172                 ($1,qualify($2),$3,$4,$5);
173             $suffix= '' if !defined $suffix;
174             $subfile= '' if !defined $subfile;
175             $suffix= '_db' if !length $suffix && !length $subfile;
176             if (-d "$dir/$prefix") { $dir.='/'; $dir.=$prefix; $prefix=''; }
177             opendir D, $dir or cfg_fail("open primary-dir $dir:\n $!");
178             $lprefix= length $prefix; $lsuffix= length $suffix;
179             while (defined($_= readdir D)) {
180                 next if m/^\./ && !$lprefix;
181                 next unless length > $lprefix+$lsuffix;
182                 next unless substr($_,0,$lprefix) eq $prefix;
183                 next unless substr($_,length($_)-$lsuffix) eq $suffix;
184                 $z= substr($_,$lprefix,length($_)-($lprefix+$lsuffix));
185                 $zf= $dir.'/'.$prefix.$z.$suffix.$subfile;
186                 if (!stat $zf) {
187                     next if length $subfile && $! == &ENOENT;
188                     cfg_fail("cannot stat zonefile $zf:\n $!");
189                 }
190                 -f _ or cfg_fail("zonefile $zf is not a plain file");
191                 zone_conf($z,'primary','p',$mod,$zf);
192             }
193             closedir D or cfg_fail("close primary-dir $dir:\n $!");
194         } elsif (m/^primary([*?]?)\s+(\S+)\s+(\S+)$/) {
195             zone_conf($2,'primary','p',$1,qualify($3));
196         } elsif (m/^published([*?]?)\s+(\S+)\s+([0-9.\t]+)$/) {
197             zone_conf($2,'published','s',$1,'',$3);
198         } elsif (m/^stealth([*?]?)\s+(\S+)\s+([0-9. \t]+)$/) {
199             zone_conf($2,'stealth','u',$1,'',split /\s+/, $3);
200         } elsif (m/^slave\-dir\s+(\S+)(?:(?:\s+(\S+))\s+(\S+))?$/) {
201             ($slave_dir, $slave_prefix, $slave_suffix) = (qualify($1),$2,$3);
202             $slave_prefix='' if !defined $slave_prefix;
203             $slave_suffix='' if !defined $slave_suffix;
204         } elsif (m/^output\s+bind8\+(\S+)$/) {
205             cfg_fail("default output may not apply to only some zones")
206                 if @zone_cfg_list && length $default_output;
207             set_output(qualify($1));
208         } elsif (m/^include\s+(\S+)$/) {
209             read_config($1);
210         } else {
211             cfg_fail("unknown configuration directive".
212                      " or incorrect syntax or arguments:\n".
213                      " \`$_'");
214         }
215     }
216     $fh->close or cfg_fail("close config file $if:\n $!");
217 }
218
219 sub qualify ($) {
220     my ($i) = @_;
221     $i= "$default_dir$i" unless $i =~ m,^/,;
222     return $i;
223 }
224
225 sub zone_conf ($$$$$@) {
226     my ($zone,$style,$sabbr,$mod,$file,@servers) = @_;
227     my ($sfx,$aref);
228     $file= qualify("$slave_dir/$slave_prefix".$zone.$slave_suffix)
229         unless length $file;
230     if (!length $output) {
231         $default_output= qualify('chiark-conf-gen.bind8')
232             unless length $default_output;
233         set_output($default_output);
234     }
235     cfg_fail("redefined zone $zone\n".
236              " earlier definition $zone_cfg{$zone}{'where'}")
237         if exists $zone_cfg{$zone};
238     $zone_cfg{$zone}{'where'}= $where;
239     $zone_cfg{$zone}{'file'}= $file;
240     $zone_cfg{$zone}{'style_p'}= $style.$mod;
241     $zone_cfg{$zone}{'s'}= $sabbr.$mod; # p)rimary s)econdary u)npub f)oreign
242     $zone_cfg{$zone}{'servers'}= [ @servers ];
243     foreach $sfx (qw(self_soa self_ns self_addr forbid_addr conv_glueless)) {
244         { no strict 'refs'; $aref= [ @$sfx ]; }
245         @$aref or cfg_fail("failed to specify $sfx before zone")
246             if $sfx =~ m/^self/;
247         $zone_cfg{$zone}{$sfx}= $aref;
248     }
249     $zone_cfg{$zone}{'output'}= $output;
250     push @zone_cfg_list, $zone;
251 }
252
253 sub set_output($) {
254     my ($newout) = @_;
255     $output= $newout;
256     $output_contents{$output}= '';
257 }
258
259
260 #-------------------- checking
261
262 use vars qw($zone $cfg $warnings %zone_warnings);
263 $warnings= 0;
264
265 sub progress ($$) {
266     my ($minv,$m) = @_;
267     return if $verbosity < $minv;
268     print "$m\n";
269 }
270
271 sub verbose ($) { progress(3, '    ' . $_[0]); }
272
273 sub process_zones (@) {
274     my (@zones) = @_;
275     local ($zone,$cfg);
276
277     foreach $zone (@zones) {
278         zone_reset();
279         $cfg= $zone_cfg{$zone} || {
280             'style_p' => 'foreign',
281             's' => 'f',
282             'servers' => [ ],
283             };
284         progress(1, sprintf "%-20s %s", $zone, $$cfg{'style_p'});
285         if ($check && ($doall || $cfg->{'s'} !~ m/\?/)) {
286             eval {
287                 if ($localonly && $cfg->{'s'} =~ m/f/) {
288                     zone_warning("foreign zone specified with -l",'');
289                 } elsif ($localonly && $cfg->{'s'} !~ m/p/) {
290                     zone_check_local();
291                 } else {
292                     zone_check_full();
293                 }
294             };
295             zone_warning("checks failed: $@",'') if length $@;
296         }
297         $output_contents{$$cfg{'output'}} .= zone_output()
298             if $install;
299     }
300     if ($warnings) {
301         printf STDERR ("%s: %d warning(s) in %d zone(s);".
302                        " %d zone(s) checked ok.\n",
303                        $quis,
304                        $warnings,
305                        scalar(keys %zone_warnings),
306                        scalar(@zones - keys %zone_warnings));
307     } else {
308         progress(1, sprintf "%d zone(s) checked ok", scalar @zones);
309     }
310 }
311
312 use vars qw(%delgs); # $delgs{$nameserver_list} = [ $whosaidandwhy ]
313 use vars qw(%auths); # $auths{$nameserver_list} = [ $whosaidandwhy ]
314 use vars qw(%glue);  # $glue{$name}{$addr_list} = [ $whosaidandwhy ]
315 use vars qw(%soas);  # $soa{"$serial $origin"} = [ $whosaidandwhy ]
316 use vars qw(%addr_is_ok %warned);
317 use vars qw($delg_to_us);
318 use vars qw(@to_check); # ($addr,$whyask,$name_if_auth,$glueless_ok, ...)
319 use vars qw(@to_check_soa); # ($addr,$whyask,$name,$is_ns, ...)
320
321 sub zone_warning ($$) {
322     my ($w,$o) = @_;
323     my ($wk);
324
325     return 0 if !$repeat && $warned{$w}++;
326
327     $w =~ s/\n$//;
328     $w =~ s,\n, // ,g;
329
330     $w .= " ($o)" if length $o;
331     print STDERR "$zone: warning: $w\n" or die $!;
332     $warnings++;
333     $zone_warnings{$zone}++;
334     return 1;
335 }
336
337 sub zone_warnmore ($) {
338     print STDERR "$zone:  $_[0]\n" or die $!;
339 }
340
341 sub zone_check_full () {
342     zone_investigate();
343     zone_consistency();
344     zone_servers_ok();
345 }
346
347 sub zone_reset() {
348     %delgs= %auths= %glue= %soas= %warned= %addr_is_ok= ();
349     $delg_to_us= 0;
350     @to_check= @to_check_soa= ();
351 }
352
353 sub zone_investigate() {
354     my ($super_zone, @start_nsnames, $start_ww,
355         $start_ns, @start_ns_addrs, $s, $wa, $name_if_auth,
356         %nsrrset_checked, %soa_checked, $addr, $glueless_ok,
357         $rcode, $name, $is_ns);
358
359     if ($cfg->{'s'} !~ m/\*/) {
360         $super_zone= $zone;
361         for (;;) {
362             debug_trace("zone $zone superzone $super_zone");
363             $super_zone eq '.'
364                 and die "no superzone ? ($super_zone)\n";
365             $super_zone =~ s/^[^.]+\.//
366                 or $super_zone= '.';
367             ($rcode,@start_nsnames)=
368                 lookup($super_zone,'ns-','06',"superzone search");
369             last if !$rcode;
370         }
371         $start_ww= "server for $super_zone";
372     } else {
373         ($rcode,@start_nsnames)=
374             lookup($zone,'ns-','0',"initial nameserver search");
375         $start_ww= "nameserver for $zone";
376     }
377     for $start_ns (@start_nsnames) {
378         $start_ns= lc $start_ns;
379         ($rcode,@start_ns_addrs)= lookup($start_ns,'a','0',"$start_ww");
380         foreach $addr (@start_ns_addrs) {
381             push @to_check, $addr, "$start_ns, $start_ww", undef, 0;
382         }
383     }
384     for (;;) {
385         # We do these in order so that we always do NS RRset checks on
386         # nameservers that came from other NS RRsets first; otherwise
387         # we might set nsrrset_checked due to a glueless_ok check,
388         # and then not check for gluefulness later.
389         debug_dump('@to_check @to_check_soa');
390         if (($addr,$wa,$name_if_auth,$glueless_ok,@to_check) = @to_check) {
391             push @to_check_soa, $addr, $wa, $name_if_auth, 1,
392                 if defined $name_if_auth;
393             next if $nsrrset_checked{$addr}++;
394             zone_check_nsrrset($addr, $wa, $name_if_auth, $glueless_ok);
395         } elsif (($addr,$wa,$name,$is_ns,@to_check_soa) = @to_check_soa) {
396             next if $soa_checked{$addr}++;
397             zone_check_soa($addr,$wa,$name,$is_ns);
398         } else {
399             last;
400         }
401     }
402 }
403
404 sub zone_check_nsrrset ($$$$) {
405     my ($uaddr,$wa, $name_if_auth, $glueless_ok) = @_;
406     my (@s, $s, $a, %s2g, @glue, $glue, $delgs_or_auths, $wwn, $ww);
407     my ($rcode);
408     $ww= "[$uaddr] $wa";
409     verbose("checking delegation by $ww");
410     dig(sub {
411         if ($dig_type eq 'ns' && $dig_owner eq $zone) {
412             $s2g{lc $dig_rdata} = [ ];
413         } elsif ($dig_type eq 'a' && exists $s2g{$dig_owner}) {
414             $wwn= "in glue from $ww";
415             zone_server_queue($dig_rdata,$dig_owner,$wwn,"NS [$uaddr]",0);
416             push @{ $s2g{$dig_owner} }, $dig_rdata;
417         }
418     },
419              $zone,'ns',$uaddr);
420     if (!%s2g) {
421         zone_warning("unable to find NS RRset at [$uaddr]", $wa);
422         return;
423     } elsif (keys %s2g == 1) {
424         zone_warning("only one nameserver ". (join '', keys %s2g),
425                      $ww);
426     }
427     @s= sort keys %s2g;
428     foreach $s (@s) {
429         zone_ns_name($s,$ww);
430         @glue= @{ $s2g{$s} };
431         if (!@glue) {
432             zone_warning("glueless NS $s", $ww)
433                 unless $glueless_ok || !$needglue ||
434                        grep { has_suffix_of($zone,".$_"); }
435                            @{ $cfg->{'conv_glueless'} };
436             ($rcode,@glue)= lookup($s,'a','0',"glueless NS from $ww");
437             foreach $a (@glue) {
438                 $wwn= "glueless NS from $ww";
439                 zone_server_queue($a,$s,$wwn,"NS [$uaddr]",0);
440             }
441         }
442         $glue= join ' ', sort @glue;
443         push @{ $glue{$s}{$glue} }, $ww;
444     }
445     $s= join ' ', @s;
446     $delgs_or_auths= defined($name_if_auth) ? \%auths : \%delgs;
447     push @{ $delgs_or_auths->{$s} }, $ww;
448 }
449
450 sub zone_ns_name ($$) {
451     my ($name,$ww) = @_;
452     my ($cg);
453     $delg_to_us=1 if grep { $name eq $_ } @{ $cfg->{'self_ns'} };
454     foreach $cg (@{ $cfg->{'conv_glueless'} }) {
455         zone_warning("nameserver $name in serverless-glueless".
456                      " namespace area $cg",
457                      $ww)
458             if has_suffix_of(".$name",".$cg");
459     }
460     zone_warning("published server, as $name, but configured as stealth",
461                  $ww)
462         if $cfg->{'s'} =~ m/u/ &&
463            grep { $_ eq $name }
464                @{ $cfg->{'self_ns'} }, @{ $cfg->{'self_soa'} };
465 }
466
467 sub zone_server_queue ($$$$$) {
468     my ($addr,$name,$wwn,$wwq,$is_soa) = @_;
469     zone_server_addr($addr,$name,$wwn,$wwq,$is_soa);
470     push @to_check, $addr, "$name, $wwn", $name, $is_soa;
471 }
472
473 sub zone_server_addr ($$$$$) {
474     my ($addr,$name,$ww,$wwq,$is_soa) = @_;
475     debug_trace("zone_server_addr ".join '|',@_);
476     $addr_is_ok{$addr}= "$name ($wwq)"
477         if $is_soa || $cfg->{'s'} =~ m/u/;
478     zone_warning("forbidden nameserver address [$addr] $name",$ww)
479         if grep { $_ eq $addr } @{ $cfg->{'forbid_addr'} };
480
481     my ($name_is_self, $addr_is_self);
482     $name_is_self= grep { $_ eq $name }
483         @{ $cfg->{$is_soa ? 'self_soa' : 'self_ns'} };
484     $addr_is_self= grep { $_ eq $addr }
485         @{ $cfg->{'self_addr'} };
486     if ($name_is_self && !$addr_is_self) {
487         zone_warning("our $name supplied with wrong address [$addr]", $ww);
488     }
489     if (!$name_is_self && $addr_is_self) {
490         zone_warning("we [$addr] are named in ".
491                      ($is_soa ? "SOA" : "NS").
492                      " by wrong name $name",
493                      $ww);
494     }
495     if (!$name_is_self && !$addr_is_self &&
496         $is_soa && $cfg->{'s'} =~ m/p/) {
497         zone_warning("SOA ORIGIN $name is not us (".
498                      (join ' ', @{ $cfg->{'self_soa'} }).")", $ww);
499     }
500     $delg_to_us=1 if $addr_is_self && !$is_soa;
501 }
502
503 sub zone_check_soa ($$$$) {
504     my ($uaddr,$wa,$name,$is_ns) = @_;
505     my ($lame,$serial,$origin,$got,$rcode,@soa_addrs,$soa_addr,$ww,$wwn);
506     verbose("checking service at [$uaddr] $name");
507     $lame= 'dead or lame';
508     $ww= "[$uaddr] $wa";
509     dig(sub {
510         if ($dig_type eq 'flags:') {
511             $lame= $dig_rdata =~ m/ aa / ? '' : 'lame';
512         } elsif ($dig_type eq 'soa' && $dig_owner eq $zone && !$lame) {
513             die "several SOAs ? $ww" if defined $origin;
514             $got= $dig_rdata;
515             $got =~ m/^(\d+) (\S+)$/ or die "$got ?";
516             ($serial,$origin) = ($1,$2);
517         }
518     },
519              $zone,'soa',$uaddr);
520     $lame= 'broken' if !$lame && !defined $origin;
521     if ($lame) { zone_warning("$lame server [$uaddr]",$wa); return; }
522     progress(2, sprintf "%-16s %46s has %s%s",
523              $zone, "$name [$uaddr]", $serial, $is_ns ? '' : '*');
524     push @{ $soas{$got} }, $ww;
525     ($rcode,@soa_addrs)= lookup($origin,'a','0',"SOA ORIGIN");
526     $wwn= "SOA ORIGIN from $ww";
527     foreach $soa_addr (@soa_addrs) {
528         zone_server_queue($soa_addr,$origin,$wwn,"SOA [$uaddr]",1);
529     }
530 }
531
532 sub zone_consistency() {
533     my ($d, $org_ser, $origin, $a, $h, $self_soa, $wa);
534     zone_consistency_set('delegations',\%delgs);
535     foreach $d (keys %delgs) { delete $auths{$d}; }
536     zone_consistency_set('zone nameserver rrset',\%auths);
537     foreach $h (keys %glue) {
538         zone_consistency_set("glue for $h", $glue{$h});
539     }
540     zone_consistency_set("serial number and/or SOA ORIGIN",\%soas);
541     $self_soa= $cfg->{'self_soa'};
542 }
543
544 sub zone_servers_ok () {
545     my ($showok,%fs);
546     if (%addr_is_ok) {
547         $showok= 0;
548         foreach $a (@{ $cfg->{'servers'} }) {
549             next if exists $addr_is_ok{$a};
550             zone_warning("we slave from [$a]",'')
551                 and $showok=1;
552         }
553         if ($showok) {
554             foreach $a (keys %addr_is_ok) {
555                 zone_warnmore("permitted master [$a] $addr_is_ok{$a}");
556             }
557         }
558     }
559     if ($cfg->{'s'} =~ m/s/ && !$delg_to_us) {
560         zone_warning("we are supposedly published secondary,".
561                      " but not listed as a nameserver",'');
562         map { $fs{$_}=1 } keys(%delgs), keys(%auths);
563         zone_warnmore("servers are: ". join ' ', sort keys %fs);
564     }
565 }
566
567 sub zone_consistency_set ($%) {
568     my ($msg,$set) = @_;
569     my ($d,$o);
570     if (keys(%$set) > 1) {
571         zone_warning("inconsistent $msg:",'');
572         foreach $d (keys %$set) {
573             foreach $o (@{ $set->{$d} }) { zone_warnmore(" $d from $o"); }
574         }
575     }
576 }
577
578 sub zone_check_local () {
579     zone_servers_simplefind();
580     zone_servers_ok();
581 }
582
583 sub zone_servers_simplefind () {
584     my ($rcode,@nsnames,$ns,@soas,$origin);
585
586     ($rcode,@nsnames)= lookup($zone,'ns-','0',"zone's servers");
587     foreach $ns (@nsnames) {
588         zone_ns_name($ns,"NS");
589         zone_server_simple($ns,'NS',0);
590     }
591     $delgs{join ' ', sort @nsnames} = [ "zone's servers" ];
592
593     ($rcode,@soas)= lookup($zone,'soa','0',"SOA ORIGIN");
594     die "multiple SOA RRs in set!  @soas ?" if @soas!=1;
595     $soas[0] =~ m/^(\S+)\s/ or die "SOA ? $_";
596     zone_server_simple(domain_canon($1,"lookup $zone SOA"),'SOA',1);
597 }
598
599 sub zone_server_simple ($$$) {
600     my ($name,$ww,$is_soa) = @_;
601     my ($rcode,@addrs,$addr);
602     ($rcode,@addrs)= lookup($name,'a','0', "server - ".
603                             ($is_soa ? "SOA ORIGIN" : "NS"));
604     foreach $addr (@addrs) { zone_server_addr($addr,$name,$ww,$ww,$is_soa); }
605 }
606
607 #-------------------- outputting
608
609 sub zone_output () {
610     my ($o,$m);
611
612     $o= "zone \"$zone\" {\n";
613     if ($$cfg{'s'} =~ m/p/) {
614         $o.= "    type master;\n";
615     } else {
616         $o.= "    type slave;\n".
617              "    masters {\n";
618         foreach $m (@{ $$cfg{'servers'} }) { $o.= "        $m;\n"; }
619         $o.= "    };\n";
620     }
621     $o.= "    file \"$$cfg{'file'}\";\n";
622     $o.= "};\n";
623     return $o;
624 }
625
626 sub output_files () {
627     my ($fn,$ofn,$mfn,$l,$dir, $maxmode,$h,@to_install);
628     
629     foreach $ofn (keys %output_contents) {
630         $fn= $ofn; $mfn= "output file $fn";
631         for (;;) {
632             if (!lstat $fn) {
633                 $! == &ENOENT or die "$quis: stat $mfn:\n $!\n";
634                 $maxmode= 0666;
635                 last;
636             } elsif (-f _) {
637                 $maxmode= (stat _)[2];
638                 last;
639             } elsif (-l _) {
640                 defined($l= readlink $fn)
641                     or die "$quis: readlink $mfn:\n $!\n";
642                 $dir= $fn =~ m,^.*/, ? $& : './';
643                 $fn= "$dir$l" unless $l =~ m,^/,;
644                 $mfn= "output file $fn (symlink target of $ofn)";
645             } else {
646                 die "$quis: output file $mfn exists but is not a file".
647                     " (or symlink to one)";
648             }
649         }
650         unlink "$fn.new" or $! == &ENOENT or
651             die "$quis: cannot clear out old .new version of $mfn:\n $!";
652         $h= new IO::File "$fn.new",'w',$maxmode
653             or die("$quis: create .new version of $mfn:\n $!");
654         print $h
655             "# generated by $quis, do not edit\n",
656             $output_contents{$ofn}
657             or die "$quis: write data to .new version of $mfn:\n $!";
658         $h->close
659             or die "$quis: close .new version of $mfn:\n $!";
660         push @to_install, $fn,$mfn;
661     }
662
663     while (($fn,$mfn, @to_install) = @to_install) {
664         rename "$fn.new",$fn
665             or die "$quis: install new version of $mfn:\n $!";
666     }
667 }
668
669 #-------------------- general utilities
670
671 sub debug_dump ($) {
672     my ($vn);
673     return unless $debug>1;
674     local $Data::Dumper::Terse=1;
675     foreach $vn (split /\s+/, $_[0]) {
676         print "$vn := ", eval "Dumper(\\$vn)";
677     }
678 }
679
680 sub debug_trace ($) {
681     return unless $debug;
682     print "D $_[0]\n";
683 }
684
685 sub has_suffix_of ($$) {
686     my ($whole,$suffix) = @_;
687     debug_trace("has_suffix_of $whole $suffix");
688     return 0 if length $whole < length $suffix;
689     return 0 if substr($whole, length($whole) - length($suffix)) ne $suffix;
690     debug_trace("has_suffix_of $whole $suffix YES");
691     return 1;
692 }
693
694 sub lookup ($$$$) {
695     my ($domain,$type,$okrcodes,$w) = @_;
696     my ($c,$h,@result);
697     debug_trace("lookup ==> (->$okrcodes) $domain $type");
698     $h= new IO::Handle;
699
700     defined($c= open $h, "-|") or die "$quis: fork adnshost:\n $!\n";
701     if (!$c) {
702         exec 'adnshost','-Fi','+Do','+Dt','+Dc','-Cf',"-t$type",
703              '-',"$domain";
704         die "$quis: exec adnshost:\n $!\n";
705     }
706     @result= $h->getlines();
707     $h->error and die "$quis: read from adnshost:\n $!\n";
708     chomp @result;
709     $!=0; $h->close;
710     die "$quis: lookup -t$type $domain $okrcodes ($w) failed $? $! @result\n"
711         if $! or $?&255 or $?>1536 or index($okrcodes,$?>>8)<0;
712     debug_trace("lookup <== $? @result");
713     return ($?,@result);
714 }
715
716 sub dig (&$$$) {
717     my ($eachrr, $qowner,$qtype,$qaddr) = @_;
718     # also pseudo-rr with type `flags:'
719     my ($h,$inmid,$irdata,$c,$digwhy);
720     local ($_);
721
722     debug_trace("dig ==> \@$qaddr $qowner $qtype");
723
724     $h= new IO::Handle;
725     defined($c= open $h, "-|") or die "$quis: fork dig:\n $!\n";
726     if (!$c) {
727         open STDERR, ">&STDOUT" or die $!;
728         exec ('dig',
729               '+nodef','+nosea','+nodebug','+norecurse',
730               "\@$qaddr",'-t',$qtype,$qowner);
731         die "$quis: exec dig:\n $!\n";
732     }
733     $inmid='';
734     for (;;) {
735         if (!defined($_= $h->getline())) {
736             $h->error() and die "$quis: read from dig:\n $!\n";
737             last;
738         }
739         chomp;
740         if (length $inmid) {
741             s/^\s+/ / or die "$inmid // $_ ?";
742             s/\;.*$//;
743             $_= $inmid.$_;
744             $inmid='';
745             s/$/ \(/ unless s/\s*\)\s*$//;
746         }
747         if (s/\s*\(\s*$//) { $inmid= $_; next; }
748         $digwhy= "dig $qowner $qtype $qaddr \`$_'";
749         if (m/^\;\; flags\:( [-0-9a-z ]+)\;/) {
750             $dig_owner=''; $dig_type='flags:'; $dig_rdata= "$1 ";
751             debug_trace("dig  f: $dig_rdata");
752             &$eachrr;
753         } elsif (m/^\;/) {
754         } elsif (!m/\S/) {
755         } elsif (m/^([-.0-9a-z]+)\s+\d\w+\s+in\s+([a-z]+)\s+(\S.*)/i) {
756             $dig_owner=domain_canon($1,$digwhy); $dig_type=lc $2; $irdata=$3;
757             if ($dig_type eq 'a') {
758                 $irdata =~ m/^[.0-9]+$/ or die "$irdata ?";
759                 $dig_rdata= $&;
760             } elsif ($dig_type eq 'ns') {
761                 $irdata =~ m/^[-.0-9a-z]+$/i or die "bad nameserver $irdata ?";
762                 $dig_rdata= domain_canon($irdata,$digwhy);
763             } elsif ($dig_type eq 'soa') {
764                 $irdata =~ m/^([-.0-9a-z]+)\s+.*\s+(\d+)(?:\s+\d\w+){4}$/i
765                     or die "bad SOA $irdata ?";
766                 $dig_rdata= $2.' '.domain_canon($1,$digwhy);
767             } else {
768                 debug_trace("ignoring uknown RR type $dig_type");
769                 next;
770             }
771             debug_trace("dig  $dig_owner $dig_type $dig_rdata");
772             &$eachrr;
773         } else {
774             debug_trace("ignoring unknown dig output $_");
775         }
776     }
777     $h->close;
778     debug_trace("dig <== gave $?");
779 }
780
781 sub domain_canon ($$) {
782     my ($i,$w) = @_;
783     $i =~ s/(.)\.$/$1/;
784     return '.' if $i eq '.';
785     die "domain $i ($w) ?" unless $i =~ m/^[0-9a-z]/i;
786     return lc $i;
787 }