scripts/named-conf

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use IO::File;
   5 use Data::Dumper;
   6 use POSIX;
   7
   8 use vars qw($quis
   9             $mode $doall
  10             $etcfile $where
  11             $debug $needglue $localonly $repeat $verbosity);
  12
  13 $quis= $0; $quis =~ s,.*/,,;
  14
  15 $mode= '';
  16 $doall= 0;
  17 $etcfile= "/etc/bind/chiark-conf-gen.zones";
  18 $where= '<built-in>';
  19 $debug= 0;
  20 $needglue= 1;
  21 $localonly= 0;
  22 $verbosity= 1;
  23 $repeat= 0;
  24
  25 use vars qw($dig_owner $dig_type $dig_rdata);
  26
  27 while (@ARGV && $ARGV[0] =~ m/^\-/) {
  28     $_= shift @ARGV;
  29     if (s/^\-\-//) {
  30         last if m/^$/;
  31         if (m/^(yes|no|force)$/) { m/^./; $mode= $&; }
  32         elsif (m/^all$/) { $doall=1; }
  33         elsif (m/^config$/) { $etcfile= loarg(); $where= '--config option'; }
  34         elsif (m/^glueless$/) { $needglue=0; }
  35         elsif (m/^localonly$/) { $localonly=1; }
  36         elsif (m/^quiet$/) { $verbosity=0; }
  37         elsif (m/^repeat$/) { $repeat=1; }
  38         elsif (m/^verbose$/) { $verbosity=2; }
  39         else { usageerr("unknown option --$_"); }
  40     } else {
  41         s/^\-//;
  42         last if m/^$/;
  43         while (m/^./) {
  44             if (s/^[ynf]//) { $mode=$&; }
  45             elsif (s/^A//) { $doall=1; }
  46             elsif (s/^C//) { $etcfile= soarg(); $where= '-C option'; }
  47             elsif (s/^D//) { $debug++; }
  48             elsif (s/^g//) { $needglue=0; }
  49             elsif (s/^l//) { $localonly=1; }
  50             elsif (s/^q//) { $verbosity=0; }
  51             elsif (s/^r//) { $repeat=1; }
  52             elsif (s/^v//) { $verbosity=2; }
  53             else { usageerr("unknown option -$&"); }
  54         }
  55     }
  56 }
  57
  58 sub loarg() { usageerr("missing option value") if !@ARGV; return shift @ARGV; }
  59 sub soarg() { my ($rv); $rv=$_; $_=''; return length $rv ? $rv : loarg(); }
  60
  61 usageerr("-D may be specified at most twice") if $debug>2;
  62 usageerr("must specify either -f|-y|-n or zones (and not both)")
  63     if !!$mode == !!@ARGV;
  64
  65 sub usageerr ($) {
  66     die
  67 "$_[0]
  68 usage: named-conf-regen [options] -f|-y|-n|<zone>...\n".
  69 "operation modes:\n".
  70 " -f --force   install without checking\n".
  71 " -y --yes     check and install\n".
  72 " -n --no      check only\n".
  73 "additional options:\n".
  74 " -A --all       report on zones marked ? (ones we know are broken)\n".
  75 " -D             debug $quis (does not help debug your DNS config)\n".
  76 " -g --glueless  do not warn about any glueless referrals (not recommended)\n".
  77 " -l --localonly full checks only on zones which we primary\n".
  78 " -q --quiet     no output for OK zones\n".
  79 " -r --repeat    repeat warnings for all sources of imperfect data\n".
  80 " -v --verbose   extra verbose info about each zone\n".
  81 " -C|--config <DIR/FILE  use FILE as default config and DIR as default dir\n";
  82 }
  83
  84 cfg_fail("config filename $etcfile should not be directory")
  85     if $etcfile =~ m,/$,;
  86
  87 use vars qw($default_dir);
  88 $default_dir= $etcfile =~ m,^.*/, ? $& : './';
  89
  90 use vars qw($slave_dir $slave_prefix $slave_suffix);
  91 $slave_dir= 'slave';
  92 $slave_prefix= '';
  93 $slave_suffix= '';
  94
  95 use vars qw(@self_ns @self_soa @self_addr @forbid_addr @conv_glueless);
  96 @self_ns= @self_soa= @self_addr= @forbid_addr= ();
  97 @conv_glueless= qw(in-addr.arpa ip6.arpa ip6.int);
  98
  99 use vars qw(%zone_cfg @zone_cfg_list);
 100 %zone_cfg= ();
 101 @zone_cfg_list= ();
 102
 103 use vars qw($output $default_output %output_contents);
 104 $output= '';
 105 $default_output= '';
 106 %output_contents= ();
 107
 108 use vars qw($check $install);
 109 $check= $mode !~ m/^f/;
 110 $install= $mode =~ m/^[yf]/;
 111
 112 read_config($etcfile);
 113 debug_dump('@zone_cfg_list %zone_cfg');
 114 process_zones($mode ? @zone_cfg_list : @ARGV);
 115 debug_dump('%output_contents');
 116 output_files() if $install;
 117
 118 exit 0;
 119
 120 #-------------------- configuration reading
 121
 122 sub cfg_fail ($) { die "$quis: $where:\n $_[0]\n"; }
 123
 124 sub read_config ($) {
 125     my ($if) = @_;
 126     my ($fh,$z,@self,$before,
 127         $mod,$dir,$prefix,$suffix,$subfile,$lprefix,$lsuffix,$zf);
 128     local ($_);
 129
 130     $fh= new IO::File $if,'r' or cfg_fail("open $if:\n $!");
 131     $before= '';
 132     for (;;) {
 133         if (!defined($_= <$fh>)) {
 134             cfg_fail("read config file $if:\n $!") if $fh->error();
 135             last;
 136         }
 137         chomp; s/\s+$//;
 138         if (s/\\$//) { $before.= $_; next; }
 139         $_= $before.$_;
 140         $before= '';
 141         s/^\s+//;
 142         $where= "$if:$.";
 143         next if m/^\#/;
 144         last if m/^end$/;
 145         next unless m/\S/;
 146         if (m/^self(\-ns|\-soa|)\s+(\S.*\S)/) {
 147             @self= split /\s+/, $2;
 148             @self_ns= @self if $1 ne '-soa';
 149             @self_soa= @self if $1 ne '-ns';
 150         } elsif (m/^serverless\-glueless\s+(\S.*\S)/) {
 151             @conv_glueless= split /\s+/, $1;
 152         } elsif (m/^self\-addr\s+([0-9. \t]+)/) {
 153             @self_addr= split /\s+/, $1;
 154         } elsif (m/^forbid\-addr(?:\s+([0-9. \t]+))?/) {
 155             @forbid_addr= defined $1 ? split /\s+/, $1 : ();
 156         } elsif (m,^
 157                  primary\-dir ([*?]?)
 158                  \s+ (\S+)/([^/ \t]*)
 159                  (?: \s+ ([^/ \t]*) (?: (/.+) )?
 160                   )?
 161                  $,x) {
 162             ($mod, $dir, $prefix, $suffix, $subfile) =
 163                 ($1,qualify($2),$3,$4,$5);
 164             $suffix= '' if !defined $suffix;
 165             $subfile= '' if !defined $subfile;
 166             $suffix= '_db' if !length $suffix && !length $subfile;
 167             if (-d "$dir/$prefix") { $dir.='/'; $dir.=$prefix; $prefix=''; }
 168             opendir D, $dir or cfg_fail("open primary-dir $dir:\n $!");
 169             $lprefix= length $prefix; $lsuffix= length $suffix;
 170             while (defined($_= readdir D)) {
 171                 next if m/^\./ && !$lprefix;
 172                 next unless length > $lprefix+$lsuffix;
 173                 next unless substr($_,0,$lprefix) eq $prefix;
 174                 next unless substr($_,length($_)-$lsuffix) eq $suffix;
 175                 $z= substr($_,$lprefix,length($_)-($lprefix+$lsuffix));
 176                 $zf= $dir.'/'.$prefix.$z.$suffix.$subfile;
 177                 if (!stat $zf) {
 178                     next if length $subfile && $! == &ENOENT;
 179                     cfg_fail("cannot stat zonefile $zf:\n $!");
 180                 }
 181                 -f _ or cfg_fail("zonefile $zf is not a plain file");
 182                 zone_conf($z,'primary','p',$mod,$zf);
 183             }
 184             closedir D or cfg_fail("close primary-dir $dir:\n $!");
 185         } elsif (m/^primary([*?]?)\s+(\S+)\s+(\S+)$/) {
 186             zone_conf($2,'primary','p',$1,qualify($3));
 187         } elsif (m/^published([*?]?)\s+(\S+)\s+([0-9.\t]+)$/) {
 188             zone_conf($2,'published','s',$1,'',$3);
 189         } elsif (m/^stealth([*?]?)\s+(\S+)\s+([0-9. \t]+)$/) {
 190             zone_conf($2,'stealth','u',$1,'',split /\s+/, $3);
 191         } elsif (m/^slave\-dir\s+(\S+)(?:(?:\s+(\S+))\s+(\S+))?$/) {
 192             ($slave_dir, $slave_prefix, $slave_suffix) = (qualify($1),$2,$3);
 193             $slave_prefix='' if !defined $slave_prefix;
 194             $slave_suffix='' if !defined $slave_suffix;
 195         } elsif (m/^output\s+bind8\+(\S+)$/) {
 196             cfg_fail("default output may not apply to only some zones")
 197                 if @zone_cfg_list && length $default_output;
 198             set_output(qualify($1));
 199         } elsif (m/^include\s+(\S+)$/) {
 200             read_config($1);
 201         } else {
 202             cfg_fail("unknown configuration directive".
 203                      " or incorrect syntax or arguments:\n".
 204                      " \`$_'");
 205         }
 206     }
 207     $fh->close or cfg_fail("close config file $if:\n $!");
 208 }
 209
 210 sub qualify ($) {
 211     my ($i) = @_;
 212     $i= "$default_dir$i" unless $i =~ m,^/,;
 213     return $i;
 214 }
 215
 216 sub zone_conf ($$$$$@) {
 217     my ($zone,$style,$sabbr,$mod,$file,@servers) = @_;
 218     my ($sfx,$aref);
 219     $file= qualify("$slave_dir/$slave_prefix".$zone.$slave_suffix)
 220         unless length $file;
 221     if (!length $output) {
 222         $default_output= qualify('chiark-conf-gen.bind8')
 223             unless length $default_output;
 224         set_output($default_output);
 225     }
 226     cfg_fail("redefined zone $zone\n".
 227              " earlier definition $zone_cfg{$zone}{'where'}")
 228         if exists $zone_cfg{$zone};
 229     $zone_cfg{$zone}{'where'}= $where;
 230     $zone_cfg{$zone}{'file'}= $file;
 231     $zone_cfg{$zone}{'style_p'}= $style.$mod;
 232     $zone_cfg{$zone}{'s'}= $sabbr.$mod; # p)rimary s)econdary u)npub f)oreign
 233     $zone_cfg{$zone}{'servers'}= [ @servers ];
 234     foreach $sfx (qw(self_soa self_ns self_addr forbid_addr conv_glueless)) {
 235         { no strict 'refs'; $aref= [ @$sfx ]; }
 236         @$aref or cfg_fail("failed to specify $sfx before zone")
 237             if $sfx =~ m/^self/;
 238         $zone_cfg{$zone}{$sfx}= $aref;
 239     }
 240     $zone_cfg{$zone}{'output'}= $output;
 241     push @zone_cfg_list, $zone;
 242 }
 243
 244 sub set_output($) {
 245     my ($newout) = @_;
 246     $output= $newout;
 247     $output_contents{$output}= '';
 248 }
 249
 250
 251 #-------------------- checking
 252
 253 use vars qw($zone $cfg $warnings %zone_warnings);
 254 $warnings= 0;
 255
 256 sub progress ($) {
 257     return if !$verbosity;
 258     print "$_[0]\n";
 259 }
 260
 261 sub verbose ($) {
 262     return if $verbosity<2;
 263     print "    $_[0]\n";
 264 }
 265
 266 sub process_zones (@) {
 267     my (@zones) = @_;
 268     local ($zone,$cfg);
 269
 270     foreach $zone (@zones) {
 271         zone_reset();
 272         $cfg= $zone_cfg{$zone} || {
 273             'style_p' => 'foreign',
 274             's' => 'f',
 275             'servers' => [ ],
 276             };
 277         progress(sprintf "%-40s %s", $zone, $$cfg{'style_p'});
 278         if ($check && ($doall || $cfg->{'s'} !~ m/\?/)) {
 279             eval {
 280                 if ($localonly && $cfg->{'s'} =~ m/f/) {
 281                     zone_warning("foreign zone specified with -l",'');
 282                 } elsif ($cfg->{'s'} =~ m/\*/ ||
 283                          ($localonly && $cfg->{'s'} !~ m/p/)) {
 284                     zone_check_local();
 285                 } else {
 286                     zone_check_full();
 287                 }
 288             };
 289             zone_warning("checks failed: $@",'') if length $@;
 290         }
 291         $output_contents{$$cfg{'output'}} .= zone_output()
 292             if $install;
 293     }
 294     if ($warnings) {
 295         printf STDERR ("%s: %d warning(s) in %d zone(s);".
 296                        " %d zone(s) checked ok.\n",
 297                        $quis,
 298                        $warnings,
 299                        scalar(keys %zone_warnings),
 300                        scalar(@zones - keys %zone_warnings));
 301     } else {
 302         progress(sprintf "%d zone(s) checked ok", scalar @zones);
 303     }
 304 }
 305
 306 use vars qw(%delgs); # $delgs{$nameserver_list} = [ $whosaidandwhy ]
 307 use vars qw(%auths); # $auths{$nameserver_list} = [ $whosaidandwhy ]
 308 use vars qw(%glue);  # $glue{$name}{$addr_list} = [ $whosaidandwhy ]
 309 use vars qw(%soas);  # $soa{"$serial $origin"} = [ $whosaidandwhy ]
 310 use vars qw(%addr_is_ok %warned);
 311 use vars qw($delg_to_us);
 312 use vars qw(@to_check); # ($addr,$whyask,$is_auth,$glueless_ok, ...)
 313 use vars qw(@to_check_soa); # ($addr,$whyask, ...)
 314
 315 sub zone_warning ($$) {
 316     my ($w,$o) = @_;
 317     my ($wk);
 318
 319     return 0 if !$repeat && $warned{$w}++;
 320
 321     $w =~ s/\n$//;
 322     $w =~ s,\n, // ,g;
 323
 324     $w .= " ($o)" if length $o;
 325     print STDERR "$zone: warning: $w\n" or die $!;
 326     $warnings++;
 327     $zone_warnings{$zone}++;
 328     return 1;
 329 }
 330
 331 sub zone_warnmore ($) {
 332     print STDERR "$zone:  $_[0]\n" or die $!;
 333 }
 334
 335 sub zone_check_full () {
 336     zone_investigate();
 337     zone_consistency();
 338     zone_servers_ok();
 339 }
 340
 341 sub zone_reset() {
 342     %delgs= %auths= %glue= %soas= %warned= %addr_is_ok= ();
 343     $delg_to_us= 0;
 344     @to_check= @to_check_soa= ();
 345 }
 346
 347 sub zone_investigate() {
 348     my ($super_zone, @super_nsnames,
 349         $super_ns, @super_ns_addrs, $s, $wa, $is_auth,
 350         %nsrrset_checked, %soa_checked, $addr, $glueless_ok, $rcode);
 351
 352     $super_zone= $zone;
 353     for (;;) {
 354         debug_trace("zone $zone superzone $super_zone");
 355         $super_zone =~ s/^[^.]+\.// or die "no superzone ? ($super_zone)\n";
 356         ($rcode,@super_nsnames)=
 357             lookup($super_zone,'ns-','06',"superzone search");
 358         last if !$rcode;
 359     }
 360     for $super_ns (@super_nsnames) {
 361         $super_ns= lc $super_ns;
 362         ($rcode,@super_ns_addrs)=
 363             lookup($super_ns,'a','0',"published nameserver");
 364         foreach $addr (@super_ns_addrs) {
 365             push @to_check,
 366                  $addr,
 367                  "$super_ns, server for $super_zone",
 368                  0, 0;
 369         }
 370     }
 371     for (;;) {
 372         # We do these in order so that we always do NS RRset checks on
 373         # nameservers that came from other NS RRsets first; otherwise
 374         # we might set nsrrset_checked due to a glueless_ok check,
 375         # and then not check for gluefulness later.
 376         debug_dump('@to_check @to_check_soa');
 377         if (($addr,$wa,$is_auth,$glueless_ok,@to_check) = @to_check) {
 378             push @to_check_soa, $addr, $wa if $is_auth;
 379             next if $nsrrset_checked{$addr}++;
 380             zone_check_nsrrset($addr, $wa, $is_auth, $glueless_ok);
 381         } elsif (($addr,$wa,@to_check_soa) = @to_check_soa) {
 382             next if $soa_checked{$addr}++;
 383             zone_check_soa($addr, $wa, "NS [$addr]");
 384         } else {
 385             last;
 386         }
 387     }
 388 }
 389
 390 sub zone_check_nsrrset ($$$$) {
 391     my ($uaddr,$wa, $is_auth, $glueless_ok) = @_;
 392     my (@s, $s, %s2g, @glue, $glue, $delgs_or_auths, $wwn, $ww);
 393     $ww= "[$uaddr] $wa";
 394     verbose("checking delegation by $ww");
 395     dig(sub {
 396         if ($dig_type eq 'ns' && $dig_owner eq $zone) {
 397             $s2g{lc $dig_rdata} = [ ];
 398         } elsif ($dig_type eq 'a' && exists $s2g{$dig_owner}) {
 399             $wwn= "in glue from $ww";
 400             push @to_check, $dig_rdata, "$dig_owner, $wwn", 1, 0;
 401             zone_server_addr($dig_rdata,$dig_owner,$wwn,"NS [$uaddr]",0);
 402             push @{ $s2g{$dig_owner} }, $dig_rdata;
 403         }
 404     },
 405              $zone,'ns',$uaddr);
 406     if (!%s2g) {
 407         zone_warning("unable to find NS RRset at [$uaddr]", $wa);
 408         return;
 409     } elsif (keys %s2g == 1) {
 410         zone_warning("only one nameserver ". (join '', keys %s2g),
 411                      $ww);
 412     }
 413     @s= sort keys %s2g;
 414     foreach $s (@s) {
 415         zone_ns_name($s,$ww);
 416         @glue= @{ $s2g{$s} };
 417         if (!@glue) {
 418             zone_warning("glueless NS $s", $ww)
 419                 unless $glueless_ok || !$needglue ||
 420                        grep { has_suffix_of($s,".$_"); }
 421                            @{ $cfg->{'conv_glueless'} };
 422             next;
 423         }
 424         $glue= join ' ', sort @glue;
 425         push @{ $glue{$s}{$glue} }, $ww;
 426     }
 427     $s= join ' ', @s;
 428     $delgs_or_auths= $is_auth ? \%auths : \%delgs;
 429     push @{ $delgs_or_auths->{$s} }, $ww;
 430 }
 431
 432 sub zone_ns_name ($$) {
 433     my ($name,$ww) = @_;
 434     my ($cg);
 435     $delg_to_us=1 if grep { $name eq $_ } @{ $cfg->{'self_ns'} };
 436     foreach $cg (@{ $cfg->{'conv_glueless'} }) {
 437         zone_warning("nameserver $name in serverless-glueless".
 438                      " namespace area $cg",
 439                      $ww)
 440             if has_suffix_of(".$name",".$cg");
 441     }
 442     zone_warning("published server, as $name, but configured as stealth",
 443                  $ww)
 444         if $cfg->{'s'} =~ m/u/ &&
 445            grep { $_ eq $name }
 446                @{ $cfg->{'self_ns'} }, @{ $cfg->{'self_soa'} };
 447 }
 448
 449 sub zone_server_addr ($$$$$) {
 450     my ($addr,$name,$ww,$wwq,$is_soa) = @_;
 451     debug_trace("zone_server_addr ".join '|',@_);
 452     $addr_is_ok{$addr}= "$name ($wwq)"
 453         if $is_soa || $cfg->{'s'} =~ m/u/;
 454     zone_warning("forbidden nameserver address [$addr] $name",$ww)
 455         if grep { $_ eq $addr } @{ $cfg->{'forbid_addr'} };
 456
 457     my ($name_is_self, $addr_is_self);
 458     $name_is_self= grep { $_ eq $name }
 459         @{ $cfg->{$is_soa ? 'self_soa' : 'self_ns'} };
 460     $addr_is_self= grep { $_ eq $addr }
 461         @{ $cfg->{'self_addr'} };
 462     if ($name_is_self && !$addr_is_self) {
 463         zone_warning("our $name supplied with wrong address [$addr]", $ww);
 464     }
 465     if (!$name_is_self && $addr_is_self) {
 466         zone_warning("we [$addr] are named in ".
 467                      ($is_soa ? "SOA" : "NS").
 468                      " by wrong name $name",
 469                      $ww);
 470     }
 471     if (!$name_is_self && !$addr_is_self &&
 472         $is_soa && $cfg->{'s'} =~ m/p/) {
 473         zone_warning("SOA ORIGIN $name is not us (".
 474                      (join ' ', @{ $cfg->{'self_soa'} }).")", $ww);
 475     }
 476     $delg_to_us=1 if $addr_is_self && !$is_soa;
 477 }
 478
 479 sub zone_check_soa ($$$) {
 480     my ($uaddr,$wa,$waq) = @_;
 481     my ($lame,$origin,$got,$rcode,@soa_addrs,$soa_addr,$ww,$wwn);
 482     verbose("checking service at [$uaddr] $waq");
 483     $lame= 'dead or lame';
 484     $ww= "[$uaddr] $wa";
 485     dig(sub {
 486         if ($dig_type eq 'flags:') {
 487             $lame= $dig_rdata =~ m/ aa / ? '' : 'lame';
 488         } elsif ($dig_type eq 'soa' && $dig_owner eq $zone && !$lame) {
 489             die "several SOAs ? $ww" if defined $origin;
 490             $got= $dig_rdata;
 491             $got =~ m/^\d+ (\S+)$/ or die "$got ?";
 492             $origin= $1;
 493         }
 494     },
 495              $zone,'soa',$uaddr);
 496     $lame= 'broken' if !$lame && !defined $origin;
 497     if ($lame) { zone_warning("$lame server [$uaddr]",$wa); return; }
 498     push @{ $soas{$got} }, $ww;
 499     ($rcode,@soa_addrs)= lookup($origin,'a','0',"SOA ORIGIN");
 500     $wwn= "SOA ORIGIN from $ww";
 501     foreach $soa_addr (@soa_addrs) {
 502         zone_server_addr($soa_addr,$origin,$wwn,"SOA [$uaddr]",1);
 503         push @to_check, $soa_addr, "$origin, $wwn", 1, 1;
 504     }
 505 }
 506
 507 sub zone_consistency() {
 508     my ($d, $org_ser, $origin, $a, $h, $self_soa, $wa);
 509     zone_consistency_set('delegations',\%delgs);
 510     foreach $d (keys %delgs) { delete $auths{$d}; }
 511     zone_consistency_set('zone nameserver rrset',\%auths);
 512     foreach $h (keys %glue) {
 513         zone_consistency_set("glue for $h", $glue{$h});
 514     }
 515     zone_consistency_set("serial number and/or SOA ORIGIN",\%soas);
 516     $self_soa= $cfg->{'self_soa'};
 517 }
 518
 519 sub zone_servers_ok () {
 520     my ($showok,%fs);
 521     if (%addr_is_ok) {
 522         $showok= 0;
 523         foreach $a (@{ $cfg->{'servers'} }) {
 524             next if exists $addr_is_ok{$a};
 525             zone_warning("we slave from [$a]",'')
 526                 and $showok=1;
 527         }
 528         if ($showok) {
 529             foreach $a (keys %addr_is_ok) {
 530                 zone_warnmore("permitted master [$a] $addr_is_ok{$a}");
 531             }
 532         }
 533     }
 534     if ($cfg->{'s'} =~ m/s/ && !$delg_to_us) {
 535         zone_warning("we are supposedly published secondary,".
 536                      " but not listed as a nameserver",'');
 537         map { $fs{$_}=1 } keys(%delgs), keys(%auths);
 538         zone_warnmore("servers are: ". join ' ', sort keys %fs);
 539     }
 540 }
 541
 542 sub zone_consistency_set ($%) {
 543     my ($msg,$set) = @_;
 544     my ($d,$o);
 545     if (keys(%$set) > 1) {
 546         zone_warning("inconsistent $msg:",'');
 547         foreach $d (keys %$set) {
 548             foreach $o (@{ $set->{$d} }) { zone_warnmore(" $d from $o"); }
 549         }
 550     }
 551 }
 552
 553 sub zone_check_local () {
 554     zone_servers_simplefind();
 555     zone_servers_ok();
 556 }
 557
 558 sub zone_servers_simplefind () {
 559     my ($rcode,@nsnames,$ns,@soas,$origin);
 560
 561     ($rcode,@nsnames)= lookup($zone,'ns-','0',"zone's servers");
 562     foreach $ns (@nsnames) {
 563         zone_ns_name($ns,"NS");
 564         zone_server_simple($ns,'NS',0);
 565     }
 566
 567     ($rcode,@soas)= lookup($zone,'soa','0',"SOA ORIGIN");
 568     die "multiple SOA RRs in set!  @soas ?" if @soas!=1;
 569     $soas[0] =~ m/^(\S+)\s/ or die "SOA ? $_";
 570     zone_server_simple(domain_canon($1,"lookup $zone SOA"),'SOA',1);
 571 }
 572
 573 sub zone_server_simple ($$$) {
 574     my ($name,$ww,$is_soa) = @_;
 575     my ($rcode,@addrs,$addr);
 576     ($rcode,@addrs)= lookup($name,'a','0', "server - ".
 577                             ($is_soa ? "SOA ORIGIN" : "NS"));
 578     foreach $addr (@addrs) { zone_server_addr($addr,$name,$ww,$ww,$is_soa); }
 579 }
 580
 581 #-------------------- outputting
 582
 583 sub zone_output () {
 584     my ($o,$m);
 585
 586     $o= "zone \"$zone\" {\n";
 587     if ($$cfg{'s'} =~ m/p/) {
 588         $o.= "    type master;\n";
 589     } else {
 590         $o.= "    type slave;\n".
 591              "    masters {\n";
 592         foreach $m (@{ $$cfg{'servers'} }) { $o.= "        $m;\n"; }
 593         $o.= "    };\n";
 594     }
 595     $o.= "    file \"$$cfg{'file'}\";\n";
 596     $o.= "};\n";
 597     return $o;
 598 }
 599
 600 sub output_files () {
 601     my ($fn,$ofn,$mfn,$l,$dir, $maxmode,$h,@to_install);
 602
 603     foreach $ofn (keys %output_contents) {
 604         $fn= $ofn; $mfn= "output file $fn";
 605         for (;;) {
 606             if (!lstat $fn) {
 607                 $! == &ENOENT or die "$quis: stat $mfn:\n $!\n";
 608                 $maxmode= 0666;
 609                 last;
 610             } elsif (-f _) {
 611                 $maxmode= (stat _)[2];
 612                 last;
 613             } elsif (-l _) {
 614                 defined($l= readlink $fn)
 615                     or die "$quis: readlink $mfn:\n $!\n";
 616                 $dir= $fn =~ m,^.*/, ? $& : './';
 617                 $fn= "$dir$l" unless $l =~ m,^/,;
 618                 $mfn= "output file $fn (symlink target of $ofn)";
 619             } else {
 620                 die "$quis: output file $mfn exists but is not a file".
 621                     " (or symlink to one)";
 622             }
 623         }
 624         unlink "$fn.new" or $! == &ENOENT or
 625             die "$quis: cannot clear out old .new version of $mfn:\n $!";
 626         $h= new IO::File "$fn.new",'w',$maxmode
 627             or die("$quis: create .new version of $mfn:\n $!");
 628         print $h
 629             "# generated by $quis, do not edit\n",
 630             $output_contents{$ofn}
 631             or die "$quis: write data to .new version of $mfn:\n $!";
 632         $h->close
 633             or die "$quis: close .new version of $mfn:\n $!";
 634         push @to_install, $fn,$mfn;
 635     }
 636
 637     while (($fn,$mfn, @to_install) = @to_install) {
 638         rename "$fn.new",$fn
 639             or die "$quis: install new version of $mfn:\n $!";
 640     }
 641 }
 642
 643 #-------------------- general utilities
 644
 645 sub debug_dump ($) {
 646     my ($vn);
 647     return unless $debug>1;
 648     local $Data::Dumper::Terse=1;
 649     foreach $vn (split /\s+/, $_[0]) {
 650         print "$vn := ", eval "Dumper(\\$vn)";
 651     }
 652 }
 653
 654 sub debug_trace ($) {
 655     return unless $debug;
 656     print "D $_[0]\n";
 657 }
 658
 659 sub has_suffix_of ($$) {
 660     my ($whole,$suffix) = @_;
 661     debug_trace("has_suffix_of $whole $suffix");
 662     return 0 if length $whole < length $suffix;
 663     return 0 if substr($whole, length($whole) - length($suffix)) ne $suffix;
 664     debug_trace("has_suffix_of $whole $suffix YES");
 665     return 1;
 666 }
 667
 668 sub lookup ($$$$) {
 669     my ($domain,$type,$okrcodes,$w) = @_;
 670     my ($c,$h,@result);
 671     debug_trace("lookup ==> (->$okrcodes) $domain $type");
 672     $h= new IO::Handle;
 673
 674     defined($c= open $h, "-|") or die "$quis: fork adnshost:\n $!\n";
 675     if (!$c) {
 676         exec 'adnshost','-Fi','+Do','+Dt','+Dc','-Cf',"-t$type",
 677              '-',"$domain.";
 678         die "$quis: exec adnshost:\n $!\n";
 679     }
 680     @result= $h->getlines();
 681     $h->error and die "$quis: read from adnshost:\n $!\n";
 682     chomp @result;
 683     $!=0; $h->close;
 684     die "$quis: lookup -t$type $domain $okrcodes ($w) failed $? $! @result\n"
 685         if $! or $?&255 or $?>1536 or index($okrcodes,$?>>8)<0;
 686     debug_trace("lookup <== $? @result");
 687     return ($?,@result);
 688 }
 689
 690 sub dig (&$$$) {
 691     my ($eachrr, $qowner,$qtype,$qaddr) = @_;
 692     # also pseudo-rr with type `flags:'
 693     my ($h,$inmid,$irdata,$c,$digwhy);
 694     local ($_);
 695
 696     debug_trace("dig ==> \@$qaddr $qowner $qtype");
 697
 698     $h= new IO::Handle;
 699     defined($c= open $h, "-|") or die "$quis: fork dig:\n $!\n";
 700     if (!$c) {
 701         open STDERR, ">&STDOUT" or die $!;
 702         exec ('dig',
 703               '+nodef','+nosea','+nodebug','+norecurse',
 704               "\@$qaddr",'-t',$qtype,$qowner);
 705         die "$quis: exec dig:\n $!\n";
 706     }
 707     $inmid='';
 708     for (;;) {
 709         if (!defined($_= $h->getline())) {
 710             $h->error() and die "$quis: read from dig:\n $!\n";
 711             last;
 712         }
 713         chomp;
 714         if (length $inmid) {
 715             s/^\s+/ / or die "$inmid // $_ ?";
 716             s/\;.*$//;
 717             $_= $inmid.$_;
 718             $inmid='';
 719             s/$/ \(/ unless s/\s*\)\s*$//;
 720         }
 721         if (s/\s*\(\s*$//) { $inmid= $_; next; }
 722         $digwhy= "dig $qowner $qtype $qaddr \`$_'";
 723         if (m/^\;\; flags\:( [-0-9a-z ]+)\;/) {
 724             $dig_owner=''; $dig_type='flags:'; $dig_rdata= "$1 ";
 725             debug_trace("dig  f: $dig_rdata");
 726             &$eachrr;
 727         } elsif (m/^\;/) {
 728         } elsif (!m/\S/) {
 729         } elsif (m/^([-.0-9a-z]+)\s+\d\w+\s+in\s+([a-z]+)\s+(\S.*)/i) {
 730             $dig_owner=domain_canon($1,$digwhy); $dig_type=lc $2; $irdata=$3;
 731             if ($dig_type eq 'a') {
 732                 $irdata =~ m/^[.0-9]+$/ or die "$irdata ?";
 733                 $dig_rdata= $&;
 734             } elsif ($dig_type eq 'ns') {
 735                 $irdata =~ m/^[-.0-9a-z]+$/i or die "bad nameserver $irdata ?";
 736                 $dig_rdata= domain_canon($irdata,$digwhy);
 737             } elsif ($dig_type eq 'soa') {
 738                 $irdata =~ m/^([-.0-9a-z]+)\s+.*\s+(\d+)(?:\s+\d\w+){4}$/i
 739                     or die "bad SOA $irdata ?";
 740                 $dig_rdata= $2.' '.domain_canon($1,$digwhy);
 741             } else {
 742                 debug_trace("ignoring uknown RR type $dig_type");
 743                 next;
 744             }
 745             debug_trace("dig  $dig_owner $dig_type $dig_rdata");
 746             &$eachrr;
 747         } else {
 748             debug_trace("ignoring unknown dig output $_");
 749         }
 750     }
 751     $h->close;
 752     debug_trace("dig <== gave $?");
 753 }
 754
 755 sub domain_canon ($$) {
 756     my ($i,$w) = @_;
 757     $i =~ s/(.)\.$/$1/;
 758     return '.' if $i eq '.';
 759     die "domain $i ($w) ?" unless $i =~ m/^[0-9a-z]/i;
 760     return lc $i;
 761 }