scripts/named-conf

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use IO::File;
   5 use Data::Dumper;
   6 use POSIX;
   7
   8 use vars qw($quis
   9             $mode $doall
  10             $etcfile $where
  11             $debug $needglue $localonly $repeat $verbosity);
  12
  13 $quis= $0; $quis =~ s,.*/,,;
  14
  15 $mode= '';
  16 $doall= 0;
  17 $etcfile= "/etc/bind/chiark-conf-gen.zones";
  18 $where= '<built-in>';
  19 $debug= 0;
  20 $needglue= 1;
  21 $localonly= 0;
  22 $verbosity= 2;
  23 $repeat= 0;
  24
  25 use vars qw($dig_owner $dig_type $dig_rdata);
  26
  27 while (@ARGV && $ARGV[0] =~ m/^\-/) {
  28     $_= shift @ARGV;
  29     if (s/^\-\-//) {
  30         last if m/^$/;
  31         if (m/^(yes|no|force)$/) { m/^./; $mode= $&; }
  32         elsif (m/^all$/) { $doall=1; }
  33         elsif (m/^config$/) { $etcfile= loarg(); $where= '--config option'; }
  34         elsif (m/^glueless$/) { $needglue=0; }
  35         elsif (m/^localonly$/) { $localonly=1; }
  36         elsif (m/^quiet$/) { $verbosity--; }
  37         elsif (m/^repeat$/) { $repeat=1; }
  38         elsif (m/^verbose$/) { $verbosity++; }
  39         else { usageerr("unknown option --$_"); }
  40     } else {
  41         s/^\-//;
  42         last if m/^$/;
  43         while (m/^./) {
  44             if (s/^[ynf]//) { $mode=$&; }
  45             elsif (s/^A//) { $doall=1; }
  46             elsif (s/^C//) { $etcfile= soarg(); $where= '-C option'; }
  47             elsif (s/^D//) { $debug++; }
  48             elsif (s/^g//) { $needglue=0; }
  49             elsif (s/^l//) { $localonly=1; }
  50             elsif (s/^q//) { $verbosity--; }
  51             elsif (s/^r//) { $repeat=1; }
  52             elsif (s/^v//) { $verbosity++; }
  53             else { usageerr("unknown option -$&"); }
  54         }
  55     }
  56 }
  57
  58 sub loarg() { usageerr("missing option value") if !@ARGV; return shift @ARGV; }
  59 sub soarg() { my ($rv); $rv=$_; $_=''; return length $rv ? $rv : loarg(); }
  60
  61 usageerr("-q may be specified at most twice") if $verbosity<0;
  62 usageerr("-v may be specified at most once") if $verbosity>3;
  63 usageerr("-D may be specified at most twice") if $debug>2;
  64 usageerr("must specify either -f|-y|-n or zones (and not both)")
  65     if !!$mode == !!@ARGV;
  66
  67 sub usageerr ($) {
  68     die
  69 "$_[0]
  70 usage: named-conf-regen [options] -f|-y|-n|<zone>...\n".
  71 "operation modes:\n".
  72 " -f --force   install without checking\n".
  73 " -y --yes     check and install\n".
  74 " -n --no      check only\n".
  75 "additional options:\n".
  76 " -A --all       report on zones marked ? (ones we know are broken)\n".
  77 " -D             debug $quis (does not help debug your DNS config)\n".
  78 " -g --glueless  do not warn about any glueless referrals (not recommended)\n".
  79 " -l --localonly full checks only on zones which we primary\n".
  80 " -q --quiet     no output for OK zones\n".
  81 " -r --repeat    repeat warnings for all sources of imperfect data\n".
  82 " -v --verbose   extra verbose info about each zone\n".
  83 " -C|--config <DIR/FILE  use FILE as default config and DIR as default dir\n";
  84 }
  85
  86 cfg_fail("config filename $etcfile should not be directory")
  87     if $etcfile =~ m,/$,;
  88
  89 use vars qw($default_dir);
  90 $default_dir= $etcfile =~ m,^.*/, ? $& : './';
  91
  92 use vars qw($slave_dir $slave_prefix $slave_suffix);
  93 $slave_dir= 'slave';
  94 $slave_prefix= '';
  95 $slave_suffix= '';
  96
  97 use vars qw(@self_ns @self_soa @self_addr @forbid_addr @conv_glueless);
  98 @self_ns= @self_soa= @self_addr= @forbid_addr= ();
  99 @conv_glueless= qw(in-addr.arpa ip6.arpa ip6.int);
 100
 101 use vars qw(%zone_cfg @zone_cfg_list);
 102 %zone_cfg= ();
 103 @zone_cfg_list= ();
 104
 105 use vars qw($output $default_output %output_contents);
 106 $output= '';
 107 $default_output= '';
 108 %output_contents= ();
 109
 110 use vars qw($check $install);
 111 $check= $mode !~ m/^f/;
 112 $install= $mode =~ m/^[yf]/;
 113
 114 read_config($etcfile);
 115 debug_dump('@zone_cfg_list %zone_cfg');
 116 process_zones($mode ? @zone_cfg_list : @ARGV);
 117 debug_dump('%output_contents');
 118 output_files() if $install;
 119
 120 exit 0;
 121
 122 #-------------------- configuration reading
 123
 124 sub cfg_fail ($) { die "$quis: $where:\n $_[0]\n"; }
 125
 126 sub read_config ($) {
 127     my ($if) = @_;
 128     my ($fh,$z,@self,$before,
 129         $mod,$dir,$prefix,$suffix,$subfile,$lprefix,$lsuffix,$zf);
 130     local ($_);
 131
 132     $fh= new IO::File $if,'r' or cfg_fail("open $if:\n $!");
 133     $before= '';
 134     for (;;) {
 135         if (!defined($_= <$fh>)) {
 136             cfg_fail("read config file $if:\n $!") if $fh->error();
 137             last;
 138         }
 139         chomp; s/\s+$//;
 140         if (s/\\$//) { $before.= $_; next; }
 141         $_= $before.$_;
 142         $before= '';
 143         s/^\s+//;
 144         $where= "$if:$.";
 145         next if m/^\#/;
 146         last if m/^end$/;
 147         next unless m/\S/;
 148         if (m/^self(\-ns|\-soa|)\s+(\S.*\S)/) {
 149             @self= split /\s+/, $2;
 150             @self_ns= @self if $1 ne '-soa';
 151             @self_soa= @self if $1 ne '-ns';
 152         } elsif (m/^serverless\-glueless\s+(\S.*\S)/) {
 153             @conv_glueless= split /\s+/, $1;
 154         } elsif (m/^self\-addr\s+([0-9. \t]+)/) {
 155             @self_addr= split /\s+/, $1;
 156         } elsif (m/^forbid\-addr(?:\s+([0-9. \t]+))?/) {
 157             @forbid_addr= defined $1 ? split /\s+/, $1 : ();
 158         } elsif (m,^
 159                  primary\-dir ([*?]?)
 160                  \s+ (\S+)/([^/ \t]*)
 161                  (?: \s+ ([^/ \t]*) (?: (/.+) )?
 162                   )?
 163                  $,x) {
 164             ($mod, $dir, $prefix, $suffix, $subfile) =
 165                 ($1,qualify($2),$3,$4,$5);
 166             $suffix= '' if !defined $suffix;
 167             $subfile= '' if !defined $subfile;
 168             $suffix= '_db' if !length $suffix && !length $subfile;
 169             if (-d "$dir/$prefix") { $dir.='/'; $dir.=$prefix; $prefix=''; }
 170             opendir D, $dir or cfg_fail("open primary-dir $dir:\n $!");
 171             $lprefix= length $prefix; $lsuffix= length $suffix;
 172             while (defined($_= readdir D)) {
 173                 next if m/^\./ && !$lprefix;
 174                 next unless length > $lprefix+$lsuffix;
 175                 next unless substr($_,0,$lprefix) eq $prefix;
 176                 next unless substr($_,length($_)-$lsuffix) eq $suffix;
 177                 $z= substr($_,$lprefix,length($_)-($lprefix+$lsuffix));
 178                 $zf= $dir.'/'.$prefix.$z.$suffix.$subfile;
 179                 if (!stat $zf) {
 180                     next if length $subfile && $! == &ENOENT;
 181                     cfg_fail("cannot stat zonefile $zf:\n $!");
 182                 }
 183                 -f _ or cfg_fail("zonefile $zf is not a plain file");
 184                 zone_conf($z,'primary','p',$mod,$zf);
 185             }
 186             closedir D or cfg_fail("close primary-dir $dir:\n $!");
 187         } elsif (m/^primary([*?]?)\s+(\S+)\s+(\S+)$/) {
 188             zone_conf($2,'primary','p',$1,qualify($3));
 189         } elsif (m/^published([*?]?)\s+(\S+)\s+([0-9.\t]+)$/) {
 190             zone_conf($2,'published','s',$1,'',$3);
 191         } elsif (m/^stealth([*?]?)\s+(\S+)\s+([0-9. \t]+)$/) {
 192             zone_conf($2,'stealth','u',$1,'',split /\s+/, $3);
 193         } elsif (m/^slave\-dir\s+(\S+)(?:(?:\s+(\S+))\s+(\S+))?$/) {
 194             ($slave_dir, $slave_prefix, $slave_suffix) = (qualify($1),$2,$3);
 195             $slave_prefix='' if !defined $slave_prefix;
 196             $slave_suffix='' if !defined $slave_suffix;
 197         } elsif (m/^output\s+bind8\+(\S+)$/) {
 198             cfg_fail("default output may not apply to only some zones")
 199                 if @zone_cfg_list && length $default_output;
 200             set_output(qualify($1));
 201         } elsif (m/^include\s+(\S+)$/) {
 202             read_config($1);
 203         } else {
 204             cfg_fail("unknown configuration directive".
 205                      " or incorrect syntax or arguments:\n".
 206                      " \`$_'");
 207         }
 208     }
 209     $fh->close or cfg_fail("close config file $if:\n $!");
 210 }
 211
 212 sub qualify ($) {
 213     my ($i) = @_;
 214     $i= "$default_dir$i" unless $i =~ m,^/,;
 215     return $i;
 216 }
 217
 218 sub zone_conf ($$$$$@) {
 219     my ($zone,$style,$sabbr,$mod,$file,@servers) = @_;
 220     my ($sfx,$aref);
 221     $file= qualify("$slave_dir/$slave_prefix".$zone.$slave_suffix)
 222         unless length $file;
 223     if (!length $output) {
 224         $default_output= qualify('chiark-conf-gen.bind8')
 225             unless length $default_output;
 226         set_output($default_output);
 227     }
 228     cfg_fail("redefined zone $zone\n".
 229              " earlier definition $zone_cfg{$zone}{'where'}")
 230         if exists $zone_cfg{$zone};
 231     $zone_cfg{$zone}{'where'}= $where;
 232     $zone_cfg{$zone}{'file'}= $file;
 233     $zone_cfg{$zone}{'style_p'}= $style.$mod;
 234     $zone_cfg{$zone}{'s'}= $sabbr.$mod; # p)rimary s)econdary u)npub f)oreign
 235     $zone_cfg{$zone}{'servers'}= [ @servers ];
 236     foreach $sfx (qw(self_soa self_ns self_addr forbid_addr conv_glueless)) {
 237         { no strict 'refs'; $aref= [ @$sfx ]; }
 238         @$aref or cfg_fail("failed to specify $sfx before zone")
 239             if $sfx =~ m/^self/;
 240         $zone_cfg{$zone}{$sfx}= $aref;
 241     }
 242     $zone_cfg{$zone}{'output'}= $output;
 243     push @zone_cfg_list, $zone;
 244 }
 245
 246 sub set_output($) {
 247     my ($newout) = @_;
 248     $output= $newout;
 249     $output_contents{$output}= '';
 250 }
 251
 252
 253 #-------------------- checking
 254
 255 use vars qw($zone $cfg $warnings %zone_warnings);
 256 $warnings= 0;
 257
 258 sub progress ($$) {
 259     my ($minv,$m) = @_;
 260     return if $verbosity < $minv;
 261     print "$m\n";
 262 }
 263
 264 sub verbose ($) { progress(3, '    ' . $_[0]); }
 265
 266 sub process_zones (@) {
 267     my (@zones) = @_;
 268     local ($zone,$cfg);
 269
 270     foreach $zone (@zones) {
 271         zone_reset();
 272         $cfg= $zone_cfg{$zone} || {
 273             'style_p' => 'foreign',
 274             's' => 'f',
 275             'servers' => [ ],
 276             };
 277         progress(1, sprintf "%-20s %s", $zone, $$cfg{'style_p'});
 278         if ($check && ($doall || $cfg->{'s'} !~ m/\?/)) {
 279             eval {
 280                 if ($localonly && $cfg->{'s'} =~ m/f/) {
 281                     zone_warning("foreign zone specified with -l",'');
 282                 } elsif ($cfg->{'s'} =~ m/\*/ ||
 283                          ($localonly && $cfg->{'s'} !~ m/p/)) {
 284                     zone_check_local();
 285                 } else {
 286                     zone_check_full();
 287                 }
 288             };
 289             zone_warning("checks failed: $@",'') if length $@;
 290         }
 291         $output_contents{$$cfg{'output'}} .= zone_output()
 292             if $install;
 293     }
 294     if ($warnings) {
 295         printf STDERR ("%s: %d warning(s) in %d zone(s);".
 296                        " %d zone(s) checked ok.\n",
 297                        $quis,
 298                        $warnings,
 299                        scalar(keys %zone_warnings),
 300                        scalar(@zones - keys %zone_warnings));
 301     } else {
 302         progress(1, sprintf "%d zone(s) checked ok", scalar @zones);
 303     }
 304 }
 305
 306 use vars qw(%delgs); # $delgs{$nameserver_list} = [ $whosaidandwhy ]
 307 use vars qw(%auths); # $auths{$nameserver_list} = [ $whosaidandwhy ]
 308 use vars qw(%glue);  # $glue{$name}{$addr_list} = [ $whosaidandwhy ]
 309 use vars qw(%soas);  # $soa{"$serial $origin"} = [ $whosaidandwhy ]
 310 use vars qw(%addr_is_ok %warned);
 311 use vars qw($delg_to_us);
 312 use vars qw(@to_check); # ($addr,$whyask,$name_if_auth,$glueless_ok, ...)
 313 use vars qw(@to_check_soa); # ($addr,$whyask,$name,$is_ns, ...)
 314
 315 sub zone_warning ($$) {
 316     my ($w,$o) = @_;
 317     my ($wk);
 318
 319     return 0 if !$repeat && $warned{$w}++;
 320
 321     $w =~ s/\n$//;
 322     $w =~ s,\n, // ,g;
 323
 324     $w .= " ($o)" if length $o;
 325     print STDERR "$zone: warning: $w\n" or die $!;
 326     $warnings++;
 327     $zone_warnings{$zone}++;
 328     return 1;
 329 }
 330
 331 sub zone_warnmore ($) {
 332     print STDERR "$zone:  $_[0]\n" or die $!;
 333 }
 334
 335 sub zone_check_full () {
 336     zone_investigate();
 337     zone_consistency();
 338     zone_servers_ok();
 339 }
 340
 341 sub zone_reset() {
 342     %delgs= %auths= %glue= %soas= %warned= %addr_is_ok= ();
 343     $delg_to_us= 0;
 344     @to_check= @to_check_soa= ();
 345 }
 346
 347 sub zone_investigate() {
 348     my ($super_zone, @super_nsnames,
 349         $super_ns, @super_ns_addrs, $s, $wa, $name_if_auth,
 350         %nsrrset_checked, %soa_checked, $addr, $glueless_ok,
 351         $rcode, $name, $is_ns);
 352
 353     $super_zone= $zone;
 354     for (;;) {
 355         debug_trace("zone $zone superzone $super_zone");
 356         $super_zone =~ s/^[^.]+\.// or die "no superzone ? ($super_zone)\n";
 357         ($rcode,@super_nsnames)=
 358             lookup($super_zone,'ns-','06',"superzone search");
 359         last if !$rcode;
 360     }
 361     for $super_ns (@super_nsnames) {
 362         $super_ns= lc $super_ns;
 363         ($rcode,@super_ns_addrs)=
 364             lookup($super_ns,'a','0',"published nameserver");
 365         foreach $addr (@super_ns_addrs) {
 366             push @to_check,
 367                  $addr,
 368                  "$super_ns, server for $super_zone",
 369                  undef, 0;
 370         }
 371     }
 372     for (;;) {
 373         # We do these in order so that we always do NS RRset checks on
 374         # nameservers that came from other NS RRsets first; otherwise
 375         # we might set nsrrset_checked due to a glueless_ok check,
 376         # and then not check for gluefulness later.
 377         debug_dump('@to_check @to_check_soa');
 378         if (($addr,$wa,$name_if_auth,$glueless_ok,@to_check) = @to_check) {
 379             push @to_check_soa, $addr, $wa, $name_if_auth, 1,
 380                 if defined $name_if_auth;
 381             next if $nsrrset_checked{$addr}++;
 382             zone_check_nsrrset($addr, $wa, $name_if_auth, $glueless_ok);
 383         } elsif (($addr,$wa,$name,$is_ns,@to_check_soa) = @to_check_soa) {
 384             next if $soa_checked{$addr}++;
 385             zone_check_soa($addr,$wa,$name,$is_ns);
 386         } else {
 387             last;
 388         }
 389     }
 390 }
 391
 392 sub zone_check_nsrrset ($$$$) {
 393     my ($uaddr,$wa, $name_if_auth, $glueless_ok) = @_;
 394     my (@s, $s, %s2g, @glue, $glue, $delgs_or_auths, $wwn, $ww);
 395     my ($rcode, $sa);
 396     $ww= "[$uaddr] $wa";
 397     verbose("checking delegation by $ww");
 398     dig(sub {
 399         if ($dig_type eq 'ns' && $dig_owner eq $zone) {
 400             $s2g{lc $dig_rdata} = [ ];
 401         } elsif ($dig_type eq 'a' && exists $s2g{$dig_owner}) {
 402             $wwn= "in glue from $ww";
 403             push @to_check, $dig_rdata, "$dig_owner, $wwn", $dig_owner, 0;
 404             push @{ $s2g{$dig_owner} }, $dig_rdata;
 405         }
 406     },
 407              $zone,'ns',$uaddr);
 408     if (!%s2g) {
 409         zone_warning("unable to find NS RRset at [$uaddr]", $wa);
 410         return;
 411     } elsif (keys %s2g == 1) {
 412         zone_warning("only one nameserver ". (join '', keys %s2g),
 413                      $ww);
 414     }
 415     @s= sort keys %s2g;
 416     foreach $s (@s) {
 417         zone_ns_name($s,$ww);
 418         @glue= @{ $s2g{$s} };
 419         if (!@glue) {
 420             zone_warning("glueless NS $s", $ww)
 421                 unless $glueless_ok || !$needglue ||
 422                        grep { has_suffix_of($s,".$_"); }
 423                            @{ $cfg->{'conv_glueless'} };
 424             ($rcode,@glue)= lookup($s,'a','0',"glueless NS from $ww");
 425         }
 426         foreach ($sa) {
 427             zone_server_addr($sa,$s,$wwn,"NS [$uaddr]",0);
 428         }
 429         $glue= join ' ', sort @glue;
 430         push @{ $glue{$s}{$glue} }, $ww;
 431     }
 432     $s= join ' ', @s;
 433     $delgs_or_auths= defined($name_if_auth) ? \%auths : \%delgs;
 434     push @{ $delgs_or_auths->{$s} }, $ww;
 435 }
 436
 437 sub zone_ns_name ($$) {
 438     my ($name,$ww) = @_;
 439     my ($cg);
 440     $delg_to_us=1 if grep { $name eq $_ } @{ $cfg->{'self_ns'} };
 441     foreach $cg (@{ $cfg->{'conv_glueless'} }) {
 442         zone_warning("nameserver $name in serverless-glueless".
 443                      " namespace area $cg",
 444                      $ww)
 445             if has_suffix_of(".$name",".$cg");
 446     }
 447     zone_warning("published server, as $name, but configured as stealth",
 448                  $ww)
 449         if $cfg->{'s'} =~ m/u/ &&
 450            grep { $_ eq $name }
 451                @{ $cfg->{'self_ns'} }, @{ $cfg->{'self_soa'} };
 452 }
 453
 454 sub zone_server_addr ($$$$$) {
 455     my ($addr,$name,$ww,$wwq,$is_soa) = @_;
 456     debug_trace("zone_server_addr ".join '|',@_);
 457     $addr_is_ok{$addr}= "$name ($wwq)"
 458         if $is_soa || $cfg->{'s'} =~ m/u/;
 459     zone_warning("forbidden nameserver address [$addr] $name",$ww)
 460         if grep { $_ eq $addr } @{ $cfg->{'forbid_addr'} };
 461
 462     my ($name_is_self, $addr_is_self);
 463     $name_is_self= grep { $_ eq $name }
 464         @{ $cfg->{$is_soa ? 'self_soa' : 'self_ns'} };
 465     $addr_is_self= grep { $_ eq $addr }
 466         @{ $cfg->{'self_addr'} };
 467     if ($name_is_self && !$addr_is_self) {
 468         zone_warning("our $name supplied with wrong address [$addr]", $ww);
 469     }
 470     if (!$name_is_self && $addr_is_self) {
 471         zone_warning("we [$addr] are named in ".
 472                      ($is_soa ? "SOA" : "NS").
 473                      " by wrong name $name",
 474                      $ww);
 475     }
 476     if (!$name_is_self && !$addr_is_self &&
 477         $is_soa && $cfg->{'s'} =~ m/p/) {
 478         zone_warning("SOA ORIGIN $name is not us (".
 479                      (join ' ', @{ $cfg->{'self_soa'} }).")", $ww);
 480     }
 481     $delg_to_us=1 if $addr_is_self && !$is_soa;
 482 }
 483
 484 sub zone_check_soa ($$$$) {
 485     my ($uaddr,$wa,$name,$is_ns) = @_;
 486     my ($lame,$serial,$origin,$got,$rcode,@soa_addrs,$soa_addr,$ww,$wwn);
 487     verbose("checking service at [$uaddr] $name");
 488     $lame= 'dead or lame';
 489     $ww= "[$uaddr] $wa";
 490     dig(sub {
 491         if ($dig_type eq 'flags:') {
 492             $lame= $dig_rdata =~ m/ aa / ? '' : 'lame';
 493         } elsif ($dig_type eq 'soa' && $dig_owner eq $zone && !$lame) {
 494             die "several SOAs ? $ww" if defined $origin;
 495             $got= $dig_rdata;
 496             $got =~ m/^(\d+) (\S+)$/ or die "$got ?";
 497             ($serial,$origin) = ($1,$2);
 498         }
 499     },
 500              $zone,'soa',$uaddr);
 501     $lame= 'broken' if !$lame && !defined $origin;
 502     if ($lame) { zone_warning("$lame server [$uaddr]",$wa); return; }
 503     progress(2, sprintf "%-16s %46s has %s%s",
 504              $zone, "$name [$uaddr]", $serial, $is_ns ? '' : '*');
 505     push @{ $soas{$got} }, $ww;
 506     ($rcode,@soa_addrs)= lookup($origin,'a','0',"SOA ORIGIN");
 507     $wwn= "SOA ORIGIN from $ww";
 508     foreach $soa_addr (@soa_addrs) {
 509         zone_server_addr($soa_addr,$origin,$wwn,"SOA [$uaddr]",1);
 510         push @to_check, $soa_addr, "$origin, $wwn", $origin, 1;
 511     }
 512 }
 513
 514 sub zone_consistency() {
 515     my ($d, $org_ser, $origin, $a, $h, $self_soa, $wa);
 516     zone_consistency_set('delegations',\%delgs);
 517     foreach $d (keys %delgs) { delete $auths{$d}; }
 518     zone_consistency_set('zone nameserver rrset',\%auths);
 519     foreach $h (keys %glue) {
 520         zone_consistency_set("glue for $h", $glue{$h});
 521     }
 522     zone_consistency_set("serial number and/or SOA ORIGIN",\%soas);
 523     $self_soa= $cfg->{'self_soa'};
 524 }
 525
 526 sub zone_servers_ok () {
 527     my ($showok,%fs);
 528     if (%addr_is_ok) {
 529         $showok= 0;
 530         foreach $a (@{ $cfg->{'servers'} }) {
 531             next if exists $addr_is_ok{$a};
 532             zone_warning("we slave from [$a]",'')
 533                 and $showok=1;
 534         }
 535         if ($showok) {
 536             foreach $a (keys %addr_is_ok) {
 537                 zone_warnmore("permitted master [$a] $addr_is_ok{$a}");
 538             }
 539         }
 540     }
 541     if ($cfg->{'s'} =~ m/s/ && !$delg_to_us) {
 542         zone_warning("we are supposedly published secondary,".
 543                      " but not listed as a nameserver",'');
 544         map { $fs{$_}=1 } keys(%delgs), keys(%auths);
 545         zone_warnmore("servers are: ". join ' ', sort keys %fs);
 546     }
 547 }
 548
 549 sub zone_consistency_set ($%) {
 550     my ($msg,$set) = @_;
 551     my ($d,$o);
 552     if (keys(%$set) > 1) {
 553         zone_warning("inconsistent $msg:",'');
 554         foreach $d (keys %$set) {
 555             foreach $o (@{ $set->{$d} }) { zone_warnmore(" $d from $o"); }
 556         }
 557     }
 558 }
 559
 560 sub zone_check_local () {
 561     zone_servers_simplefind();
 562     zone_servers_ok();
 563 }
 564
 565 sub zone_servers_simplefind () {
 566     my ($rcode,@nsnames,$ns,@soas,$origin);
 567
 568     ($rcode,@nsnames)= lookup($zone,'ns-','0',"zone's servers");
 569     foreach $ns (@nsnames) {
 570         zone_ns_name($ns,"NS");
 571         zone_server_simple($ns,'NS',0);
 572     }
 573
 574     ($rcode,@soas)= lookup($zone,'soa','0',"SOA ORIGIN");
 575     die "multiple SOA RRs in set!  @soas ?" if @soas!=1;
 576     $soas[0] =~ m/^(\S+)\s/ or die "SOA ? $_";
 577     zone_server_simple(domain_canon($1,"lookup $zone SOA"),'SOA',1);
 578 }
 579
 580 sub zone_server_simple ($$$) {
 581     my ($name,$ww,$is_soa) = @_;
 582     my ($rcode,@addrs,$addr);
 583     ($rcode,@addrs)= lookup($name,'a','0', "server - ".
 584                             ($is_soa ? "SOA ORIGIN" : "NS"));
 585     foreach $addr (@addrs) { zone_server_addr($addr,$name,$ww,$ww,$is_soa); }
 586 }
 587
 588 #-------------------- outputting
 589
 590 sub zone_output () {
 591     my ($o,$m);
 592
 593     $o= "zone \"$zone\" {\n";
 594     if ($$cfg{'s'} =~ m/p/) {
 595         $o.= "    type master;\n";
 596     } else {
 597         $o.= "    type slave;\n".
 598              "    masters {\n";
 599         foreach $m (@{ $$cfg{'servers'} }) { $o.= "        $m;\n"; }
 600         $o.= "    };\n";
 601     }
 602     $o.= "    file \"$$cfg{'file'}\";\n";
 603     $o.= "};\n";
 604     return $o;
 605 }
 606
 607 sub output_files () {
 608     my ($fn,$ofn,$mfn,$l,$dir, $maxmode,$h,@to_install);
 609
 610     foreach $ofn (keys %output_contents) {
 611         $fn= $ofn; $mfn= "output file $fn";
 612         for (;;) {
 613             if (!lstat $fn) {
 614                 $! == &ENOENT or die "$quis: stat $mfn:\n $!\n";
 615                 $maxmode= 0666;
 616                 last;
 617             } elsif (-f _) {
 618                 $maxmode= (stat _)[2];
 619                 last;
 620             } elsif (-l _) {
 621                 defined($l= readlink $fn)
 622                     or die "$quis: readlink $mfn:\n $!\n";
 623                 $dir= $fn =~ m,^.*/, ? $& : './';
 624                 $fn= "$dir$l" unless $l =~ m,^/,;
 625                 $mfn= "output file $fn (symlink target of $ofn)";
 626             } else {
 627                 die "$quis: output file $mfn exists but is not a file".
 628                     " (or symlink to one)";
 629             }
 630         }
 631         unlink "$fn.new" or $! == &ENOENT or
 632             die "$quis: cannot clear out old .new version of $mfn:\n $!";
 633         $h= new IO::File "$fn.new",'w',$maxmode
 634             or die("$quis: create .new version of $mfn:\n $!");
 635         print $h
 636             "# generated by $quis, do not edit\n",
 637             $output_contents{$ofn}
 638             or die "$quis: write data to .new version of $mfn:\n $!";
 639         $h->close
 640             or die "$quis: close .new version of $mfn:\n $!";
 641         push @to_install, $fn,$mfn;
 642     }
 643
 644     while (($fn,$mfn, @to_install) = @to_install) {
 645         rename "$fn.new",$fn
 646             or die "$quis: install new version of $mfn:\n $!";
 647     }
 648 }
 649
 650 #-------------------- general utilities
 651
 652 sub debug_dump ($) {
 653     my ($vn);
 654     return unless $debug>1;
 655     local $Data::Dumper::Terse=1;
 656     foreach $vn (split /\s+/, $_[0]) {
 657         print "$vn := ", eval "Dumper(\\$vn)";
 658     }
 659 }
 660
 661 sub debug_trace ($) {
 662     return unless $debug;
 663     print "D $_[0]\n";
 664 }
 665
 666 sub has_suffix_of ($$) {
 667     my ($whole,$suffix) = @_;
 668     debug_trace("has_suffix_of $whole $suffix");
 669     return 0 if length $whole < length $suffix;
 670     return 0 if substr($whole, length($whole) - length($suffix)) ne $suffix;
 671     debug_trace("has_suffix_of $whole $suffix YES");
 672     return 1;
 673 }
 674
 675 sub lookup ($$$$) {
 676     my ($domain,$type,$okrcodes,$w) = @_;
 677     my ($c,$h,@result);
 678     debug_trace("lookup ==> (->$okrcodes) $domain $type");
 679     $h= new IO::Handle;
 680
 681     defined($c= open $h, "-|") or die "$quis: fork adnshost:\n $!\n";
 682     if (!$c) {
 683         exec 'adnshost','-Fi','+Do','+Dt','+Dc','-Cf',"-t$type",
 684              '-',"$domain.";
 685         die "$quis: exec adnshost:\n $!\n";
 686     }
 687     @result= $h->getlines();
 688     $h->error and die "$quis: read from adnshost:\n $!\n";
 689     chomp @result;
 690     $!=0; $h->close;
 691     die "$quis: lookup -t$type $domain $okrcodes ($w) failed $? $! @result\n"
 692         if $! or $?&255 or $?>1536 or index($okrcodes,$?>>8)<0;
 693     debug_trace("lookup <== $? @result");
 694     return ($?,@result);
 695 }
 696
 697 sub dig (&$$$) {
 698     my ($eachrr, $qowner,$qtype,$qaddr) = @_;
 699     # also pseudo-rr with type `flags:'
 700     my ($h,$inmid,$irdata,$c,$digwhy);
 701     local ($_);
 702
 703     debug_trace("dig ==> \@$qaddr $qowner $qtype");
 704
 705     $h= new IO::Handle;
 706     defined($c= open $h, "-|") or die "$quis: fork dig:\n $!\n";
 707     if (!$c) {
 708         open STDERR, ">&STDOUT" or die $!;
 709         exec ('dig',
 710               '+nodef','+nosea','+nodebug','+norecurse',
 711               "\@$qaddr",'-t',$qtype,$qowner);
 712         die "$quis: exec dig:\n $!\n";
 713     }
 714     $inmid='';
 715     for (;;) {
 716         if (!defined($_= $h->getline())) {
 717             $h->error() and die "$quis: read from dig:\n $!\n";
 718             last;
 719         }
 720         chomp;
 721         if (length $inmid) {
 722             s/^\s+/ / or die "$inmid // $_ ?";
 723             s/\;.*$//;
 724             $_= $inmid.$_;
 725             $inmid='';
 726             s/$/ \(/ unless s/\s*\)\s*$//;
 727         }
 728         if (s/\s*\(\s*$//) { $inmid= $_; next; }
 729         $digwhy= "dig $qowner $qtype $qaddr \`$_'";
 730         if (m/^\;\; flags\:( [-0-9a-z ]+)\;/) {
 731             $dig_owner=''; $dig_type='flags:'; $dig_rdata= "$1 ";
 732             debug_trace("dig  f: $dig_rdata");
 733             &$eachrr;
 734         } elsif (m/^\;/) {
 735         } elsif (!m/\S/) {
 736         } elsif (m/^([-.0-9a-z]+)\s+\d\w+\s+in\s+([a-z]+)\s+(\S.*)/i) {
 737             $dig_owner=domain_canon($1,$digwhy); $dig_type=lc $2; $irdata=$3;
 738             if ($dig_type eq 'a') {
 739                 $irdata =~ m/^[.0-9]+$/ or die "$irdata ?";
 740                 $dig_rdata= $&;
 741             } elsif ($dig_type eq 'ns') {
 742                 $irdata =~ m/^[-.0-9a-z]+$/i or die "bad nameserver $irdata ?";
 743                 $dig_rdata= domain_canon($irdata,$digwhy);
 744             } elsif ($dig_type eq 'soa') {
 745                 $irdata =~ m/^([-.0-9a-z]+)\s+.*\s+(\d+)(?:\s+\d\w+){4}$/i
 746                     or die "bad SOA $irdata ?";
 747                 $dig_rdata= $2.' '.domain_canon($1,$digwhy);
 748             } else {
 749                 debug_trace("ignoring uknown RR type $dig_type");
 750                 next;
 751             }
 752             debug_trace("dig  $dig_owner $dig_type $dig_rdata");
 753             &$eachrr;
 754         } else {
 755             debug_trace("ignoring unknown dig output $_");
 756         }
 757     }
 758     $h->close;
 759     debug_trace("dig <== gave $?");
 760 }
 761
 762 sub domain_canon ($$) {
 763     my ($i,$w) = @_;
 764     $i =~ s/(.)\.$/$1/;
 765     return '.' if $i eq '.';
 766     die "domain $i ($w) ?" unless $i =~ m/^[0-9a-z]/i;
 767     return lc $i;
 768 }