backup/backuplib.pl

   1 # backuplib.pl
   2 # core common routines
   3 #
   4 # This file is part of chiark backup, a system for backing up GNU/Linux and
   5 # other UN*X-compatible machines, as used on chiark.greenend.org.uk.
   6 #
   7 # chiark backup is:
   8 #  Copyright (C) 1997-1998,2000-2001 Ian Jackson <ian@chiark.greenend.org.uk>
   9 #  Copyright (C) 1999 Peter Maydell <pmaydell@chiark.greenend.org.uk>
  10 #
  11 # This is free software; you can redistribute it and/or modify it under the
  12 # terms of the GNU General Public License as published by the Free Software
  13 # Foundation; either version 2, or (at your option) any later version.
  14 #
  15 # This is distributed in the hope that it will be useful, but WITHOUT ANY
  16 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  17 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  18 # details.
  19 #
  20 # You should have received a copy of the GNU General Public License along
  21 # with this program; if not, write to the Free Software Foundation, Inc.,
  22 # 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23
  24 require IO::File;
  25
  26 sub printdate () {
  27     print scalar(localtime),"\n";
  28 }
  29
  30 # Set status info -- we write the current status to a file
  31 # so if we hang or crash the last thing written to the file
  32 # will tell us where we were when things went pear-shaped.
  33 sub setstatus ($) {
  34     open S, ">this-status.new" or die $!;
  35     print S $_[0],"\n" or die $!;
  36     close S or die $!;
  37     rename "this-status.new","this-status" or die $!;
  38 }
  39
  40 # startprocess, endprocesses, killprocesses are
  41 # used to implement the funky pipeline stuff.
  42 sub startprocess ($$$) {
  43     my ($i,$o,$c) = @_;
  44     print LOG "  $c\n" or die $!;
  45     print "  $c\n" or die $!;
  46     defined($p= fork) or die $!;
  47     if ($p) { $processes{$p}= $c; return; }
  48     open STDIN,"$i" or die "$c stdin $i: $!";
  49     open STDOUT,"$o" or die "$c stdout $o: $!";
  50     &closepipes;
  51     exec $c; die "$c: $!";
  52 }
  53
  54 sub endprocesses () {
  55     while (keys %processes) {
  56         $p= waitpid(-1,0) or die "wait: $!";
  57         if (!exists $processes{$p}) { warn "unknown pid exited: $p, code $?\n"; next; }
  58         $c= $processes{$p};
  59         delete $processes{$p};
  60         $? && die "error: command gave code $?: $c\n";
  61     }
  62     print LOG "  ok\n" or die $!;
  63     print "  ok\n" or die $!;
  64 }
  65
  66 sub killprocesses {
  67     for $p (keys %processes) {
  68         kill 15,$p or warn "kill process $p: $!";
  69     }
  70     undef %processes;
  71 }
  72
  73 # Read a fsys.foo filesystem group definition file.
  74 # Syntax is: empty lines and those beginning with '#' are ignored.
  75 # Trailing whitespace is ignored. Lines of the form 'prefix foo bar'
  76 # are handled specially, as arex lines 'exclude regexp'; otherwise
  77 # we just shove the line into @fsys and let parsefsys deal with it.
  78
  79 sub readfsysfile ($) {
  80     my ($fn) = @_;
  81     my ($fh,$sfn);
  82     $fh= new IO::File "$fn", "r" or die "cannot open fsys file $fn ($!).\n";
  83     for (;;) {
  84         $!=0; $_= <$fh> or die "unexpected EOF in $fn ($!)\n";
  85         chomp; s/\s*$//;
  86         last if m/^end$/;
  87         next unless m/\S/;
  88         next if m/^\#/;
  89         if (m/^prefix\s+(\w+)\s+(\S.*\S)$/) {
  90             $prefix{$1}= $2;
  91         } elsif (m/^prefix\-df\s+(\w+)\s+(\S.*\S)$/) {
  92             $prefixdf{$1}= $2;
  93         } elsif (m/^excludedir\s+(\S.*\S)$/) {
  94             push @excldir,$1;
  95         } elsif (m/^exclude\s+(\S.*\S)$/) {
  96             push @excl,$1;
  97         } elsif (m/^include\s+(\S.*\S)$/) {
  98             $sfn = $1;
  99             $sfn =~ s/^\./fsys./;
 100             $sfn = "$etc/$sfn" unless $sfn =~ m,^/,;
 101             readfsysfile($sfn);
 102         } else {
 103             push @fsys,$_;
 104         }
 105     }
 106     close $fh or die $!;
 107 }
 108
 109 sub readfsys ($) {
 110     my ($fsnm) = @_;
 111     my ($fsf);
 112     $fsf= "$etc/fsys.$fsnm";
 113     stat $fsf or die "Filesystems $fsnm unknown ($!).\n";
 114     readfsysfile($fsf);
 115 }
 116
 117 # Parse a line from a filesystem definition file. We expect the line
 118 # to be in $tf.
 119 sub parsefsys () {
 120     if ($tf =~ m,^(/\S*)\s+(\w+)$,) {
 121         # Line of form '/file/system    dumptype'
 122         $atf= $1;
 123         $tm= $2;
 124         $prefix= '<local>';
 125         stat $atf or die "stat $atf: $!";
 126         -d _ or die "not a dir: $atf";
 127         $rstr= '';
 128     } elsif ($tf =~ m,^(/\S*)\s+(\w+)\s+(\w+)$,) {
 129         # Line of form '/file/system dumptype prefix'
 130         # (used for remote backups, I think)
 131         $atf= $1;
 132         $tm= $2;
 133         $prefix= $3;
 134         defined($prefix{$prefix}) or die "prefix $prefix in $tf ?\n";
 135         $rstr= $prefix{$prefix}.' ';
 136     }
 137 }
 138
 139 sub openlog () {
 140     unlink 'log';
 141     $u= umask(007);
 142     open LOG, ">log" or die $!;
 143     umask $u;
 144     select(LOG); $|=1; select(STDOUT);
 145 }
 146
 147 $SIG{'__DIE__'}= 'killprocesses';
 148
 149 1;