scripts/named-conf

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use IO::File;
   5 use Data::Dumper;
   6
   7 use vars qw($quis
   8             $mode $doall
   9             $etcfile $where
  10             $debug $needglue $localonly $verbosity);
  11
  12 $quis= $0; $quis =~ s,.*/,,;
  13
  14 $mode= '';
  15 $doall= 0;
  16 $etcfile= "/etc/bind/chiark-conf-gen.zones";
  17 $where= '<built-in>';
  18 $debug= 0;
  19 $needglue= 2;
  20 $localonly= 0;
  21 $verbosity= 1;
  22
  23 use vars qw($dig_owner $dig_type $dig_rdata);
  24
  25 while (@ARGV && $ARGV[0] =~ m/^\-/) {
  26     $_= shift @ARGV;
  27     if (s/^\-\-//) {
  28         last if m/^$/;
  29         if (m/^(yes|no|force)$/) { m/^./; $mode= $&; }
  30         elsif (m/^all$/) { $doall=1; }
  31         elsif (m/^config$/) { $etcfile= loarg(); $where= '--config option'; }
  32         elsif (m/^glueless$/) { $needglue--; }
  33         elsif (m/^localonly$/) { $localonly=1; }
  34         elsif (m/^quiet$/) { $verbosity=0; }
  35         elsif (m/^verbose$/) { $verbosity=2; }
  36         else { usageerr("unknown option --$_"); }
  37     } else {
  38         s/^\-//;
  39         last if m/^$/;
  40         while (m/^./) {
  41             if (s/^[ynf]//) { $mode=$&; }
  42             elsif (s/^A//) { $doall=1; }
  43             elsif (s/^C//) { $etcfile= soarg(); $where= '-C option'; }
  44             elsif (s/^D//) { $debug++; }
  45             elsif (s/^g//) { $needglue--; }
  46             elsif (s/^l//) { $localonly=1; }
  47             elsif (s/^q//) { $verbosity=0; }
  48             elsif (s/^v//) { $verbosity=2; }
  49             else { usageerr("unknown option -$&"); }
  50         }
  51     }
  52 }
  53
  54 sub loarg() { usageerr("missing option value") if !@ARGV; return shift @ARGV; }
  55 sub soarg() { my ($rv); $rv=$_; $_=''; return length $rv ? $rv : loarg(); }
  56
  57 usageerr("-g may be specified at most twice") if $needglue<0;
  58 usageerr("-D may be specified at most twice") if $debug>2;
  59 usageerr("must specify either -f|-y|-n or zones (and not both)")
  60     if !!$mode == !!@ARGV;
  61
  62 sub usageerr ($) {
  63     die
  64 "$_[0]
  65 usage: named-conf-regen [-rvq] -f|-y|-n|<zone>...\n".
  66 "operation modes:\n".
  67 " -f --force   install without checking\n".
  68 " -y --yes     check and install\n".
  69 " -n --no      check only\n".
  70 "additional options:\n".
  71 " -q --quiet   no output for OK zones\n".
  72 " -v --verbose extra verbose\n";
  73 }
  74
  75 cfg_fail("config filename $etcfile should have been absolute path of a file")
  76     unless $etcfile =~ m,^/, && $etcfile !~ m,/$,;
  77
  78 use vars qw($default_dir);
  79 $default_dir= $etcfile;
  80 $default_dir =~ s,/[^/]+$,,;
  81
  82 use vars qw($slave_dir $slave_prefix $slave_suffix);
  83 $slave_dir= 'slave';
  84 $slave_prefix= '';
  85 $slave_suffix= '';
  86
  87 use vars qw(@self_ns @self_soa @self_addr);
  88 @self_ns= @self_soa= @self_addr= ();
  89
  90 use vars qw(%zone_cfg @zone_cfg_list);
  91 %zone_cfg= ();
  92 @zone_cfg_list= ();
  93
  94 use vars qw($output $default_output %output_contents);
  95 $output= '';
  96 $default_output= '';
  97 %output_contents= ();
  98
  99 use vars qw($check $install);
 100 $check= $mode !~ m/^f/;
 101 $install= $mode =~ m/^[yf]/;
 102
 103 read_config($etcfile);
 104 debug_dump('@zone_cfg_list %zone_cfg');
 105 process_zones($mode ? @zone_cfg_list : @ARGV);
 106 debug_dump('%output_contents');
 107
 108 exit 0;
 109
 110 #-------------------- configuration reading
 111
 112 sub cfg_fail ($) { die "$quis: $where:\n $_[0]\n"; }
 113
 114 sub read_config ($) {
 115     my ($if) = @_;
 116     my ($fh,$z,@self, $mod,$dir,$prefix,$suffix,$lprefix,$lsuffix);
 117     local ($_);
 118
 119     $fh= new IO::File $if,'r' or cfg_fail("open $if:\n $!");
 120     for (;;) {
 121         if (!defined($_= <$fh>)) {
 122             cfg_fail("read config file $if:\n $!") if $fh->error();
 123             last;
 124         }
 125         $where= "$if:$.";
 126         s/^\s+//; chomp; s/\s+$//;
 127         next if m/^\#/;
 128         last if m/^end$/;
 129         next unless m/\S/;
 130         if (m/^self(\-ns|\-soa|)\s+(\S.*\S)/) {
 131             @self= split /\s+/, $2;
 132             @self_ns= @self if $1 ne '-soa';
 133             @self_soa= @self if $1 ne '-ns';
 134         } elsif (m/^self\-addr\s+([0-9. \t]+)/) {
 135             @self_addr= split /\s+/, $1;
 136         } elsif (m/^primary\-dir([*?]?)\s+(\S+)((?:\s+(\S+))?:\s+(\S+))?$/) {
 137             ($mod, $dir, $prefix, $suffix) = ($1,qualify($2),$3,$4);
 138             $suffix= '_db' if !defined $suffix;
 139             $prefix= '' if !defined $prefix;
 140             opendir D, $dir or cfg_fail("open primary-dir $dir:\n $!");
 141             $lprefix= length $prefix; $lsuffix= length $suffix;
 142             while (defined($_= readdir D)) {
 143                 next if m/^\./ && !$lprefix;
 144                 next unless length > $lprefix+$lsuffix;
 145                 next unless substr($_,0,$lprefix) eq $prefix;
 146                 next unless substr($_,length($_)-$lsuffix) eq $suffix;
 147                 $z= substr($_,$lprefix,length($_)-($lprefix+$lsuffix));
 148                 zone_conf($z,'primary','p',$mod,"$dir/$_");
 149             }
 150             closedir D or cfg_fail("close primary-dir $dir:\n $!");
 151         } elsif (m/^primary([*?]?)\s+(\S+)\s+(\S+)$/) {
 152             zone_conf($2,'primary','p',$1,qualify($3));
 153         } elsif (m/^published([*?]?)\s+(\S+)\s+([0-9.\t]+)$/) {
 154             zone_conf($2,'published','s',$1,'',$3);
 155         } elsif (m/^stealth([*?]?)\s+(\S+)\s+([0-9. \t]+)$/) {
 156             zone_conf($2,'stealth','u',$1,'',split /\s+/, $3);
 157         } elsif (m/^slave\-dir\s+(\S+)((?:\s+(\S+))?:\s+(\S+))?$/) {
 158             ($slave_dir, $slave_prefix, $slave_suffix) = (qualify($1),$2,$3);
 159         } elsif (m/^output\s+bind8\+(\S+)$/) {
 160             cfg_fail("default output may not apply to only some zones")
 161                 if @zone_cfg_list && length $default_output;
 162             set_output(qualify($1));
 163         } elsif (m/^include\s+(\S+)$/) {
 164             read_config($1);
 165         } else {
 166             cfg_fail("unknown configuration directive".
 167                      " or incorrect syntax or arguments");
 168         }
 169     }
 170     $fh->close or cfg_fail("close config file $if:\n $!");
 171 }
 172
 173 sub qualify ($) {
 174     my ($i) = @_;
 175     $i= "$default_dir/$i" unless $i =~ m,^/,;
 176     return $i;
 177 }
 178
 179 sub zone_conf ($$$$$@) {
 180     my ($zone,$style,$sabbr,$mod,$file,@servers) = @_;
 181     my ($sfx,$aref);
 182     $file= qualify("$slave_dir/$slave_prefix".$zone.$slave_suffix)
 183         unless length $file;
 184     if (!length $output) {
 185         $default_output= qualify('chiark-conf-gen.bind8')
 186             unless length $default_output;
 187         set_output($default_output);
 188     }
 189     cfg_fail("redefined zone $zone") if exists $zone_cfg{$zone};
 190     $zone_cfg{$zone}{'file'}= $file;
 191     $zone_cfg{$zone}{'style_p'}= $style.$mod;
 192     $zone_cfg{$zone}{'s'}= $sabbr.$mod; # p)rimary s)econdary u)npub f)oreign
 193     $zone_cfg{$zone}{'servers'}= [ @servers ];
 194     foreach $sfx (qw(soa ns addr)) {
 195         { no strict 'refs'; $aref= [ @{ "self_$sfx" } ]; }
 196         @$aref or cfg_fail("failed to specify self-$sfx before zone");
 197         $zone_cfg{$zone}{"self_$sfx"}= $aref;
 198     }
 199     $zone_cfg{$zone}{'output'}= $output;
 200     push @zone_cfg_list, $zone;
 201 }
 202
 203 sub set_output($) {
 204     my ($newout) = @_;
 205     $output= $newout;
 206     $output_contents{$output}= '';
 207 }
 208
 209
 210 #-------------------- checking
 211
 212 use vars qw($zone $cfg $warnings);
 213 $warnings= 0;
 214
 215 sub progress ($) {
 216     return if !$verbosity;
 217     print "$_[0]\n";
 218 }
 219
 220 sub verbose ($) {
 221     return if $verbosity<2;
 222     print "    $_[0]\n";
 223 }
 224
 225 sub process_zones (@) {
 226     my (@zones) = @_;
 227     local ($zone,$cfg);
 228
 229     foreach $zone (@zones) {
 230         $cfg= $zone_cfg{$zone} || {
 231             'style_p' => 'foreign',
 232             's' => 'f',
 233             'servers' => [ ],
 234             };
 235         progress(sprintf "%-40s %s", $zone, $$cfg{'style_p'});
 236         if ($check && ($doall || $cfg->{'s'} !~ m/\?/)) {
 237             eval {
 238                 if ($localonly && $cfg->{'s'} =~ m/f/) {
 239                     zone_warning("foreign zone specified with -l");
 240                 } elsif ($cfg->{'s'} =~ m/\*/ ||
 241                          ($localonly && $cfg->{'s'} !~ m/p/)) {
 242                     zone_check_local();
 243                 } else {
 244                     zone_check_full();
 245                 }
 246             };
 247             zone_warning("checks failed: $@") if length $@;
 248         }
 249         zone_output() if $install;
 250     }
 251     print STDERR "$quis: $warnings warnings\n" or die $!
 252         if $warnings;
 253 }
 254
 255 sub zone_warning ($) {
 256     my ($w) = @_;
 257     $w =~ s/\n$//;
 258     $w =~ s,\n, // ,g;
 259     print STDERR "$zone: warning: $w\n" or die $!;
 260     $warnings++;
 261 }
 262
 263 sub zone_warnmore ($) {
 264     print STDERR " $_[0]\n" or die $!;
 265 }
 266
 267 use vars qw(%delgs); # $delgs{$nameserver_list} = [ $whosaidandwhy ]
 268 use vars qw(%auths); # $auths{$nameserver_list} = [ $whosaidandwhy ]
 269 use vars qw(%glue);  # $glue{$name}{$addr_list} = [ $whosaidandwhy ]
 270 use vars qw(%soas);  # $soa{"$origin $serial"} = [ $whosaidandwhy ]
 271 use vars qw(%addr_is_ok %warned_glueless %warned_mynameaddr);
 272 use vars qw($delg_to_us);
 273 use vars qw(@to_check); # ($addr,$whyask,$is_auth,$glueless_ok, ...)
 274 use vars qw(@to_check_soa); # ($addr,$whyask, ...)
 275
 276 sub zone_check_full () {
 277     zone_reset();
 278     zone_investigate();
 279     zone_consistency();
 280     zone_servers_ok();
 281 }
 282
 283 sub zone_reset() {
 284     %delgs= %auths= %glue= %soas=
 285         %warned_glueless= %warned_mynameaddr=
 286             %addr_is_ok= ();
 287     $delg_to_us= 0;
 288     @to_check= @to_check_soa= ();
 289 }
 290
 291 sub zone_investigate() {
 292     my ($super_zone, @super_nsnames,
 293         $super_ns, @super_ns_addrs, $s, $wa, $is_auth,
 294         %nsrrset_checked, %soa_checked, $addr, $glueless_ok, $rcode);
 295
 296     $super_zone= $zone;
 297     for (;;) {
 298         debug_trace("zone $zone superzone $super_zone");
 299         $super_zone =~ s/^[^.]+\.// or die "no superzone ? ($super_zone)\n";
 300         ($rcode,@super_nsnames)= lookup($super_zone,'ns-','06');
 301         last if !$rcode;
 302     }
 303     for $super_ns (@super_nsnames) {
 304         $super_ns= lc $super_ns;
 305         ($rcode,@super_ns_addrs)= lookup($super_ns,'a','0');
 306         foreach $addr (@super_ns_addrs) {
 307             push @to_check,
 308                  $addr,
 309                  "$super_ns, server for $super_zone",
 310                  0, 0;
 311         }
 312     }
 313     for (;;) {
 314         # We do these in order so that we always do NS RRset checks on
 315         # nameservers that came from other NS RRsets first; otherwise
 316         # we might set nsrrset_checked due to a glueless_ok check,
 317         # and then not check for gluefulness later.
 318         debug_dump('@to_check @to_check_soa');
 319         if (($addr,$wa,$is_auth,$glueless_ok,@to_check) = @to_check) {
 320             push @to_check_soa, $addr, $wa if $is_auth;
 321             next if $nsrrset_checked{$addr}++;
 322             zone_check_nsrrset($addr, "[$addr] $wa",
 323                                $is_auth, $glueless_ok);
 324         } elsif (($addr,$wa,@to_check_soa) = @to_check_soa) {
 325             next if $soa_checked{$addr}++;
 326             zone_check_soa($addr,"[$addr] $wa","[$addr] NS");
 327         } else {
 328             last;
 329         }
 330     }
 331 }
 332
 333 sub zone_check_nsrrset ($$$$) {
 334     my ($uaddr,$ww, $is_auth, $glueless_ok) = @_;
 335     my (@s, $s, %s2g, @glue, $glue, $delgs_or_auths, $wwn);
 336     verbose("checking delegation by $ww");
 337     dig(sub {
 338         if ($dig_type eq 'ns' && $dig_owner eq $zone) {
 339             $s2g{lc $dig_rdata} = [ ];
 340         } elsif ($dig_type eq 'a' && exists $s2g{$dig_owner}) {
 341             $wwn= "in glue from $ww";
 342             push @to_check, $dig_rdata, "$dig_owner, $wwn", 1, 0;
 343             zone_server_addr($dig_rdata,$dig_owner,$wwn,"NS [$uaddr]",0);
 344             push @{ $s2g{$dig_owner} }, $dig_rdata;
 345         }
 346     },
 347              $zone,'ns',$uaddr);
 348     if (!%s2g) { zone_warning("unable to find NS RRset at $ww"); return; }
 349     elsif (keys %s2g == 1) { zone_warning("only one nameserver at $ww"); }
 350     @s= sort keys %s2g;
 351     foreach $s (@s) {
 352         @glue= @{ $s2g{$s} };
 353         if (!@glue) {
 354             zone_warning("glueless NS $s,".
 355                          ($needglue<=1 ? " (eg)" : "").
 356                          " from $ww")
 357                 unless $glueless_ok || !$needglue ||
 358                        ($needglue<=1 && $warned_glueless{$s}++);
 359             next;
 360         }
 361         $glue= join ' ', sort @glue;
 362         push @{ $glue{$s}{$glue} }, $ww;
 363     }
 364     $s= join ' ', @s;
 365     $delgs_or_auths= $is_auth ? \%auths : \%delgs;
 366     push @{ $delgs_or_auths->{$s} }, $ww;
 367 }
 368
 369 sub zone_server_addr ($$$$$) {
 370     my ($addr,$name,$ww,$wwq,$is_soa) = @_;
 371     $addr_is_ok{$addr}= "$name ($wwq)"
 372         if $is_soa || $cfg->{'s'} =~ m/u/;
 373     zone_warning("configured as stealth but we [$addr]".
 374                  " are published ($name $wwq)")
 375         if $cfg->{'s'} =~ m/u/ && grep { $_ eq $addr } @self_addr;
 376
 377     my ($name_is_self, $addr_is_self);
 378     $name_is_self= grep { $_ eq $name }
 379         @{ $cfg->{$is_soa ? 'self_soa' : 'self_ns'} };
 380     $addr_is_self= grep { $_ eq $addr }
 381         @{ $cfg->{'self_addr'} };
 382     if ($name_is_self && !$addr_is_self) {
 383         zone_warning("our name $name with wrong address [$addr], (eg) $ww")
 384             unless $warned_mynameaddr{$name}{$addr}++;
 385     } elsif (!$name_is_self && $addr_is_self) {
 386         zone_warning(($is_soa ? "SOA ORIGIN maps to" : "allegedly served by").
 387                      " us [$addr] with wrong name $name, (eg) $ww")
 388             unless $warned_mynameaddr{$name}{$addr}++;
 389     }
 390     $delg_to_us=1 if $name_is_self;
 391 }
 392
 393 sub zone_check_soa ($$$) {
 394     my ($uaddr,$ww,$wwq) = @_;
 395     my ($lame,$origin,$got,$rcode,@soa_addrs,$soa_addr,$wwn);
 396     verbose("checking service at $wwq");
 397     $lame= 'dead or lame';
 398     dig(sub {
 399         if ($dig_type eq 'flags:') {
 400             $lame= $dig_rdata =~ m/ aa / ? '' : 'lame';
 401         } elsif ($dig_type eq 'soa' && $dig_owner eq $zone && !$lame) {
 402             die "several SOAs ? $ww" if defined $origin;
 403             $got= $dig_rdata;
 404             $got =~ m/^(\S+) \d+/ or die "$got ?";
 405             $origin= $1;
 406         }
 407     },
 408              $zone,'soa',$uaddr);
 409     $lame= 'broken' if !$lame && !defined $origin;
 410     if ($lame) { zone_warning("$lame server $ww"); return; }
 411     push @{ $soas{$got} }, $ww;
 412     ($rcode,@soa_addrs)= lookup($origin,'a','0');
 413     foreach $soa_addr (@soa_addrs) {
 414         $wwn= "SOA ORIGIN from $ww";
 415         zone_server_addr($soa_addr,$origin,$wwn,"SOA [$uaddr]",1);
 416         push @to_check, $soa_addr, "$origin, $wwn";
 417     }
 418 }
 419
 420 sub zone_consistency() {
 421     my ($d, $org_ser, $origin, $a, $h, $self_soa);
 422     zone_consistency_set('delegations',\%delgs);
 423     foreach $d (keys %delgs) { delete $auths{$d}; }
 424     zone_consistency_set('zone nameserver rrset',\%auths);
 425     foreach $h (keys %glue) {
 426         zone_consistency_set("glue for $h", $glue{$h});
 427     }
 428     zone_consistency_set("SOA ORIGIN and SERIAL",\%soas);
 429     $self_soa= $cfg->{'self_soa'};
 430     if ($cfg->{'s'} =~ m/p/) {
 431         foreach $org_ser (keys %soas) {
 432             $org_ser =~ m/^(\S+) \d+$/ or die "$org_ser ?";
 433             $origin= $1;
 434             next if grep { $_ eq $origin } @$self_soa;
 435             zone_warning("SOA ORIGIN $origin is not our name (@$self_soa),".
 436                          " eg from ".($soas{$org_ser}[0]));
 437         }
 438     }
 439 }
 440
 441 sub zone_servers_ok () {
 442     my ($showok);
 443     if (%addr_is_ok) {
 444         $showok= 0;
 445         foreach $a (@{ $cfg->{'servers'} }) {
 446             next if exists $addr_is_ok{$a};
 447             zone_warning("we slave from $a"); $showok=1;
 448         }
 449         if ($showok) {
 450             foreach $a (keys %addr_is_ok) {
 451                 zone_warnmore("permitted master [$a] $addr_is_ok{$a}");
 452             }
 453         }
 454     }
 455     if ($cfg->{'s'} =~ m/s/ && !$delg_to_us) {
 456         zone_warnmore("we are supposedly published secondary,".
 457                       " but not listed as a nameserver");
 458     }
 459 }
 460
 461 sub zone_consistency_set ($%) {
 462     my ($msg,$set) = @_;
 463     my ($d,$o);
 464     if (keys(%$set) > 1) {
 465         zone_warning("inconsistent $msg:");
 466         foreach $d (keys %$set) {
 467             foreach $o (@{ $set->{$d} }) { zone_warnmore(" $d from $o"); }
 468         }
 469     }
 470 }
 471
 472 sub zone_check_local () {
 473     zone_reset();
 474     zone_servers_simplefind();
 475     zone_servers_ok();
 476 }
 477
 478 sub zone_servers_simplefind () {
 479     my ($rcode,@nsnames,$ns,@soas,$origin);
 480
 481     ($rcode,@nsnames)= lookup($zone,'ns-','0');
 482     foreach $ns (@nsnames) { zone_server_simple($ns,'NS',0); }
 483
 484     ($rcode,@soas)= lookup($zone,'soa','0');
 485     die "multiple SOA RRs in set!  @soas ?" if @soas!=1;
 486     $soas[0] =~ m/^(\S+)\s/ or die "SOA ? $_";
 487     zone_server_simple(domain_canon($1),'SOA',1);
 488 }
 489
 490 sub zone_server_simple ($$$) {
 491     my ($name,$ww,$is_soa) = @_;
 492     my ($rcode,@addrs,$addr);
 493     ($rcode,@addrs)= lookup($name,'a','0');
 494     foreach $addr (@addrs) { zone_server_addr($addr,$name,$ww,$ww,$is_soa); }
 495 }
 496
 497 #-------------------- outputting
 498
 499 sub zone_output () {
 500     $output_contents{$$cfg{'output'}}.=
 501         sprintf(<<'END',
 502 zone "%s" {
 503     type %s;
 504     file "%s";
 505 };
 506 END
 507                 $zone,
 508                 $$cfg{'s'} =~ m/p/ ? 'master' : 'slave',
 509                 $$cfg{'file'});
 510 }
 511
 512
 513 #-------------------- general utilities
 514
 515 sub debug_dump ($) {
 516     my ($vn);
 517     return unless $debug>1;
 518     local $Data::Dumper::Terse=1;
 519     foreach $vn (split /\s+/, $_[0]) {
 520         print "$vn := ", eval "Dumper(\\$vn)";
 521     }
 522 }
 523
 524 sub debug_trace ($) {
 525     return unless $debug;
 526     print "D $_[0]\n";
 527 }
 528
 529 sub lookup ($$$) {
 530     my ($domain,$type,$okrcodes) = @_;
 531     my ($c,$h,@result);
 532     debug_trace("lookup ==> (->$okrcodes) $domain $type");
 533     $h= new IO::Handle;
 534
 535     defined($c= open $h, "-|") or die "$quis: fork adnshost:\n $!\n";
 536     if (!$c) {
 537         exec 'adnshost','-Fi','+Do','+Dt','+Dc','-Cf',"-t$type",
 538              '-',"$domain.";
 539         die "$quis: exec adnshost:\n $!\n";
 540     }
 541     @result= $h->getlines();
 542     $h->error and die "$quis: read from adnshost:\n $!\n";
 543     chomp @result;
 544     $!=0; $h->close;
 545     die "$quis: lookup -t$type $domain $okrcodes failed $? $!\n"
 546         if $! or $?>6 or index($okrcodes,$?)<0;
 547     debug_trace("lookup <== $? @result");
 548     return ($?,@result);
 549 }
 550
 551
 552 sub dig (&$$$) {
 553     my ($eachrr, $qowner,$qtype,$qaddr) = @_;
 554     # also pseudo-rr with type `flags:'
 555     my ($h,$inmid,$irdata,$c);
 556     local ($_);
 557
 558     debug_trace("dig ==> \@$qaddr $qowner $qtype");
 559
 560     $h= new IO::Handle;
 561     defined($c= open $h, "-|") or die "$quis: fork dig:\n $!\n";
 562     if (!$c) {
 563         open STDERR, ">&STDOUT" or die $!;
 564         exec ('dig',
 565               '+nodef','+nosea','+nodebug','+norecurse',
 566               "\@$qaddr",'-t',$qtype,$qowner);
 567         die "$quis: exec dig:\n $!\n";
 568     }
 569     $inmid='';
 570     for (;;) {
 571         if (!defined($_= $h->getline())) {
 572             $h->error() and die "$quis: read from dig:\n $!\n";
 573             last;
 574         }
 575         chomp;
 576         if (length $inmid) {
 577             s/^\s+/ / or die "$inmid // $_ ?";
 578             s/\;.*$//;
 579             $_= $inmid.$_;
 580             $inmid='';
 581             s/$/ \(/ unless s/\s*\)\s*$//;
 582         }
 583         if (s/\s*\(\s*$//) { $inmid= $_; next; }
 584         if (m/^\;\; flags\:( [-0-9a-z ]+)\;/) {
 585             $dig_owner=''; $dig_type='flags:'; $dig_rdata= "$1 ";
 586             debug_trace("dig  f: $dig_rdata");
 587             &$eachrr;
 588         } elsif (m/^\;/) {
 589         } elsif (!m/\S/) {
 590         } elsif (m/^([-.0-9a-z]+)\s+\d\w+\s+in\s+([a-z]+)\s+(\S.*)/i) {
 591             $dig_owner=domain_canon($1); $dig_type=lc $2; $irdata=$3;
 592             if ($dig_type eq 'a') {
 593                 $irdata =~ m/^[.0-9]+$/ or die "$irdata ?";
 594                 $dig_rdata= $&;
 595             } elsif ($dig_type eq 'ns') {
 596                 $irdata =~ m/^[-.0-9a-z]+$/i or die "bad nameserver $irdata ?";
 597                 $dig_rdata= domain_canon($irdata);
 598             } elsif ($dig_type eq 'soa') {
 599                 $irdata =~ m/^([-.0-9a-z]+)\s+.*\s+(\d+)(?:\s+\d\w+){4}$/i
 600                     or die "bad SOA $irdata ?";
 601                 $dig_rdata= domain_canon($1).' '.$2;
 602             } else {
 603                 debug_trace("ignoring uknown RR type $dig_type");
 604                 next;
 605             }
 606             debug_trace("dig  $dig_owner $dig_type $dig_rdata");
 607             &$eachrr;
 608         } else {
 609             debug_trace("ignoring unknown dig output $_");
 610         }
 611     }
 612     $h->close;
 613     debug_trace("dig <== gave $?");
 614 }
 615
 616 sub domain_canon ($) {
 617     local ($_) = @_;
 618     s/(.)\.$/$1/;
 619     die "domain $_ ?" unless m/^[0-9a-z]/i;
 620     return lc $_;
 621 }