perl/Prefork.pm

   1
   2 package Proc::Prefork;
   3 require Exporter;
   4 our @ISA = qw(Exporter);
   5 our @EXPORT = qw(initialisation_complete);
   6
   7 use Carp;
   8 use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
   9 use IO::FDPass;
  10 use POSIX qw(_exit setsid);
  11 use Sys::Syslog;
  12
  13 our $logger;
  14
  15 our $env_name = 'PREFORK_INTERP';
  16
  17 our @call_fds;
  18 our $socket_path;
  19 our $fail_log = 0;
  20
  21 sub fail_log ($) {
  22   my ($m) = @_;
  23   if ($fail_log) {
  24     syslog(LOG_ERR, "$0: prefork [$$]: error: $m");
  25   } else {
  26     croak "$0: prefork: initialisation error: $m";
  27   }
  28   _exit 127;
  29 }
  30
  31 sub server_quit ($) {
  32   my ($m) = @_;
  33   syslog(LOG_INFO, "$0 prefork [$$]: $m, quitting");
  34   _exit(0);
  35 }
  36
  37 # Returns in the executor process
  38 sub become_monitor () {
  39   my $child = fork // fail("fork executor: $!");
  40   if (!$child) {
  41     #---- executor ----
  42     open ::STDIN , "<& $call_fds[0]" or fail_log("dup for fd0");
  43     open ::STDOUT, ">& $call_fds[1]" or fail_log("dup for fd1");
  44     open ::STDERR, ">& $call_fds[2]" or fail_log("dup for fd2");
  45     close_call_fds();
  46     return;
  47   }
  48
  49   #---- monitor [2] ----
  50   my $got = waitpid $child, 0 // fail_log("wait for executor: $!");
  51   $got == $child or fail_log("wait for esecutor gave $got, expected $child");
  52
  53   protocol_write(pack "L", $?);
  54   _exit(0);
  55 }
  56
  57 sub close_call_fds () {
  58   foreach (@call_fds) {
  59     next if $_ <= 2;
  60     POSIX::close($_);
  61   }
  62   close CALL;
  63 }
  64
  65 sub protocol_write ($) {
  66   my ($d) = @_;
  67   return if (print CALL $d and flush CALL);
  68   _exit(0) if $!==EPIPE || $!==ECONNRESET;
  69   fail_log("protocol write: $!");
  70 }
  71
  72 sub eintr_retry ($) {
  73   my ($f) = @_;
  74   for (;;) {
  75     my $r = $f->();
  76     return $r if defined $r;
  77     next if $!==EINTR;
  78     return $r;
  79   }
  80 }
  81
  82 sub protocol_read_fail ($) {
  83   my ($what) = @_;
  84   _exit(0) if $!==ECONNRESET;
  85   die("recv $what: $!");
  86 }
  87
  88 sub protocol_exchange () {
  89   protocol_write("\n");
  90
  91   @call_fds = map {
  92     my $r;
  93     for (;;) {
  94       $! = 0;
  95       $r = IO::FDPass::recv(fileno(CALL));
  96       last if $r >= 0;
  97       _exit(0) if $!==0;
  98       protocol_read_fail("fd $_");
  99     }
 100     $r;
 101   } 0..2;
 102
 103   my $len;
 104   $r = read(CALL, $len, 4) // protocol_read_fail("message length");
 105   $r == 4 or _exit(0);
 106
 107   $len = unpack "L", $len;
 108   my $data;
 109   $r = read(CALL, $data, $len) // protocol_read_fail("message data ($len)");
 110   $r == $len or _exit(0);
 111
 112   @ARGV = split /\0/, $data;
 113   @ARGV >= 2 or die("message data has too few strings");
 114   length(pop(@ARGV)) and die("message data missing trailing nul");
 115   %ENV = ();
 116   while (my $s = shift @ARGV) {
 117     last if !length $s;
 118     $s =~ m/=/ or die("message data env var missing equals");
 119     $ENV{$`} = $';
 120   }
 121 }
 122
 123 sub initialisation_complete {
 124   my %opts = @_;
 125
 126   # if env var not set, we're not running under prefork-interp
 127   my @env_data = split / /, ($ENV{$env_name} // return), 3;
 128   croak "$env_name has the wrong number of words" unless @env_data == 3;
 129   my (@vsns) = split /,/, $env_data[0];
 130   croak "$env_name doesn't offer protocol v1" unless grep { $_ eq 'v1' } @vsns;
 131   my @env_fds = split /,/, $env_data[1];
 132   croak "$env_name has too few fds" unless @env_fds >= 3;;
 133   $#env_fds = 1;
 134   $socket_path = $env_data[2];
 135
 136   $num_servers = $opts{max_servers} // 4;
 137
 138   #---- setup (pm) [1] ----
 139
 140   foreach (@env_fds) {
 141     $_ eq ($_+0) or croak "$env_name contains $_, not a number";
 142   }
 143   open LISTEN, "+>&=$env_fds[0]" or croak "listen fd: $!";
 144   open CALL,   "+>&=$env_fds[1]" or croak "listen fd: $!";
 145
 146   if (!$opts{no_openlog}) {
 147     openlog("prefork-interp $0", 'ndelay,nofatal,pid',
 148             $opts{log_facility} // 'log_user');
 149   }
 150
 151   open NULL, "+>/dev/null" or croak "open /dev/null: $!";
 152
 153   #---- fork for server ----
 154
 155   my $child = fork // croak "first fork failed: $!";
 156   if ($child) {
 157     #---- setup (pm) [2], exits ----
 158     _exit(0);
 159   }
 160
 161   #---- server(pm) [1] ----
 162
 163   $child = fork // croak "second fork failed: $!";
 164   if (!$child) {
 165     # we are the child, i.e. the one fa-monitor
 166     return become_monitor();
 167   }
 168
 169   our %children;
 170   $children{$child} = 1;
 171
 172   # --- server(pm) [2] ----
 173
 174   $fail_log = 1;
 175   setsid() > 0 or fail_log("setsid: $!");
 176   open STDIN, "<&NULL" or fail_log("dup null onto stdin: $!");
 177   open STDOUT, ">&NULL" or fail_log("dup null onto stdout: $!");
 178   open STDERR, ">&NULL" or fail_log("dup null onto stderr: $!");
 179   close NULL;
 180
 181   close_call_fds();
 182
 183   my $flags = fcntl(LISTEN, F_GETFL, 0)
 184     or fail_log("F_GETFL listen socket: $!");
 185   $flags |= O_NONBLOCK;
 186   fcntl(LISTEN, F_SETFL, $flags)
 187     or fail_log("F_SETFL listen socket: $!");
 188
 189   my $errcount = 0;
 190
 191   for (;;) {
 192     # reap children
 193     if (%children) {
 194       my $full = %children >= $num_servers;
 195       my $got = waitpid -1, ($full ? 0 : WNOHANG);
 196       if ($?) {
 197         syslog(LOG_WARNING,
 198  "$0 prefork [$$]: monitor process [$got] failed with wait status $?");
 199       }
 200       if (!exists $children{$got}) {
 201         syslog(LOG_WARNING,
 202  "$0 prefork [$$]: monitor process [$got] wasn't one of ours?!");
 203       }
 204       delete $children{$got};
 205       next;
 206     }
 207
 208     # select for accepting or housekeeping timeout
 209     my $rbits = '';
 210     vec($rbits, fileno(LISTEN), 1) = 1;
 211     my $ebits = $rbits;
 212     my $nfound = select($rbits, '', $ebits, ($opts{check_interval} // 86400));
 213
 214     if ($nfound) {
 215       if (accept(CALL, LISTEN)) {
 216         $child = fork // fail_log("fork for accepted call failed: $!");
 217         if (!$child) {
 218           #---- monitor [1] ----
 219           close LISTEN;
 220           eval { protocol_exchange(); 1; }
 221             or fail_log("protocol exchange failed: $@");
 222           return become_monitor();
 223         }
 224         close(CALL);
 225         $errcount = 0;
 226         $children{$child} = 1;
 227       } elsif ($! == EINTR || $! == EAGAIN || $! == EWOULDBLOCK) {
 228       } else {
 229         syslog(LOG_WARNING, "$0 prefork [$$]: accept failed: $!");
 230         if ($errcount > ($opts{max_errors} // 100)) {
 231           syslog(LOG_ERR,
 232                  "$0 prefork [$$]: too many accept failures, quitting");
 233           _exit(16);
 234         }
 235       }
 236       next;
 237     }
 238
 239     # are we still live?
 240     my @st_listen = stat(LISTEN) // fail_log("fstat listening socket: $!");
 241     my @st_socket = stat($socket_path) // do {
 242       if ($! == ENOENT) { server_quit("socket $socket is ENOENT"); }
 243       fail_log("stat socket $socket: $!");
 244     };
 245     if ("@st_listen[0..2]" ne "@st_socket[0..2]") {
 246       server_quit("socket $socket is no longer ours");
 247     }
 248   }
 249 }
 250
 251 1;
 252
 253 __END__