scripts/named-conf

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use IO::File;
   5 use Data::Dumper;
   6 use POSIX;
   7
   8 use vars qw($quis
   9             $mode $doall
  10             $etcfile $where
  11             $debug $needglue $localonly $repeat $verbosity);
  12
  13 $quis= $0; $quis =~ s,.*/,,;
  14
  15 $mode= '';
  16 $doall= 0;
  17 $etcfile= "/etc/bind/chiark-conf-gen.zones";
  18 $where= '<built-in>';
  19 $debug= 0;
  20 $needglue= 1;
  21 $localonly= 0;
  22 $verbosity= 1;
  23 $repeat= 0;
  24
  25 use vars qw($dig_owner $dig_type $dig_rdata);
  26
  27 while (@ARGV && $ARGV[0] =~ m/^\-/) {
  28     $_= shift @ARGV;
  29     if (s/^\-\-//) {
  30         last if m/^$/;
  31         if (m/^(yes|no|force)$/) { m/^./; $mode= $&; }
  32         elsif (m/^all$/) { $doall=1; }
  33         elsif (m/^config$/) { $etcfile= loarg(); $where= '--config option'; }
  34         elsif (m/^glueless$/) { $needglue=0; }
  35         elsif (m/^localonly$/) { $localonly=1; }
  36         elsif (m/^quiet$/) { $verbosity=0; }
  37         elsif (m/^repeat$/) { $repeat=1; }
  38         elsif (m/^verbose$/) { $verbosity=2; }
  39         else { usageerr("unknown option --$_"); }
  40     } else {
  41         s/^\-//;
  42         last if m/^$/;
  43         while (m/^./) {
  44             if (s/^[ynf]//) { $mode=$&; }
  45             elsif (s/^A//) { $doall=1; }
  46             elsif (s/^C//) { $etcfile= soarg(); $where= '-C option'; }
  47             elsif (s/^D//) { $debug++; }
  48             elsif (s/^g//) { $needglue=0; }
  49             elsif (s/^l//) { $localonly=1; }
  50             elsif (s/^q//) { $verbosity=0; }
  51             elsif (s/^r//) { $repeat=1; }
  52             elsif (s/^v//) { $verbosity=2; }
  53             else { usageerr("unknown option -$&"); }
  54         }
  55     }
  56 }
  57
  58 sub loarg() { usageerr("missing option value") if !@ARGV; return shift @ARGV; }
  59 sub soarg() { my ($rv); $rv=$_; $_=''; return length $rv ? $rv : loarg(); }
  60
  61 usageerr("-D may be specified at most twice") if $debug>2;
  62 usageerr("must specify either -f|-y|-n or zones (and not both)")
  63     if !!$mode == !!@ARGV;
  64
  65 sub usageerr ($) {
  66     die
  67 "$_[0]
  68 usage: named-conf-regen [options] -f|-y|-n|<zone>...\n".
  69 "operation modes:\n".
  70 " -f --force   install without checking\n".
  71 " -y --yes     check and install\n".
  72 " -n --no      check only\n".
  73 "additional options:\n".
  74 " -A --all       report on zones marked ? (ones we know are broken)\n".
  75 " -D             debug $quis (does not help debug your DNS config)\n".
  76 " -g --glueless  do not warn about any glueless referrals (not recommended)\n".
  77 " -l --localonly full checks only on zones which we primary\n".
  78 " -q --quiet     no output for OK zones\n".
  79 " -r --repeat    repeat warnings for all sources of imperfect data\n".
  80 " -v --verbose   extra verbose info about each zone\n".
  81 " -C|--config <DIR/FILE  use FILE as default config and DIR as default dir\n";
  82 }
  83
  84 cfg_fail("config filename $etcfile should not be directory")
  85     if $etcfile =~ m,/$,;
  86
  87 use vars qw($default_dir);
  88 $default_dir= $etcfile =~ m,^.*/, ? $& : './';
  89
  90 use vars qw($slave_dir $slave_prefix $slave_suffix);
  91 $slave_dir= 'slave';
  92 $slave_prefix= '';
  93 $slave_suffix= '';
  94
  95 use vars qw(@self_ns @self_soa @self_addr @forbid_addr @conv_glueless);
  96 @self_ns= @self_soa= @self_addr= @forbid_addr= ();
  97 @conv_glueless= qw(in-addr.arpa ip6.arpa ip6.int);
  98
  99 use vars qw(%zone_cfg @zone_cfg_list);
 100 %zone_cfg= ();
 101 @zone_cfg_list= ();
 102
 103 use vars qw($output $default_output %output_contents);
 104 $output= '';
 105 $default_output= '';
 106 %output_contents= ();
 107
 108 use vars qw($check $install);
 109 $check= $mode !~ m/^f/;
 110 $install= $mode =~ m/^[yf]/;
 111
 112 read_config($etcfile);
 113 debug_dump('@zone_cfg_list %zone_cfg');
 114 process_zones($mode ? @zone_cfg_list : @ARGV);
 115 debug_dump('%output_contents');
 116 output_files() if $install;
 117
 118 exit 0;
 119
 120 #-------------------- configuration reading
 121
 122 sub cfg_fail ($) { die "$quis: $where:\n $_[0]\n"; }
 123
 124 sub read_config ($) {
 125     my ($if) = @_;
 126     my ($fh,$z,@self,$before,
 127         $mod,$dir,$prefix,$suffix,$subfile,$lprefix,$lsuffix,$zf);
 128     local ($_);
 129
 130     $fh= new IO::File $if,'r' or cfg_fail("open $if:\n $!");
 131     $before= '';
 132     for (;;) {
 133         if (!defined($_= <$fh>)) {
 134             cfg_fail("read config file $if:\n $!") if $fh->error();
 135             last;
 136         }
 137         chomp; s/\s+$//;
 138         if (s/\\$//) { $before.= $_; next; }
 139         $_= $before.$_;
 140         $before= '';
 141         s/^\s+//;
 142         $where= "$if:$.";
 143         next if m/^\#/;
 144         last if m/^end$/;
 145         next unless m/\S/;
 146         if (m/^self(\-ns|\-soa|)\s+(\S.*\S)/) {
 147             @self= split /\s+/, $2;
 148             @self_ns= @self if $1 ne '-soa';
 149             @self_soa= @self if $1 ne '-ns';
 150         } elsif (m/^serverless\-glueless\s+(\S.*\S)/) {
 151             @conv_glueless= split /\s+/, $1;
 152         } elsif (m/^self\-addr\s+([0-9. \t]+)/) {
 153             @self_addr= split /\s+/, $1;
 154         } elsif (m/^forbid\-addr(?:\s+([0-9. \t]+))?/) {
 155             @forbid_addr= defined $1 ? split /\s+/, $1 : ();
 156         } elsif (m,^
 157                  primary\-dir ([*?]?)
 158                  \s+ (\S+)/([^/ \t]*)
 159                  (?: \s+ ([^/ \t]*) (?: (/.+) )?
 160                   )?
 161                  $,x) {
 162             ($mod, $dir, $prefix, $suffix, $subfile) =
 163                 ($1,qualify($2),$3,$4,$5);
 164             $suffix= '' if !defined $suffix;
 165             $subfile= '' if !defined $subfile;
 166             $suffix= '_db' if !length $suffix && !length $subfile;
 167             if (-d "$dir/$prefix") { $dir.='/'; $dir.=$prefix; $prefix=''; }
 168             opendir D, $dir or cfg_fail("open primary-dir $dir:\n $!");
 169             $lprefix= length $prefix; $lsuffix= length $suffix;
 170             while (defined($_= readdir D)) {
 171                 next if m/^\./ && !$lprefix;
 172                 next unless length > $lprefix+$lsuffix;
 173                 next unless substr($_,0,$lprefix) eq $prefix;
 174                 next unless substr($_,length($_)-$lsuffix) eq $suffix;
 175                 $z= substr($_,$lprefix,length($_)-($lprefix+$lsuffix));
 176                 $zf= $dir.'/'.$prefix.$z.$suffix.$subfile;
 177                 if (!stat $zf) {
 178                     next if length $subfile && $! == &ENOENT;
 179                     cfg_fail("cannot stat zonefile $zf:\n $!");
 180                 }
 181                 -f _ or cfg_fail("zonefile $zf is not a plain file");
 182                 zone_conf($z,'primary','p',$mod,$zf);
 183             }
 184             closedir D or cfg_fail("close primary-dir $dir:\n $!");
 185         } elsif (m/^primary([*?]?)\s+(\S+)\s+(\S+)$/) {
 186             zone_conf($2,'primary','p',$1,qualify($3));
 187         } elsif (m/^published([*?]?)\s+(\S+)\s+([0-9.\t]+)$/) {
 188             zone_conf($2,'published','s',$1,'',$3);
 189         } elsif (m/^stealth([*?]?)\s+(\S+)\s+([0-9. \t]+)$/) {
 190             zone_conf($2,'stealth','u',$1,'',split /\s+/, $3);
 191         } elsif (m/^slave\-dir\s+(\S+)(?:(?:\s+(\S+))\s+(\S+))?$/) {
 192             ($slave_dir, $slave_prefix, $slave_suffix) = (qualify($1),$2,$3);
 193             $slave_prefix='' if !defined $slave_prefix;
 194             $slave_suffix='' if !defined $slave_suffix;
 195         } elsif (m/^output\s+bind8\+(\S+)$/) {
 196             cfg_fail("default output may not apply to only some zones")
 197                 if @zone_cfg_list && length $default_output;
 198             set_output(qualify($1));
 199         } elsif (m/^include\s+(\S+)$/) {
 200             read_config($1);
 201         } else {
 202             cfg_fail("unknown configuration directive".
 203                      " or incorrect syntax or arguments:\n".
 204                      " \`$_'");
 205         }
 206     }
 207     $fh->close or cfg_fail("close config file $if:\n $!");
 208 }
 209
 210 sub qualify ($) {
 211     my ($i) = @_;
 212     $i= "$default_dir$i" unless $i =~ m,^/,;
 213     return $i;
 214 }
 215
 216 sub zone_conf ($$$$$@) {
 217     my ($zone,$style,$sabbr,$mod,$file,@servers) = @_;
 218     my ($sfx,$aref);
 219     $file= qualify("$slave_dir/$slave_prefix".$zone.$slave_suffix)
 220         unless length $file;
 221     if (!length $output) {
 222         $default_output= qualify('chiark-conf-gen.bind8')
 223             unless length $default_output;
 224         set_output($default_output);
 225     }
 226     cfg_fail("redefined zone $zone\n".
 227              " earlier definition $zone_cfg{$zone}{'where'}")
 228         if exists $zone_cfg{$zone};
 229     $zone_cfg{$zone}{'where'}= $where;
 230     $zone_cfg{$zone}{'file'}= $file;
 231     $zone_cfg{$zone}{'style_p'}= $style.$mod;
 232     $zone_cfg{$zone}{'s'}= $sabbr.$mod; # p)rimary s)econdary u)npub f)oreign
 233     $zone_cfg{$zone}{'servers'}= [ @servers ];
 234     foreach $sfx (qw(self_soa self_ns self_addr forbid_addr)) {
 235         { no strict 'refs'; $aref= [ @$sfx ]; }
 236         @$aref or cfg_fail("failed to specify $sfx before zone")
 237             if $sfx =~ m/^self/;
 238         $zone_cfg{$zone}{$sfx}= $aref;
 239     }
 240     $zone_cfg{$zone}{'output'}= $output;
 241     push @zone_cfg_list, $zone;
 242 }
 243
 244 sub set_output($) {
 245     my ($newout) = @_;
 246     $output= $newout;
 247     $output_contents{$output}= '';
 248 }
 249
 250
 251 #-------------------- checking
 252
 253 use vars qw($zone $cfg $warnings);
 254 $warnings= 0;
 255
 256 sub progress ($) {
 257     return if !$verbosity;
 258     print "$_[0]\n";
 259 }
 260
 261 sub verbose ($) {
 262     return if $verbosity<2;
 263     print "    $_[0]\n";
 264 }
 265
 266 sub process_zones (@) {
 267     my (@zones) = @_;
 268     local ($zone,$cfg);
 269
 270     foreach $zone (@zones) {
 271         zone_reset();
 272         $cfg= $zone_cfg{$zone} || {
 273             'style_p' => 'foreign',
 274             's' => 'f',
 275             'servers' => [ ],
 276             };
 277         progress(sprintf "%-40s %s", $zone, $$cfg{'style_p'});
 278         if ($check && ($doall || $cfg->{'s'} !~ m/\?/)) {
 279             eval {
 280                 if ($localonly && $cfg->{'s'} =~ m/f/) {
 281                     zone_warning("foreign zone specified with -l",'');
 282                 } elsif ($cfg->{'s'} =~ m/\*/ ||
 283                          ($localonly && $cfg->{'s'} !~ m/p/)) {
 284                     zone_check_local();
 285                 } else {
 286                     zone_check_full();
 287                 }
 288             };
 289             zone_warning("checks failed: $@",'') if length $@;
 290         }
 291         $output_contents{$$cfg{'output'}} .= zone_output()
 292             if $install;
 293     }
 294     print STDERR "$quis: $warnings warnings\n" or die $!
 295         if $warnings;
 296 }
 297
 298 use vars qw(%delgs); # $delgs{$nameserver_list} = [ $whosaidandwhy ]
 299 use vars qw(%auths); # $auths{$nameserver_list} = [ $whosaidandwhy ]
 300 use vars qw(%glue);  # $glue{$name}{$addr_list} = [ $whosaidandwhy ]
 301 use vars qw(%soas);  # $soa{"$serial $origin"} = [ $whosaidandwhy ]
 302 use vars qw(%addr_is_ok %warned);
 303 use vars qw($delg_to_us);
 304 use vars qw(@to_check); # ($addr,$whyask,$is_auth,$glueless_ok, ...)
 305 use vars qw(@to_check_soa); # ($addr,$whyask, ...)
 306
 307 sub zone_warning ($$) {
 308     my ($w,$o) = @_;
 309     my ($wk);
 310
 311     return 0 if !$repeat && $warned{$w}++;
 312
 313     $w =~ s/\n$//;
 314     $w =~ s,\n, // ,g;
 315
 316     $w .= " ($o)" if length $o;
 317     print STDERR "$zone: warning: $w\n" or die $!;
 318     $warnings++;
 319     return 1;
 320 }
 321
 322 sub zone_warnmore ($) {
 323     print STDERR "$zone:  $_[0]\n" or die $!;
 324 }
 325
 326 sub zone_check_full () {
 327     zone_investigate();
 328     zone_consistency();
 329     zone_servers_ok();
 330 }
 331
 332 sub zone_reset() {
 333     %delgs= %auths= %glue= %soas= %warned= %addr_is_ok= ();
 334     $delg_to_us= 0;
 335     @to_check= @to_check_soa= ();
 336 }
 337
 338 sub zone_investigate() {
 339     my ($super_zone, @super_nsnames,
 340         $super_ns, @super_ns_addrs, $s, $wa, $is_auth,
 341         %nsrrset_checked, %soa_checked, $addr, $glueless_ok, $rcode);
 342
 343     $super_zone= $zone;
 344     for (;;) {
 345         debug_trace("zone $zone superzone $super_zone");
 346         $super_zone =~ s/^[^.]+\.// or die "no superzone ? ($super_zone)\n";
 347         ($rcode,@super_nsnames)=
 348             lookup($super_zone,'ns-','06',"superzone search");
 349         last if !$rcode;
 350     }
 351     for $super_ns (@super_nsnames) {
 352         $super_ns= lc $super_ns;
 353         ($rcode,@super_ns_addrs)=
 354             lookup($super_ns,'a','0',"published nameserver");
 355         foreach $addr (@super_ns_addrs) {
 356             push @to_check,
 357                  $addr,
 358                  "$super_ns, server for $super_zone",
 359                  0, 0;
 360         }
 361     }
 362     for (;;) {
 363         # We do these in order so that we always do NS RRset checks on
 364         # nameservers that came from other NS RRsets first; otherwise
 365         # we might set nsrrset_checked due to a glueless_ok check,
 366         # and then not check for gluefulness later.
 367         debug_dump('@to_check @to_check_soa');
 368         if (($addr,$wa,$is_auth,$glueless_ok,@to_check) = @to_check) {
 369             push @to_check_soa, $addr, $wa if $is_auth;
 370             next if $nsrrset_checked{$addr}++;
 371             zone_check_nsrrset($addr, $wa, $is_auth, $glueless_ok);
 372         } elsif (($addr,$wa,@to_check_soa) = @to_check_soa) {
 373             next if $soa_checked{$addr}++;
 374             zone_check_soa($addr, $wa, "NS [$addr]");
 375         } else {
 376             last;
 377         }
 378     }
 379 }
 380
 381 sub zone_check_nsrrset ($$$$) {
 382     my ($uaddr,$wa, $is_auth, $glueless_ok) = @_;
 383     my (@s, $s, %s2g, @glue, $glue, $delgs_or_auths, $wwn, $ww);
 384     $ww= "[$uaddr] $wa";
 385     verbose("checking delegation by $ww");
 386     dig(sub {
 387         if ($dig_type eq 'ns' && $dig_owner eq $zone) {
 388             $s2g{lc $dig_rdata} = [ ];
 389         } elsif ($dig_type eq 'a' && exists $s2g{$dig_owner}) {
 390             $wwn= "in glue from $ww";
 391             push @to_check, $dig_rdata, "$dig_owner, $wwn", 1, 0;
 392             zone_server_addr($dig_rdata,$dig_owner,$wwn,"NS [$uaddr]",0);
 393             push @{ $s2g{$dig_owner} }, $dig_rdata;
 394         }
 395     },
 396              $zone,'ns',$uaddr);
 397     if (!%s2g) {
 398         zone_warning("unable to find NS RRset at [$uaddr]", $wa);
 399         return;
 400     } elsif (keys %s2g == 1) {
 401         zone_warning("only one nameserver ". (join '', keys %s2g),
 402                      $ww);
 403     }
 404     @s= sort keys %s2g;
 405     foreach $s (@s) {
 406         $delg_to_us=1 if grep { $s eq $_ } @{ $cfg->{'self_ns'} };
 407         @glue= @{ $s2g{$s} };
 408         if (!@glue) {
 409             zone_warning("glueless NS $s", $ww)
 410                 unless $glueless_ok || !$needglue ||
 411                        grep { has_suffix_of($s,".$_"); } @conv_glueless;
 412             next;
 413         }
 414         $glue= join ' ', sort @glue;
 415         push @{ $glue{$s}{$glue} }, $ww;
 416     }
 417     $s= join ' ', @s;
 418     $delgs_or_auths= $is_auth ? \%auths : \%delgs;
 419     push @{ $delgs_or_auths->{$s} }, $ww;
 420 }
 421
 422 sub zone_server_addr ($$$$$) {
 423     my ($addr,$name,$ww,$wwq,$is_soa) = @_;
 424     my ($cg);
 425     debug_trace("zone_server_addr ".join '|',@_);
 426     $addr_is_ok{$addr}= "$name ($wwq)"
 427         if $is_soa || $cfg->{'s'} =~ m/u/;
 428     foreach $cg (@conv_glueless) {
 429         next unless has_suffix_of(".$name",".$cg");
 430         zone_warning("nameserver [$addr] $name in serverless-glueless".
 431                      " namespace area $cg",
 432                      $ww);
 433     }
 434     zone_warning("configured as stealth but we [$addr] $name are published",
 435                  $ww)
 436         if $cfg->{'s'} =~ m/u/ && grep { $_ eq $addr } @self_addr;
 437     zone_warning("forbidden nameserver address [$addr] $name",$ww)
 438         if grep { $_ eq $addr } @{ $cfg->{'forbid_addr'} };
 439
 440     my ($name_is_self, $addr_is_self);
 441     $name_is_self= grep { $_ eq $name }
 442         @{ $cfg->{$is_soa ? 'self_soa' : 'self_ns'} };
 443     $addr_is_self= grep { $_ eq $addr }
 444         @{ $cfg->{'self_addr'} };
 445     if ($name_is_self && !$addr_is_self) {
 446         zone_warning("our $name supplied with wrong address [$addr]", $ww);
 447     }
 448     if (!$name_is_self && $addr_is_self) {
 449         zone_warning("we [$addr] are named in ".
 450                      ($is_soa ? "SOA" : "NS").
 451                      " by wrong name $name",
 452                      $ww);
 453     }
 454     if (!$name_is_self && !$addr_is_self &&
 455         $is_soa && $cfg->{'s'} =~ m/p/) {
 456         zone_warning("SOA ORIGIN $name is not us (".
 457                      (join ' ', @{ $cfg->{'self_soa'} }).")", $ww);
 458     }
 459     $delg_to_us=1 if $addr_is_self && !$is_soa;
 460 }
 461
 462 sub zone_check_soa ($$$) {
 463     my ($uaddr,$wa,$waq) = @_;
 464     my ($lame,$origin,$got,$rcode,@soa_addrs,$soa_addr,$ww,$wwn);
 465     verbose("checking service at [$uaddr] $waq");
 466     $lame= 'dead or lame';
 467     $ww= "[$uaddr] $wa";
 468     dig(sub {
 469         if ($dig_type eq 'flags:') {
 470             $lame= $dig_rdata =~ m/ aa / ? '' : 'lame';
 471         } elsif ($dig_type eq 'soa' && $dig_owner eq $zone && !$lame) {
 472             die "several SOAs ? $ww" if defined $origin;
 473             $got= $dig_rdata;
 474             $got =~ m/^\d+ (\S+)$/ or die "$got ?";
 475             $origin= $1;
 476         }
 477     },
 478              $zone,'soa',$uaddr);
 479     $lame= 'broken' if !$lame && !defined $origin;
 480     if ($lame) { zone_warning("$lame server [$uaddr]",$wa); return; }
 481     push @{ $soas{$got} }, $ww;
 482     ($rcode,@soa_addrs)= lookup($origin,'a','0',"SOA ORIGIN");
 483     $wwn= "SOA ORIGIN from $ww";
 484     foreach $soa_addr (@soa_addrs) {
 485         zone_server_addr($soa_addr,$origin,$wwn,"SOA [$uaddr]",1);
 486         push @to_check, $soa_addr, "$origin, $wwn";
 487     }
 488 }
 489
 490 sub zone_consistency() {
 491     my ($d, $org_ser, $origin, $a, $h, $self_soa, $wa);
 492     zone_consistency_set('delegations',\%delgs);
 493     foreach $d (keys %delgs) { delete $auths{$d}; }
 494     zone_consistency_set('zone nameserver rrset',\%auths);
 495     foreach $h (keys %glue) {
 496         zone_consistency_set("glue for $h", $glue{$h});
 497     }
 498     zone_consistency_set("serial number and/or SOA ORIGIN",\%soas);
 499     $self_soa= $cfg->{'self_soa'};
 500 }
 501
 502 sub zone_servers_ok () {
 503     my ($showok,%fs);
 504     if (%addr_is_ok) {
 505         $showok= 0;
 506         foreach $a (@{ $cfg->{'servers'} }) {
 507             next if exists $addr_is_ok{$a};
 508             zone_warning("we slave from [$a]",'')
 509                 and $showok=1;
 510         }
 511         if ($showok) {
 512             foreach $a (keys %addr_is_ok) {
 513                 zone_warnmore("permitted master [$a] $addr_is_ok{$a}");
 514             }
 515         }
 516     }
 517     if ($cfg->{'s'} =~ m/s/ && !$delg_to_us) {
 518         zone_warning("we are supposedly published secondary,".
 519                      " but not listed as a nameserver",'');
 520         map { $fs{$_}=1 } keys(%delgs), keys(%auths);
 521         zone_warnmore("servers are: ". join ' ', sort keys %fs);
 522     }
 523 }
 524
 525 sub zone_consistency_set ($%) {
 526     my ($msg,$set) = @_;
 527     my ($d,$o);
 528     if (keys(%$set) > 1) {
 529         zone_warning("inconsistent $msg:",'');
 530         foreach $d (keys %$set) {
 531             foreach $o (@{ $set->{$d} }) { zone_warnmore(" $d from $o"); }
 532         }
 533     }
 534 }
 535
 536 sub zone_check_local () {
 537     zone_servers_simplefind();
 538     zone_servers_ok();
 539 }
 540
 541 sub zone_servers_simplefind () {
 542     my ($rcode,@nsnames,$ns,@soas,$origin);
 543
 544     ($rcode,@nsnames)= lookup($zone,'ns-','0',"zone's servers");
 545     foreach $ns (@nsnames) { zone_server_simple($ns,'NS',0); }
 546
 547     ($rcode,@soas)= lookup($zone,'soa','0',"SOA ORIGIN");
 548     die "multiple SOA RRs in set!  @soas ?" if @soas!=1;
 549     $soas[0] =~ m/^(\S+)\s/ or die "SOA ? $_";
 550     zone_server_simple(domain_canon($1,"lookup $zone SOA"),'SOA',1);
 551 }
 552
 553 sub zone_server_simple ($$$) {
 554     my ($name,$ww,$is_soa) = @_;
 555     my ($rcode,@addrs,$addr);
 556     ($rcode,@addrs)= lookup($name,'a','0', "server - ".
 557                             ($is_soa ? "SOA ORIGIN" : "NS"));
 558     foreach $addr (@addrs) { zone_server_addr($addr,$name,$ww,$ww,$is_soa); }
 559 }
 560
 561 #-------------------- outputting
 562
 563 sub zone_output () {
 564     my ($o,$m);
 565
 566     $o= "zone \"$zone\" {\n";
 567     if ($$cfg{'s'} =~ m/p/) {
 568         $o.= "    type master;\n";
 569     } else {
 570         $o.= "    type slave;\n".
 571              "    masters {\n";
 572         foreach $m (@{ $$cfg{'servers'} }) { $o.= "        $m;\n"; }
 573         $o.= "    };\n";
 574     }
 575     $o.= "    file \"$$cfg{'file'}\";\n";
 576     $o.= "};\n";
 577     return $o;
 578 }
 579
 580 sub output_files () {
 581     my ($fn,$ofn,$mfn,$l,$dir, $maxmode,$h,@to_install);
 582
 583     foreach $ofn (keys %output_contents) {
 584         $fn= $ofn; $mfn= "output file $fn";
 585         for (;;) {
 586             if (!lstat $fn) {
 587                 $! == &ENOENT or die "$quis: stat $mfn:\n $!\n";
 588                 $maxmode= 0666;
 589                 last;
 590             } elsif (-f _) {
 591                 $maxmode= (stat _)[2];
 592                 last;
 593             } elsif (-l _) {
 594                 defined($l= readlink $fn)
 595                     or die "$quis: readlink $mfn:\n $!\n";
 596                 $dir= $fn =~ m,^.*/, ? $& : './';
 597                 $fn= "$dir$l" unless $l =~ m,^/,;
 598                 $mfn= "output file $fn (symlink target of $ofn)";
 599             } else {
 600                 die "$quis: output file $mfn exists but is not a file".
 601                     " (or symlink to one)";
 602             }
 603         }
 604         unlink "$fn.new" or $! == &ENOENT or
 605             die "$quis: cannot clear out old .new version of $mfn:\n $!";
 606         $h= new IO::File "$fn.new",'w',$maxmode
 607             or die("$quis: create .new version of $mfn:\n $!");
 608         print $h
 609             "# generated by $quis, do not edit\n",
 610             $output_contents{$ofn}
 611             or die "$quis: write data to .new version of $mfn:\n $!";
 612         $h->close
 613             or die "$quis: close .new version of $mfn:\n $!";
 614         push @to_install, $fn,$mfn;
 615     }
 616
 617     while (($fn,$mfn, @to_install) = @to_install) {
 618         rename "$fn.new",$fn
 619             or die "$quis: install new version of $mfn:\n $!";
 620     }
 621 }
 622
 623 #-------------------- general utilities
 624
 625 sub debug_dump ($) {
 626     my ($vn);
 627     return unless $debug>1;
 628     local $Data::Dumper::Terse=1;
 629     foreach $vn (split /\s+/, $_[0]) {
 630         print "$vn := ", eval "Dumper(\\$vn)";
 631     }
 632 }
 633
 634 sub debug_trace ($) {
 635     return unless $debug;
 636     print "D $_[0]\n";
 637 }
 638
 639 sub has_suffix_of ($$) {
 640     my ($whole,$suffix) = @_;
 641     return 0 if length $whole < length $suffix;
 642     return 0 if substr($whole, length($whole) - length($suffix)) ne $suffix;
 643     return 1;
 644 }
 645
 646 sub lookup ($$$$) {
 647     my ($domain,$type,$okrcodes,$w) = @_;
 648     my ($c,$h,@result);
 649     debug_trace("lookup ==> (->$okrcodes) $domain $type");
 650     $h= new IO::Handle;
 651
 652     defined($c= open $h, "-|") or die "$quis: fork adnshost:\n $!\n";
 653     if (!$c) {
 654         exec 'adnshost','-Fi','+Do','+Dt','+Dc','-Cf',"-t$type",
 655              '-',"$domain.";
 656         die "$quis: exec adnshost:\n $!\n";
 657     }
 658     @result= $h->getlines();
 659     $h->error and die "$quis: read from adnshost:\n $!\n";
 660     chomp @result;
 661     $!=0; $h->close;
 662     die "$quis: lookup -t$type $domain $okrcodes ($w) failed $? $! @result\n"
 663         if $! or $?&255 or $?>1536 or index($okrcodes,$?>>8)<0;
 664     debug_trace("lookup <== $? @result");
 665     return ($?,@result);
 666 }
 667
 668
 669 sub dig (&$$$) {
 670     my ($eachrr, $qowner,$qtype,$qaddr) = @_;
 671     # also pseudo-rr with type `flags:'
 672     my ($h,$inmid,$irdata,$c,$digwhy);
 673     local ($_);
 674
 675     debug_trace("dig ==> \@$qaddr $qowner $qtype");
 676
 677     $h= new IO::Handle;
 678     defined($c= open $h, "-|") or die "$quis: fork dig:\n $!\n";
 679     if (!$c) {
 680         open STDERR, ">&STDOUT" or die $!;
 681         exec ('dig',
 682               '+nodef','+nosea','+nodebug','+norecurse',
 683               "\@$qaddr",'-t',$qtype,$qowner);
 684         die "$quis: exec dig:\n $!\n";
 685     }
 686     $inmid='';
 687     for (;;) {
 688         if (!defined($_= $h->getline())) {
 689             $h->error() and die "$quis: read from dig:\n $!\n";
 690             last;
 691         }
 692         chomp;
 693         if (length $inmid) {
 694             s/^\s+/ / or die "$inmid // $_ ?";
 695             s/\;.*$//;
 696             $_= $inmid.$_;
 697             $inmid='';
 698             s/$/ \(/ unless s/\s*\)\s*$//;
 699         }
 700         if (s/\s*\(\s*$//) { $inmid= $_; next; }
 701         $digwhy= "dig $qowner $qtype $qaddr \`$_'";
 702         if (m/^\;\; flags\:( [-0-9a-z ]+)\;/) {
 703             $dig_owner=''; $dig_type='flags:'; $dig_rdata= "$1 ";
 704             debug_trace("dig  f: $dig_rdata");
 705             &$eachrr;
 706         } elsif (m/^\;/) {
 707         } elsif (!m/\S/) {
 708         } elsif (m/^([-.0-9a-z]+)\s+\d\w+\s+in\s+([a-z]+)\s+(\S.*)/i) {
 709             $dig_owner=domain_canon($1,$digwhy); $dig_type=lc $2; $irdata=$3;
 710             if ($dig_type eq 'a') {
 711                 $irdata =~ m/^[.0-9]+$/ or die "$irdata ?";
 712                 $dig_rdata= $&;
 713             } elsif ($dig_type eq 'ns') {
 714                 $irdata =~ m/^[-.0-9a-z]+$/i or die "bad nameserver $irdata ?";
 715                 $dig_rdata= domain_canon($irdata,$digwhy);
 716             } elsif ($dig_type eq 'soa') {
 717                 $irdata =~ m/^([-.0-9a-z]+)\s+.*\s+(\d+)(?:\s+\d\w+){4}$/i
 718                     or die "bad SOA $irdata ?";
 719                 $dig_rdata= $2.' '.domain_canon($1,$digwhy);
 720             } else {
 721                 debug_trace("ignoring uknown RR type $dig_type");
 722                 next;
 723             }
 724             debug_trace("dig  $dig_owner $dig_type $dig_rdata");
 725             &$eachrr;
 726         } else {
 727             debug_trace("ignoring unknown dig output $_");
 728         }
 729     }
 730     $h->close;
 731     debug_trace("dig <== gave $?");
 732 }
 733
 734 sub domain_canon ($$) {
 735     my ($i,$w) = @_;
 736     $i =~ s/(.)\.$/$1/;
 737     return '.' if $i eq '.';
 738     die "domain $i ($w) ?" unless $i =~ m/^[0-9a-z]/i;
 739     return lc $i;
 740 }