scripts/named-conf

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use IO::File;
   5 use Data::Dumper;
   6 use POSIX;
   7
   8 use vars qw($quis
   9             $mode $doall
  10             $etcfile $where
  11             $debug $needglue $localonly $repeat $verbosity);
  12
  13 $quis= $0; $quis =~ s,.*/,,;
  14
  15 $mode= '';
  16 $doall= 0;
  17 $etcfile= "/etc/bind/chiark-conf-gen.zones";
  18 $where= '<built-in>';
  19 $debug= 0;
  20 $needglue= 1;
  21 $localonly= 0;
  22 $verbosity= 2;
  23 $repeat= 0;
  24
  25 use vars qw($dig_owner $dig_type $dig_rdata);
  26
  27 while (@ARGV && $ARGV[0] =~ m/^\-/) {
  28     $_= shift @ARGV;
  29     if (s/^\-\-//) {
  30         last if m/^$/;
  31         if (m/^(yes|no|force)$/) { m/^./; $mode= $&; }
  32         elsif (m/^all$/) { $doall=1; }
  33         elsif (m/^config$/) { $etcfile= loarg(); $where= '--config option'; }
  34         elsif (m/^glueless$/) { $needglue=0; }
  35         elsif (m/^localonly$/) { $localonly=1; }
  36         elsif (m/^quiet$/) { $verbosity--; }
  37         elsif (m/^repeat$/) { $repeat=1; }
  38         elsif (m/^verbose$/) { $verbosity++; }
  39         else { usageerr("unknown option --$_"); }
  40     } else {
  41         s/^\-//;
  42         last if m/^$/;
  43         while (m/^./) {
  44             if (s/^[ynf]//) { $mode=$&; }
  45             elsif (s/^A//) { $doall=1; }
  46             elsif (s/^C//) { $etcfile= soarg(); $where= '-C option'; }
  47             elsif (s/^D//) { $debug++; }
  48             elsif (s/^g//) { $needglue=0; }
  49             elsif (s/^l//) { $localonly=1; }
  50             elsif (s/^q//) { $verbosity--; }
  51             elsif (s/^r//) { $repeat=1; }
  52             elsif (s/^v//) { $verbosity++; }
  53             else { usageerr("unknown option -$&"); }
  54         }
  55     }
  56 }
  57
  58 sub loarg() { usageerr("missing option value") if !@ARGV; return shift @ARGV; }
  59 sub soarg() { my ($rv); $rv=$_; $_=''; return length $rv ? $rv : loarg(); }
  60
  61 usageerr("-q may be specified at most twice") if $verbosity<0;
  62 usageerr("-v may be specified at most once") if $verbosity>3;
  63 usageerr("-D may be specified at most twice") if $debug>2;
  64 usageerr("must specify either -f|-y|-n or zones (and not both)")
  65     if !!$mode == !!@ARGV;
  66
  67 sub usageerr ($) {
  68     die <<END;
  69 $_[0]
  70
  71 usage: chiark-named-conf [options] -f|-y|-n|<zone>...
  72 operation modes:
  73  -f --force   install without checking
  74  -y --yes     check and install
  75  -n --no      check only (configured zones)
  76  <zone> ...   check only (specified zones, even unconfigured ones)
  77 additional options:
  78  -A --all       report on zones marked ? (ones we know are broken)
  79  -D             debug $quis (does not help debug your DNS config)
  80  -g --glueless  do not warn about any glueless referrals (not recommended)
  81  -l --localonly full checks only on zones which we primary
  82  -q --quiet     no output for OK zones
  83  -r --repeat    repeat warnings for all sources of imperfect data
  84  -v --verbose   extra verbose info about each zone
  85  -C|--config <DIR/FILE  use FILE as default config and DIR as default dir
  86
  87 chiark-named-conf is Copyright 2002 Ian Jackson.  It is Free software, under
  88 the GNU General Public License, and you are welcome to change it and/or
  89 distribute copies under certain conditions.  There is ABSOLUTELY NO WARRANTY.
  90 END
  91 }
  92
  93 cfg_fail("config filename $etcfile should not be directory")
  94     if $etcfile =~ m,/$,;
  95
  96 use vars qw($default_dir);
  97 $default_dir= $etcfile =~ m,^.*/, ? $& : './';
  98
  99 use vars qw($slave_dir $slave_prefix $slave_suffix);
 100 $slave_dir= 'slave';
 101 $slave_prefix= '';
 102 $slave_suffix= '';
 103
 104 use vars qw(@self_ns @self_soa @self_addr @forbid_addr @conv_glueless);
 105 @self_ns= @self_soa= @self_addr= @forbid_addr= ();
 106 @conv_glueless= qw(in-addr.arpa ip6.arpa ip6.int);
 107
 108 use vars qw(%zone_cfg @zone_cfg_list);
 109 %zone_cfg= ();
 110 @zone_cfg_list= ();
 111
 112 use vars qw($output $default_output %output_contents);
 113 $output= '';
 114 $default_output= '';
 115 %output_contents= ();
 116
 117 use vars qw($check $install);
 118 $check= $mode !~ m/^f/;
 119 $install= $mode =~ m/^[yf]/;
 120
 121 read_config($etcfile);
 122 debug_dump('@zone_cfg_list %zone_cfg');
 123 process_zones($mode ? @zone_cfg_list : @ARGV);
 124 debug_dump('%output_contents');
 125 output_files() if $install;
 126
 127 exit 0;
 128
 129 #-------------------- configuration reading
 130
 131 sub cfg_fail ($) { die "$quis: $where:\n $_[0]\n"; }
 132
 133 sub read_config ($) {
 134     my ($if) = @_;
 135     my ($fh,$z,@self,$before,
 136         $mod,$dir,$prefix,$suffix,$subfile,$lprefix,$lsuffix,$zf);
 137     local ($_);
 138
 139     $fh= new IO::File $if,'r' or cfg_fail("open $if:\n $!");
 140     $before= '';
 141     for (;;) {
 142         if (!defined($_= <$fh>)) {
 143             cfg_fail("read config file $if:\n $!") if $fh->error();
 144             last;
 145         }
 146         chomp; s/\s+$//;
 147         if (s/\\$//) { $before.= $_; next; }
 148         $_= $before.$_;
 149         $before= '';
 150         s/^\s+//;
 151         $where= "$if:$.";
 152         next if m/^\#/;
 153         last if m/^end$/;
 154         next unless m/\S/;
 155         if (m/^self(\-ns|\-soa|)\s+(\S.*\S)/) {
 156             @self= split /\s+/, $2;
 157             @self_ns= @self if $1 ne '-soa';
 158             @self_soa= @self if $1 ne '-ns';
 159         } elsif (m/^serverless\-glueless\s+(\S.*\S)/) {
 160             @conv_glueless= split /\s+/, $1;
 161         } elsif (m/^self\-addr\s+([0-9. \t]+)/) {
 162             @self_addr= split /\s+/, $1;
 163         } elsif (m/^forbid\-addr(?:\s+([0-9. \t]+))?/) {
 164             @forbid_addr= defined $1 ? split /\s+/, $1 : ();
 165         } elsif (m,^
 166                  primary\-dir ([*?]?)
 167                  \s+ (\S+)/([^/ \t]*)
 168                  (?: \s+ ([^/ \t]*) (?: (/.+) )?
 169                   )?
 170                  $,x) {
 171             ($mod, $dir, $prefix, $suffix, $subfile) =
 172                 ($1,qualify($2),$3,$4,$5);
 173             $suffix= '' if !defined $suffix;
 174             $subfile= '' if !defined $subfile;
 175             $suffix= '_db' if !length $suffix && !length $subfile;
 176             if (-d "$dir/$prefix") { $dir.='/'; $dir.=$prefix; $prefix=''; }
 177             opendir D, $dir or cfg_fail("open primary-dir $dir:\n $!");
 178             $lprefix= length $prefix; $lsuffix= length $suffix;
 179             while (defined($_= readdir D)) {
 180                 next if m/^\./ && !$lprefix;
 181                 next unless length > $lprefix+$lsuffix;
 182                 next unless substr($_,0,$lprefix) eq $prefix;
 183                 next unless substr($_,length($_)-$lsuffix) eq $suffix;
 184                 $z= substr($_,$lprefix,length($_)-($lprefix+$lsuffix));
 185                 $zf= $dir.'/'.$prefix.$z.$suffix.$subfile;
 186                 if (!stat $zf) {
 187                     next if length $subfile && $! == &ENOENT;
 188                     cfg_fail("cannot stat zonefile $zf:\n $!");
 189                 }
 190                 -f _ or cfg_fail("zonefile $zf is not a plain file");
 191                 zone_conf($z,'primary','p',$mod,$zf);
 192             }
 193             closedir D or cfg_fail("close primary-dir $dir:\n $!");
 194         } elsif (m/^primary([*?]?)\s+(\S+)\s+(\S+)$/) {
 195             zone_conf($2,'primary','p',$1,qualify($3));
 196         } elsif (m/^published([*?]?)\s+(\S+)\s+([0-9.\t]+)$/) {
 197             zone_conf($2,'published','s',$1,'',$3);
 198         } elsif (m/^stealth([*?]?)\s+(\S+)\s+([0-9. \t]+)$/) {
 199             zone_conf($2,'stealth','u',$1,'',split /\s+/, $3);
 200         } elsif (m/^slave\-dir\s+(\S+)(?:(?:\s+(\S+))\s+(\S+))?$/) {
 201             ($slave_dir, $slave_prefix, $slave_suffix) = (qualify($1),$2,$3);
 202             $slave_prefix='' if !defined $slave_prefix;
 203             $slave_suffix='' if !defined $slave_suffix;
 204         } elsif (m/^output\s+bind8\+(\S+)$/) {
 205             cfg_fail("default output may not apply to only some zones")
 206                 if @zone_cfg_list && length $default_output;
 207             set_output(qualify($1));
 208         } elsif (m/^include\s+(\S+)$/) {
 209             read_config($1);
 210         } else {
 211             cfg_fail("unknown configuration directive".
 212                      " or incorrect syntax or arguments:\n".
 213                      " \`$_'");
 214         }
 215     }
 216     $fh->close or cfg_fail("close config file $if:\n $!");
 217 }
 218
 219 sub qualify ($) {
 220     my ($i) = @_;
 221     $i= "$default_dir$i" unless $i =~ m,^/,;
 222     return $i;
 223 }
 224
 225 sub zone_conf ($$$$$@) {
 226     my ($zone,$style,$sabbr,$mod,$file,@servers) = @_;
 227     my ($sfx,$aref);
 228     $file= qualify("$slave_dir/$slave_prefix".$zone.$slave_suffix)
 229         unless length $file;
 230     if (!length $output) {
 231         $default_output= qualify('chiark-conf-gen.bind8')
 232             unless length $default_output;
 233         set_output($default_output);
 234     }
 235     cfg_fail("redefined zone $zone\n".
 236              " earlier definition $zone_cfg{$zone}{'where'}")
 237         if exists $zone_cfg{$zone};
 238     $zone_cfg{$zone}{'where'}= $where;
 239     $zone_cfg{$zone}{'file'}= $file;
 240     $zone_cfg{$zone}{'style_p'}= $style.$mod;
 241     $zone_cfg{$zone}{'s'}= $sabbr.$mod; # p)rimary s)econdary u)npub f)oreign
 242     $zone_cfg{$zone}{'servers'}= [ @servers ];
 243     foreach $sfx (qw(self_soa self_ns self_addr forbid_addr conv_glueless)) {
 244         { no strict 'refs'; $aref= [ @$sfx ]; }
 245         @$aref or cfg_fail("failed to specify $sfx before zone")
 246             if $sfx =~ m/^self/;
 247         $zone_cfg{$zone}{$sfx}= $aref;
 248     }
 249     $zone_cfg{$zone}{'output'}= $output;
 250     push @zone_cfg_list, $zone;
 251 }
 252
 253 sub set_output($) {
 254     my ($newout) = @_;
 255     $output= $newout;
 256     $output_contents{$output}= '';
 257 }
 258
 259
 260 #-------------------- checking
 261
 262 use vars qw($zone $cfg $warnings %zone_warnings);
 263 $warnings= 0;
 264
 265 sub progress ($$) {
 266     my ($minv,$m) = @_;
 267     return if $verbosity < $minv;
 268     print "$m\n";
 269 }
 270
 271 sub verbose ($) { progress(3, '    ' . $_[0]); }
 272
 273 sub process_zones (@) {
 274     my (@zones) = @_;
 275     local ($zone,$cfg);
 276
 277     foreach $zone (@zones) {
 278         zone_reset();
 279         $cfg= $zone_cfg{$zone} || {
 280             'style_p' => 'foreign',
 281             's' => 'f',
 282             'servers' => [ ],
 283             };
 284         progress(1, sprintf "%-20s %s", $zone, $$cfg{'style_p'});
 285         if ($check && ($doall || $cfg->{'s'} !~ m/\?/)) {
 286             eval {
 287                 if ($localonly && $cfg->{'s'} =~ m/f/) {
 288                     zone_warning("foreign zone specified with -l",'');
 289                 } elsif ($localonly && $cfg->{'s'} !~ m/p/) {
 290                     zone_check_local();
 291                 } else {
 292                     zone_check_full();
 293                 }
 294             };
 295             zone_warning("checks failed: $@",'') if length $@;
 296         }
 297         $output_contents{$$cfg{'output'}} .= zone_output()
 298             if $install;
 299     }
 300     if ($warnings) {
 301         printf STDERR ("%s: %d warning(s) in %d zone(s);".
 302                        " %d zone(s) checked ok.\n",
 303                        $quis,
 304                        $warnings,
 305                        scalar(keys %zone_warnings),
 306                        scalar(@zones - keys %zone_warnings));
 307     } else {
 308         progress(1, sprintf "%d zone(s) checked ok", scalar @zones);
 309     }
 310 }
 311
 312 use vars qw(%delgs); # $delgs{$nameserver_list} = [ $whosaidandwhy ]
 313 use vars qw(%auths); # $auths{$nameserver_list} = [ $whosaidandwhy ]
 314 use vars qw(%glue);  # $glue{$name}{$addr_list} = [ $whosaidandwhy ]
 315 use vars qw(%soas);  # $soa{"$serial $origin"} = [ $whosaidandwhy ]
 316 use vars qw(%addr_is_ok %warned);
 317 use vars qw($delg_to_us);
 318 use vars qw(@to_check); # ($addr,$whyask,$name_if_auth,$glueless_ok, ...)
 319 use vars qw(@to_check_soa); # ($addr,$whyask,$name,$is_ns, ...)
 320
 321 sub zone_warning ($$) {
 322     my ($w,$o) = @_;
 323     my ($wk);
 324
 325     return 0 if !$repeat && $warned{$w}++;
 326
 327     $w =~ s/\n$//;
 328     $w =~ s,\n, // ,g;
 329
 330     $w .= " ($o)" if length $o;
 331     print STDERR "$zone: warning: $w\n" or die $!;
 332     $warnings++;
 333     $zone_warnings{$zone}++;
 334     return 1;
 335 }
 336
 337 sub zone_warnmore ($) {
 338     print STDERR "$zone:  $_[0]\n" or die $!;
 339 }
 340
 341 sub zone_check_full () {
 342     zone_investigate();
 343     zone_consistency();
 344     zone_servers_ok();
 345 }
 346
 347 sub zone_reset() {
 348     %delgs= %auths= %glue= %soas= %warned= %addr_is_ok= ();
 349     $delg_to_us= 0;
 350     @to_check= @to_check_soa= ();
 351 }
 352
 353 sub zone_investigate() {
 354     my ($super_zone, @start_nsnames, $start_ww,
 355         $start_ns, @start_ns_addrs, $s, $wa, $name_if_auth,
 356         %nsrrset_checked, %soa_checked, $addr, $glueless_ok,
 357         $rcode, $name, $is_ns);
 358
 359     if ($cfg->{'s'} !~ m/\*/) {
 360         $super_zone= $zone;
 361         for (;;) {
 362             debug_trace("zone $zone superzone $super_zone");
 363             $super_zone =~ s/^[^.]+\.//
 364                 or die "no superzone ? ($super_zone)\n";
 365             ($rcode,@start_nsnames)=
 366                 lookup($super_zone,'ns-','06',"superzone search");
 367             last if !$rcode;
 368         }
 369         $start_ww= "server for $super_zone";
 370     } else {
 371         ($rcode,@start_nsnames)=
 372             lookup($zone,'ns-','0',"initial nameserver search");
 373         $start_ww= "nameserver for $zone";
 374     }
 375     for $start_ns (@start_nsnames) {
 376         $start_ns= lc $start_ns;
 377         ($rcode,@start_ns_addrs)= lookup($start_ns,'a','0',"$start_ww");
 378         foreach $addr (@start_ns_addrs) {
 379             push @to_check, $addr, "$start_ns, $start_ww", undef, 0;
 380         }
 381     }
 382     for (;;) {
 383         # We do these in order so that we always do NS RRset checks on
 384         # nameservers that came from other NS RRsets first; otherwise
 385         # we might set nsrrset_checked due to a glueless_ok check,
 386         # and then not check for gluefulness later.
 387         debug_dump('@to_check @to_check_soa');
 388         if (($addr,$wa,$name_if_auth,$glueless_ok,@to_check) = @to_check) {
 389             push @to_check_soa, $addr, $wa, $name_if_auth, 1,
 390                 if defined $name_if_auth;
 391             next if $nsrrset_checked{$addr}++;
 392             zone_check_nsrrset($addr, $wa, $name_if_auth, $glueless_ok);
 393         } elsif (($addr,$wa,$name,$is_ns,@to_check_soa) = @to_check_soa) {
 394             next if $soa_checked{$addr}++;
 395             zone_check_soa($addr,$wa,$name,$is_ns);
 396         } else {
 397             last;
 398         }
 399     }
 400 }
 401
 402 sub zone_check_nsrrset ($$$$) {
 403     my ($uaddr,$wa, $name_if_auth, $glueless_ok) = @_;
 404     my (@s, $s, $a, %s2g, @glue, $glue, $delgs_or_auths, $wwn, $ww);
 405     my ($rcode);
 406     $ww= "[$uaddr] $wa";
 407     verbose("checking delegation by $ww");
 408     dig(sub {
 409         if ($dig_type eq 'ns' && $dig_owner eq $zone) {
 410             $s2g{lc $dig_rdata} = [ ];
 411         } elsif ($dig_type eq 'a' && exists $s2g{$dig_owner}) {
 412             $wwn= "in glue from $ww";
 413             zone_server_queue($dig_rdata,$dig_owner,$wwn,"NS [$uaddr]",0);
 414             push @{ $s2g{$dig_owner} }, $dig_rdata;
 415         }
 416     },
 417              $zone,'ns',$uaddr);
 418     if (!%s2g) {
 419         zone_warning("unable to find NS RRset at [$uaddr]", $wa);
 420         return;
 421     } elsif (keys %s2g == 1) {
 422         zone_warning("only one nameserver ". (join '', keys %s2g),
 423                      $ww);
 424     }
 425     @s= sort keys %s2g;
 426     foreach $s (@s) {
 427         zone_ns_name($s,$ww);
 428         @glue= @{ $s2g{$s} };
 429         if (!@glue) {
 430             zone_warning("glueless NS $s", $ww)
 431                 unless $glueless_ok || !$needglue ||
 432                        grep { has_suffix_of($s,".$_"); }
 433                            @{ $cfg->{'conv_glueless'} };
 434             ($rcode,@glue)= lookup($s,'a','0',"glueless NS from $ww");
 435             foreach $a (@glue) {
 436                 $wwn= "glueless NS from $ww";
 437                 zone_server_queue($a,$s,$wwn,"NS [$uaddr]",0);
 438             }
 439         }
 440         $glue= join ' ', sort @glue;
 441         push @{ $glue{$s}{$glue} }, $ww;
 442     }
 443     $s= join ' ', @s;
 444     $delgs_or_auths= defined($name_if_auth) ? \%auths : \%delgs;
 445     push @{ $delgs_or_auths->{$s} }, $ww;
 446 }
 447
 448 sub zone_ns_name ($$) {
 449     my ($name,$ww) = @_;
 450     my ($cg);
 451     $delg_to_us=1 if grep { $name eq $_ } @{ $cfg->{'self_ns'} };
 452     foreach $cg (@{ $cfg->{'conv_glueless'} }) {
 453         zone_warning("nameserver $name in serverless-glueless".
 454                      " namespace area $cg",
 455                      $ww)
 456             if has_suffix_of(".$name",".$cg");
 457     }
 458     zone_warning("published server, as $name, but configured as stealth",
 459                  $ww)
 460         if $cfg->{'s'} =~ m/u/ &&
 461            grep { $_ eq $name }
 462                @{ $cfg->{'self_ns'} }, @{ $cfg->{'self_soa'} };
 463 }
 464
 465 sub zone_server_queue ($$$$$) {
 466     my ($addr,$name,$wwn,$wwq,$is_soa) = @_;
 467     zone_server_addr($addr,$name,$wwn,$wwq,$is_soa);
 468     push @to_check, $addr, "$name, $wwn", $name, $is_soa;
 469 }
 470
 471 sub zone_server_addr ($$$$$) {
 472     my ($addr,$name,$ww,$wwq,$is_soa) = @_;
 473     debug_trace("zone_server_addr ".join '|',@_);
 474     $addr_is_ok{$addr}= "$name ($wwq)"
 475         if $is_soa || $cfg->{'s'} =~ m/u/;
 476     zone_warning("forbidden nameserver address [$addr] $name",$ww)
 477         if grep { $_ eq $addr } @{ $cfg->{'forbid_addr'} };
 478
 479     my ($name_is_self, $addr_is_self);
 480     $name_is_self= grep { $_ eq $name }
 481         @{ $cfg->{$is_soa ? 'self_soa' : 'self_ns'} };
 482     $addr_is_self= grep { $_ eq $addr }
 483         @{ $cfg->{'self_addr'} };
 484     if ($name_is_self && !$addr_is_self) {
 485         zone_warning("our $name supplied with wrong address [$addr]", $ww);
 486     }
 487     if (!$name_is_self && $addr_is_self) {
 488         zone_warning("we [$addr] are named in ".
 489                      ($is_soa ? "SOA" : "NS").
 490                      " by wrong name $name",
 491                      $ww);
 492     }
 493     if (!$name_is_self && !$addr_is_self &&
 494         $is_soa && $cfg->{'s'} =~ m/p/) {
 495         zone_warning("SOA ORIGIN $name is not us (".
 496                      (join ' ', @{ $cfg->{'self_soa'} }).")", $ww);
 497     }
 498     $delg_to_us=1 if $addr_is_self && !$is_soa;
 499 }
 500
 501 sub zone_check_soa ($$$$) {
 502     my ($uaddr,$wa,$name,$is_ns) = @_;
 503     my ($lame,$serial,$origin,$got,$rcode,@soa_addrs,$soa_addr,$ww,$wwn);
 504     verbose("checking service at [$uaddr] $name");
 505     $lame= 'dead or lame';
 506     $ww= "[$uaddr] $wa";
 507     dig(sub {
 508         if ($dig_type eq 'flags:') {
 509             $lame= $dig_rdata =~ m/ aa / ? '' : 'lame';
 510         } elsif ($dig_type eq 'soa' && $dig_owner eq $zone && !$lame) {
 511             die "several SOAs ? $ww" if defined $origin;
 512             $got= $dig_rdata;
 513             $got =~ m/^(\d+) (\S+)$/ or die "$got ?";
 514             ($serial,$origin) = ($1,$2);
 515         }
 516     },
 517              $zone,'soa',$uaddr);
 518     $lame= 'broken' if !$lame && !defined $origin;
 519     if ($lame) { zone_warning("$lame server [$uaddr]",$wa); return; }
 520     progress(2, sprintf "%-16s %46s has %s%s",
 521              $zone, "$name [$uaddr]", $serial, $is_ns ? '' : '*');
 522     push @{ $soas{$got} }, $ww;
 523     ($rcode,@soa_addrs)= lookup($origin,'a','0',"SOA ORIGIN");
 524     $wwn= "SOA ORIGIN from $ww";
 525     foreach $soa_addr (@soa_addrs) {
 526         zone_server_queue($soa_addr,$origin,$wwn,"SOA [$uaddr]",1);
 527     }
 528 }
 529
 530 sub zone_consistency() {
 531     my ($d, $org_ser, $origin, $a, $h, $self_soa, $wa);
 532     zone_consistency_set('delegations',\%delgs);
 533     foreach $d (keys %delgs) { delete $auths{$d}; }
 534     zone_consistency_set('zone nameserver rrset',\%auths);
 535     foreach $h (keys %glue) {
 536         zone_consistency_set("glue for $h", $glue{$h});
 537     }
 538     zone_consistency_set("serial number and/or SOA ORIGIN",\%soas);
 539     $self_soa= $cfg->{'self_soa'};
 540 }
 541
 542 sub zone_servers_ok () {
 543     my ($showok,%fs);
 544     if (%addr_is_ok) {
 545         $showok= 0;
 546         foreach $a (@{ $cfg->{'servers'} }) {
 547             next if exists $addr_is_ok{$a};
 548             zone_warning("we slave from [$a]",'')
 549                 and $showok=1;
 550         }
 551         if ($showok) {
 552             foreach $a (keys %addr_is_ok) {
 553                 zone_warnmore("permitted master [$a] $addr_is_ok{$a}");
 554             }
 555         }
 556     }
 557     if ($cfg->{'s'} =~ m/s/ && !$delg_to_us) {
 558         zone_warning("we are supposedly published secondary,".
 559                      " but not listed as a nameserver",'');
 560         map { $fs{$_}=1 } keys(%delgs), keys(%auths);
 561         zone_warnmore("servers are: ". join ' ', sort keys %fs);
 562     }
 563 }
 564
 565 sub zone_consistency_set ($%) {
 566     my ($msg,$set) = @_;
 567     my ($d,$o);
 568     if (keys(%$set) > 1) {
 569         zone_warning("inconsistent $msg:",'');
 570         foreach $d (keys %$set) {
 571             foreach $o (@{ $set->{$d} }) { zone_warnmore(" $d from $o"); }
 572         }
 573     }
 574 }
 575
 576 sub zone_check_local () {
 577     zone_servers_simplefind();
 578     zone_servers_ok();
 579 }
 580
 581 sub zone_servers_simplefind () {
 582     my ($rcode,@nsnames,$ns,@soas,$origin);
 583
 584     ($rcode,@nsnames)= lookup($zone,'ns-','0',"zone's servers");
 585     foreach $ns (@nsnames) {
 586         zone_ns_name($ns,"NS");
 587         zone_server_simple($ns,'NS',0);
 588     }
 589     $delgs{join ' ', sort @nsnames} = [ "zone's servers" ];
 590
 591     ($rcode,@soas)= lookup($zone,'soa','0',"SOA ORIGIN");
 592     die "multiple SOA RRs in set!  @soas ?" if @soas!=1;
 593     $soas[0] =~ m/^(\S+)\s/ or die "SOA ? $_";
 594     zone_server_simple(domain_canon($1,"lookup $zone SOA"),'SOA',1);
 595 }
 596
 597 sub zone_server_simple ($$$) {
 598     my ($name,$ww,$is_soa) = @_;
 599     my ($rcode,@addrs,$addr);
 600     ($rcode,@addrs)= lookup($name,'a','0', "server - ".
 601                             ($is_soa ? "SOA ORIGIN" : "NS"));
 602     foreach $addr (@addrs) { zone_server_addr($addr,$name,$ww,$ww,$is_soa); }
 603 }
 604
 605 #-------------------- outputting
 606
 607 sub zone_output () {
 608     my ($o,$m);
 609
 610     $o= "zone \"$zone\" {\n";
 611     if ($$cfg{'s'} =~ m/p/) {
 612         $o.= "    type master;\n";
 613     } else {
 614         $o.= "    type slave;\n".
 615              "    masters {\n";
 616         foreach $m (@{ $$cfg{'servers'} }) { $o.= "        $m;\n"; }
 617         $o.= "    };\n";
 618     }
 619     $o.= "    file \"$$cfg{'file'}\";\n";
 620     $o.= "};\n";
 621     return $o;
 622 }
 623
 624 sub output_files () {
 625     my ($fn,$ofn,$mfn,$l,$dir, $maxmode,$h,@to_install);
 626
 627     foreach $ofn (keys %output_contents) {
 628         $fn= $ofn; $mfn= "output file $fn";
 629         for (;;) {
 630             if (!lstat $fn) {
 631                 $! == &ENOENT or die "$quis: stat $mfn:\n $!\n";
 632                 $maxmode= 0666;
 633                 last;
 634             } elsif (-f _) {
 635                 $maxmode= (stat _)[2];
 636                 last;
 637             } elsif (-l _) {
 638                 defined($l= readlink $fn)
 639                     or die "$quis: readlink $mfn:\n $!\n";
 640                 $dir= $fn =~ m,^.*/, ? $& : './';
 641                 $fn= "$dir$l" unless $l =~ m,^/,;
 642                 $mfn= "output file $fn (symlink target of $ofn)";
 643             } else {
 644                 die "$quis: output file $mfn exists but is not a file".
 645                     " (or symlink to one)";
 646             }
 647         }
 648         unlink "$fn.new" or $! == &ENOENT or
 649             die "$quis: cannot clear out old .new version of $mfn:\n $!";
 650         $h= new IO::File "$fn.new",'w',$maxmode
 651             or die("$quis: create .new version of $mfn:\n $!");
 652         print $h
 653             "# generated by $quis, do not edit\n",
 654             $output_contents{$ofn}
 655             or die "$quis: write data to .new version of $mfn:\n $!";
 656         $h->close
 657             or die "$quis: close .new version of $mfn:\n $!";
 658         push @to_install, $fn,$mfn;
 659     }
 660
 661     while (($fn,$mfn, @to_install) = @to_install) {
 662         rename "$fn.new",$fn
 663             or die "$quis: install new version of $mfn:\n $!";
 664     }
 665 }
 666
 667 #-------------------- general utilities
 668
 669 sub debug_dump ($) {
 670     my ($vn);
 671     return unless $debug>1;
 672     local $Data::Dumper::Terse=1;
 673     foreach $vn (split /\s+/, $_[0]) {
 674         print "$vn := ", eval "Dumper(\\$vn)";
 675     }
 676 }
 677
 678 sub debug_trace ($) {
 679     return unless $debug;
 680     print "D $_[0]\n";
 681 }
 682
 683 sub has_suffix_of ($$) {
 684     my ($whole,$suffix) = @_;
 685     debug_trace("has_suffix_of $whole $suffix");
 686     return 0 if length $whole < length $suffix;
 687     return 0 if substr($whole, length($whole) - length($suffix)) ne $suffix;
 688     debug_trace("has_suffix_of $whole $suffix YES");
 689     return 1;
 690 }
 691
 692 sub lookup ($$$$) {
 693     my ($domain,$type,$okrcodes,$w) = @_;
 694     my ($c,$h,@result);
 695     debug_trace("lookup ==> (->$okrcodes) $domain $type");
 696     $h= new IO::Handle;
 697
 698     defined($c= open $h, "-|") or die "$quis: fork adnshost:\n $!\n";
 699     if (!$c) {
 700         exec 'adnshost','-Fi','+Do','+Dt','+Dc','-Cf',"-t$type",
 701              '-',"$domain.";
 702         die "$quis: exec adnshost:\n $!\n";
 703     }
 704     @result= $h->getlines();
 705     $h->error and die "$quis: read from adnshost:\n $!\n";
 706     chomp @result;
 707     $!=0; $h->close;
 708     die "$quis: lookup -t$type $domain $okrcodes ($w) failed $? $! @result\n"
 709         if $! or $?&255 or $?>1536 or index($okrcodes,$?>>8)<0;
 710     debug_trace("lookup <== $? @result");
 711     return ($?,@result);
 712 }
 713
 714 sub dig (&$$$) {
 715     my ($eachrr, $qowner,$qtype,$qaddr) = @_;
 716     # also pseudo-rr with type `flags:'
 717     my ($h,$inmid,$irdata,$c,$digwhy);
 718     local ($_);
 719
 720     debug_trace("dig ==> \@$qaddr $qowner $qtype");
 721
 722     $h= new IO::Handle;
 723     defined($c= open $h, "-|") or die "$quis: fork dig:\n $!\n";
 724     if (!$c) {
 725         open STDERR, ">&STDOUT" or die $!;
 726         exec ('dig',
 727               '+nodef','+nosea','+nodebug','+norecurse',
 728               "\@$qaddr",'-t',$qtype,$qowner);
 729         die "$quis: exec dig:\n $!\n";
 730     }
 731     $inmid='';
 732     for (;;) {
 733         if (!defined($_= $h->getline())) {
 734             $h->error() and die "$quis: read from dig:\n $!\n";
 735             last;
 736         }
 737         chomp;
 738         if (length $inmid) {
 739             s/^\s+/ / or die "$inmid // $_ ?";
 740             s/\;.*$//;
 741             $_= $inmid.$_;
 742             $inmid='';
 743             s/$/ \(/ unless s/\s*\)\s*$//;
 744         }
 745         if (s/\s*\(\s*$//) { $inmid= $_; next; }
 746         $digwhy= "dig $qowner $qtype $qaddr \`$_'";
 747         if (m/^\;\; flags\:( [-0-9a-z ]+)\;/) {
 748             $dig_owner=''; $dig_type='flags:'; $dig_rdata= "$1 ";
 749             debug_trace("dig  f: $dig_rdata");
 750             &$eachrr;
 751         } elsif (m/^\;/) {
 752         } elsif (!m/\S/) {
 753         } elsif (m/^([-.0-9a-z]+)\s+\d\w+\s+in\s+([a-z]+)\s+(\S.*)/i) {
 754             $dig_owner=domain_canon($1,$digwhy); $dig_type=lc $2; $irdata=$3;
 755             if ($dig_type eq 'a') {
 756                 $irdata =~ m/^[.0-9]+$/ or die "$irdata ?";
 757                 $dig_rdata= $&;
 758             } elsif ($dig_type eq 'ns') {
 759                 $irdata =~ m/^[-.0-9a-z]+$/i or die "bad nameserver $irdata ?";
 760                 $dig_rdata= domain_canon($irdata,$digwhy);
 761             } elsif ($dig_type eq 'soa') {
 762                 $irdata =~ m/^([-.0-9a-z]+)\s+.*\s+(\d+)(?:\s+\d\w+){4}$/i
 763                     or die "bad SOA $irdata ?";
 764                 $dig_rdata= $2.' '.domain_canon($1,$digwhy);
 765             } else {
 766                 debug_trace("ignoring uknown RR type $dig_type");
 767                 next;
 768             }
 769             debug_trace("dig  $dig_owner $dig_type $dig_rdata");
 770             &$eachrr;
 771         } else {
 772             debug_trace("ignoring unknown dig output $_");
 773         }
 774     }
 775     $h->close;
 776     debug_trace("dig <== gave $?");
 777 }
 778
 779 sub domain_canon ($$) {
 780     my ($i,$w) = @_;
 781     $i =~ s/(.)\.$/$1/;
 782     return '.' if $i eq '.';
 783     die "domain $i ($w) ?" unless $i =~ m/^[0-9a-z]/i;
 784     return lc $i;
 785 }