scripts/named-conf

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use IO::File;
   5 use Data::Dumper;
   6 use POSIX;
   7
   8 use vars qw($quis
   9             $mode $doall
  10             $etcfile $where
  11             $debug $needglue $localonly $repeat $verbosity);
  12
  13 $quis= $0; $quis =~ s,.*/,,;
  14
  15 $mode= '';
  16 $doall= 0;
  17 $etcfile= "/etc/bind/chiark-conf-gen.zones";
  18 $where= '<built-in>';
  19 $debug= 0;
  20 $needglue= 1;
  21 $localonly= 0;
  22 $verbosity= 1;
  23 $repeat= 0;
  24
  25 use vars qw($dig_owner $dig_type $dig_rdata);
  26
  27 while (@ARGV && $ARGV[0] =~ m/^\-/) {
  28     $_= shift @ARGV;
  29     if (s/^\-\-//) {
  30         last if m/^$/;
  31         if (m/^(yes|no|force)$/) { m/^./; $mode= $&; }
  32         elsif (m/^all$/) { $doall=1; }
  33         elsif (m/^config$/) { $etcfile= loarg(); $where= '--config option'; }
  34         elsif (m/^glueless$/) { $needglue=0; }
  35         elsif (m/^localonly$/) { $localonly=1; }
  36         elsif (m/^quiet$/) { $verbosity=0; }
  37         elsif (m/^repeat$/) { $repeat=1; }
  38         elsif (m/^verbose$/) { $verbosity=2; }
  39         else { usageerr("unknown option --$_"); }
  40     } else {
  41         s/^\-//;
  42         last if m/^$/;
  43         while (m/^./) {
  44             if (s/^[ynf]//) { $mode=$&; }
  45             elsif (s/^A//) { $doall=1; }
  46             elsif (s/^C//) { $etcfile= soarg(); $where= '-C option'; }
  47             elsif (s/^D//) { $debug++; }
  48             elsif (s/^g//) { $needglue=0; }
  49             elsif (s/^l//) { $localonly=1; }
  50             elsif (s/^q//) { $verbosity=0; }
  51             elsif (s/^r//) { $repeat=1; }
  52             elsif (s/^v//) { $verbosity=2; }
  53             else { usageerr("unknown option -$&"); }
  54         }
  55     }
  56 }
  57
  58 sub loarg() { usageerr("missing option value") if !@ARGV; return shift @ARGV; }
  59 sub soarg() { my ($rv); $rv=$_; $_=''; return length $rv ? $rv : loarg(); }
  60
  61 usageerr("-D may be specified at most twice") if $debug>2;
  62 usageerr("must specify either -f|-y|-n or zones (and not both)")
  63     if !!$mode == !!@ARGV;
  64
  65 sub usageerr ($) {
  66     die
  67 "$_[0]
  68 usage: named-conf-regen [options] -f|-y|-n|<zone>...\n".
  69 "operation modes:\n".
  70 " -f --force   install without checking\n".
  71 " -y --yes     check and install\n".
  72 " -n --no      check only\n".
  73 "additional options:\n".
  74 " -A --all       report on zones marked ? (ones we know are broken)\n".
  75 " -D             debug $quis (does not help debug your DNS config)\n".
  76 " -g --glueless  do not warn about any glueless referrals (not recommended)\n".
  77 " -l --localonly full checks only on zones which we primary\n".
  78 " -q --quiet     no output for OK zones\n".
  79 " -r --repeat    repeat warnings for all sources of imperfect data\n".
  80 " -v --verbose   extra verbose info about each zone\n".
  81 " -C|--config <DIR/FILE  use FILE as default config and DIR as default dir\n";
  82 }
  83
  84 cfg_fail("config filename $etcfile should not be directory")
  85     if $etcfile =~ m,/$,;
  86
  87 use vars qw($default_dir);
  88 $default_dir= $etcfile =~ m,^.*/, ? $& : './';
  89
  90 use vars qw($slave_dir $slave_prefix $slave_suffix);
  91 $slave_dir= 'slave';
  92 $slave_prefix= '';
  93 $slave_suffix= '';
  94
  95 use vars qw(@self_ns @self_soa @self_addr @forbid_addr @conv_glueless);
  96 @self_ns= @self_soa= @self_addr= @forbid_addr= ();
  97 @conv_glueless= qw(in-addr.arpa ip6.arpa ip6.int);
  98
  99 use vars qw(%zone_cfg @zone_cfg_list);
 100 %zone_cfg= ();
 101 @zone_cfg_list= ();
 102
 103 use vars qw($output $default_output %output_contents);
 104 $output= '';
 105 $default_output= '';
 106 %output_contents= ();
 107
 108 use vars qw($check $install);
 109 $check= $mode !~ m/^f/;
 110 $install= $mode =~ m/^[yf]/;
 111
 112 read_config($etcfile);
 113 debug_dump('@zone_cfg_list %zone_cfg');
 114 process_zones($mode ? @zone_cfg_list : @ARGV);
 115 debug_dump('%output_contents');
 116 output_files() if $install;
 117
 118 exit 0;
 119
 120 #-------------------- configuration reading
 121
 122 sub cfg_fail ($) { die "$quis: $where:\n $_[0]\n"; }
 123
 124 sub read_config ($) {
 125     my ($if) = @_;
 126     my ($fh,$z,@self,$before,
 127         $mod,$dir,$prefix,$suffix,$subfile,$lprefix,$lsuffix,$zf);
 128     local ($_);
 129
 130     $fh= new IO::File $if,'r' or cfg_fail("open $if:\n $!");
 131     $before= '';
 132     for (;;) {
 133         if (!defined($_= <$fh>)) {
 134             cfg_fail("read config file $if:\n $!") if $fh->error();
 135             last;
 136         }
 137         chomp; s/\s+$//;
 138         if (s/\\$//) { $before.= $_; next; }
 139         $_= $before.$_;
 140         $before= '';
 141         s/^\s+//;
 142         $where= "$if:$.";
 143         next if m/^\#/;
 144         last if m/^end$/;
 145         next unless m/\S/;
 146         if (m/^self(\-ns|\-soa|)\s+(\S.*\S)/) {
 147             @self= split /\s+/, $2;
 148             @self_ns= @self if $1 ne '-soa';
 149             @self_soa= @self if $1 ne '-ns';
 150         } elsif (m/^serverless\-glueless\s+(\S.*\S)/) {
 151             @conv_glueless= split /\s+/, $1;
 152         } elsif (m/^self\-addr\s+([0-9. \t]+)/) {
 153             @self_addr= split /\s+/, $1;
 154         } elsif (m/^forbid\-addr(?:\s+([0-9. \t]+))?/) {
 155             @forbid_addr= defined $1 ? split /\s+/, $1 : ();
 156         } elsif (m,^
 157                  primary\-dir ([*?]?)
 158                  \s+ (\S+)/([^/ \t]*)
 159                  (?: \s+ ([^/ \t]*) (?: (/.+) )?
 160                   )?
 161                  $,x) {
 162             ($mod, $dir, $prefix, $suffix, $subfile) =
 163                 ($1,qualify($2),$3,$4,$5);
 164             $suffix= '' if !defined $suffix;
 165             $subfile= '' if !defined $subfile;
 166             $suffix= '_db' if !length $suffix && !length $subfile;
 167             if (-d "$dir/$prefix") { $dir.='/'; $dir.=$prefix; $prefix=''; }
 168             opendir D, $dir or cfg_fail("open primary-dir $dir:\n $!");
 169             $lprefix= length $prefix; $lsuffix= length $suffix;
 170             while (defined($_= readdir D)) {
 171                 next if m/^\./ && !$lprefix;
 172                 next unless length > $lprefix+$lsuffix;
 173                 next unless substr($_,0,$lprefix) eq $prefix;
 174                 next unless substr($_,length($_)-$lsuffix) eq $suffix;
 175                 $z= substr($_,$lprefix,length($_)-($lprefix+$lsuffix));
 176                 $zf= $dir.'/'.$prefix.$z.$suffix.$subfile;
 177                 if (!stat $zf) {
 178                     next if length $subfile && $! == &ENOENT;
 179                     cfg_fail("cannot stat zonefile $zf:\n $!");
 180                 }
 181                 -f _ or cfg_fail("zonefile $zf is not a plain file");
 182                 zone_conf($z,'primary','p',$mod,$zf);
 183             }
 184             closedir D or cfg_fail("close primary-dir $dir:\n $!");
 185         } elsif (m/^primary([*?]?)\s+(\S+)\s+(\S+)$/) {
 186             zone_conf($2,'primary','p',$1,qualify($3));
 187         } elsif (m/^published([*?]?)\s+(\S+)\s+([0-9.\t]+)$/) {
 188             zone_conf($2,'published','s',$1,'',$3);
 189         } elsif (m/^stealth([*?]?)\s+(\S+)\s+([0-9. \t]+)$/) {
 190             zone_conf($2,'stealth','u',$1,'',split /\s+/, $3);
 191         } elsif (m/^slave\-dir\s+(\S+)(?:(?:\s+(\S+))\s+(\S+))?$/) {
 192             ($slave_dir, $slave_prefix, $slave_suffix) = (qualify($1),$2,$3);
 193             $slave_prefix='' if !defined $slave_prefix;
 194             $slave_suffix='' if !defined $slave_suffix;
 195         } elsif (m/^output\s+bind8\+(\S+)$/) {
 196             cfg_fail("default output may not apply to only some zones")
 197                 if @zone_cfg_list && length $default_output;
 198             set_output(qualify($1));
 199         } elsif (m/^include\s+(\S+)$/) {
 200             read_config($1);
 201         } else {
 202             cfg_fail("unknown configuration directive".
 203                      " or incorrect syntax or arguments:\n".
 204                      " \`$_'");
 205         }
 206     }
 207     $fh->close or cfg_fail("close config file $if:\n $!");
 208 }
 209
 210 sub qualify ($) {
 211     my ($i) = @_;
 212     $i= "$default_dir$i" unless $i =~ m,^/,;
 213     return $i;
 214 }
 215
 216 sub zone_conf ($$$$$@) {
 217     my ($zone,$style,$sabbr,$mod,$file,@servers) = @_;
 218     my ($sfx,$aref);
 219     $file= qualify("$slave_dir/$slave_prefix".$zone.$slave_suffix)
 220         unless length $file;
 221     if (!length $output) {
 222         $default_output= qualify('chiark-conf-gen.bind8')
 223             unless length $default_output;
 224         set_output($default_output);
 225     }
 226     cfg_fail("redefined zone $zone\n".
 227              " earlier definition $zone_cfg{$zone}{'where'}")
 228         if exists $zone_cfg{$zone};
 229     $zone_cfg{$zone}{'where'}= $where;
 230     $zone_cfg{$zone}{'file'}= $file;
 231     $zone_cfg{$zone}{'style_p'}= $style.$mod;
 232     $zone_cfg{$zone}{'s'}= $sabbr.$mod; # p)rimary s)econdary u)npub f)oreign
 233     $zone_cfg{$zone}{'servers'}= [ @servers ];
 234     foreach $sfx (qw(self_soa self_ns self_addr forbid_addr)) {
 235         { no strict 'refs'; $aref= [ @$sfx ]; }
 236         @$aref or cfg_fail("failed to specify $sfx before zone")
 237             if $sfx =~ m/^self/;
 238         $zone_cfg{$zone}{$sfx}= $aref;
 239     }
 240     $zone_cfg{$zone}{'output'}= $output;
 241     push @zone_cfg_list, $zone;
 242 }
 243
 244 sub set_output($) {
 245     my ($newout) = @_;
 246     $output= $newout;
 247     $output_contents{$output}= '';
 248 }
 249
 250
 251 #-------------------- checking
 252
 253 use vars qw($zone $cfg $warnings);
 254 $warnings= 0;
 255
 256 sub progress ($) {
 257     return if !$verbosity;
 258     print "$_[0]\n";
 259 }
 260
 261 sub verbose ($) {
 262     return if $verbosity<2;
 263     print "    $_[0]\n";
 264 }
 265
 266 sub process_zones (@) {
 267     my (@zones) = @_;
 268     local ($zone,$cfg);
 269
 270     foreach $zone (@zones) {
 271         zone_reset();
 272         $cfg= $zone_cfg{$zone} || {
 273             'style_p' => 'foreign',
 274             's' => 'f',
 275             'servers' => [ ],
 276             };
 277         progress(sprintf "%-40s %s", $zone, $$cfg{'style_p'});
 278         if ($check && ($doall || $cfg->{'s'} !~ m/\?/)) {
 279             eval {
 280                 if ($localonly && $cfg->{'s'} =~ m/f/) {
 281                     zone_warning("foreign zone specified with -l",'');
 282                 } elsif ($cfg->{'s'} =~ m/\*/ ||
 283                          ($localonly && $cfg->{'s'} !~ m/p/)) {
 284                     zone_check_local();
 285                 } else {
 286                     zone_check_full();
 287                 }
 288             };
 289             zone_warning("checks failed: $@",'') if length $@;
 290         }
 291         $output_contents{$$cfg{'output'}} .= zone_output()
 292             if $install;
 293     }
 294     print STDERR "$quis: $warnings warnings\n" or die $!
 295         if $warnings;
 296 }
 297
 298 use vars qw(%delgs); # $delgs{$nameserver_list} = [ $whosaidandwhy ]
 299 use vars qw(%auths); # $auths{$nameserver_list} = [ $whosaidandwhy ]
 300 use vars qw(%glue);  # $glue{$name}{$addr_list} = [ $whosaidandwhy ]
 301 use vars qw(%soas);  # $soa{"$origin $serial"} = [ $whosaidandwhy ]
 302 use vars qw(%addr_is_ok %warned);
 303 use vars qw($delg_to_us);
 304 use vars qw(@to_check); # ($addr,$whyask,$is_auth,$glueless_ok, ...)
 305 use vars qw(@to_check_soa); # ($addr,$whyask, ...)
 306
 307 sub zone_warning ($$) {
 308     my ($w,$o) = @_;
 309     my ($wk);
 310
 311     return 0 if !$repeat && $warned{$w}++;
 312
 313     $w =~ s/\n$//;
 314     $w =~ s,\n, // ,g;
 315
 316     $w .= " ($o)" if length $o;
 317     print STDERR "$zone: warning: $w\n" or die $!;
 318     $warnings++;
 319     return 1;
 320 }
 321
 322 sub zone_warnmore ($) {
 323     print STDERR "$zone:  $_[0]\n" or die $!;
 324 }
 325
 326 sub zone_check_full () {
 327     zone_investigate();
 328     zone_consistency();
 329     zone_servers_ok();
 330 }
 331
 332 sub zone_reset() {
 333     %delgs= %auths= %glue= %soas= %warned= %addr_is_ok= ();
 334     $delg_to_us= 0;
 335     @to_check= @to_check_soa= ();
 336 }
 337
 338 sub zone_investigate() {
 339     my ($super_zone, @super_nsnames,
 340         $super_ns, @super_ns_addrs, $s, $wa, $is_auth,
 341         %nsrrset_checked, %soa_checked, $addr, $glueless_ok, $rcode);
 342
 343     $super_zone= $zone;
 344     for (;;) {
 345         debug_trace("zone $zone superzone $super_zone");
 346         $super_zone =~ s/^[^.]+\.// or die "no superzone ? ($super_zone)\n";
 347         ($rcode,@super_nsnames)= lookup($super_zone,'ns-','06');
 348         last if !$rcode;
 349     }
 350     for $super_ns (@super_nsnames) {
 351         $super_ns= lc $super_ns;
 352         ($rcode,@super_ns_addrs)= lookup($super_ns,'a','0');
 353         foreach $addr (@super_ns_addrs) {
 354             push @to_check,
 355                  $addr,
 356                  "$super_ns, server for $super_zone",
 357                  0, 0;
 358         }
 359     }
 360     for (;;) {
 361         # We do these in order so that we always do NS RRset checks on
 362         # nameservers that came from other NS RRsets first; otherwise
 363         # we might set nsrrset_checked due to a glueless_ok check,
 364         # and then not check for gluefulness later.
 365         debug_dump('@to_check @to_check_soa');
 366         if (($addr,$wa,$is_auth,$glueless_ok,@to_check) = @to_check) {
 367             push @to_check_soa, $addr, $wa if $is_auth;
 368             next if $nsrrset_checked{$addr}++;
 369             zone_check_nsrrset($addr, $wa, $is_auth, $glueless_ok);
 370         } elsif (($addr,$wa,@to_check_soa) = @to_check_soa) {
 371             next if $soa_checked{$addr}++;
 372             zone_check_soa($addr, $wa, "NS [$addr]");
 373         } else {
 374             last;
 375         }
 376     }
 377 }
 378
 379 sub zone_check_nsrrset ($$$$) {
 380     my ($uaddr,$wa, $is_auth, $glueless_ok) = @_;
 381     my (@s, $s, %s2g, @glue, $glue, $delgs_or_auths, $wwn, $ww);
 382     $ww= "[$uaddr] $wa";
 383     verbose("checking delegation by $ww");
 384     dig(sub {
 385         if ($dig_type eq 'ns' && $dig_owner eq $zone) {
 386             $s2g{lc $dig_rdata} = [ ];
 387         } elsif ($dig_type eq 'a' && exists $s2g{$dig_owner}) {
 388             $wwn= "in glue from $ww";
 389             push @to_check, $dig_rdata, "$dig_owner, $wwn", 1, 0;
 390             zone_server_addr($dig_rdata,$dig_owner,$wwn,"NS [$uaddr]",0);
 391             push @{ $s2g{$dig_owner} }, $dig_rdata;
 392         }
 393     },
 394              $zone,'ns',$uaddr);
 395     if (!%s2g) {
 396         zone_warning("unable to find NS RRset at [$uaddr]", $wa);
 397         return;
 398     } elsif (keys %s2g == 1) {
 399         zone_warning("only one nameserver ". (join '', keys %s2g),
 400                      $ww);
 401     }
 402     @s= sort keys %s2g;
 403     foreach $s (@s) {
 404         $delg_to_us=1 if grep { $s eq $_ } @{ $cfg->{'self_ns'} };
 405         @glue= @{ $s2g{$s} };
 406         if (!@glue) {
 407             zone_warning("glueless NS $s", $ww)
 408                 unless $glueless_ok || !$needglue ||
 409                        grep { has_suffix_of($s,".$_"); } @conv_glueless;
 410             next;
 411         }
 412         $glue= join ' ', sort @glue;
 413         push @{ $glue{$s}{$glue} }, $ww;
 414     }
 415     $s= join ' ', @s;
 416     $delgs_or_auths= $is_auth ? \%auths : \%delgs;
 417     push @{ $delgs_or_auths->{$s} }, $ww;
 418 }
 419
 420 sub zone_server_addr ($$$$$) {
 421     my ($addr,$name,$ww,$wwq,$is_soa) = @_;
 422     my ($cg);
 423     debug_trace("zone_server_addr ".join '|',@_);
 424     $addr_is_ok{$addr}= "$name ($wwq)"
 425         if $is_soa || $cfg->{'s'} =~ m/u/;
 426     foreach $cg (@conv_glueless) {
 427         next unless has_suffix_of(".$name",".$cg");
 428         zone_warning("nameserver [$addr] $name in serverless-glueless".
 429                      " namespace area $cg",
 430                      $ww);
 431     }
 432     zone_warning("configured as stealth but we [$addr] $name are published",
 433                  $ww)
 434         if $cfg->{'s'} =~ m/u/ && grep { $_ eq $addr } @self_addr;
 435     zone_warning("forbidden nameserver address [$addr] $name",$ww)
 436         if grep { $_ eq $addr } @{ $cfg->{'forbid_addr'} };
 437
 438     my ($name_is_self, $addr_is_self);
 439     $name_is_self= grep { $_ eq $name }
 440         @{ $cfg->{$is_soa ? 'self_soa' : 'self_ns'} };
 441     $addr_is_self= grep { $_ eq $addr }
 442         @{ $cfg->{'self_addr'} };
 443     if ($name_is_self && !$addr_is_self) {
 444         zone_warning("our $name supplied with wrong address [$addr]", $ww);
 445     }
 446     if (!$name_is_self && $addr_is_self) {
 447         zone_warning("we [$addr] are named in ".
 448                      ($is_soa ? "SOA" : "NS").
 449                      " by wrong name $name",
 450                      $ww);
 451     }
 452     if (!$name_is_self && !$addr_is_self &&
 453         $is_soa && $cfg->{'s'} =~ m/p/) {
 454         zone_warning("SOA ORIGIN $name is not us (".
 455                      (join ' ', @{ $cfg->{'self_soa'} }).")", $ww);
 456     }
 457     $delg_to_us=1 if $addr_is_self && !$is_soa;
 458 }
 459
 460 sub zone_check_soa ($$$) {
 461     my ($uaddr,$wa,$waq) = @_;
 462     my ($lame,$origin,$got,$rcode,@soa_addrs,$soa_addr,$ww,$wwn);
 463     verbose("checking service at [$uaddr] $waq");
 464     $lame= 'dead or lame';
 465     $ww= "[$uaddr] $wa";
 466     dig(sub {
 467         if ($dig_type eq 'flags:') {
 468             $lame= $dig_rdata =~ m/ aa / ? '' : 'lame';
 469         } elsif ($dig_type eq 'soa' && $dig_owner eq $zone && !$lame) {
 470             die "several SOAs ? $ww" if defined $origin;
 471             $got= $dig_rdata;
 472             $got =~ m/^(\S+) \d+/ or die "$got ?";
 473             $origin= $1;
 474         }
 475     },
 476              $zone,'soa',$uaddr);
 477     $lame= 'broken' if !$lame && !defined $origin;
 478     if ($lame) { zone_warning("$lame server [$uaddr]",$wa); return; }
 479     push @{ $soas{$got} }, $ww;
 480     ($rcode,@soa_addrs)= lookup($origin,'a','0');
 481     $wwn= "SOA ORIGIN from $ww";
 482     foreach $soa_addr (@soa_addrs) {
 483         zone_server_addr($soa_addr,$origin,$wwn,"SOA [$uaddr]",1);
 484         push @to_check, $soa_addr, "$origin, $wwn";
 485     }
 486 }
 487
 488 sub zone_consistency() {
 489     my ($d, $org_ser, $origin, $a, $h, $self_soa, $wa);
 490     zone_consistency_set('delegations',\%delgs);
 491     foreach $d (keys %delgs) { delete $auths{$d}; }
 492     zone_consistency_set('zone nameserver rrset',\%auths);
 493     foreach $h (keys %glue) {
 494         zone_consistency_set("glue for $h", $glue{$h});
 495     }
 496     zone_consistency_set("SOA ORIGIN and SERIAL",\%soas);
 497     $self_soa= $cfg->{'self_soa'};
 498 }
 499
 500 sub zone_servers_ok () {
 501     my ($showok,%fs);
 502     if (%addr_is_ok) {
 503         $showok= 0;
 504         foreach $a (@{ $cfg->{'servers'} }) {
 505             next if exists $addr_is_ok{$a};
 506             zone_warning("we slave from [$a]",'')
 507                 and $showok=1;
 508         }
 509         if ($showok) {
 510             foreach $a (keys %addr_is_ok) {
 511                 zone_warnmore("permitted master [$a] $addr_is_ok{$a}");
 512             }
 513         }
 514     }
 515     if ($cfg->{'s'} =~ m/s/ && !$delg_to_us) {
 516         zone_warning("we are supposedly published secondary,".
 517                      " but not listed as a nameserver",'');
 518         map { $fs{$_}=1 } keys(%delgs), keys(%auths);
 519         zone_warnmore("servers are: ". join ' ', sort keys %fs);
 520     }
 521 }
 522
 523 sub zone_consistency_set ($%) {
 524     my ($msg,$set) = @_;
 525     my ($d,$o);
 526     if (keys(%$set) > 1) {
 527         zone_warning("inconsistent $msg:",'');
 528         foreach $d (keys %$set) {
 529             foreach $o (@{ $set->{$d} }) { zone_warnmore(" $d from $o"); }
 530         }
 531     }
 532 }
 533
 534 sub zone_check_local () {
 535     zone_servers_simplefind();
 536     zone_servers_ok();
 537 }
 538
 539 sub zone_servers_simplefind () {
 540     my ($rcode,@nsnames,$ns,@soas,$origin);
 541
 542     ($rcode,@nsnames)= lookup($zone,'ns-','0');
 543     foreach $ns (@nsnames) { zone_server_simple($ns,'NS',0); }
 544
 545     ($rcode,@soas)= lookup($zone,'soa','0');
 546     die "multiple SOA RRs in set!  @soas ?" if @soas!=1;
 547     $soas[0] =~ m/^(\S+)\s/ or die "SOA ? $_";
 548     zone_server_simple(domain_canon($1,"lookup $zone SOA"),'SOA',1);
 549 }
 550
 551 sub zone_server_simple ($$$) {
 552     my ($name,$ww,$is_soa) = @_;
 553     my ($rcode,@addrs,$addr);
 554     ($rcode,@addrs)= lookup($name,'a','0');
 555     foreach $addr (@addrs) { zone_server_addr($addr,$name,$ww,$ww,$is_soa); }
 556 }
 557
 558 #-------------------- outputting
 559
 560 sub zone_output () {
 561     my ($o,$m);
 562
 563     $o= "zone \"$zone\" {\n";
 564     if ($$cfg{'s'} =~ m/p/) {
 565         $o.= "    type master;\n";
 566     } else {
 567         $o.= "    type slave;\n".
 568              "    masters {\n";
 569         foreach $m (@{ $$cfg{'servers'} }) { $o.= "        $m;\n"; }
 570         $o.= "    };\n";
 571     }
 572     $o.= "    file \"$$cfg{'file'}\";\n";
 573     $o.= "};\n";
 574     return $o;
 575 }
 576
 577 sub output_files () {
 578     my ($fn,$ofn,$mfn,$l,$dir, $maxmode,$h,@to_install);
 579
 580     foreach $ofn (keys %output_contents) {
 581         $fn= $ofn; $mfn= "output file $fn";
 582         for (;;) {
 583             if (!lstat $fn) {
 584                 $! == &ENOENT or die "$quis: stat $mfn:\n $!\n";
 585                 $maxmode= 0666;
 586                 last;
 587             } elsif (-f _) {
 588                 $maxmode= (stat _)[2];
 589                 last;
 590             } elsif (-l _) {
 591                 defined($l= readlink $fn)
 592                     or die "$quis: readlink $mfn:\n $!\n";
 593                 $dir= $fn =~ m,^.*/, ? $& : './';
 594                 $fn= "$dir$l" unless $l =~ m,^/,;
 595                 $mfn= "output file $fn (symlink target of $ofn)";
 596             } else {
 597                 die "$quis: output file $mfn exists but is not a file".
 598                     " (or symlink to one)";
 599             }
 600         }
 601         unlink "$fn.new" or $! == &ENOENT or
 602             die "$quis: cannot clear out old .new version of $mfn:\n $!";
 603         $h= new IO::File "$fn.new",'w',$maxmode
 604             or die("$quis: create .new version of $mfn:\n $!");
 605         print $h
 606             "# generated by $quis, do not edit\n",
 607             $output_contents{$ofn}
 608             or die "$quis: write data to .new version of $mfn:\n $!";
 609         $h->close
 610             or die "$quis: close .new version of $mfn:\n $!";
 611         push @to_install, $fn,$mfn;
 612     }
 613
 614     while (($fn,$mfn, @to_install) = @to_install) {
 615         rename "$fn.new",$fn
 616             or die "$quis: install new version of $mfn:\n $!";
 617     }
 618 }
 619
 620 #-------------------- general utilities
 621
 622 sub debug_dump ($) {
 623     my ($vn);
 624     return unless $debug>1;
 625     local $Data::Dumper::Terse=1;
 626     foreach $vn (split /\s+/, $_[0]) {
 627         print "$vn := ", eval "Dumper(\\$vn)";
 628     }
 629 }
 630
 631 sub debug_trace ($) {
 632     return unless $debug;
 633     print "D $_[0]\n";
 634 }
 635
 636 sub has_suffix_of ($$) {
 637     my ($whole,$suffix) = @_;
 638     return 0 if length $whole < length $suffix;
 639     return 0 if substr($whole, length($whole) - length($suffix)) ne $suffix;
 640     return 1;
 641 }
 642
 643 sub lookup ($$$) {
 644     my ($domain,$type,$okrcodes) = @_;
 645     my ($c,$h,@result);
 646     debug_trace("lookup ==> (->$okrcodes) $domain $type");
 647     $h= new IO::Handle;
 648
 649     defined($c= open $h, "-|") or die "$quis: fork adnshost:\n $!\n";
 650     if (!$c) {
 651         exec 'adnshost','-Fi','+Do','+Dt','+Dc','-Cf',"-t$type",
 652              '-',"$domain.";
 653         die "$quis: exec adnshost:\n $!\n";
 654     }
 655     @result= $h->getlines();
 656     $h->error and die "$quis: read from adnshost:\n $!\n";
 657     chomp @result;
 658     $!=0; $h->close;
 659     die "$quis: lookup -t$type $domain $okrcodes failed $? $! @result\n"
 660         if $! or $?&255 or $?>1536 or index($okrcodes,$?>>8)<0;
 661     debug_trace("lookup <== $? @result");
 662     return ($?,@result);
 663 }
 664
 665
 666 sub dig (&$$$) {
 667     my ($eachrr, $qowner,$qtype,$qaddr) = @_;
 668     # also pseudo-rr with type `flags:'
 669     my ($h,$inmid,$irdata,$c,$digwhy);
 670     local ($_);
 671
 672     debug_trace("dig ==> \@$qaddr $qowner $qtype");
 673
 674     $h= new IO::Handle;
 675     defined($c= open $h, "-|") or die "$quis: fork dig:\n $!\n";
 676     if (!$c) {
 677         open STDERR, ">&STDOUT" or die $!;
 678         exec ('dig',
 679               '+nodef','+nosea','+nodebug','+norecurse',
 680               "\@$qaddr",'-t',$qtype,$qowner);
 681         die "$quis: exec dig:\n $!\n";
 682     }
 683     $inmid='';
 684     for (;;) {
 685         if (!defined($_= $h->getline())) {
 686             $h->error() and die "$quis: read from dig:\n $!\n";
 687             last;
 688         }
 689         chomp;
 690         if (length $inmid) {
 691             s/^\s+/ / or die "$inmid // $_ ?";
 692             s/\;.*$//;
 693             $_= $inmid.$_;
 694             $inmid='';
 695             s/$/ \(/ unless s/\s*\)\s*$//;
 696         }
 697         if (s/\s*\(\s*$//) { $inmid= $_; next; }
 698         $digwhy= "dig $qowner $qtype $qaddr \`$_'";
 699         if (m/^\;\; flags\:( [-0-9a-z ]+)\;/) {
 700             $dig_owner=''; $dig_type='flags:'; $dig_rdata= "$1 ";
 701             debug_trace("dig  f: $dig_rdata");
 702             &$eachrr;
 703         } elsif (m/^\;/) {
 704         } elsif (!m/\S/) {
 705         } elsif (m/^([-.0-9a-z]+)\s+\d\w+\s+in\s+([a-z]+)\s+(\S.*)/i) {
 706             $dig_owner=domain_canon($1,$digwhy); $dig_type=lc $2; $irdata=$3;
 707             if ($dig_type eq 'a') {
 708                 $irdata =~ m/^[.0-9]+$/ or die "$irdata ?";
 709                 $dig_rdata= $&;
 710             } elsif ($dig_type eq 'ns') {
 711                 $irdata =~ m/^[-.0-9a-z]+$/i or die "bad nameserver $irdata ?";
 712                 $dig_rdata= domain_canon($irdata,$digwhy);
 713             } elsif ($dig_type eq 'soa') {
 714                 $irdata =~ m/^([-.0-9a-z]+)\s+.*\s+(\d+)(?:\s+\d\w+){4}$/i
 715                     or die "bad SOA $irdata ?";
 716                 $dig_rdata= domain_canon($1,$digwhy).' '.$2;
 717             } else {
 718                 debug_trace("ignoring uknown RR type $dig_type");
 719                 next;
 720             }
 721             debug_trace("dig  $dig_owner $dig_type $dig_rdata");
 722             &$eachrr;
 723         } else {
 724             debug_trace("ignoring unknown dig output $_");
 725         }
 726     }
 727     $h->close;
 728     debug_trace("dig <== gave $?");
 729 }
 730
 731 sub domain_canon ($$) {
 732     my ($i,$w) = @_;
 733     $i =~ s/(.)\.$/$1/;
 734     return '.' if $i eq '.';
 735     die "domain $i ($w) ?" unless $i =~ m/^[0-9a-z]/i;
 736     return lc $i;
 737 }