scripts/named-conf

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use IO::File;
   5 use Data::Dumper;
   6 use POSIX;
   7
   8 use vars qw($quis
   9             $mode $doall
  10             $etcfile $where
  11             $debug $needglue $localonly $verbosity);
  12
  13 $quis= $0; $quis =~ s,.*/,,;
  14
  15 $mode= '';
  16 $doall= 0;
  17 $etcfile= "/etc/bind/chiark-conf-gen.zones";
  18 $where= '<built-in>';
  19 $debug= 0;
  20 $needglue= 2;
  21 $localonly= 0;
  22 $verbosity= 1;
  23
  24 use vars qw($dig_owner $dig_type $dig_rdata);
  25
  26 while (@ARGV && $ARGV[0] =~ m/^\-/) {
  27     $_= shift @ARGV;
  28     if (s/^\-\-//) {
  29         last if m/^$/;
  30         if (m/^(yes|no|force)$/) { m/^./; $mode= $&; }
  31         elsif (m/^all$/) { $doall=1; }
  32         elsif (m/^config$/) { $etcfile= loarg(); $where= '--config option'; }
  33         elsif (m/^glueless$/) { $needglue--; }
  34         elsif (m/^localonly$/) { $localonly=1; }
  35         elsif (m/^quiet$/) { $verbosity=0; }
  36         elsif (m/^verbose$/) { $verbosity=2; }
  37         else { usageerr("unknown option --$_"); }
  38     } else {
  39         s/^\-//;
  40         last if m/^$/;
  41         while (m/^./) {
  42             if (s/^[ynf]//) { $mode=$&; }
  43             elsif (s/^A//) { $doall=1; }
  44             elsif (s/^C//) { $etcfile= soarg(); $where= '-C option'; }
  45             elsif (s/^D//) { $debug++; }
  46             elsif (s/^g//) { $needglue--; }
  47             elsif (s/^l//) { $localonly=1; }
  48             elsif (s/^q//) { $verbosity=0; }
  49             elsif (s/^v//) { $verbosity=2; }
  50             else { usageerr("unknown option -$&"); }
  51         }
  52     }
  53 }
  54
  55 sub loarg() { usageerr("missing option value") if !@ARGV; return shift @ARGV; }
  56 sub soarg() { my ($rv); $rv=$_; $_=''; return length $rv ? $rv : loarg(); }
  57
  58 usageerr("-g may be specified at most twice") if $needglue<0;
  59 usageerr("-D may be specified at most twice") if $debug>2;
  60 usageerr("must specify either -f|-y|-n or zones (and not both)")
  61     if !!$mode == !!@ARGV;
  62
  63 sub usageerr ($) {
  64     die
  65 "$_[0]
  66 usage: named-conf-regen [-rvq] -f|-y|-n|<zone>...\n".
  67 "operation modes:\n".
  68 " -f --force   install without checking\n".
  69 " -y --yes     check and install\n".
  70 " -n --no      check only\n".
  71 "additional options:\n".
  72 " -q --quiet   no output for OK zones\n".
  73 " -v --verbose extra verbose\n";
  74 }
  75
  76 cfg_fail("config filename $etcfile should not be directory")
  77     if $etcfile =~ m,/$,;
  78
  79 use vars qw($default_dir);
  80 $default_dir= $etcfile =~ m,^.*/, ? $& : './';
  81
  82 use vars qw($slave_dir $slave_prefix $slave_suffix);
  83 $slave_dir= 'slave';
  84 $slave_prefix= '';
  85 $slave_suffix= '';
  86
  87 use vars qw(@self_ns @self_soa @self_addr);
  88 @self_ns= @self_soa= @self_addr= ();
  89
  90 use vars qw(%zone_cfg @zone_cfg_list);
  91 %zone_cfg= ();
  92 @zone_cfg_list= ();
  93
  94 use vars qw($output $default_output %output_contents);
  95 $output= '';
  96 $default_output= '';
  97 %output_contents= ();
  98
  99 use vars qw($check $install);
 100 $check= $mode !~ m/^f/;
 101 $install= $mode =~ m/^[yf]/;
 102
 103 read_config($etcfile);
 104 debug_dump('@zone_cfg_list %zone_cfg');
 105 process_zones($mode ? @zone_cfg_list : @ARGV);
 106 debug_dump('%output_contents');
 107 output_files() if $install;
 108
 109 exit 0;
 110
 111 #-------------------- configuration reading
 112
 113 sub cfg_fail ($) { die "$quis: $where:\n $_[0]\n"; }
 114
 115 sub read_config ($) {
 116     my ($if) = @_;
 117     my ($fh,$z,@self,$before,
 118         $mod,$dir,$prefix,$suffix,$subfile,$lprefix,$lsuffix,$zf);
 119     local ($_);
 120
 121     $fh= new IO::File $if,'r' or cfg_fail("open $if:\n $!");
 122     $before= '';
 123     for (;;) {
 124         if (!defined($_= <$fh>)) {
 125             cfg_fail("read config file $if:\n $!") if $fh->error();
 126             last;
 127         }
 128         chomp; s/\s+$//;
 129         if (m/\\$/) { $before.= $_; next; }
 130         $_= $before.$_;
 131         $before= '';
 132         s/^\s+//;
 133         $where= "$if:$.";
 134         next if m/^\#/;
 135         last if m/^end$/;
 136         next unless m/\S/;
 137         if (m/^self(\-ns|\-soa|)\s+(\S.*\S)/) {
 138             @self= split /\s+/, $2;
 139             @self_ns= @self if $1 ne '-soa';
 140             @self_soa= @self if $1 ne '-ns';
 141         } elsif (m/^self\-addr\s+([0-9. \t]+)/) {
 142             @self_addr= split /\s+/, $1;
 143         } elsif (m,^
 144                  primary\-dir ([*?]?)
 145                  \s+ (\S+)/([^/ \t]*)
 146                  (?: \s+ ([^/ \t]*) (?: (/.+) )?
 147                   )?
 148                  $,x) {
 149             ($mod, $dir, $prefix, $suffix, $subfile) =
 150                 ($1,qualify($2),$3,$4,$5);
 151             $suffix= '' if !defined $suffix;
 152             $subfile= '' if !defined $subfile;
 153             $suffix= '_db' if !length $suffix && !length $subfile;
 154             if (-d "$dir/$prefix") { $dir.='/'; $dir.=$prefix; $prefix=''; }
 155             opendir D, $dir or cfg_fail("open primary-dir $dir:\n $!");
 156             $lprefix= length $prefix; $lsuffix= length $suffix;
 157             while (defined($_= readdir D)) {
 158                 next if m/^\./ && !$lprefix;
 159                 next unless length > $lprefix+$lsuffix;
 160                 next unless substr($_,0,$lprefix) eq $prefix;
 161                 next unless substr($_,length($_)-$lsuffix) eq $suffix;
 162                 $z= substr($_,$lprefix,length($_)-($lprefix+$lsuffix));
 163                 $zf= $dir.'/'.$prefix.$z.$suffix.$subfile;
 164                 if (!stat $zf) {
 165                     next if length $subfile && $! == &ENOENT;
 166                     cfg_fail("cannot stat zonefile $zf:\n $!");
 167                 }
 168                 -f _ or cfg_fail("zonefile $zf is not a plain file");
 169                 zone_conf($z,'primary','p',$mod,$zf);
 170             }
 171             closedir D or cfg_fail("close primary-dir $dir:\n $!");
 172         } elsif (m/^primary([*?]?)\s+(\S+)\s+(\S+)$/) {
 173             zone_conf($2,'primary','p',$1,qualify($3));
 174         } elsif (m/^published([*?]?)\s+(\S+)\s+([0-9.\t]+)$/) {
 175             zone_conf($2,'published','s',$1,'',$3);
 176         } elsif (m/^stealth([*?]?)\s+(\S+)\s+([0-9. \t]+)$/) {
 177             zone_conf($2,'stealth','u',$1,'',split /\s+/, $3);
 178         } elsif (m/^slave\-dir\s+(\S+)(?:(?:\s+(\S+))\s+(\S+))?$/) {
 179             ($slave_dir, $slave_prefix, $slave_suffix) = (qualify($1),$2,$3);
 180         } elsif (m/^output\s+bind8\+(\S+)$/) {
 181             cfg_fail("default output may not apply to only some zones")
 182                 if @zone_cfg_list && length $default_output;
 183             set_output(qualify($1));
 184         } elsif (m/^include\s+(\S+)$/) {
 185             read_config($1);
 186         } else {
 187             cfg_fail("unknown configuration directive".
 188                      " or incorrect syntax or arguments");
 189         }
 190     }
 191     $fh->close or cfg_fail("close config file $if:\n $!");
 192 }
 193
 194 sub qualify ($) {
 195     my ($i) = @_;
 196     $i= "$default_dir$i" unless $i =~ m,^/,;
 197     return $i;
 198 }
 199
 200 sub zone_conf ($$$$$@) {
 201     my ($zone,$style,$sabbr,$mod,$file,@servers) = @_;
 202     my ($sfx,$aref);
 203     $file= qualify("$slave_dir/$slave_prefix".$zone.$slave_suffix)
 204         unless length $file;
 205     if (!length $output) {
 206         $default_output= qualify('chiark-conf-gen.bind8')
 207             unless length $default_output;
 208         set_output($default_output);
 209     }
 210     cfg_fail("redefined zone $zone\n".
 211              " earlier definition $zone_cfg{$zone}{'where'}")
 212         if exists $zone_cfg{$zone};
 213     $zone_cfg{$zone}{'where'}= $where;
 214     $zone_cfg{$zone}{'file'}= $file;
 215     $zone_cfg{$zone}{'style_p'}= $style.$mod;
 216     $zone_cfg{$zone}{'s'}= $sabbr.$mod; # p)rimary s)econdary u)npub f)oreign
 217     $zone_cfg{$zone}{'servers'}= [ @servers ];
 218     foreach $sfx (qw(soa ns addr)) {
 219         { no strict 'refs'; $aref= [ @{ "self_$sfx" } ]; }
 220         @$aref or cfg_fail("failed to specify self-$sfx before zone");
 221         $zone_cfg{$zone}{"self_$sfx"}= $aref;
 222     }
 223     $zone_cfg{$zone}{'output'}= $output;
 224     push @zone_cfg_list, $zone;
 225 }
 226
 227 sub set_output($) {
 228     my ($newout) = @_;
 229     $output= $newout;
 230     $output_contents{$output}= '';
 231 }
 232
 233
 234 #-------------------- checking
 235
 236 use vars qw($zone $cfg $warnings);
 237 $warnings= 0;
 238
 239 sub progress ($) {
 240     return if !$verbosity;
 241     print "$_[0]\n";
 242 }
 243
 244 sub verbose ($) {
 245     return if $verbosity<2;
 246     print "    $_[0]\n";
 247 }
 248
 249 sub process_zones (@) {
 250     my (@zones) = @_;
 251     local ($zone,$cfg);
 252
 253     foreach $zone (@zones) {
 254         $cfg= $zone_cfg{$zone} || {
 255             'style_p' => 'foreign',
 256             's' => 'f',
 257             'servers' => [ ],
 258             };
 259         progress(sprintf "%-40s %s", $zone, $$cfg{'style_p'});
 260         if ($check && ($doall || $cfg->{'s'} !~ m/\?/)) {
 261             eval {
 262                 if ($localonly && $cfg->{'s'} =~ m/f/) {
 263                     zone_warning("foreign zone specified with -l");
 264                 } elsif ($cfg->{'s'} =~ m/\*/ ||
 265                          ($localonly && $cfg->{'s'} !~ m/p/)) {
 266                     zone_check_local();
 267                 } else {
 268                     zone_check_full();
 269                 }
 270             };
 271             zone_warning("checks failed: $@") if length $@;
 272         }
 273         zone_output() if $install;
 274     }
 275     print STDERR "$quis: $warnings warnings\n" or die $!
 276         if $warnings;
 277 }
 278
 279 sub zone_warning ($) {
 280     my ($w) = @_;
 281     $w =~ s/\n$//;
 282     $w =~ s,\n, // ,g;
 283     print STDERR "$zone: warning: $w\n" or die $!;
 284     $warnings++;
 285 }
 286
 287 sub zone_warnmore ($) {
 288     print STDERR "$zone:  $_[0]\n" or die $!;
 289 }
 290
 291 use vars qw(%delgs); # $delgs{$nameserver_list} = [ $whosaidandwhy ]
 292 use vars qw(%auths); # $auths{$nameserver_list} = [ $whosaidandwhy ]
 293 use vars qw(%glue);  # $glue{$name}{$addr_list} = [ $whosaidandwhy ]
 294 use vars qw(%soas);  # $soa{"$origin $serial"} = [ $whosaidandwhy ]
 295 use vars qw(%addr_is_ok %warned_glueless %warned_mynameaddr);
 296 use vars qw($delg_to_us);
 297 use vars qw(@to_check); # ($addr,$whyask,$is_auth,$glueless_ok, ...)
 298 use vars qw(@to_check_soa); # ($addr,$whyask, ...)
 299
 300 sub zone_check_full () {
 301     zone_reset();
 302     zone_investigate();
 303     zone_consistency();
 304     zone_servers_ok();
 305 }
 306
 307 sub zone_reset() {
 308     %delgs= %auths= %glue= %soas=
 309         %warned_glueless= %warned_mynameaddr=
 310             %addr_is_ok= ();
 311     $delg_to_us= 0;
 312     @to_check= @to_check_soa= ();
 313 }
 314
 315 sub zone_investigate() {
 316     my ($super_zone, @super_nsnames,
 317         $super_ns, @super_ns_addrs, $s, $wa, $is_auth,
 318         %nsrrset_checked, %soa_checked, $addr, $glueless_ok, $rcode);
 319
 320     $super_zone= $zone;
 321     for (;;) {
 322         debug_trace("zone $zone superzone $super_zone");
 323         $super_zone =~ s/^[^.]+\.// or die "no superzone ? ($super_zone)\n";
 324         ($rcode,@super_nsnames)= lookup($super_zone,'ns-','06');
 325         last if !$rcode;
 326     }
 327     for $super_ns (@super_nsnames) {
 328         $super_ns= lc $super_ns;
 329         ($rcode,@super_ns_addrs)= lookup($super_ns,'a','0');
 330         foreach $addr (@super_ns_addrs) {
 331             push @to_check,
 332                  $addr,
 333                  "$super_ns, server for $super_zone",
 334                  0, 0;
 335         }
 336     }
 337     for (;;) {
 338         # We do these in order so that we always do NS RRset checks on
 339         # nameservers that came from other NS RRsets first; otherwise
 340         # we might set nsrrset_checked due to a glueless_ok check,
 341         # and then not check for gluefulness later.
 342         debug_dump('@to_check @to_check_soa');
 343         if (($addr,$wa,$is_auth,$glueless_ok,@to_check) = @to_check) {
 344             push @to_check_soa, $addr, $wa if $is_auth;
 345             next if $nsrrset_checked{$addr}++;
 346             zone_check_nsrrset($addr, "[$addr] $wa",
 347                                $is_auth, $glueless_ok);
 348         } elsif (($addr,$wa,@to_check_soa) = @to_check_soa) {
 349             next if $soa_checked{$addr}++;
 350             zone_check_soa($addr,"[$addr] $wa","[$addr] NS");
 351         } else {
 352             last;
 353         }
 354     }
 355 }
 356
 357 sub zone_check_nsrrset ($$$$) {
 358     my ($uaddr,$ww, $is_auth, $glueless_ok) = @_;
 359     my (@s, $s, %s2g, @glue, $glue, $delgs_or_auths, $wwn);
 360     verbose("checking delegation by $ww");
 361     dig(sub {
 362         if ($dig_type eq 'ns' && $dig_owner eq $zone) {
 363             $s2g{lc $dig_rdata} = [ ];
 364         } elsif ($dig_type eq 'a' && exists $s2g{$dig_owner}) {
 365             $wwn= "in glue from $ww";
 366             push @to_check, $dig_rdata, "$dig_owner, $wwn", 1, 0;
 367             zone_server_addr($dig_rdata,$dig_owner,$wwn,"NS [$uaddr]",0);
 368             push @{ $s2g{$dig_owner} }, $dig_rdata;
 369         }
 370     },
 371              $zone,'ns',$uaddr);
 372     if (!%s2g) { zone_warning("unable to find NS RRset at $ww"); return; }
 373     elsif (keys %s2g == 1) { zone_warning("only one nameserver at $ww"); }
 374     @s= sort keys %s2g;
 375     foreach $s (@s) {
 376         @glue= @{ $s2g{$s} };
 377         if (!@glue) {
 378             zone_warning("glueless NS $s,".
 379                          ($needglue<=1 ? " (eg)" : "").
 380                          " from $ww")
 381                 unless $glueless_ok || !$needglue ||
 382                        ($needglue<=1 && $warned_glueless{$s}++);
 383             next;
 384         }
 385         $glue= join ' ', sort @glue;
 386         push @{ $glue{$s}{$glue} }, $ww;
 387     }
 388     $s= join ' ', @s;
 389     $delgs_or_auths= $is_auth ? \%auths : \%delgs;
 390     push @{ $delgs_or_auths->{$s} }, $ww;
 391 }
 392
 393 sub zone_server_addr ($$$$$) {
 394     my ($addr,$name,$ww,$wwq,$is_soa) = @_;
 395     $addr_is_ok{$addr}= "$name ($wwq)"
 396         if $is_soa || $cfg->{'s'} =~ m/u/;
 397     zone_warning("configured as stealth but we [$addr]".
 398                  " are published ($name $wwq)")
 399         if $cfg->{'s'} =~ m/u/ && grep { $_ eq $addr } @self_addr;
 400
 401     my ($name_is_self, $addr_is_self);
 402     $name_is_self= grep { $_ eq $name }
 403         @{ $cfg->{$is_soa ? 'self_soa' : 'self_ns'} };
 404     $addr_is_self= grep { $_ eq $addr }
 405         @{ $cfg->{'self_addr'} };
 406     if ($name_is_self && !$addr_is_self) {
 407         zone_warning("our name $name with wrong address [$addr], (eg) $ww")
 408             unless $warned_mynameaddr{$name}{$addr}++;
 409     } elsif (!$name_is_self && $addr_is_self) {
 410         zone_warning(($is_soa ? "SOA ORIGIN maps to" : "allegedly served by").
 411                      " us [$addr] with wrong name $name, (eg) $ww")
 412             unless $warned_mynameaddr{$name}{$addr}++;
 413     }
 414     $delg_to_us=1 if $name_is_self;
 415 }
 416
 417 sub zone_check_soa ($$$) {
 418     my ($uaddr,$ww,$wwq) = @_;
 419     my ($lame,$origin,$got,$rcode,@soa_addrs,$soa_addr,$wwn);
 420     verbose("checking service at $wwq");
 421     $lame= 'dead or lame';
 422     dig(sub {
 423         if ($dig_type eq 'flags:') {
 424             $lame= $dig_rdata =~ m/ aa / ? '' : 'lame';
 425         } elsif ($dig_type eq 'soa' && $dig_owner eq $zone && !$lame) {
 426             die "several SOAs ? $ww" if defined $origin;
 427             $got= $dig_rdata;
 428             $got =~ m/^(\S+) \d+/ or die "$got ?";
 429             $origin= $1;
 430         }
 431     },
 432              $zone,'soa',$uaddr);
 433     $lame= 'broken' if !$lame && !defined $origin;
 434     if ($lame) { zone_warning("$lame server $ww"); return; }
 435     push @{ $soas{$got} }, $ww;
 436     ($rcode,@soa_addrs)= lookup($origin,'a','0');
 437     foreach $soa_addr (@soa_addrs) {
 438         $wwn= "SOA ORIGIN from $ww";
 439         zone_server_addr($soa_addr,$origin,$wwn,"SOA [$uaddr]",1);
 440         push @to_check, $soa_addr, "$origin, $wwn";
 441     }
 442 }
 443
 444 sub zone_consistency() {
 445     my ($d, $org_ser, $origin, $a, $h, $self_soa);
 446     zone_consistency_set('delegations',\%delgs);
 447     foreach $d (keys %delgs) { delete $auths{$d}; }
 448     zone_consistency_set('zone nameserver rrset',\%auths);
 449     foreach $h (keys %glue) {
 450         zone_consistency_set("glue for $h", $glue{$h});
 451     }
 452     zone_consistency_set("SOA ORIGIN and SERIAL",\%soas);
 453     $self_soa= $cfg->{'self_soa'};
 454     if ($cfg->{'s'} =~ m/p/) {
 455         foreach $org_ser (keys %soas) {
 456             $org_ser =~ m/^(\S+) \d+$/ or die "$org_ser ?";
 457             $origin= $1;
 458             next if grep { $_ eq $origin } @$self_soa;
 459             zone_warning("SOA ORIGIN $origin is not our name (@$self_soa),".
 460                          " eg from ".($soas{$org_ser}[0]));
 461         }
 462     }
 463 }
 464
 465 sub zone_servers_ok () {
 466     my ($showok);
 467     if (%addr_is_ok) {
 468         $showok= 0;
 469         foreach $a (@{ $cfg->{'servers'} }) {
 470             next if exists $addr_is_ok{$a};
 471             zone_warning("we slave from $a"); $showok=1;
 472         }
 473         if ($showok) {
 474             foreach $a (keys %addr_is_ok) {
 475                 zone_warnmore("permitted master [$a] $addr_is_ok{$a}");
 476             }
 477         }
 478     }
 479     if ($cfg->{'s'} =~ m/s/ && !$delg_to_us) {
 480         zone_warning("we are supposedly published secondary,".
 481                      " but not listed as a nameserver");
 482     }
 483 }
 484
 485 sub zone_consistency_set ($%) {
 486     my ($msg,$set) = @_;
 487     my ($d,$o);
 488     if (keys(%$set) > 1) {
 489         zone_warning("inconsistent $msg:");
 490         foreach $d (keys %$set) {
 491             foreach $o (@{ $set->{$d} }) { zone_warnmore(" $d from $o"); }
 492         }
 493     }
 494 }
 495
 496 sub zone_check_local () {
 497     zone_reset();
 498     zone_servers_simplefind();
 499     zone_servers_ok();
 500 }
 501
 502 sub zone_servers_simplefind () {
 503     my ($rcode,@nsnames,$ns,@soas,$origin);
 504
 505     ($rcode,@nsnames)= lookup($zone,'ns-','0');
 506     foreach $ns (@nsnames) { zone_server_simple($ns,'NS',0); }
 507
 508     ($rcode,@soas)= lookup($zone,'soa','0');
 509     die "multiple SOA RRs in set!  @soas ?" if @soas!=1;
 510     $soas[0] =~ m/^(\S+)\s/ or die "SOA ? $_";
 511     zone_server_simple(domain_canon($1),'SOA',1);
 512 }
 513
 514 sub zone_server_simple ($$$) {
 515     my ($name,$ww,$is_soa) = @_;
 516     my ($rcode,@addrs,$addr);
 517     ($rcode,@addrs)= lookup($name,'a','0');
 518     foreach $addr (@addrs) { zone_server_addr($addr,$name,$ww,$ww,$is_soa); }
 519 }
 520
 521 #-------------------- outputting
 522
 523 sub zone_output () {
 524     $output_contents{$$cfg{'output'}}.=
 525         sprintf(<<'END',
 526 zone "%s" {
 527     type %s;
 528     file "%s";
 529 };
 530 END
 531                 $zone,
 532                 $$cfg{'s'} =~ m/p/ ? 'master' : 'slave',
 533                 $$cfg{'file'});
 534 }
 535
 536 sub output_files () {
 537     my ($fn,$ofn,$mfn,$l,$dir, $maxmode,$h,@to_install);
 538
 539     foreach $ofn (keys %output_contents) {
 540         $fn= $ofn; $mfn= "output file $fn";
 541         for (;;) {
 542             if (!lstat $fn) {
 543                 $! == &ENOENT or die "$quis: stat $mfn:\n $!\n";
 544                 $maxmode= 0666;
 545                 last;
 546             } elsif (-f _) {
 547                 $maxmode= (stat _)[2];
 548                 last;
 549             } elsif (-l _) {
 550                 defined($l= readlink $fn)
 551                     or die "$quis: readlink $mfn:\n $!\n";
 552                 $dir= $fn =~ m,^.*/, ? $& : './';
 553                 $fn= "$dir$l" unless $l =~ m,^/,;
 554                 $mfn= "output file $fn (symlink target of $ofn)";
 555             } else {
 556                 die "$quis: output file $mfn exists but is not a file".
 557                     " (or symlink to one)";
 558             }
 559         }
 560         unlink "$fn.new" or $! == &ENOENT or
 561             die "$quis: cannot clear out old .new version of $mfn:\n $!";
 562         $h= new IO::File "$fn.new",'w',$maxmode
 563             or die("$quis: create .new version of $mfn:\n $!");
 564         print $h
 565             "# generated by $quis, do not edit\n",
 566             $output_contents{$ofn}
 567             or die "$quis: write data to .new version of $mfn:\n $!";
 568         $h->close
 569             or die "$quis: close .new version of $mfn:\n $!";
 570         push @to_install, $fn,$mfn;
 571     }
 572
 573     while (($fn,$mfn, @to_install) = @to_install) {
 574         rename "$fn.new",$fn
 575             or die "$quis: install new version of $mfn:\n $!";
 576     }
 577 }
 578
 579 #-------------------- general utilities
 580
 581 sub debug_dump ($) {
 582     my ($vn);
 583     return unless $debug>1;
 584     local $Data::Dumper::Terse=1;
 585     foreach $vn (split /\s+/, $_[0]) {
 586         print "$vn := ", eval "Dumper(\\$vn)";
 587     }
 588 }
 589
 590 sub debug_trace ($) {
 591     return unless $debug;
 592     print "D $_[0]\n";
 593 }
 594
 595 sub lookup ($$$) {
 596     my ($domain,$type,$okrcodes) = @_;
 597     my ($c,$h,@result);
 598     debug_trace("lookup ==> (->$okrcodes) $domain $type");
 599     $h= new IO::Handle;
 600
 601     defined($c= open $h, "-|") or die "$quis: fork adnshost:\n $!\n";
 602     if (!$c) {
 603         exec 'adnshost','-Fi','+Do','+Dt','+Dc','-Cf',"-t$type",
 604              '-',"$domain.";
 605         die "$quis: exec adnshost:\n $!\n";
 606     }
 607     @result= $h->getlines();
 608     $h->error and die "$quis: read from adnshost:\n $!\n";
 609     chomp @result;
 610     $!=0; $h->close;
 611     die "$quis: lookup -t$type $domain $okrcodes failed $? $! @result\n"
 612         if $! or $?>6 or index($okrcodes,$?)<0;
 613     debug_trace("lookup <== $? @result");
 614     return ($?,@result);
 615 }
 616
 617
 618 sub dig (&$$$) {
 619     my ($eachrr, $qowner,$qtype,$qaddr) = @_;
 620     # also pseudo-rr with type `flags:'
 621     my ($h,$inmid,$irdata,$c);
 622     local ($_);
 623
 624     debug_trace("dig ==> \@$qaddr $qowner $qtype");
 625
 626     $h= new IO::Handle;
 627     defined($c= open $h, "-|") or die "$quis: fork dig:\n $!\n";
 628     if (!$c) {
 629         open STDERR, ">&STDOUT" or die $!;
 630         exec ('dig',
 631               '+nodef','+nosea','+nodebug','+norecurse',
 632               "\@$qaddr",'-t',$qtype,$qowner);
 633         die "$quis: exec dig:\n $!\n";
 634     }
 635     $inmid='';
 636     for (;;) {
 637         if (!defined($_= $h->getline())) {
 638             $h->error() and die "$quis: read from dig:\n $!\n";
 639             last;
 640         }
 641         chomp;
 642         if (length $inmid) {
 643             s/^\s+/ / or die "$inmid // $_ ?";
 644             s/\;.*$//;
 645             $_= $inmid.$_;
 646             $inmid='';
 647             s/$/ \(/ unless s/\s*\)\s*$//;
 648         }
 649         if (s/\s*\(\s*$//) { $inmid= $_; next; }
 650         if (m/^\;\; flags\:( [-0-9a-z ]+)\;/) {
 651             $dig_owner=''; $dig_type='flags:'; $dig_rdata= "$1 ";
 652             debug_trace("dig  f: $dig_rdata");
 653             &$eachrr;
 654         } elsif (m/^\;/) {
 655         } elsif (!m/\S/) {
 656         } elsif (m/^([-.0-9a-z]+)\s+\d\w+\s+in\s+([a-z]+)\s+(\S.*)/i) {
 657             $dig_owner=domain_canon($1); $dig_type=lc $2; $irdata=$3;
 658             if ($dig_type eq 'a') {
 659                 $irdata =~ m/^[.0-9]+$/ or die "$irdata ?";
 660                 $dig_rdata= $&;
 661             } elsif ($dig_type eq 'ns') {
 662                 $irdata =~ m/^[-.0-9a-z]+$/i or die "bad nameserver $irdata ?";
 663                 $dig_rdata= domain_canon($irdata);
 664             } elsif ($dig_type eq 'soa') {
 665                 $irdata =~ m/^([-.0-9a-z]+)\s+.*\s+(\d+)(?:\s+\d\w+){4}$/i
 666                     or die "bad SOA $irdata ?";
 667                 $dig_rdata= domain_canon($1).' '.$2;
 668             } else {
 669                 debug_trace("ignoring uknown RR type $dig_type");
 670                 next;
 671             }
 672             debug_trace("dig  $dig_owner $dig_type $dig_rdata");
 673             &$eachrr;
 674         } else {
 675             debug_trace("ignoring unknown dig output $_");
 676         }
 677     }
 678     $h->close;
 679     debug_trace("dig <== gave $?");
 680 }
 681
 682 sub domain_canon ($) {
 683     local ($_) = @_;
 684     s/(.)\.$/$1/;
 685     die "domain $_ ?" unless m/^[0-9a-z]/i;
 686     return lc $_;
 687 }