scripts/git-cache-proxy

   1 #!/usr/bin/perl -w
   2 #
   3 # git caching proxy
   4
   5 # usage: run it on some port, and then clone or fetch
   6 #  "git://<realhost>:<realport>/<real-git-url>[ <options>]"
   7 # where <real-git-url> is http://<host>/... or git://<host>/...
   8 # and <options> is zero or more (whitespace-separated) of
   9 #    [<some-option>]      will be ignored if not recognised
  10 #    {<some-option>}      error if not recognised
  11 # options currently known:
  12 #    fetch=must           fail if the fetch/clone from upstream fails
  13 #    fetch=no             just use what is in the cache
  14 #    fetch=try            use what is in the cache if the fetch/clone fails
  15 #    timeout=<seconds>    length of time to allow for fetch/clone
  16
  17 # git-cache-proxy is free software; you can redistribute it and/or
  18 # modify them under the terms of the GNU General Public License as
  19 # published by the Free Software Foundation; either version 3, or (at
  20 # your option) any later version.
  21 #
  22 # git-cache-proxy is distributed in the hope that it will be useful,
  23 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  25 # General Public License for more details.
  26 #
  27 # You should have received a copy of the GNU General Public License along
  28 # with this program; if not, consult the Free Software Foundation's
  29 # website at www.fsf.org, or the GNU Project website at www.gnu.org.
  30 #
  31 # (Some code taken from userv-utils's git-daemon.in and git-service.in
  32 # which were written by Tony Finch <dot@dotat.at> and subsequently
  33 # heavily modified by Ian Jackson <ijackson@chiark.greenend.org.uk>
  34 # and were released under CC0 1.0.  The whole program is now GPLv3+.)
  35
  36 use strict;
  37 use warnings;
  38
  39 use POSIX;
  40 use Socket;
  41 use Sys::Syslog;
  42 use Fcntl qw(:flock SEEK_SET);
  43
  44 our $us = 'git-cache-proxy';
  45
  46 #---------- error handling and logging ----------
  47
  48 # This is a bit fiddly, because we want to catch errors sent to stderr
  49 # and dump them to syslog if we can, but only if we are running as an
  50 # inetd service.
  51
  52 our $log; # filehandle (ref), or "1" meaning syslog
  53
  54 sub ntoa {
  55     my $sockaddr = shift;
  56     return ('(local)') unless defined $sockaddr;
  57     my ($port,$addr) = sockaddr_in $sockaddr;
  58     $addr = inet_ntoa $addr;
  59     return ("[$addr]:$port",$addr,$port);
  60 }
  61
  62 our ($client) = ntoa getpeername STDIN;
  63 our ($server) = ntoa getsockname STDIN;
  64
  65 sub ensurelog () {
  66     return if $log;
  67     openlog $us, qw(pid), 'daemon';
  68     $log = 1;
  69 }
  70
  71 sub logm ($$) {
  72     my ($pri, $msg) = @_;
  73     if ($client eq '(local)') {
  74         print STDERR "$us: $pri: $msg\n" or die $!;
  75         exit 1;
  76     }
  77     ensurelog();
  78     my $mainmsg = sprintf "%s-%s: %s", $server, $client, $msg;
  79     if (ref $log) {
  80         my $wholemsg = sprintf("%s [%d] %s: %s\n",
  81                                strftime("%Y-%m-%d %H:%M:%S Z", gmtime),
  82                                $$,
  83                                $pri,
  84                                $mainmsg);
  85         print $log $wholemsg;
  86     } else {
  87         syslog $pri, $mainmsg;
  88     }
  89 }
  90
  91 if ($client ne '(local)') {
  92     open STDERR, ">/dev/null" or exit 255;
  93     open TEMPERR, "+>", undef or exit 255;
  94     open STDERR, ">&TEMPERR" or exit 255;
  95 }
  96
  97 END {
  98     if ($client ne '(local)') {
  99         if ($?) { logm 'crit', "crashing ($?)"; }
 100         seek TEMPERR, 0, SEEK_SET;
 101         while (<TEMPERR>) {
 102             chomp;
 103             logm 'crit', $_;
 104         }
 105     }
 106     exit $?;
 107 }
 108
 109 sub fail ($) {
 110     my ($msg) = @_;
 111     logm 'err', $msg;
 112     exit 0;
 113 }
 114
 115 sub gitfail ($) {
 116     my ($msg) = @_;
 117     close LOCK;
 118     alarm 60;
 119     logm 'notice', $msg;
 120     my $gitmsg = "ERR $us: $msg";
 121     $gitmsg = substr($gitmsg,0,65535); # just in case
 122     printf "%04x%s", length($gitmsg)+4, $gitmsg;
 123     flush STDOUT;
 124     exit 0;
 125 }
 126
 127 #---------- argument parsing ----------
 128
 129 our $fetchtimeout = 1800;
 130 our $maxfetchtimeout = 3600;
 131 our $cachedir = '/var/cache/git-cache-proxy';
 132
 133 for (;;) {
 134     last unless @ARGV;
 135     last unless $ARGV[0] =~ m/^-/;
 136     $_ = shift @ARGV;
 137     for (;;) {
 138         last unless m/^-./;
 139         if (s/^-L(.*)$//) {
 140             my $logfile = $_;
 141             open STDERR, ">>", $logfile or fail "open $logfile: $!";
 142             $log = \*STDERR;
 143         } elsif (s/^-d(.*)$//) {
 144             $cachedir = $1;
 145         } elsif (s/^--(maxfetchtimeout|fetchtimeout)=(\d+)$//) {
 146             ${ $::{$1} } = $2;
 147         } else {
 148             fail "bad usage: unknown option `$_'";
 149         }
 150     }
 151 }
 152
 153 !@ARGV or fail "bad usage: no non-option arguments permitted";
 154
 155 #---------- main program ----------
 156
 157 chdir $cachedir or fail "chdir $cachedir: $!";
 158
 159 our ($service,$specpath,$spechost,$subdir);
 160 our ($tmpd,$gitd,$lock);
 161 our ($fetch,$url);
 162
 163 sub xread {
 164     my $length = shift;
 165     my $buffer = "";
 166     while ($length > length $buffer) {
 167         my $ret = sysread STDIN, $buffer, $length, length $buffer;
 168         fail "expected $length bytes, got ".length $buffer
 169                             if defined $ret and $ret == 0;
 170         fail "read: $!" if not defined $ret and $! != EINTR and $! != EAGAIN;
 171     }
 172     return $buffer;
 173 }
 174
 175 sub servinfo ($) {
 176     my ($msg) = @_;
 177     logm 'info', "service `$specpath': $msg";
 178 }
 179
 180 sub readcommand () {
 181     $SIG{ALRM} = sub { fail "timeout" };
 182     alarm 30;
 183
 184     my $hex_len = xread 4;
 185     fail "Bad hex in packet length" unless $hex_len =~ m|^[0-9a-fA-F]{4}$|;
 186     my $line = xread -4 + hex $hex_len;
 187     unless (($service,$specpath,$spechost) = $line =~
 188             m|^(git-[a-z-]+) /*([!-~ ]+)\0host=([!-~]+)\0$|) {
 189         $line =~ s|[^ -~]+| |g;
 190         gitfail "unknown/unsupported instruction `$line'"
 191     }
 192
 193     alarm 0;
 194
 195     $service eq 'git-upload-pack'
 196         or gitfail "unknown/unsupported service `$service'";
 197
 198     $fetch = 2; # 0:don't; 1:try; 2:force
 199     $url = $specpath;
 200
 201     while ($url =~ s#\s+(\[)([^][{}]+)\]$## ||
 202            $url =~ s#\s+(\{)([^][{}]+)\}$##) {
 203         $_ = $2;
 204         my $must = $1 eq '{';
 205         if (m/^fetch=try$/) {
 206             $fetch = 1;
 207         } elsif (m/^fetch=no$/) {
 208             $fetch = 0;
 209         } elsif (m/^fetch=must$/) {
 210             $fetch = 2; # the default
 211         } elsif (m/^timeout=(\d+)$/) {
 212             $fetchtimeout = $1 <= $maxfetchtimeout ? $1 : $maxfetchtimeout;
 213         } elsif ($must) {
 214             gitfail "unknown/unsupported option `$_'";
 215         }
 216     }
 217
 218     $url =~ m{^(?:https?|git)://[-.0-9a-z]+/}
 219         or gitfail "unknown/unsupported url scheme or format `$url'";
 220
 221     $subdir = $url;
 222     $subdir =~ s|\\|\\\\|g;
 223     $subdir =~ s|,|\\,|g;
 224     $subdir =~ s|/|,|g;
 225
 226     $tmpd= "$subdir\\.tmp";
 227     $gitd= "$subdir\\.git";
 228     $lock = "$subdir\\.lock";
 229
 230     servinfo "locking";
 231 }
 232
 233 sub clonefetch () {
 234     open LOCK, "+>", $lock or fail "open/create $lock: $!";
 235     flock LOCK, LOCK_EX or fail "lock exclusive $lock: $!";
 236
 237     my $exists = stat $gitd;
 238     $exists or $!==ENOENT or fail "stat $gitd: $!";
 239
 240     our $fetchfail = '';
 241
 242     if ($fetch) {
 243
 244         our @cmd;
 245
 246         if (!$exists) {
 247             system qw(rm -rf --), $tmpd;
 248             @cmd = (qw(git clone -q --mirror), $url, $tmpd);
 249             servinfo "cloning";
 250         } else {
 251             @cmd = (qw(git remote update --prune));
 252             servinfo "fetching";
 253         }
 254         my $cmd = "@cmd[0..1]";
 255
 256         my $child = open FETCHERR, "-|";
 257         defined $child or fail "fork: $!";
 258         if (!$child) {
 259             if ($exists) {
 260                 chdir $gitd or fail "chdir $gitd: $!";
 261             }
 262             setpgrp or fail "setpgrp: $!";
 263             open STDERR, ">&STDOUT" or fail "redirect stderr: $!";
 264             exec @cmd or fail "exec $cmd[0]: $!";
 265         }
 266
 267         my $fetcherr = '';
 268         my $timedout = 0;
 269         {
 270             local $SIG{ALRM} = sub {
 271                 servinfo "fetch/clone timeout";
 272                 $timedout=1; kill 9, -$child;
 273             };
 274             alarm($fetchtimeout);
 275             $!=0; { local $/=undef; $fetcherr = <FETCHERR>; }
 276             !FETCHERR->error or fail "read pipe from fetch/clone: $!";
 277             alarm(10);
 278         }
 279
 280         kill -9, $child or fail "kill fetch/clone: $!";
 281         $!=0; $?=0; if (!close FETCHERR) {
 282             fail "reap fetch/clone: $!" if $!;
 283             my $fetchfail =
 284                 !($? & 255) ? "$cmd died with error exit code ".($? >> 8) :
 285                 $? != 9 ? "$cmd died due to fatal signa, status $?" :
 286                 $timedout ? "$cmd timed out (${fetchtimeout}s)" :
 287                 "$cmd died due to unexpected SIGKILL";
 288             if (length $fetcherr) {
 289                 $fetchfail .= "\n$fetcherr";
 290                 $fetchfail =~ s/\n$//;
 291                 $fetchfail =~ s{\n}{ // }g;
 292             }
 293             if ($fetch >= 2) {
 294                 gitfail $fetchfail;
 295             } else {
 296                 servinfo "fetch/clone failed: $fetchfail";
 297             }
 298         }
 299
 300         if (!$exists) {
 301             rename $tmpd, $gitd or fail "rename fresh $tmpd to $gitd: $!";
 302             $exists = 1;
 303         }
 304     } else {
 305         $fetchfail = 'not attempted';
 306     }
 307
 308     if (!$exists) {
 309         gitfail "no cached data, and not cloned: $fetchfail";
 310     }
 311
 312     servinfo "sharing";
 313     flock LOCK, LOCK_UN or fail "unlock $lock: $!";
 314     flock LOCK, LOCK_SH or fail "lock shared $lock: $!";
 315     # actually, just relocking as shared would have the same semantics
 316     # but it's best to be explicit
 317
 318     if (chdir $gitd) {
 319         return 1;
 320     }
 321     $!==ENOENT or fail "chdir $gitd: $!";
 322
 323     # Well, err, someone must have taken the lock in between
 324     # and garbage collected it.  How annoying.
 325     return 0;
 326 }
 327
 328 sub runcommand () {
 329     servinfo "servicing";
 330     exec qw(git-upload-pack --strict --timeout=1000 .)
 331         or fail "exec git-upload-pack: $!";
 332 }
 333
 334 sub daemonservice () {
 335     readcommand();
 336     while (!clonefetch()) { }
 337     runcommand();
 338 }
 339
 340 daemonservice();