scripts/named-conf

   1 #!/usr/bin/perl -w
   2 # This is chiark-named-conf, which is Copyright 2002 Ian Jackson.
   3 #
   4 # chiark-named-conf and its manpage are free software; you can
   5 # redistribute it and/or modify them under the terms of the GNU
   6 # General Public License as published by the Free Software Foundation;
   7 # either version 3, or (at your option) any later version.
   8 #
   9 # chiark-named-conf and its manpage are distributed in the hope that
  10 # it will be useful, but WITHOUT ANY WARRANTY; without even the
  11 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  12 # PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along
  15 # with this program; if not, consult the Free Software Foundation's
  16 # website at www.fsf.org, or the GNU Project website at www.gnu.org.
  17
  18 use strict;
  19 use IO::File;
  20 use Data::Dumper;
  21 use POSIX;
  22 use Fcntl qw(:DEFAULT :flock);
  23
  24 # bastard Perl wants me to do this now !
  25 sub loarg();
  26 sub soarg();
  27 sub usageerr ($);
  28 sub cfg_fail ($);
  29 sub read_config ($);
  30 sub qualify ($);
  31 sub bad_modifiers ($);
  32 sub zone_conf ($$$$$@);
  33 sub set_output($);
  34 sub progress ($$);
  35 sub verbose ($);
  36 sub process_zones (@);
  37 sub zone_warning ($$);
  38 sub zone_warnmore ($);
  39 sub zone_check_full ();
  40 sub zone_reset();
  41 sub zone_investigate();
  42 sub zone_check_nsrrset ($$$$);
  43 sub zone_ns_name ($$);
  44 sub zone_server_queue ($$$$$);
  45 sub zone_server_addr ($$$$$);
  46 sub zone_check_soa ($$$$);
  47 sub zone_consistency();
  48 sub zone_servers_ok ();
  49 sub zone_consistency_set ($%);
  50 sub zone_check_local ();
  51 sub zone_servers_simplefind ();
  52 sub zone_server_simple ($$$);
  53 sub zone_style ($$);
  54 sub mail_zone_before ();
  55 sub mail_zone_after ();
  56 sub pmail ($);
  57 sub ptime ($);
  58 sub mail_zone_mail ();
  59 sub zone_output ();
  60 sub output_files ();
  61 sub debug_dump ($);
  62 sub debug_trace ($);
  63 sub has_suffix_of ($$);
  64 sub lookup ($$$$);
  65 sub dig (&$$$);
  66 sub domain_canon ($$);
  67
  68 use vars qw($quis $stdout_fh $stderr_fh
  69             $mode $doall $domail
  70             $etcfile $where
  71             $debug $needglue $localonly $repeat $verbosity
  72             $admin $mail_state_dir $mail_max_warnfreq
  73             $progress_fh $warn_fh $modifiers
  74             %group2modcmd %group2used);
  75
  76 $|=1;
  77 $quis= $0; $quis =~ s,.*/,,;
  78
  79 $mode= '';
  80 $doall= 0;
  81 $etcfile= "/etc/bind/chiark-conf-gen.zones";
  82 $where= '<built-in>';
  83 $debug= 0;
  84 $needglue= 1;
  85 $localonly= 0;
  86 $verbosity= 2;
  87 $admin=''; $mail_state_dir=''; $mail_max_warnfreq= 50;
  88 $repeat= 0;
  89 $domail= '';
  90 $modifiers= '';
  91 $group2modcmd{'foreign'}= '$!*@?';
  92 $group2used{'foreign'}= 1;
  93
  94 ($progress_fh= $stdout_fh= new_from_fd IO::Handle(1,'w') and
  95  $warn_fh= $stderr_fh = new_from_fd IO::Handle(2,'w'))
  96     or die "$quis: setup standard filehandles: $!\n";
  97
  98 use vars qw($dig_owner $dig_type $dig_rdata);
  99
 100 while (@ARGV && $ARGV[0] =~ m/^\-/) {
 101     $_= shift @ARGV;
 102     if (s/^\-\-//) {
 103         last if m/^$/;
 104         if (m/^(yes|no|force)$/) { m/^./; $mode= $&; $domail=''; }
 105         elsif (m/^nothing$/) { $mode= 'x'; $domail=''; }
 106         elsif (m/^mail\-(first|middle|final|final\-test)$/) {
 107             $mode='n';
 108             $domail=$1;
 109         }
 110         elsif (m/^all$/) { $doall=1; }
 111         elsif (m/^config$/) { $etcfile= loarg(); $where= '--config option'; }
 112         elsif (m/^glueless$/) { $needglue=0; }
 113         elsif (m/^localonly$/) { $localonly=1; }
 114         elsif (m/^quiet$/) { $verbosity--; }
 115         elsif (m/^repeat$/) { $repeat=1; }
 116         elsif (m/^verbose$/) { $verbosity++; }
 117         else { usageerr("unknown option --$_"); }
 118     } else {
 119         s/^\-//;
 120         last if m/^$/;
 121         while (m/^./) {
 122             if (s/^[ynf]//) { $mode=$&; $domail=''; }
 123             elsif (s/^A//) { $doall=1; }
 124             elsif (s/^C//) { $etcfile= soarg(); $where= '-C option'; }
 125             elsif (s/^D//) { $debug++; }
 126             elsif (s/^g//) { $needglue=0; }
 127             elsif (s/^l//) { $localonly=1; }
 128             elsif (s/^m(\w+)(\W+)$//) {
 129                 my ($g,$m) = ($1,$2);
 130                 $group2modcmd{$g}=$m;
 131                 usageerr("modifiers $m for group $g: $@") if bad_modifiers($m);
 132             }
 133             elsif (s/^q//) { $verbosity--; }
 134             elsif (s/^r//) { $repeat=1; }
 135             elsif (s/^v//) { $verbosity++; }
 136             else { usageerr("unknown option -$&"); }
 137         }
 138     }
 139 }
 140
 141 sub loarg() { usageerr("missing option value") if !@ARGV; return shift @ARGV; }
 142 sub soarg() { my ($rv); $rv=$_; $_=''; return length $rv ? $rv : loarg(); }
 143
 144 usageerr("-q may be specified at most twice") if $verbosity<0;
 145 usageerr("-v may be specified at most once") if $verbosity>3;
 146 usageerr("-D may be specified at most twice") if $debug>2;
 147 usageerr("must specify either -f|-y|-n or zones (and not both)")
 148     if !!$mode == !!@ARGV && !$domail;
 149
 150 sub usageerr ($) {
 151     die <<END;
 152 $_[0]
 153
 154 usage: chiark-named-conf [options] -f|-y|-n|<zone>...
 155 operation modes:
 156  -f --force   install without checking
 157  -y --yes     check and install
 158  -n --no      check only (configured zones)
 159  --nothing    list zones only
 160  --mail-*     send mail about broken zones (see manpage)
 161  <zone> ...   check only (specified zones, even unconfigured ones)
 162 additional options:
 163  -A --all       report on zones marked ? (ones we know are broken)
 164  -D             debug $quis (does not help debug your DNS config)
 165  -g --glueless  do not warn about any glueless referrals (not recommended)
 166  -l --localonly full checks only on zones which we primary
 167  -q --quiet     no output for OK zones
 168  -r --repeat    repeat warnings for all sources of imperfect data
 169  -v --verbose   extra verbose info about each zone
 170  -C|--config <DIR/FILE  use FILE as default config and DIR as default dir
 171
 172 chiark-named-conf is Copyright 2002 Ian Jackson.  It is Free software, under
 173 the GNU General Public License, and you are welcome to change it and/or
 174 distribute copies under certain conditions.  There is ABSOLUTELY NO WARRANTY.
 175 END
 176 }
 177
 178 cfg_fail("config filename $etcfile should not be directory")
 179     if $etcfile =~ m,/$,;
 180
 181 use vars qw($default_dir);
 182 $default_dir= $etcfile =~ m,^.*/, ? $& : './';
 183
 184 use vars qw($slave_dir $slave_prefix $slave_suffix);
 185 $slave_dir= 'slave';
 186 $slave_prefix= '';
 187 $slave_suffix= '';
 188
 189 use vars qw(@self_ns @self_soa @self_addr @forbid_addr @forbid_slave
 190             @conv_glueless @indirect_glue);
 191 @self_ns= @self_soa= @self_addr= @forbid_addr= @forbid_slave= @indirect_glue= ();
 192 @conv_glueless= qw(in-addr.arpa ip6.arpa ip6.int);
 193
 194 use vars qw(%zone_cfg @zone_cfg_list);
 195 %zone_cfg= ();
 196 @zone_cfg_list= ();
 197
 198 use vars qw($output $default_output %output_contents);
 199 $output= '';
 200 $default_output= '';
 201 %output_contents= ();
 202
 203 use vars qw($check $install);
 204 $check= $mode !~ m/^[fx]/;
 205 $install= $mode =~ m/^[yf]/;
 206
 207 read_config($etcfile);
 208 debug_dump('@zone_cfg_list %zone_cfg');
 209 process_zones(!@ARGV ? @zone_cfg_list : @ARGV);
 210 debug_dump('%output_contents');
 211 output_files() if $install;
 212
 213 $stdout_fh->close or die "$quis: write messages to stdout: $!\n";
 214 $stderr_fh->close or die "$quis: write messages to stderr: $!\n";
 215 exit 0;
 216
 217 #-------------------- configuration reading
 218
 219 sub cfg_fail ($) { die "$quis: $where:\n $_[0]\n"; }
 220
 221 sub read_config ($) {
 222     my ($if) = @_;
 223     my ($fh,$z,@self,$before,$group,
 224         $mod,$dir,$prefix,$suffix,$subfile,$lprefix,$lsuffix,$zf);
 225     local ($_);
 226
 227     $fh= new IO::File $if,'r' or cfg_fail("open $if:\n $!");
 228     $before= '';
 229     for (;;) {
 230         if (!defined($_= <$fh>)) {
 231             cfg_fail("read config file $if:\n $!") if $fh->error();
 232             last;
 233         }
 234         chomp; s/\s+$//;
 235         if (s/\\$//) { $before.= $_; next; }
 236         $_= $before.$_;
 237         $before= '';
 238         s/^\s+//;
 239         $where= "$if:$.";
 240         next if m/^\#/;
 241         last if m/^end$/;
 242         next unless m/\S/;
 243         if (m/^self(\-ns|\-soa|)\s+(\S.*\S)/) {
 244             @self= split /\s+/, $2;
 245             @self_ns= @self if $1 ne '-soa';
 246             @self_soa= @self if $1 ne '-ns';
 247         } elsif (m/^serverless\-glueless\s+(\S.*\S)/) {
 248             @conv_glueless= split /\s+/, $1;
 249         } elsif (m/^allow\-indirect\-glue\s+(\S.*\S)/) {
 250             @indirect_glue= split /\s+/, $1;
 251         } elsif (m/^self\-addr\s+([0-9. \t]+)/) {
 252             @self_addr= split /\s+/, $1;
 253         } elsif (m/^forbid\-addr(?:\s+([0-9. \t]+))?/) {
 254             @forbid_addr= defined $1 ? split /\s+/, $1 : ();
 255         } elsif (m/^forbid\-slave(?:\s+([0-9. \t]+))?/) {
 256             @forbid_slave= defined $1 ? split /\s+/, $1 : ();
 257         } elsif (m,^
 258                  primary\-dir (\W*)
 259                  \s+ (\S+)/([^/ \t]*)
 260                  (?: \s+ ([^/ \t]*) (?: (/.+) )?
 261                   )?
 262                  $,x) {
 263             ($mod, $dir, $prefix, $suffix, $subfile) =
 264                 ($1,qualify($2),$3,$4,$5);
 265             cfg_fail("modifiers $mod for directory $dir: $@")
 266                 if bad_modifiers($mod);
 267             $suffix= '' if !defined $suffix;
 268             $subfile= '' if !defined $subfile;
 269             $suffix= '_db' if !length $suffix && !length $subfile;
 270             if (-d "$dir/$prefix") { $dir.='/'; $dir.=$prefix; $prefix=''; }
 271             opendir D, $dir or cfg_fail("open primary-dir $dir:\n $!");
 272             $lprefix= length $prefix; $lsuffix= length $suffix;
 273             while (defined($_= readdir D)) {
 274                 next if m/^\./ && !$lprefix;
 275                 next unless length > $lprefix+$lsuffix;
 276                 next unless substr($_,0,$lprefix) eq $prefix;
 277                 next unless substr($_,length($_)-$lsuffix) eq $suffix;
 278                 $z= substr($_,$lprefix,length($_)-($lprefix+$lsuffix));
 279                 $zf= $dir.'/'.$prefix.$z.$suffix.$subfile;
 280                 if (!stat $zf) {
 281                     next if length $subfile && $! == &ENOENT;
 282                     cfg_fail("cannot stat zonefile $zf:\n $!");
 283                 }
 284                 -f _ or cfg_fail("zonefile $zf is not a plain file");
 285                 zone_conf($z,'primary','p',$mod,$zf);
 286             }
 287             closedir D or cfg_fail("close primary-dir $dir:\n $!");
 288         } elsif (m/^primary(\W*)\s+(\S+)\s+(\S+)$/) {
 289             zone_conf($2,'primary','p',$1,qualify($3));
 290         } elsif (m/^published(\W*)\s+(\S+)\s+([0-9.\t]+)$/) {
 291             zone_conf($2,'published','s',$1,'',$3);
 292         } elsif (m/^stealth(\W*)\s+(\S+)\s+([0-9. \t]+)$/) {
 293             zone_conf($2,'stealth','u',$1,'',split /\s+/, $3);
 294         } elsif (m/^modifiers\s+(\W+)(?:\s+(\w+))$/) {
 295             ($mod,$group) = ($1,$2);
 296             cfg_fail("modifiers $mod for group $group: $@")
 297                 if bad_modifiers($mod);
 298             if (exists $group2modcmd{$group}) {
 299                 $mod= $group2modcmd{$group};
 300                 $group2used{$group}++;
 301             }
 302             $modifiers= $mod;
 303         } elsif (m/^slave\-dir\s+(\S+)(?:(?:\s+(\S+))\s+(\S+))?$/) {
 304             ($slave_dir, $slave_prefix, $slave_suffix) = (qualify($1),$2,$3);
 305             $slave_prefix='' if !defined $slave_prefix;
 306             $slave_suffix='' if !defined $slave_suffix;
 307         } elsif (m/^output\s+bind8\+(\S+)$/) {
 308             cfg_fail("default output may not apply to only some zones")
 309                 if @zone_cfg_list && length $default_output;
 310             set_output(qualify($1));
 311         } elsif (m/^include\s+(\S+)$/) {
 312             read_config($1);
 313         } elsif (m/^admin\s+(\S+)$/) {
 314             $admin=$1;
 315         } elsif (m/^mail\-state\-dir\s+(\S+)$/) {
 316             $mail_state_dir= $1;
 317         } elsif (m/^mail\-max\-warnfreq\s+(\d{1,3}(?:\.\d{0,5})?)$/) {
 318             cfg_fail("mail-max-warnfreq must be <=100") if $1>100;
 319             $mail_max_warnfreq= $1;
 320         } else {
 321             cfg_fail("unknown configuration directive".
 322                      " or incorrect syntax or arguments:\n".
 323                      " \`$_'");
 324         }
 325     }
 326     foreach $group (keys %group2modcmd) {
 327         next if exists $group2used{$group};
 328         cfg_fail("command line specifies modifier group $group".
 329                  " but missing in configuration file");
 330     }
 331     $fh->close or cfg_fail("close config file $if:\n $!");
 332 }
 333
 334 sub qualify ($) {
 335     my ($i) = @_;
 336     $i= "$default_dir$i" unless $i =~ m,^/,;
 337     return $i;
 338 }
 339
 340 sub bad_modifiers ($) {
 341     local ($_) = @_;
 342     if (!eval {
 343         die "bad modifier $&" if m/[^!*\$\@~?]/;
 344         die "repeated modifier $1" if m/(.).*\1/;
 345         1;
 346     }) {
 347         $@ =~ s/\n//;
 348         return 1;
 349     }
 350     return 0;
 351 }
 352
 353 sub zone_conf ($$$$$@) {
 354     my ($zone,$style,$sabbr,$mod,$file,@servers) = @_;
 355     my ($sfx,$aref);
 356     $file= qualify("$slave_dir/$slave_prefix".$zone.$slave_suffix)
 357         unless length $file;
 358     if (!length $output) {
 359         $default_output= qualify('chiark-conf-gen.bind8')
 360             unless length $default_output;
 361         set_output($default_output);
 362     }
 363     cfg_fail("redefined zone $zone\n".
 364              " earlier definition $zone_cfg{$zone}{'where'}")
 365         if exists $zone_cfg{$zone};
 366     $zone_cfg{$zone}{'where'}= $where;
 367     $zone_cfg{$zone}{'file'}= $file;
 368     $zone_cfg{$zone}{'style_p'}= $style.$mod;
 369     $zone_cfg{$zone}{'s'}= "$sabbr $mod $modifiers";
 370     # p)rimary s)econdary u)npub f)oreign
 371     # followed by modifiers, first per-zone, then default
 372     $zone_cfg{$zone}{'servers'}= [ @servers ];
 373     if ($domail) {
 374         length $admin && length $mail_state_dir or
 375             cfg_fail("mailing but failed to specify admin".
 376                      " or mail-state-dir before zone");
 377         $zone_cfg{$zone}{'admin'}= $admin;
 378         $zone_cfg{$zone}{'maildir'}= qualify($mail_state_dir);
 379         $zone_cfg{$zone}{'mailmwarn'}= $mail_max_warnfreq;
 380     }
 381     foreach $sfx (qw(self_soa self_ns self_addr forbid_addr forbid_slave
 382                      conv_glueless indirect_glue)) {
 383         { no strict 'refs'; $aref= [ @$sfx ]; }
 384         @$aref or cfg_fail("failed to specify $sfx before zone")
 385             if $sfx =~ m/^self/;
 386         $zone_cfg{$zone}{$sfx}= $aref;
 387     }
 388     foreach $sfx (qw(self_soa self_ns)) {
 389         map { s/\*$/$zone/ } @{ $zone_cfg{$zone}{$sfx} };
 390     }
 391     $zone_cfg{$zone}{'output'}= $output;
 392     push @zone_cfg_list, $zone;
 393 }
 394
 395 sub set_output($) {
 396     my ($newout) = @_;
 397     $output= $newout;
 398     $output_contents{$output}= '';
 399 }
 400
 401 #-------------------- checking
 402
 403 use vars qw($zone $cfg $warnings %zone_warnings);
 404 $warnings= 0;
 405
 406 sub progress ($$) {
 407     my ($minv,$m) = @_;
 408     return if $verbosity < $minv;
 409     print $progress_fh "$m\n" or die "$quis: $zone: write log: $!\n";
 410 }
 411
 412 sub verbose ($) { progress(3, '    ' . $_[0]); }
 413
 414 sub process_zones (@) {
 415     my (@zones) = @_;
 416     local ($zone,$cfg);
 417
 418     foreach $zone (@zones) {
 419         $cfg= $zone_cfg{$zone} || {
 420             'style_p' => 'foreign',
 421             's' => "f $group2modcmd{'foreign'}",
 422             'servers' => [ ],
 423             };
 424
 425         mail_zone_before() or next
 426             if $domail;
 427         zone_reset();
 428         progress(1, sprintf "%-20s %s", $zone, $$cfg{'style_p'});
 429         if ($check && ($doall || !zone_style('?',0))) {
 430             eval {
 431                 if ($localonly && $cfg->{'s'} =~ m/f/) {
 432                     zone_warning("foreign zone specified with -l",'');
 433                 } elsif ($localonly && $cfg->{'s'} !~ m/p/) {
 434                     zone_check_local();
 435                 } else {
 436                     zone_check_full();
 437                 }
 438             };
 439             zone_warning("checks failed: $@",'') if length $@;
 440         }
 441         $output_contents{$$cfg{'output'}} .= zone_output()
 442             if $install;
 443
 444         mail_zone_after() if $domail;
 445     }
 446     if ($domail) {
 447     } elsif ($warnings) {
 448         printf STDERR ("%s: %d warning(s) in %d zone(s);".
 449                        " %d zone(s) checked ok.\n",
 450                        $quis,
 451                        $warnings,
 452                        scalar(keys %zone_warnings),
 453                        scalar(@zones - keys %zone_warnings));
 454     } else {
 455         progress(1, sprintf "%d zone(s) checked ok", scalar @zones);
 456     }
 457 }
 458
 459 use vars qw(%delgs); # $delgs{$nameserver_list} = [ $whosaidandwhy ]
 460 use vars qw(%auths); # $auths{$nameserver_list} = [ $whosaidandwhy ]
 461 use vars qw(%glue);  # $glue{$name}{$addr_list} = [ $whosaidandwhy ]
 462 use vars qw(%soas);  # $soa{"$serial $mname"} = [ $whosaidandwhy ]
 463 use vars qw(%addr_is_ok %warned);
 464 use vars qw($delg_to_us);
 465 use vars qw(@to_check); # ($addr,$whyask,$name_if_auth,$glueless_ok, ...)
 466 use vars qw(@to_check_soa); # ($addr,$whyask,$name,$is_ns, ...)
 467
 468 sub zone_warning ($$) {
 469     my ($w,$o) = @_;
 470     my ($wk);
 471
 472     return 0 if !$repeat && $warned{$w}++;
 473
 474     $w =~ s/\n$//;
 475     $w =~ s,\n, // ,g;
 476
 477     $w .= " ($o)" if length $o;
 478     print $warn_fh "$zone: warning: $w\n" or die $!;
 479     $warnings++;
 480     $zone_warnings{$zone}++;
 481     return 1;
 482 }
 483
 484 sub zone_warnmore ($) {
 485     print $warn_fh "$zone:  $_[0]\n" or die $!;
 486 }
 487
 488 sub zone_check_full () {
 489     zone_investigate();
 490     zone_consistency();
 491     zone_servers_ok();
 492 }
 493
 494 sub zone_reset() {
 495     %delgs= %auths= %glue= %soas= %warned= %addr_is_ok= ();
 496     $delg_to_us= 0;
 497     @to_check= @to_check_soa= ();
 498 }
 499
 500 sub zone_investigate() {
 501     my ($super_zone, @start_nsnames, $start_ww,
 502         $start_ns, @start_ns_addrs, $s, $wa, $name_if_auth,
 503         %nsrrset_checked, %soa_checked, $addr, $glueless_ok,
 504         $rcode, $name, $is_ns);
 505
 506     if (!zone_style('*',0)) {
 507         $super_zone= $zone;
 508         for (;;) {
 509             debug_trace("zone $zone superzone $super_zone");
 510             $super_zone eq '.'
 511                 and die "no superzone ? ($super_zone)\n";
 512             $super_zone =~ s/^[^.]+\.//
 513                 or $super_zone= '.';
 514             ($rcode,@start_nsnames)=
 515                 lookup($super_zone,'ns-','06',"superzone search");
 516             last if !$rcode;
 517         }
 518         $start_ww= "server for $super_zone";
 519     } else {
 520         ($rcode,@start_nsnames)=
 521             lookup($zone,'ns-','0',"initial nameserver search");
 522         $start_ww= "nameserver for $zone";
 523     }
 524     for $start_ns (@start_nsnames) {
 525         $start_ns= lc $start_ns;
 526         ($rcode,@start_ns_addrs)= lookup($start_ns,'a','0',"$start_ww");
 527         foreach $addr (@start_ns_addrs) {
 528             push @to_check, $addr, "$start_ns, $start_ww", undef, 0;
 529         }
 530     }
 531     for (;;) {
 532         # We do these in order so that we always do NS RRset checks on
 533         # nameservers that came from other NS RRsets first; otherwise
 534         # we might set nsrrset_checked due to a glueless_ok check,
 535         # and then not check for gluefulness later.
 536         debug_dump('@to_check @to_check_soa');
 537         if (($addr,$wa,$name_if_auth,$glueless_ok,@to_check) = @to_check) {
 538             push @to_check_soa, $addr, $wa, $name_if_auth, 1,
 539                 if defined $name_if_auth;
 540             next if $nsrrset_checked{$addr}++;
 541             zone_check_nsrrset($addr, $wa, $name_if_auth, $glueless_ok);
 542         } elsif (($addr,$wa,$name,$is_ns,@to_check_soa) = @to_check_soa) {
 543             next if $soa_checked{$addr}++;
 544             zone_check_soa($addr,$wa,$name,$is_ns);
 545         } else {
 546             last;
 547         }
 548     }
 549 }
 550
 551 sub zone_check_nsrrset ($$$$) {
 552     my ($uaddr,$wa, $name_if_auth, $glueless_ok) = @_;
 553     my (@s, $s, $a, %s2g, @glue, $glue, $delgs_or_auths, $wwn, $ww);
 554     my ($rcode);
 555     $ww= "[$uaddr] $wa";
 556     verbose("checking delegation by $ww");
 557     dig(sub {
 558         if ($dig_type eq 'ns' && $dig_owner eq $zone) {
 559             $s2g{lc $dig_rdata} = [ ];
 560         } elsif ($dig_type eq 'a' && exists $s2g{$dig_owner}) {
 561             $wwn= "in glue from $ww";
 562             zone_server_queue($dig_rdata,$dig_owner,$wwn,"NS [$uaddr]",0);
 563             push @{ $s2g{$dig_owner} }, $dig_rdata;
 564         }
 565     },
 566              $zone,'ns',$uaddr);
 567     if (!%s2g) {
 568         zone_warning("unable to find NS RRset at [$uaddr]", $wa);
 569         return;
 570     } elsif (keys %s2g == 1) {
 571         zone_warning("only one nameserver ". (join '', keys %s2g),
 572                      $ww);
 573     }
 574     @s= sort keys %s2g;
 575     foreach $s (@s) {
 576         zone_ns_name($s,$ww);
 577         @glue= @{ $s2g{$s} };
 578         if (!@glue) {
 579             zone_warning("glueless NS $s", $ww)
 580                 unless $glueless_ok
 581                     or zone_style('~',!$needglue)
 582                     or grep { has_suffix_of($zone,".$_"); }
 583                            @{ $cfg->{'conv_glueless'} }
 584                     or ((grep { has_suffix_of($s,".$_"); }
 585                            @{ $cfg->{'indirect_glue'} }) and
 586                         !(grep { has_suffix_of($zone,".$_"); }
 587                            @{ $cfg->{'indirect_glue'} }));
 588             ($rcode,@glue)= lookup($s,'a','0',"glueless NS from $ww");
 589             foreach $a (@glue) {
 590                 $wwn= "glueless NS from $ww";
 591                 zone_server_queue($a,$s,$wwn,"NS [$uaddr]",0);
 592             }
 593         }
 594         $glue= join ' ', sort @glue;
 595         push @{ $glue{$s}{$glue} }, $ww;
 596     }
 597     $s= join ' ', @s;
 598     $delgs_or_auths= defined($name_if_auth) ? \%auths : \%delgs;
 599     push @{ $delgs_or_auths->{$s} }, $ww;
 600 }
 601
 602 sub zone_ns_name ($$) {
 603     my ($name,$ww) = @_;
 604     my ($cg);
 605     $delg_to_us=1 if grep { $name eq $_ } @{ $cfg->{'self_ns'} };
 606     foreach $cg (@{ $cfg->{'conv_glueless'} }) {
 607         zone_warning("nameserver $name in serverless-glueless".
 608                      " namespace area $cg",
 609                      $ww)
 610             if has_suffix_of(".$name",".$cg");
 611     }
 612     zone_warning("published server, as $name, but configured as stealth",
 613                  $ww)
 614         if $cfg->{'s'} =~ m/u/ &&
 615            grep { $_ eq $name }
 616                @{ $cfg->{'self_ns'} }, @{ $cfg->{'self_soa'} };
 617 }
 618
 619 sub zone_server_queue ($$$$$) {
 620     my ($addr,$name,$wwn,$wwq,$is_soa) = @_;
 621     zone_server_addr($addr,$name,$wwn,$wwq,$is_soa);
 622     push @to_check, $addr, "$name, $wwn", $name, $is_soa;
 623 }
 624
 625 sub zone_server_addr ($$$$$) {
 626     my ($addr,$name,$ww,$wwq,$is_soa) = @_;
 627     debug_trace("zone_server_addr ".join('|',@_));
 628     $addr_is_ok{$addr}= "$name ($wwq)"
 629         if $is_soa || $cfg->{'s'} =~ m/u/;
 630     zone_warning("forbidden nameserver address [$addr] $name",$ww)
 631         if grep { $_ eq $addr } @{ $cfg->{'forbid_addr'} };
 632     zone_warning("forbidden server address for our slave [$addr] $name",$ww)
 633         if $cfg->{'s'} =~ m/p/ and
 634            grep { $_ eq $addr } @{ $cfg->{'forbid_slave'} };
 635
 636     my ($name_is_self, $addr_is_self);
 637     $name_is_self= grep { $_ eq $name }
 638         @{ $cfg->{$is_soa ? 'self_soa' : 'self_ns'} };
 639     $addr_is_self= grep { $_ eq $addr }
 640         @{ $cfg->{'self_addr'} };
 641     if ($name_is_self && !$addr_is_self) {
 642         zone_warning("our $name supplied with wrong address [$addr]", $ww);
 643     }
 644     if (!$name_is_self && $addr_is_self) {
 645         zone_warning("we [$addr] are named in ".
 646                      ($is_soa ? "SOA" : "NS").
 647                      " by wrong name $name",
 648                      $ww);
 649     }
 650     if (!$name_is_self && !$addr_is_self &&
 651         $is_soa && $cfg->{'s'} =~ m/p/) {
 652         zone_warning("SOA MNAME $name is not us (".
 653                      (join ' ', @{ $cfg->{'self_soa'} }).")", $ww);
 654     }
 655     $delg_to_us=1 if $addr_is_self && !$is_soa;
 656 }
 657
 658 sub zone_check_soa ($$$$) {
 659     my ($uaddr,$wa,$name,$is_ns) = @_;
 660     my ($lame,$serial,$mname,$got,$rcode,@soa_addrs,$soa_addr,$ww,$wwn);
 661     verbose("checking service at [$uaddr] $name");
 662     $lame= 'dead or lame';
 663     $ww= "[$uaddr] $wa";
 664     dig(sub {
 665         if ($dig_type eq 'flags:') {
 666             $lame= $dig_rdata =~ m/ aa / ? '' : 'lame';
 667         } elsif ($dig_type eq 'soa' && $dig_owner eq $zone && !$lame) {
 668             die "several SOAs ? $ww" if defined $mname;
 669             $got= $dig_rdata;
 670             $got =~ m/^(\d+) (\S+)$/ or die "$got ?";
 671             ($serial,$mname) = ($1,$2);
 672         }
 673     },
 674              $zone,'soa',$uaddr);
 675     $lame= 'broken' if !$lame && !defined $mname;
 676     if ($lame) { zone_warning("$lame server [$uaddr]",$wa); return; }
 677     progress(2, sprintf "%-16s %46s has %s%s",
 678              $zone, "$name [$uaddr]", $serial, $is_ns ? '' : '*');
 679     push @{ $soas{$got} }, $ww;
 680     ($rcode,@soa_addrs)= lookup($mname,'a','0',"SOA MNAME");
 681     $wwn= "SOA MNAME from $ww";
 682     foreach $soa_addr (@soa_addrs) {
 683         zone_server_queue($soa_addr,$mname,$wwn,"SOA [$uaddr]",1);
 684     }
 685 }
 686
 687 sub zone_consistency() {
 688     my ($d, $org_ser, $mname, $a, $h, $self_soa, $wa);
 689     zone_consistency_set('delegations',\%delgs);
 690     foreach $d (keys %delgs) { delete $auths{$d}; }
 691     zone_consistency_set('zone nameserver rrset',\%auths);
 692     foreach $h (keys %glue) {
 693         zone_consistency_set("glue for $h", $glue{$h});
 694     }
 695     zone_consistency_set("serial number and/or SOA MNAME",\%soas);
 696     $self_soa= $cfg->{'self_soa'};
 697 }
 698
 699 sub zone_servers_ok () {
 700     my ($showok,%fs);
 701     if (%addr_is_ok) {
 702         $showok= 0;
 703         foreach $a (@{ $cfg->{'servers'} }) {
 704             next if exists $addr_is_ok{$a};
 705             zone_warning("we slave from [$a]",'')
 706                 and $showok=1;
 707         }
 708         if ($showok) {
 709             foreach $a (keys %addr_is_ok) {
 710                 zone_warnmore("permitted master [$a] $addr_is_ok{$a}");
 711             }
 712         }
 713     }
 714     if ($cfg->{'s'} =~ m/s/ && !$delg_to_us) {
 715         zone_warning("we are supposedly published secondary,".
 716                      " but not listed as a nameserver",'');
 717         map { $fs{$_}=1 } keys(%delgs), keys(%auths);
 718         zone_warnmore("servers are: ". join ' ', sort keys %fs);
 719     }
 720 }
 721
 722 sub zone_consistency_set ($%) {
 723     my ($msg,$set) = @_;
 724     my ($d,$o);
 725     if (keys(%$set) > 1) {
 726         zone_warning("inconsistent $msg:",'');
 727         foreach $d (keys %$set) {
 728             foreach $o (@{ $set->{$d} }) { zone_warnmore(" $d from $o"); }
 729         }
 730     }
 731 }
 732
 733 sub zone_check_local () {
 734     zone_servers_simplefind();
 735     zone_servers_ok();
 736 }
 737
 738 sub zone_servers_simplefind () {
 739     my ($rcode,@nsnames,$ns,@soas,$mname);
 740
 741     ($rcode,@nsnames)= lookup($zone,'ns-','0',"zone's servers");
 742     foreach $ns (@nsnames) {
 743         zone_ns_name($ns,"NS");
 744         zone_server_simple($ns,'NS',0);
 745     }
 746     $delgs{join ' ', sort @nsnames} = [ "zone's servers" ];
 747
 748     ($rcode,@soas)= lookup($zone,'soa','0',"SOA MNAME");
 749     die "multiple SOA RRs in set!  @soas ?" if @soas!=1;
 750     $soas[0] =~ m/^(\S+)\s/ or die "SOA ? $_";
 751     zone_server_simple(domain_canon($1,"lookup $zone SOA"),'SOA',1);
 752 }
 753
 754 sub zone_server_simple ($$$) {
 755     my ($name,$ww,$is_soa) = @_;
 756     my ($rcode,@addrs,$addr);
 757     ($rcode,@addrs)= lookup($name,'a','0', "server - ".
 758                             ($is_soa ? "SOA MNAME" : "NS"));
 759     foreach $addr (@addrs) { zone_server_addr($addr,$name,$ww,$ww,$is_soa); }
 760 }
 761
 762 sub zone_style ($$) {
 763     my ($stylechar, $default) = @_;
 764     local ($_) = $$cfg{'s'};
 765     $stylechar =~ s/\W/\\$&/ or die;
 766     return m/(\S*)$stylechar/ ? $1 !~ m/\!/ : $default;
 767 }
 768
 769 #-------------------- mailing
 770
 771 use vars qw($m_base $m_lastok @m_ok @m_fail
 772             $m_info $m_time $m_lock $m_m);
 773
 774 sub mail_zone_before () {
 775     my (@s1,@s2);
 776
 777     $m_base= $$cfg{'maildir'}.'/'.$zone;
 778     $m_lastok= '-';
 779     @m_ok= ();
 780     @m_fail= ();
 781
 782     for (;;) {
 783         $m_lock= new IO::File "${m_base}_lock", O_RDWR|O_CREAT, 0600
 784             or die "$quis: create lockfile ${m_base}_lock: $!\n";
 785         if (!flock($m_lock, LOCK_EX|LOCK_NB)) {
 786             <$m_lock> =~ m/^\d+ /;
 787             die "$quis: $zone: concurrrency? - flock $&$!\n";
 788             $m_lock->close;
 789             return 0;
 790         }
 791         (@s1= $m_lock->stat) or die "$quis: fstat ${m_base}_lock: $!\n";
 792         (@s2= stat "${m_base}_lock") or
 793             die "$quis: stat ${m_base}_lock: $!\n";
 794         last if ($s1[0] eq $s2[0] && $s1[1] eq $s2[1]);
 795         $m_lock->close;
 796     }
 797     (print $m_lock "$$        \n" and $m_lock->flush)
 798         or die "$quis: write pid to ${m_base}_lock: $!\n";
 799
 800     if ($m_info= new IO::File "${m_base}_info", 'r') {
 801         $!=0; $_= <$m_info>;
 802         $_ =~ m/\n/ or die "$quis: read ${m_base}_info: $!\n";
 803         m/^\d+ (\d+|-) ([0-9:]*) ([0-9:]*) / or
 804             die "$quis: ${m_base}_info malformed\n";
 805         $m_lastok= $1;
 806         if ($domail ne 'first') {
 807             if ($2 eq ':' && $3 eq ':') {
 808                 warn "$quis: $zone: mid/last run, but last".
 809                     "run already done, ignoring zone\n";
 810                 return 0;
 811             }
 812             @m_ok= split /\:/, $2;
 813             @m_fail= split /\:/, $3;
 814         }
 815     } elsif ($! != &ENOENT) {
 816         die "$quis: open ${m_base}_info: $!\n";
 817     } elsif ($domail ne 'first') {
 818         warn "$quis: $zone: first run, but not --mail-first,".
 819             " ignoring zone\n";
 820         return 0;
 821     }
 822     if ($domail eq 'first') {
 823         remove "${m_base}_history" or $!==&ENOENT
 824             or die "$quis: remove ${m_base}_history: $!\n";
 825     }
 826     $progress_fh= $warn_fh= new IO::File "${m_base}_history",'a',0666
 827         or die "$quis: open ${m_base}_history: $!\n";
 828     $m_info= new IO::File "${m_base}_info.tmp",'w',0666
 829         or die "$quis: open ${m_base}_info.tmp: $!\n";
 830
 831     $m_time= time;
 832     progress(-1, "\n".('-'x70)."\n".ptime($m_time)."\n");
 833     return 1;
 834 }
 835
 836 sub mail_zone_after () {
 837     if ($zone_warnings{$zone}) {
 838         push @m_fail, $m_time;
 839         progress(-1,"failed - $zone_warnings{$zone} warnings");
 840     } else {
 841         push @m_ok, $m_time;
 842         $m_lastok= $m_time;
 843         progress(-1,"everything is fine");
 844     }
 845     close $progress_fh or die "$quis: close ${m_base}_history: $!\n";
 846     $progress_fh= $warn_fh= $stderr_fh;
 847
 848     if ($domail =~ m/^final/) {
 849         if (100*@m_fail <= $$cfg{'mailmwarn'}*(@m_fail + @m_ok)) {
 850             printf " %-40s ok\n", $zone or die "$quis: mail ok report: $!\n";
 851         } elsif (zone_style('@',0)) {
 852             printf " %-40s mail suppressed\n", $zone
 853                 or die "$quis: mail suppress report: $!\n";
 854         } else {
 855             mail_zone_mail();
 856         }
 857     } else {
 858         printf " %-40s %d warns. OK %s Fail %s\n",
 859             $zone,
 860             defined $zone_warnings{$zone} ? $zone_warnings{$zone} : 0,
 861             join(',', map { $_ - $m_time } @m_ok),
 862             join(',', map { $_ - $m_time } @m_fail)
 863                 or die "$quis: checking progress report: $!\n";
 864     }
 865
 866     @m_fail= @m_ok= ('','')
 867         if $domail =~ m/^final/;
 868
 869     printf $m_info "%s %s %s %s \n",
 870         $m_time, $m_lastok, join(':',@m_ok), join(':',@m_fail)
 871             or die "$quis: write new ${m_base}_info: $!\n";
 872     $m_info->close or die "$quis: close new ${m_base}_info: $!\n";
 873     rename "${m_base}_info.tmp", "${m_base}_info"
 874         or die "$quis: install new ${m_base}_info: $!\n";
 875     $m_lock->close;
 876 }
 877
 878
 879 sub pmail ($) {
 880     print $m_m $_[0]
 881         or die "$quis: write ${m_base}_mail: $!\n";
 882 }
 883 sub ptime ($) {
 884     my ($time) = @_;
 885     return gmtime($time)." GMT ($time)";
 886 }
 887
 888 sub mail_zone_mail () {
 889     my ($log, $zone_to, $zterr, $c, $r, $t, @soas);
 890     $m_m= new IO::File "${m_base}_mail", 'w', 0666
 891         or die "$quis: create ${m_base}_mail: $!\n";
 892     $zone_to=''; $zterr='';
 893     if (!zone_style("\$", $$cfg{'s'} !~ m/[ps]/)) {
 894         eval {
 895             ($r,@soas)= lookup($zone,'soa','0','problem-addr');
 896             @soas==1 or die "multiple soas\n";
 897             $soas[0] =~ m/^\S+ (\S.*\@\S+) [0-9 ]+$/ or
 898                 die "bad soa \`$_'\n";
 899             $zone_to= $1;
 900         };
 901         $zterr= $@;
 902         $zterr =~ s/\n$//;
 903     }
 904     pmail <<END
 905 From: zone checker <$$cfg{'admin'}>
 906 Subject: $zone - configuration problems report
 907 END
 908 ;
 909     pmail("To: ");
 910     pmail("(testing!) ") if $domail ne 'final';
 911     pmail("SOA MNAME for $zone <$zone_to>\nCC: ") if length($zone_to);
 912     pmail($$cfg{'admin'}."\n\n");
 913     pmail <<END
 914 You are receiving this mail because your email address is listed
 915 in the SOA (Start Of Authority) record for $zone
 916 in the DNS, which means you are supposedly the DNS administrator
 917 responsible for this zone.  This report is generated automatically
 918 on behalf of $$cfg{'admin'}, who
 919 is the administrator for a server for the zone.  Please contact
 920 them if you have any problem with this report.
 921
 922 END
 923 if length $zone_to;
 924     pmail <<END
 925 Sent to $$cfg{'admin'} since SOA MNAME unavailable:
 926 $zterr
 927
 928 END
 929 if length $zterr;
 930     pmail <<END
 931 The zone has had configuration errors or persistent operational
 932 problems during recent checks.  See the logs below for details.
 933
 934 Recent check history for $zone:
 935 END
 936 ;
 937     if ($m_lastok ne '-') {
 938         pmail(" Last seen to be fine: ".ptime($m_lastok)."\n");
 939     } else {
 940         pmail(" No record of this zone ever being fine.\n");
 941     }
 942     for $t (@m_fail) {
 943         pmail(" Zone had problems at: ".ptime($t)."\n");
 944     }
 945     for $t (@m_ok) {
 946         pmail(" Everything in order at: ".ptime($t)."\n");
 947     }
 948     pmail("\n");
 949     $log= new IO::File "${m_base}_history",'r'
 950         or die "$quis: reopen ${m_base}_history: $!";
 951     undef $/;
 952     pmail($log->getline);
 953     $/= "\n";
 954     (!$log->error and $log->close)
 955         or die "$quis: reread or close ${m_base}_log: $!\n";
 956     $log->eof or die;
 957     $m_m->close or die "$quis: close ${m_base}_mail: $!\n";
 958     $m_m= new IO::File "${m_base}_mail"
 959         or die "$quis: reopen ${m_base}_mail: $!";
 960
 961     defined($c= fork) or die "$quis: fork for mail: $!\n";
 962     if (!$c) {
 963         defined dup2($m_m->fileno, 0)
 964             or die "$quis - sendmail: dup for stdin: $!\n";
 965         exec (qw(/usr/sbin/sendmail -odb -oee -oi),
 966               ($domail eq 'final' ? '-t' : $$cfg{'admin'}));
 967         die "$quis - sendmail: exec: $!\n";
 968     }
 969     $m_m->close;
 970     $!=0; $r= waitpid $c,0;
 971     $r == $c or die "$quis: waitpid sendmail ($c): $r $!";
 972     $? and warn "$quis: sendmail failed: $?\n";
 973
 974     printf " %-40s %s\n", $zone,
 975         length $zone_to ? $zone_to : 'reporting to admin'
 976             or die "$quis: write mailing report: $!\n";
 977 }
 978
 979 #-------------------- outputting
 980
 981 sub zone_output () {
 982     my ($o,$m);
 983
 984     $o= "zone \"$zone\" {\n";
 985     if ($$cfg{'s'} =~ m/p/) {
 986         $o.= "    type master;\n";
 987     } else {
 988         $o.= "    type slave;\n".
 989              "    masters {\n";
 990         foreach $m (@{ $$cfg{'servers'} }) { $o.= "        $m;\n"; }
 991         $o.= "    };\n";
 992     }
 993     $o.= "    file \"$$cfg{'file'}\";\n";
 994     $o.= "};\n";
 995     return $o;
 996 }
 997
 998 sub output_files () {
 999     my ($fn,$ofn,$mfn,$l,$dir, $maxmode,$h,@to_install);
1000
1001     foreach $ofn (keys %output_contents) {
1002         $fn= $ofn; $mfn= "output file $fn";
1003         for (;;) {
1004             if (!lstat $fn) {
1005                 $! == &ENOENT or die "$quis: stat $mfn:\n $!\n";
1006                 $maxmode= 0666;
1007                 last;
1008             } elsif (-f _) {
1009                 $maxmode= (stat _)[2];
1010                 last;
1011             } elsif (-l _) {
1012                 defined($l= readlink $fn)
1013                     or die "$quis: readlink $mfn:\n $!\n";
1014                 $dir= $fn =~ m,^.*/, ? $& : './';
1015                 $fn= "$dir$l" unless $l =~ m,^/,;
1016                 $mfn= "output file $fn (symlink target of $ofn)";
1017             } else {
1018                 die "$quis: output file $mfn exists but is not a file".
1019                     " (or symlink to one)";
1020             }
1021         }
1022         unlink "$fn.new" or $! == &ENOENT or
1023             die "$quis: cannot clear out old .new version of $mfn:\n $!";
1024         $h= new IO::File "$fn.new",'w',$maxmode
1025             or die("$quis: create .new version of $mfn:\n $!");
1026         print $h
1027             "# generated by $quis, do not edit\n",
1028             $output_contents{$ofn}
1029             or die "$quis: write data to .new version of $mfn:\n $!";
1030         $h->close
1031             or die "$quis: close .new version of $mfn:\n $!";
1032         push @to_install, $fn,$mfn;
1033     }
1034
1035     while (($fn,$mfn, @to_install) = @to_install) {
1036         rename "$fn.new",$fn
1037             or die "$quis: install new version of $mfn:\n $!";
1038     }
1039 }
1040
1041 #-------------------- general utilities
1042
1043 sub debug_dump ($) {
1044     my ($vn);
1045     return unless $debug>1;
1046     local $Data::Dumper::Terse=1;
1047     foreach $vn (split /\s+/, $_[0]) {
1048         print "$vn := ", eval "Dumper(\\$vn)";
1049     }
1050 }
1051
1052 sub debug_trace ($) {
1053     return unless $debug;
1054     print "D $_[0]\n";
1055 }
1056
1057 sub has_suffix_of ($$) {
1058     my ($whole,$suffix) = @_;
1059     debug_trace("has_suffix_of $whole $suffix");
1060     return 0 if length $whole < length $suffix;
1061     return 0 if substr($whole, length($whole) - length($suffix)) ne $suffix;
1062     debug_trace("has_suffix_of $whole $suffix YES");
1063     return 1;
1064 }
1065
1066 sub lookup ($$$$) {
1067     my ($domain,$type,$okrcodes,$w) = @_;
1068     my ($c,$h,@result);
1069     debug_trace("lookup ==> (->$okrcodes) $domain $type");
1070     $h= new IO::Handle;
1071
1072     defined($c= open $h, "-|") or die "$quis: fork adnshost:\n $!\n";
1073     if (!$c) {
1074         exec 'adnshost','-Fi','+Do','+Dt','+Dc','-Cf',"-t$type",
1075              '-',"$domain";
1076         die "$quis: exec adnshost:\n $!\n";
1077     }
1078     @result= $h->getlines();
1079     $h->error and die "$quis: read from adnshost:\n $!\n";
1080     chomp @result;
1081     $!=0; $h->close;
1082     die "$quis: lookup -t$type $domain $okrcodes ($w) failed $? $! @result\n"
1083         if $! or $?&255 or $?>1536 or index($okrcodes,$?>>8)<0;
1084     debug_trace("lookup <== $? @result");
1085     return ($?,@result);
1086 }
1087
1088 sub dig (&$$$) {
1089     my ($eachrr, $qowner,$qtype,$qaddr) = @_;
1090     # also pseudo-rr with type `flags:'
1091     my ($h,$inmid,$irdata,$c,$digwhy);
1092     local ($_);
1093
1094     debug_trace("dig ==> \@$qaddr $qowner $qtype");
1095
1096     $h= new IO::Handle;
1097     defined($c= open $h, "-|") or die "$quis: fork dig:\n $!\n";
1098     if (!$c) {
1099         open STDERR, ">&STDOUT" or die $!;
1100         exec ('dig',
1101               '+nodef','+nosea','+nodebug','+norecurse',
1102               "\@$qaddr",'-t',$qtype,$qowner);
1103         die "$quis: exec dig:\n $!\n";
1104     }
1105     $inmid='';
1106     for (;;) {
1107         if (!defined($_= $h->getline())) {
1108             $h->error() and die "$quis: read from dig:\n $!\n";
1109             last;
1110         }
1111         chomp;
1112         if (length $inmid) {
1113             s/^\s+/ / or die "$inmid // $_ ?";
1114             s/\;.*$//;
1115             $_= $inmid.$_;
1116             $inmid='';
1117             s/$/ \(/ unless s/\s*\)\s*$//;
1118         }
1119         if (s/\s*\(\s*$//) { $inmid= $_; next; }
1120         $digwhy= "dig $qowner $qtype $qaddr \`$_'";
1121         if (m/^\;\; flags\:( [-0-9a-z ]+)\;/) {
1122             $dig_owner=''; $dig_type='flags:'; $dig_rdata= "$1 ";
1123             debug_trace("dig  f: $dig_rdata");
1124             &$eachrr;
1125         } elsif (m/^\;/) {
1126         } elsif (!m/\S/) {
1127         } elsif (m/^([-.0-9a-z]+)\s+\d\w+\s+in\s+([a-z]+)\s+(\S.*)/i) {
1128             $dig_owner=domain_canon($1,$digwhy); $dig_type=lc $2; $irdata=$3;
1129             if ($dig_type eq 'a') {
1130                 $irdata =~ m/^[.0-9]+$/ or die "$irdata ?";
1131                 $dig_rdata= $&;
1132             } elsif ($dig_type eq 'ns') {
1133                 $irdata =~ m/^[-.0-9a-z]+$/i or die "bad nameserver $irdata ?";
1134                 $dig_rdata= domain_canon($irdata,$digwhy);
1135             } elsif ($dig_type eq 'soa') {
1136                 $irdata =~ m/^([-.0-9a-z]+)\s+.*\s+(\d+)(?:\s+\d\w+){4}$/i
1137                     or die "bad SOA $irdata ?";
1138                 $dig_rdata= $2.' '.domain_canon($1,$digwhy);
1139             } else {
1140                 debug_trace("ignoring uknown RR type $dig_type");
1141                 next;
1142             }
1143             debug_trace("dig  $dig_owner $dig_type $dig_rdata");
1144             &$eachrr;
1145         } else {
1146             debug_trace("ignoring unknown dig output $_");
1147         }
1148     }
1149     $h->close;
1150     debug_trace("dig <== gave $?");
1151 }
1152
1153 sub domain_canon ($$) {
1154     my ($i,$w) = @_;
1155     $i =~ s/(.)\.$/$1/;
1156     return '.' if $i eq '.';
1157     die "domain $i ($w) ?" unless $i =~ m/^[0-9a-z]/i;
1158     return lc $i;
1159 }