cgi-auth-hybrid.pm

   1 # -*- perl -*-
   2
   3 # This is part of CGI::Auth::Hybrid, a perl CGI authentication module.
   4 # Copyright (C) 2012 Ian Jackson.
   5 # Copyright (C) 2012 Citrix.
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU Affero General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU Affero General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU Affero General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21 use warnings;
  22
  23 package CGI::Auth::Hybrid;
  24 require Exporter;
  25
  26 BEGIN {
  27     use Exporter   ();
  28     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  29
  30     $VERSION     = 1.00;
  31     @ISA         = qw(Exporter);
  32     @EXPORT      = qw();
  33     %EXPORT_TAGS = ( );     # eg: TAG => [ qw!name1 name2! ],
  34
  35     @EXPORT_OK   = qw(setup);
  36 }
  37 our @EXPORT_OK;
  38
  39 use DBI;
  40 use CGI;
  41 use Locale::gettext;
  42
  43 #---------- public utilities ----------
  44
  45 sub flatten_params ($) {
  46     my ($p) = @_;
  47     my @p;
  48     foreach my $k (keys %$p) {
  49         foreach my $v (@{ $p->{$k} }) {
  50             push @p, $k, $v;
  51         }
  52     }
  53     return @p;
  54 }
  55
  56 #---------- default callbacks ----------
  57
  58 sub has_a_param ($$) {
  59     my ($c,$r,$cn) = @_;
  60     foreach my $pn (@{ $r->{S}{$cn} }) {
  61         return 1 if $r->_cm('get_param',$pn);
  62     }
  63     return 0;
  64 }
  65
  66 sub get_params ($$) {
  67     my ($c,$r) = @_;
  68     my %p;
  69     foreach my $name ($c->param()) {
  70         $p{$name} = [ $c->param($name) ];
  71     }
  72     return \%p;
  73 }
  74
  75 sub get_cookie_domain ($$$) {
  76     my ($c,$r) = @_;
  77     my $uri = new URI $r->_ch('get_url');
  78     return $uri->host();
  79 }
  80
  81 sub login_ok_password ($$) {
  82     my ($c, $r) = @_;
  83     my $username_params = $r->{S}{username_param_names};
  84     my $username = $r->_ch('get_param',$username_params->[0]);
  85     my $password = $r->_rp('password_param_name');
  86     return $r->_ch('username_password_ok', $username, $password);
  87 }
  88
  89 sub do_redirect_cgi ($$$$) {
  90     my ($c, $r, $new_url, $cookie) = @_;
  91     my @ha = ('text/html',
  92               -status => '303 See other',
  93               -location => $new_url);
  94     push @ha, (-cookie => $cookie) if defined $cookie;
  95     $r->_print($c->header(@ha),
  96                $r->_ch('gen_start_html',$r->_gt('Redirection')),
  97                '<a href="'.escapeHTML($new_url).'">',
  98                $r->_gt("If you aren't redirected, click to continue."),
  99                "</a>",
 100                $c->_ch('gen_end_html'));
 101 }
 102
 103 sub gen_plain_login_form ($$) {
 104     my ($c,$r, $params) = @_;
 105     my @form;
 106     push @form, ('<form method="POST" action="'.
 107                  escapeHTML($r->_ch('get_url')).'>'.
 108                  '<table>');
 109     my $sz = 'size="'.$r->{S}{form_entry_size}.'"';
 110     foreach my $up (@{ $r->{S}{username_param_names}}) {
 111         push @form, ('<tr><td>',$r->_gt(ucfirst $up),'</td>',
 112                      '<td><input type="text" ',$sz.
 113                      ' name=',$up,'></td></tr>');
 114     }
 115     push @form, ('<tr><td>'.$r->_gt('Password'),'</td>',
 116                  '<td><input type="password" '.$sz.
 117                  ' name="'.$r->{S}{password_param_name}.'"></td></tr>');
 118     push @form, ('<tr><td colspan="2">',
 119                  '<input type="submit"'.
 120                  ' name="'.$r->{S}{login_submit_name}.'"'.
 121                  ' value="'.$r->_gt('Login').'"></td></tr>',
 122                  '</table>');
 123     foreach my $n (keys %$params) {
 124         push @form, ('<input type="hidden"'.
 125                      ' name="'.$n.'"'.
 126                      ' value="'.$params->{$n}.'">');
 127     }
 128     push @form, ('</form>');
 129     return join "\n", @form;
 130 }
 131
 132 sub gen_login_link ($$) {
 133     my ($c,$r, $params) = @_;
 134     my $url = $r->url_with_query_params($params);
 135     return ('<a href="'.escapeHTML($url).'">'.
 136             $r->_gt('Log in again to continue.').
 137             '</a>');
 138 }
 139
 140 #---------- verifier object methods ----------
 141
 142 sub new_verifier {
 143     my $class = shift;
 144     my $verifier = {
 145         S => {
 146             assocdb_path => 'cah-assocs.db',
 147             assocdb_dsn => undef,
 148             assocdb_user => '',
 149             assocdb_password => '',
 150             assocdb_table => 'assocs',
 151             random_source => '/dev/urandom',
 152             associdlen => 128, # bits
 153             login_timeout => 86400, # seconds
 154             assoc_param_name => 'cah_associd',
 155             password_param_name => 'password',
 156             username_param_names => [qw(username)],
 157             form_entry_size => 60,
 158             logout_param_names => [qw(cah_logout)],
 159             login_submit_name => [qw(cah_login)],
 160             loggedout_param_names => [qw(cah_loggedout)],
 161             promise_check_mutate => 0,
 162             get_param => sub { $_[0]->param($_[2]) },
 163             get_params => sub { $_[1]->get_params() },
 164             get_cookie => sub { $_[0]->cookie($_[1]->{S}{cookie_name}) },
 165             get_method => sub { $_[0]->request_method() },
 166             get_url => sub { $_[0]->url(); },
 167             is_login => sub { defined $_[1]->_rp('password_param_name') },
 168             login_ok => \&login_ok_password,
 169             username_password_ok => sub { die },
 170             is_logout => sub { $_[1]->has_a_param('logout_param_names') },
 171             is_loggedout => sub { $_[1]->has_a_param('loggedout_param_names') },
 172             is_page => sub { return 1 },
 173             handle_divert => sub { return 0 },
 174             do_redirect => \&do_redirect_cgi, # this hook is allowed to throw
 175             cookie_path => "/",
 176             get_cookie_domain => \&get_cookie_domain,
 177             encrypted_only => 0,
 178             gen_start_html => sub { $_[0]->start_html($_[2]); },
 179             gen_end_html => sub { $_[0]->end_html(); },
 180             gen_login_form => \&gen_plain_login_form,
 181             gen_login_link => \&gen_plain_login_link,
 182             gettext => sub { gettext($_[2]); },
 183         },
 184         Dbh => undef,
 185     };
 186     my ($k,$v);
 187     while (($k,$v,@_) = @_) {
 188         die "unknown setting $k" unless exists $verifier->{S}{$k};
 189         $verifier->{S}{$k} = $v;
 190     }
 191     bless $verifier, $class;
 192     $verifier->_dbopen();
 193     return $verifier;
 194 }
 195
 196 sub _dbopen ($) {
 197     my ($v) = @_;
 198     my $dbh = $v->{Dbh};
 199     return $dbh if $dbh;
 200
 201     $v->{S}{assocdb_dsn} ||= "dbi:SQLite:dbname=$v->{S}{assocdb_path}";
 202     my $dsn = $v->{S}{assocdb_dsn};
 203
 204     my $u = umask 077;
 205     $dbh = DBI->connect($dsn, $v->{S}{assocdb_user},
 206                         $v->{S}{assocdb_password}, {
 207                             AutoCommit => 0, RaiseError => 1,
 208                         });
 209     die "$dsn $! ?" unless $dbh;
 210     $v->{Dbh} = $dbh;
 211
 212     $dbh->do("BEGIN");
 213
 214     eval {
 215         $dbh->do("CREATE TABLE $v->{S}{assocdb_table} (".
 216                  " associdh VARCHAR PRIMARY KEY,".
 217                  " username VARCHAR,".
 218                  " last INTEGER NOT NULL".
 219                  ")");
 220     };
 221     return $dbh;
 222 }
 223
 224 sub disconnect ($) {
 225     my ($v) = @_;
 226     my $dbh = $v->{Dbh};
 227     return unless $dbh;
 228     $dbh->disconnect();
 229 }
 230
 231 #---------- request object methods ----------
 232
 233 sub new_request {
 234     my ($classbase, $cgi, @extra) = @_;
 235     if (!ref $classbase) {
 236         $classbase = $classbase->new_verifier(@extra);
 237     } else {
 238         die if @extra;
 239     }
 240     my $r = {
 241         V => $classbase,
 242         S => $classbase->{S},
 243         Dbh => $classbase->{Dbh},
 244         Cgi => $cgi,
 245     };
 246     bless $r, ref $classbase;
 247 }
 248
 249 sub _ch ($$@) { # calls an application hook
 250     my ($r,$methname, @args) = @_;
 251     my $methfunc = $r->{S}{$methname};
 252     return $methfunc->($r->{Cgi}, $r, @args);
 253 }
 254
 255 sub _rp ($$@) {
 256     my ($r,$pnvb) = @_;
 257     my $pn = $r->{S}{$pnvb};
 258     my $p = scalar $r->_ch('get_param',$pn)
 259 }
 260
 261 sub _gt ($$) { my ($r, $t) = @_; return $r->_ch('gettext',$t); }
 262 sub _print ($$) { my ($r, @t) = @_; return $r->_ch('print', join '', @t); }
 263
 264 sub construct_cookie ($$$) {
 265     my ($r, $cookv) = @_;
 266     return $r->{Cgi}->cookie(-name => $r->{S}{cookie_name},
 267                              -value => $cookv,
 268                              -path => $r->{S}{cookie_path},
 269                              -domain => $r->_ch('get_cookie_domain'),
 270                              -expires => '+'.$r->{S}{login_timeout}.'s',
 271                              -secure => $r->{S}{encrypted_only});
 272 }
 273
 274 # pages/param-sets are
 275 #   n normal non-mutating page
 276 #   r retrieval of information for JS, non-mutating
 277 #   m mutating page
 278 #   u update of information by JS, mutating
 279 #   i login
 280 #   o logout
 281 #   O "you have just logged out" page load
 282
 283 # in cook and par,
 284 #    a, aN     anything including -
 285 #    t, tN     temporary value (in our db, no logged in user yet)
 286 #    y, yN     value corresponds to logged-in user
 287 #    n, nN     value not in our db
 288 #    x, xN     t or y
 289 #    -         no value supplied
 290 # if N differs the case applies only when the two values differ
 291 # (eg,   a1 y2   does not apply when the logged-in value is supplied twice)
 292
 293 # "stale session" means request originates from a page from a login
 294 # session which has been revoked (eg by logout); "cleared session"
 295 # means request originates from a browser which has a different (or
 296 # no) cookie.
 297
 298     # Case analysis, cookie mode, app promises re mutate:
 299     # cook parm meth form
 300     #
 301     #  any -   POST  nrmuoi   bug or attack, fail
 302     #  any -   GET    rmuoi   bug or attack, fail
 303     #  any any GET     muoi   bug or attack, fail
 304     #  any t   any   nrmu     bug or attack, fail
 305     #
 306     #  -   -   GET         O  "just logged out" page
 307     #  (any other)         O  bug or attack, fail
 308     #
 309     #  a1  a2  POST      o    logout
 310     #                           if a1 is valid, revoke it
 311     #                           if a2 is valid, revoke it
 312     #                           delete cookie
 313     #                           redirect to "just logged out" page
 314     #                             (which contains link to login form)
 315     #
 316     #  -   t   POST       i   complain about cookies being disabled
 317     #                           (with link to login form)
 318     #
 319     #  any n   POST       i   complain about stale login form
 320     #                           show new login form
 321     #
 322     #  x1  t2  POST       i   login (or switch user)
 323     #                           if bad
 324     #                             show new login form
 325     #                           if good
 326     #                             revoke x1 if it was valid and !=t2
 327     #                             upgrade t2 to y2 in our db (setting username)
 328     #                             set cookie to t2
 329     #                             redirect to GET of remaining params
 330     #
 331     #  t1  a2  ANY   nrmu     treat as  - a2 ANY
 332     #
 333     #  y   -   GET   n        cross-site link
 334     #                           show data
 335     #
 336     #  y   y   GET   nr       fine, show page or send data
 337     #  y   y   POST  nrmu     mutation is OK, do operation
 338     #
 339     #  y1  y2  GET   nr       request from stale page
 340     #                           do not revoke y2 as not RESTful
 341     #                           treat as   y1 n GET
 342     #
 343     #  y1  y2  POST  nrmu     request from stale page
 344     #                           revoke y2
 345     #                           treat as   y1 n POST
 346     #
 347     #  y   n   GET   n        intra-site link from stale page,
 348     #                           treat as cross-site link, show data
 349     #
 350     #  y   n   POST  n m      intra-site form submission from stale page
 351     #                           show "session interrupted"
 352     #                           with link to main data page
 353     #
 354     #  y   n   GET    r       intra-site request from stale page
 355     #                           fail
 356     #
 357     #  y   n   POST   r u     intra-site request from stale page
 358     #                           fail
 359     #
 360     #  -/n y2  GET   nr       intra-site link from cleared session
 361     #                           do not revoke y2 as not RESTful
 362     #                           treat as   -/n n GET
 363     #
 364     #  -/n y2  POST  nrmu     request from cleared session
 365     #                           revoke y2
 366     #                           treat as   -/n n POST
 367     #
 368     #  -/n n   GET   n        cross-site link but user not logged in
 369     #                           show login form with redirect to orig params
 370     #
 371     #  -/n n   GET    rmu     user not logged in
 372     #                           fail
 373     #
 374     #  -/n n   POST  n m      user not logged in
 375     #                           show login form
 376     #
 377     #  -/n n   POST   r u     user not logged in
 378     #                           fail
 379
 380 sub _check_divert_core ($) {
 381     my ($r) = @_;
 382
 383     my $meth = $r->_ch('get_method');
 384     my $cookv = $r->_ch('get_cookie');
 385     my $parmv = $r->_rp('assoc_param_name');
 386
 387     my ($cookt,$cooku) = $r->_db_lookup($cookv);
 388     my $parmt = $r->_db_lookup($parmv);
 389
 390     if ($r->_ch('is_logout')) {
 391         $r->_must_be_post();
 392         die unless $parmt;
 393         $r->_db_revoke($cookv);
 394         $r->_db_revoke($parmv);
 395         return ({ Kind => 'REDIRECT-LOGGEDOUT',
 396                   Message => "Logging out...",
 397                   CookieVal => '',
 398                   Params => { } });
 399     }
 400     if ($r->_ch('is_loggedout')) {
 401         die unless $meth eq 'GET';
 402         die unless $cookt;
 403         die unless $parmt;
 404         return ({ Kind => 'SMALLPAGE-LOGGEDOUT',
 405                   Message => "You have been logged out.",
 406                   CookieVal => '',
 407                   Params => { } });
 408     }
 409     if ($r->_ch('is_login')) {
 410         $r->_must_be_post();
 411         return ({ Kind => 'LOGIN-STALE',
 412                   Message => "Stale session; you need to log in again.",
 413                   CookieVal => $r->_fresh_cookie(),
 414                   Params => { } })
 415             if $parmt eq 'n';
 416         die unless $parmt eq 't' || $parmt eq 'y';
 417         return ({ Kind => 'SMALLPAGE-NOCOOKIE',
 418                   Message => "You do not seem to have cookies enabled.  ".
 419                       "You must enable cookies as we use them for login.",
 420                   CookieVal => $r->_fresh_cookie(),
 421                   Params => $r->_chain_params() })
 422             if !$cookt && $parmt eq 't';
 423         my $username = $r->_ch('login_ok');
 424         return ({ Kind => 'LOGIN-BAD',
 425                   Message => "Incorrect username/password.",
 426                   CookieVal => $cookv,
 427                   Params => $r->_chain_params() })
 428             unless defined $username && length $username;
 429         $r->_db_revoke($cookv)
 430             if defined $cookv && !(defined $parmv && $cookv eq $parmv);
 431         $r->_db_record_login_ok($parmv,$username);
 432         return ({ Kind => 'REDIRECT-LOGGEDIN',
 433                   Message => "Logging in...",
 434                   CookieVal => $parmv,
 435                   Params => $r->_chain_params() });
 436     }
 437     if ($cookt eq 't') {
 438         $cookt = '';
 439     }
 440     die if $parmt eq 't';
 441
 442     if ($cookt eq 'y' && $parmt eq 'y' && $cookv ne $parmv) {
 443         $r->_db_revoke($parmv) if $meth eq 'POST';
 444         $parmt = 'n';
 445     }
 446
 447     if ($cookt ne 'y') {
 448         die unless !$cookt || $cookt eq 'n';
 449         die unless !$parmt || $parmt eq 'n' || $parmt eq 'y';
 450         if ($meth eq 'GET') {
 451             return ({ Kind => 'LOGIN-INCOMINGLINK',
 452                       Message => "You need to log in again.",
 453                       CookieVal => $parmv,
 454                       Params => $r->_chain_params() });
 455         } else {
 456             return ({ Kind => 'LOGIN-FRESH',
 457                       Message => "You need to log in again.",
 458                       CookieVal => $parmv,
 459                       Params => { } });
 460         }
 461     }
 462
 463     if (!$r->{S}{promise_check_mutate}) {
 464         if ($meth ne 'POST') {
 465             return ({ Kind => 'MAINPAGEONLY',
 466                       Message => 'Entering via cross-site link.',
 467                       CookieVal => $cookv,
 468                       Params => { } });
 469             # NB caller must then ignore params & path!
 470             # if this is too hard they can spit out a small form
 471             # with a "click to continue"
 472         }
 473     }
 474
 475     die unless $cookt eq 'y';
 476     die unless $parmt eq 'y';
 477     die unless $cookv eq $parmv;
 478     $r->{Assoc} = $cookv;
 479     $r->{UserOK} = $cooku;
 480     return undef;
 481 }
 482
 483 sub _chain_params ($) {
 484     my ($r) = @_;
 485     my %p = %{ $r->_ch('get_params') };
 486     foreach my $pncn (keys %{ $r->{S} }) {
 487         my $names;
 488         if ($pncn =~ m/_param_name$/) {
 489             my $name = $r->{S}{$pncn};
 490             die "$pncn ?" if ref $name;
 491             $names = [ $name ];
 492         } elsif ($pncn =~ m/_param_names$/) {
 493             $names = $r->{S}{$pncn};
 494         } else {
 495             next;
 496         }
 497         foreach my $name (@$names) {
 498             delete $p{$name};
 499         }
 500     }
 501     return \%p;
 502 }
 503
 504 sub _db_lookup ($$) {
 505     my ($r,$v) = @_;
 506     # returns ($t,$username)
 507     # where $t is one of "t" "y" "n", or "" (for -)
 508
 509     my $dbh = $r->{Dbh};
 510
 511     my $row = $dbh->selectrow_arrayref("SELECT username, last".
 512                               " FROM $r->{S}{assocdb_table}".
 513                               " WHERE associd = ?", {}, $v);
 514     return ('') unless defined $row;
 515
 516     my ($nusername, $nlast) = @$row;
 517
 518     my $timeout = $r->{S}{login_timeout};
 519     return ('n') unless !defined $timeout || time <= $nlast + $timeout;
 520
 521     return ('t') unless defined $nusername;
 522
 523     # hooray
 524     return ('y', $nusername);
 525 }
 526
 527 sub _db_revoke ($$) {
 528     # revokes $v if it's valid; no-op if it's not
 529     my ($r,$v) = @_;
 530
 531     my $dbh = $r->{Dbh};
 532
 533     $dbh->do("DELETE FROM $r->{S}{assocdb_table}".
 534              " WHERE associd = ?", {}, $v);
 535 }
 536
 537 sub _db_record_login_ok ($$$) {
 538     my ($r,$v,$user) = @_;
 539     $r->_db_revoke($v);
 540     my $dbh = $r->{Dbh};
 541     $dbh->do("INSERT INTO $r->{S}{assocdb_table}".
 542              " (associd, username, last) VALUES (?,?,?)", {},
 543              $v, $user, time);
 544 }
 545
 546 sub check_divert ($) {
 547     my ($r) = @_;
 548     my $divert;
 549     if (exists $r->{Divert}) {
 550         return $r->{Divert};
 551     }
 552     my $dbh = $r->{Dbh};
 553     $dbh->do("BEGIN");
 554     if (!eval {
 555         $divert = $r->_check_divert_core();
 556         1;
 557     }) {
 558         $dbh->do("ABORT");
 559         die $@;
 560     }
 561     $r->{Divert} = $divert;
 562     $dbh->do("COMMIT");
 563     return $divert;
 564 }
 565
 566 sub get_divert ($) {
 567     my ($r) = @_;
 568     die "unchecked" unless exists $r->{Divert};
 569     return $r->{Divert};
 570 }
 571
 572 sub get_username ($) {
 573     my ($r) = @_;
 574     my $divert = $r->get_divert();
 575     return undef if $divert;
 576     return $r->{UserOK};
 577 }
 578
 579 sub url_with_query_params ($$) {
 580     my ($r, $params) = @_;
 581     my $uri = URI->new($r->_ch('get_url'));
 582     $uri->query_form(flatten_params($params));
 583     return $uri->as_string();
 584 }
 585
 586 sub check_ok ($) {
 587     my ($r) = @_;
 588
 589     my ($divert) = $r->check_divert();
 590     return 1 if $divert;
 591
 592     my $handled = $r->_ch('handle_divert',$divert);
 593     return 0 if $handled;
 594
 595     my $kind = $divert->{Kind};
 596     my $cookieval = $divert->{CookieVal};
 597     my $params = $divert->{Params};
 598
 599     if ($kind =~ m/^REDIRECT-/) {
 600         # for redirects, we honour stored NextParams and SetCookie,
 601         # as we would for non-divert
 602         if ($kind eq 'REDIRECT-LOGGEDOUT') {
 603             $params->{$r->{S}{loggedout_param_names}[0]} = 1;
 604         } elsif ($kind eq 'REDIRECT-LOGOUT') {
 605             $params->{$r->{S}{logout_param_names}[0]} = 1;
 606         } elsif ($kind eq 'REDIRECT-LOGGEDIN') {
 607         } else {
 608             die;
 609         }
 610         my $new_url = $r->url_with_query_params($params);
 611         my $cookie = $r->construct_cookie($r, $cookieval);
 612         $r->_ch('do_redirect',$new_url, $cookie);
 613         return 0;
 614     }
 615
 616     my ($title, @body);
 617     if ($kind =~ m/^LOGIN-/) {
 618         $title = $r->_gt('Login');
 619         push @body, $r->_gt($divert->{Message});
 620         push @body, $r->_ch('gen_login_form', $params);
 621     } elsif ($kind =~ m/^SMALLPAGE-/) {
 622         $title = $r->_gt('Not logged in');
 623         push @body, $r->_gt($divert->{Message});
 624         push @body, $r->_ch('gen_login_link');
 625     } else {
 626         die $kind;
 627     }
 628
 629     $r->_print($r->_ch('start_html',$title),
 630                @body,
 631                $r->_ch('end_html'));
 632     return 0;
 633 }
 634
 635 sub _random ($$) {
 636     my ($r, $bytes) = @_;
 637     my $v = $r->{V};
 638     my $rsf = $v->{RandomHandle};
 639     my $rsp = $r->{S}{random_source};
 640     if (!$rsf) {
 641         $v->{RandomHandle} = $rsf = new IO::File $rsp, '<' or die "$rsp $!";
 642     }
 643     my $bin;
 644     $!=0;
 645     read($rsf,$bin,$bytes) == $bytes or die "$rsp $!";
 646     close $rsf;
 647     return unpack "H*", $bin;
 648 }
 649
 650 sub _fresh_cookie ($) {
 651     my ($r) = @_;
 652     my $bytes = ($r->{S}{associdlen} + 7) >> 3;
 653     return $r->_random($bytes);
 654 }
 655
 656 sub check_mutate ($) {
 657     my ($r) = @_;
 658     die "unchecked" unless exists $r->{Divert};
 659     die if $r->{Divert};
 660     my $meth = $r->_ch('get_method');
 661     die "mutating non-POST" if $meth ne 'POST';
 662 }
 663
 664 #---------- output ----------
 665
 666 sub secret_val ($) {
 667     my ($r) = @_;
 668     $r->check();
 669     return defined $r->{Assoc} ? $r->{Assoc} : '';
 670 }
 671
 672 sub secret_hidden_html ($) {
 673     my ($r) = @_;
 674     return $r->{Cgi}->hidden(-name => $r->{S}{assoc_param_name},
 675                              -default => $r->secret_val());
 676 }
 677
 678 sub secret_cookie ($) {
 679     my ($r) = @_;
 680     return $r->construct_cookie($r->secret_val());
 681 }
 682
 683 __END__
 684
 685 =head1 NAME
 686
 687 CGI::Auth::Hybrid - web authentication optionally using cookies
 688
 689 =head1 SYNOPSYS
 690
 691  my $verifier = CGI::Auth::Hybrid->new_verifier(setting => value,...);
 692  my $authreq = $verifier->new_request($cgi_request_object);
 693
 694  my $authreq = CGI::Auth::Hybrid->new_request($cgi_request_object,
 695                                               setting => value,...);
 696
 697 =head1 USAGE PATTERN FOR SIMPLE APPLICATIONS
 698
 699  $authreq->check_ok() or return;
 700
 701  blah blah blah
 702  $authreq->check_mutate();
 703  blah blah blah
 704
 705 =head1 USAGE PATTERN FOR FANCY APPLICATIONS
 706
 707  my $divert_kind = $authreq->check_divert();
 708  if ($divert_kind) {
 709      if ($divert_kind eq 'LOGGEDOUT') {
 710          print "goodbye you are now logged out" and quit
 711      } elsif ($divert_kind eq 'NOCOOKIES') {
 712          print "you need cookies" and quit
 713      ... etc.
 714      }
 715  }
 716
 717  blah blah blah
 718  $authreq->check_mutate();
 719  blah blah blah