cgi-auth-hybrid.pm

   1 # -*- perl -*-
   2
   3 # This is part of CGI::Auth::Hybrid, a perl CGI authentication module.
   4 # Copyright (C) 2012 Ian Jackson.
   5 # Copyright (C) 2012 Citrix.
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU Affero General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU Affero General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU Affero General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21 use warnings;
  22
  23 package CGI::Auth::Hybrid;
  24 require Exporter;
  25
  26 BEGIN {
  27     use Exporter   ();
  28     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  29
  30     $VERSION     = 1.00;
  31     @ISA         = qw(Exporter);
  32     @EXPORT      = qw();
  33     %EXPORT_TAGS = ( );     # eg: TAG => [ qw!name1 name2! ],
  34
  35     @EXPORT_OK   = qw(setup);
  36 }
  37 our @EXPORT_OK;
  38
  39 use DBI;
  40 use CGI qw/escapeHTML/;
  41 use Locale::gettext;
  42 use URI;
  43 use IO::File;
  44 use Data::Dumper;
  45
  46 #---------- public utilities ----------
  47
  48 sub flatten_params ($) {
  49     my ($p) = @_;
  50     my @p;
  51     foreach my $k (keys %$p) {
  52         foreach my $v (@{ $p->{$k} }) {
  53             push @p, $k, $v;
  54         }
  55     }
  56     return @p;
  57 }
  58
  59 #---------- default callbacks ----------
  60
  61 sub has_a_param ($$) {
  62     my ($r,$cn) = @_;
  63     foreach my $pn (@{ $r->{S}{$cn} }) {
  64         return 1 if $r->_ch('get_param',$pn);
  65     }
  66     return 0;
  67 }
  68
  69 sub get_params ($) {
  70     my ($r) = @_;
  71     my %p;
  72     my $c = $r->{Cgi};
  73     foreach my $name ($c->param()) {
  74         $p{$name} = [ $c->param($name) ];
  75     }
  76     return \%p;
  77 }
  78
  79 sub get_cookie_domain ($$$) {
  80     my ($c,$r) = @_;
  81     my $uri = new URI $r->_ch('get_url');
  82     return $uri->host();
  83 }
  84
  85 sub login_ok_password ($$) {
  86     my ($c, $r) = @_;
  87     my $username_params = $r->{S}{username_param_names};
  88     my $username = $r->_ch('get_param',$username_params->[0]);
  89     my $password = $r->_rp('password_param_name');
  90     return $r->_ch('username_password_ok', $username, $password);
  91 }
  92
  93 sub do_redirect_cgi ($$$$) {
  94     my ($c, $r, $new_url, $cookie) = @_;
  95     $r->_print($c->header($r->_cgi_header_args($cookie,
  96                                                -status => '303 See other',
  97                                                -location => $new_url)),
  98                $r->_ch('gen_start_html',$r->_gt('Redirection')),
  99                '<a href="'.escapeHTML($new_url).'">',
 100                $r->_gt("If you aren't redirected, click to continue."),
 101                "</a>",
 102                $c->_ch('gen_end_html'));
 103 }
 104
 105 sub gen_plain_login_form ($$) {
 106     my ($c,$r, $params) = @_;
 107     my @form;
 108     push @form, ('<form method="POST" action="'.
 109                  escapeHTML($r->_ch('get_url')).'">'.
 110                  '<table>');
 111     my $sz = 'size="'.$r->{S}{form_entry_size}.'"';
 112     foreach my $up (@{ $r->{S}{username_param_names}}) {
 113         push @form, ('<tr><td>',$r->_gt(ucfirst $up),'</td>',
 114                      '<td><input type="text" '.$sz.
 115                      ' name='.$up.'></td></tr>');
 116     }
 117     push @form, ('<tr><td>'.$r->_gt('Password'),'</td>',
 118                  '<td><input type="password" '.$sz.
 119                  ' name="'.$r->{S}{password_param_name}.'"></td></tr>');
 120     push @form, ('<tr><td colspan="2">',
 121                  '<input type="submit"'.
 122                  ' name="'.$r->{S}{login_submit_name}[0].'"'.
 123                  ' value="'.$r->_gt('Login').'"></td></tr>',
 124                  '</table>');
 125     foreach my $n (keys %$params) {
 126         push @form, ('<input type="hidden"'.
 127                      ' name="'.$n.'"'.
 128                      ' value="'.$params->{$n}.'">');
 129     }
 130     push @form, ('</form>');
 131     return join "\n", @form;
 132 }
 133
 134 sub gen_login_link ($$) {
 135     my ($c,$r, $params) = @_;
 136     my $url = $r->url_with_query_params($params);
 137     return ('<a href="'.escapeHTML($url).'">'.
 138             $r->_gt('Log in again to continue.').
 139             '</a>');
 140 }
 141
 142 #---------- verifier object methods ----------
 143
 144 sub new_verifier {
 145     my $class = shift;
 146     my $verifier = {
 147         S => {
 148             assocdb_path => 'cah-assocs.db',
 149             assocdb_dsn => undef,
 150             assocdb_user => '',
 151             assocdb_password => '',
 152             assocdb_table => 'assocs',
 153             random_source => '/dev/urandom',
 154             assocsecretlen => 128, # bits
 155             login_timeout => 86400, # seconds
 156             assoc_param_name => 'cah_assochash',
 157             cookie_name => "cah_assocsecret",
 158             password_param_name => 'password',
 159             username_param_names => [qw(username)],
 160             form_entry_size => 60,
 161             logout_param_names => [qw(cah_logout)],
 162             login_submit_name => [qw(cah_login)],
 163             loggedout_param_names => [qw(cah_loggedout)],
 164             promise_check_mutate => 0,
 165             get_param => sub { $_[0]->param($_[2]) },
 166             get_params => sub { $_[1]->get_params() },
 167             get_cookie => sub { $_[0]->cookie($_[1]->{S}{cookie_name}) },
 168             get_method => sub { $_[0]->request_method() },
 169             get_url => sub { $_[0]->url(); },
 170             is_login => sub { defined $_[1]->_rp('password_param_name') },
 171             login_ok => \&login_ok_password,
 172             username_password_ok => sub { die },
 173             is_logout => sub { $_[1]->has_a_param('logout_param_names') },
 174             is_loggedout => sub { $_[1]->has_a_param('loggedout_param_names') },
 175             is_page => sub { return 1 },
 176             handle_divert => sub { return 0 },
 177             do_redirect => \&do_redirect_cgi, # this hook is allowed to throw
 178             cookie_path => "/",
 179             get_cookie_domain => \&get_cookie_domain,
 180             encrypted_only => 1,
 181             gen_start_html => sub { $_[0]->start_html($_[2]); },
 182             gen_end_html => sub { $_[0]->end_html(); },
 183             gen_login_form => \&gen_plain_login_form,
 184             gen_login_link => \&gen_plain_login_link,
 185             gettext => sub { gettext($_[2]); },
 186             print => sub { print $_[2] or die $!; },
 187         },
 188         Dbh => undef,
 189     };
 190     my ($k,$v);
 191     while (($k,$v,@_) = @_) {
 192         die "unknown setting $k" unless exists $verifier->{S}{$k};
 193         $verifier->{S}{$k} = $v;
 194     }
 195     bless $verifier, $class;
 196     $verifier->_dbopen();
 197     return $verifier;
 198 }
 199
 200 sub _dbopen ($) {
 201     my ($v) = @_;
 202     my $dbh = $v->{Dbh};
 203     return $dbh if $dbh;
 204
 205     $v->{S}{assocdb_dsn} ||= "dbi:SQLite:dbname=$v->{S}{assocdb_path}";
 206     my $dsn = $v->{S}{assocdb_dsn};
 207
 208     my $u = umask 077;
 209     $dbh = DBI->connect($dsn, $v->{S}{assocdb_user},
 210                         $v->{S}{assocdb_password}, {
 211                             AutoCommit => 0,
 212                             RaiseError => 1,
 213                             ShowErrorStatement => 1,
 214                         });
 215     die "$dsn $! ?" unless $dbh;
 216     $v->{Dbh} = $dbh;
 217
 218     eval {
 219         $v->_db_transaction(sub {
 220             local ($dbh->{PrintError}) = 0;
 221             $dbh->do("CREATE TABLE $v->{S}{assocdb_table} (".
 222                      " assochash VARCHAR PRIMARY KEY,".
 223                      " username VARCHAR,".
 224                      " last INTEGER NOT NULL".
 225                      ")");
 226         });
 227     };
 228     return $dbh;
 229 }
 230
 231 sub disconnect ($) {
 232     my ($v) = @_;
 233     my $dbh = $v->{Dbh};
 234     return unless $dbh;
 235     $dbh->disconnect();
 236 }
 237
 238 sub _db_transaction ($$) {
 239     my ($v, $fn) = @_;
 240     my $retries = 10;
 241     my $rv;
 242     my $dbh = $v->{Dbh};
 243 print STDERR "DT entry\n";
 244     for (;;) {
 245 print STDERR "DT loop\n";
 246         if (!eval {
 247             $rv = $fn->();
 248 print STDERR "DT fn ok\n";
 249             1;
 250         }) {
 251 print STDERR "DT fn error\n";
 252             { local ($@); $dbh->rollback(); }
 253 print STDERR "DT fn throwing\n";
 254             die $@;
 255         }
 256 print STDERR "DT fn eval ok\n";
 257         if (eval {
 258             $dbh->commit();
 259 print STDERR "DT commit ok\n";
 260             1;
 261         }) {
 262 print STDERR "DT commit eval ok $rv\n";
 263             return $rv;
 264         }
 265 print STDERR "DT commit throw?\n";
 266         die $@ if !--$retries;
 267 print STDERR "DT loop again\n";
 268     }
 269 }
 270
 271 #---------- request object methods ----------
 272
 273 sub new_request {
 274     my ($classbase, $cgi, @extra) = @_;
 275     if (!ref $classbase) {
 276         $classbase = $classbase->new_verifier(@extra);
 277     } else {
 278         die if @extra;
 279     }
 280     my $r = {
 281         V => $classbase,
 282         S => $classbase->{S},
 283         Dbh => $classbase->{Dbh},
 284         Cgi => $cgi,
 285     };
 286     bless $r, ref $classbase;
 287 }
 288
 289 sub _ch ($$@) { # calls an application hook
 290     my ($r,$methname, @args) = @_;
 291     my $methfunc = $r->{S}{$methname};
 292     die "$methname ?" unless $methfunc;
 293     return $methfunc->($r->{Cgi}, $r, @args);
 294 }
 295
 296 sub _rp ($$@) {
 297     my ($r,$pnvb) = @_;
 298     my $pn = $r->{S}{$pnvb};
 299     my $p = scalar $r->_ch('get_param',$pn)
 300 }
 301
 302 sub _gt ($$) { my ($r, $t) = @_; return $r->_ch('gettext',$t); }
 303 sub _print ($$) { my ($r, @t) = @_; return $r->_ch('print', join '', @t); }
 304
 305 sub construct_cookie ($$$) {
 306     my ($r, $cooks) = @_;
 307     return undef unless $cooks;
 308     my $c = $r->{Cgi};
 309 my @ca = (-name => $r->{S}{cookie_name},
 310                              -value => $cooks,
 311                              -path => $r->{S}{cookie_path},
 312                              -domain => $r->_ch('get_cookie_domain'),
 313                              -expires => '+'.$r->{S}{login_timeout}.'s',
 314                              -secure => $r->{S}{encrypted_only});
 315     my $cookie = $c->cookie(@ca);
 316 print STDERR "CC $r $c $cooks $cookie (@ca).\n";
 317     return $cookie;
 318 }
 319
 320 # pages/param-sets are
 321 #   n normal non-mutating page
 322 #   r retrieval of information for JS, non-mutating
 323 #   m mutating page
 324 #   u update of information by JS, mutating
 325 #   i login
 326 #   o logout
 327 #   O "you have just logged out" page load
 328
 329 # in cook and par,
 330 #    -         no value supplied (represented in code as $cookt='')
 331 #    n, nN     value not in our db
 332 #    t, tN     temporary value (in our db, no logged in user yet)
 333 #    y, yN     value corresponds to logged-in user
 334 # and, aggregated conditions:
 335 #    a, aN     anything including -
 336 #    x, xN     t or y
 337 # if N differs the case applies only when the two values differ
 338 # (eg,   a1 y2   does not apply when the logged-in value is supplied twice)
 339
 340 # "stale session" means request originates from a page from a login
 341 # session which has been revoked (eg by logout); "cleared session"
 342 # means request originates from a browser which has a different (or
 343 # no) cookie.
 344
 345     # Case analysis, cookie mode, app promises re mutate:
 346     # cook parm meth form
 347     #
 348     #  any -   POST  nrmuoi   bug or attack, fail
 349     #  any -   GET    rmuoi   bug or attack, fail
 350     #  any any GET     muoi   bug or attack, fail
 351     #  any t   any   nrmu     bug or attack, fail
 352     #
 353     #  -   -   GET         O  "just logged out" page
 354     #  (any other)         O  bug or attack, fail
 355     #
 356     #  a1  a2  POST      o    logout
 357     #                           if a1 is valid, revoke it
 358     #                           if a2 is valid, revoke it
 359     #                           delete cookie
 360     #                           redirect to "just logged out" page
 361     #                             (which contains link to login form)
 362     #
 363     #  -   t   POST       i   complain about cookies being disabled
 364     #                           (with link to login form)
 365     #
 366     #  t1  t1  POST       i   login (or switch user)
 367     #                           if bad
 368     #                             show new login form
 369     #                           if good
 370     #                             upgrade t1 to y1 in our db (setting username)
 371     #                             redirect to GET of remaining params
 372     #
 373     #  y1  a2  POST       i   complain about stale login form
 374     #                           revoke y1
 375     #                           show new login form
 376     #
 377     #  (other) POST       i   complain about stale login form
 378     #                           show new login form
 379     #
 380     #  t1  a2  ANY   nrmu     treat as  - a2 ANY
 381     #
 382     #  y   -   GET   n        cross-site link
 383     #                           show data
 384     #
 385     #  y   y   GET   nr       fine, show page or send data
 386     #  y   y   POST  nrmu     mutation is OK, do operation
 387     #
 388     #  y1  y2  GET   nr       request from stale page
 389     #                           do not revoke y2 as not RESTful
 390     #                           treat as   y1 n GET
 391     #
 392     #  y1  y2  POST  nrmu     request from stale page
 393     #                           revoke y2
 394     #                           treat as   y1 n POST
 395     #
 396     #  y   n   GET   n        intra-site link from stale page,
 397     #                           treat as cross-site link, show data
 398     #
 399     #  y   n   POST  n m      intra-site form submission from stale page
 400     #                           show "session interrupted"
 401     #                           with link to main data page
 402     #
 403     #  y   n   GET    r       intra-site request from stale page
 404     #                           fail
 405     #
 406     #  y   n   POST   r u     intra-site request from stale page
 407     #                           fail
 408     #
 409     #  -/n y2  GET   nr       intra-site link from cleared session
 410     #                           do not revoke y2 as not RESTful
 411     #                           treat as   -/n n GET
 412     #
 413     #  -/n y2  POST  nrmu     request from cleared session
 414     #                           revoke y2
 415     #                           treat as   -/n n POST
 416     #
 417     #  -/n -/n GET   n        cross-site link but user not logged in
 418     #                           show login form with redirect to orig params
 419     #                           generate fresh cookie
 420     #
 421     #  -/n n   GET    rmu     user not logged in
 422     #                           fail
 423     #
 424     #  -/n n   POST  n m      user not logged in
 425     #                           show login form
 426     #
 427     #  -/n n   POST   r u     user not logged in
 428     #                           fail
 429
 430 sub _check_divert_core ($) {
 431     my ($r) = @_;
 432
 433     my $meth = $r->_ch('get_method');
 434     my $cooks = $r->_ch('get_cookie');
 435     my $parmh = $r->_rp('assoc_param_name');
 436     my $cookh = defined $cooks ? $r->hash($cooks) : undef;
 437
 438     my ($cookt,$cooku) = $r->_db_lookup($cookh);
 439     my $parmt = $r->_db_lookup($parmh);
 440
 441     print STDERR "_c_d_c cookt=$cookt parmt=$parmt\n";
 442
 443     if ($r->_ch('is_logout')) {
 444         $r->_must_be_post();
 445         die unless $parmt;
 446         $r->_db_revoke($cookh);
 447         $r->_db_revoke($parmh);
 448         return ({ Kind => 'REDIRECT-LOGGEDOUT',
 449                   Message => "Logging out...",
 450                   CookieSecret => '',
 451                   Params => { } });
 452     }
 453     if ($r->_ch('is_loggedout')) {
 454         die unless $meth eq 'GET';
 455         die unless $cookt;
 456         die unless $parmt;
 457         return ({ Kind => 'SMALLPAGE-LOGGEDOUT',
 458                   Message => "You have been logged out.",
 459                   CookieSecret => '',
 460                   Params => { } });
 461     }
 462     if ($r->_ch('is_login')) {
 463         $r->_must_be_post();
 464         die unless $parmt;
 465         if (!$cookt && $parmt eq 't') {
 466             return ({ Kind => 'SMALLPAGE-NOCOOKIE',
 467                       Message => "You do not seem to have cookies enabled.  ".
 468                           "You must enable cookies as we use them for login.",
 469                           CookieSecret => $r->_fresh_secret(),
 470                           Params => $r->_chain_params() })
 471         }
 472         if (!$cookt || $cookt eq 'n' || $cookh ne $parmh) {
 473             $r->_db_revoke($cookh);
 474             return ({ Kind => 'LOGIN-STALE',
 475                       Message => "Stale session; you need to log in again.",
 476                       CookieSecret => $r->_fresh_secret(),
 477                       Params => { } })
 478         }
 479         die unless $parmt eq 't' || $parmt eq 'y';
 480         my $username = $r->_ch('login_ok');
 481         unless (defined $username && length $username) {
 482             return ({ Kind => 'LOGIN-BAD',
 483                       Message => "Incorrect username/password.",
 484                       CookieSecret => $cooks,
 485                       Params => $r->_chain_params() })
 486         }
 487         $r->_db_record_login_ok($parmh,$username);
 488         return ({ Kind => 'REDIRECT-LOGGEDIN',
 489                   Message => "Logging in...",
 490                   CookieSecret => $cooks,
 491                   Params => $r->_chain_params() });
 492     }
 493     if ($cookt eq 't') {
 494         $cookt = '';
 495     }
 496     die if $parmt eq 't';
 497
 498     if ($cookt eq 'y' && $parmt eq 'y' && $cookh ne $parmh) {
 499         $r->_db_revoke($parmh) if $meth eq 'POST';
 500         $parmt = 'n';
 501     }
 502
 503     if ($cookt ne 'y') {
 504         die unless !$cookt || $cookt eq 'n';
 505         die unless !$parmt || $parmt eq 'n' || $parmt eq 'y';
 506         my $news = $r->_fresh_secret();
 507         if ($meth eq 'GET') {
 508             return ({ Kind => 'LOGIN-INCOMINGLINK',
 509                       Message => "You need to log in again.",
 510                       CookieSecret => $news,
 511                       Params => $r->_chain_params() });
 512         } else {
 513             $r->_db_revoke($parmh);
 514             return ({ Kind => 'LOGIN-FRESH',
 515                       Message => "You need to log in again.",
 516                       CookieSecret => $news,
 517                       Params => { } });
 518         }
 519     }
 520
 521     if (!$r->{S}{promise_check_mutate}) {
 522         if ($meth ne 'POST') {
 523             return ({ Kind => 'MAINPAGEONLY',
 524                       Message => 'Entering via cross-site link.',
 525                       CookieSecret => $cooks,
 526                       Params => { } });
 527             # NB caller must then ignore params & path!
 528             # if this is too hard they can spit out a small form
 529             # with a "click to continue"
 530         }
 531     }
 532
 533     die unless $cookt eq 'y';
 534     die unless $parmt eq 'y';
 535     die unless $cookh eq $parmh;
 536     $r->{AssocSecret} = $cooks;
 537     $r->{UserOK} = $cooku;
 538     print STDERR "C-D-C OK\n";
 539     return undef;
 540 }
 541
 542 sub _chain_params ($) {
 543     my ($r) = @_;
 544     my %p = %{ $r->_ch('get_params') };
 545     foreach my $pncn (keys %{ $r->{S} }) {
 546         my $names;
 547         if ($pncn =~ m/_param_name$/) {
 548             my $name = $r->{S}{$pncn};
 549             die "$pncn ?" if ref $name;
 550             $names = [ $name ];
 551         } elsif ($pncn =~ m/_param_names$/) {
 552             $names = $r->{S}{$pncn};
 553         } else {
 554             next;
 555         }
 556         foreach my $name (@$names) {
 557             delete $p{$name};
 558         }
 559     }
 560     return \%p;
 561 }
 562
 563 sub _db_lookup ($$) {
 564     my ($r,$h) = @_;
 565     # returns ($t,$username)
 566     # where $t is one of "t" "y" "n", or "" (for -)
 567
 568     my $dbh = $r->{Dbh};
 569
 570     my $row = $dbh->selectrow_arrayref("SELECT username, last".
 571                               " FROM $r->{S}{assocdb_table}".
 572                               " WHERE assochash = ?", {}, $h);
 573     return ('') unless defined $row;
 574
 575     my ($nusername, $nlast) = @$row;
 576
 577     my $timeout = $r->{S}{login_timeout};
 578     return ('n') unless !defined $timeout || time <= $nlast + $timeout;
 579
 580     return ('t') unless defined $nusername;
 581
 582     # hooray
 583     return ('y', $nusername);
 584 }
 585
 586 sub _db_revoke ($$) {
 587     # revokes $h if it's valid; no-op if it's not
 588     my ($r,$h) = @_;
 589
 590     my $dbh = $r->{Dbh};
 591
 592     $dbh->do("DELETE FROM $r->{S}{assocdb_table}".
 593              " WHERE assochash = ?", {}, $h);
 594 }
 595
 596 sub _db_record_login_ok ($$$) {
 597     my ($r,$h,$user) = @_;
 598     $r->_db_revoke($h);
 599     my $dbh = $r->{Dbh};
 600     $dbh->do("INSERT INTO $r->{S}{assocdb_table}".
 601              " (associd, username, last) VALUES (?,?,?)", {},
 602              $h, $user, time);
 603 }
 604
 605 sub check_divert ($) {
 606     my ($r) = @_;
 607     if (exists $r->{Divert}) {
 608         return $r->{Divert};
 609     }
 610     my $dbh = $r->{Dbh};
 611     $r->{Divert} = $r->_db_transaction(sub { $r->_check_divert_core(); });
 612     $dbh->commit();
 613     print STDERR Dumper($r->{Divert});
 614     return $r->{Divert};
 615 }
 616
 617 sub get_divert ($) {
 618     my ($r) = @_;
 619     die "unchecked" unless exists $r->{Divert};
 620     return $r->{Divert};
 621 }
 622
 623 sub get_username ($) {
 624     my ($r) = @_;
 625     my $divert = $r->get_divert();
 626     return undef if $divert;
 627     return $r->{UserOK};
 628 }
 629
 630 sub url_with_query_params ($$) {
 631     my ($r, $params) = @_;
 632     my $uri = URI->new($r->_ch('get_url'));
 633     $uri->query_form(flatten_params($params));
 634     return $uri->as_string();
 635 }
 636
 637 sub _cgi_header_args ($$@) {
 638     my ($r, $cookie, @ha) = @_;
 639     unshift @ha, qw(-type text/html);
 640     push @ha, (-cookie => $cookie) if defined $cookie;
 641     print STDERR "_cgi_header_args ",join('|',@ha),".\n";
 642     return @ha;
 643 }
 644
 645 sub check_ok ($) {
 646     my ($r) = @_;
 647
 648     my ($divert) = $r->check_divert();
 649     return 1 if !$divert;
 650
 651     my $handled = $r->_ch('handle_divert',$divert);
 652     return 0 if $handled;
 653
 654     my $kind = $divert->{Kind};
 655     my $cookiesecret = $divert->{CookieSecret};
 656     my $params = $divert->{Params};
 657     my $cookie = $r->construct_cookie($cookiesecret);
 658
 659     if ($kind =~ m/^REDIRECT-/) {
 660         # for redirects, we honour stored NextParams and SetCookie,
 661         # as we would for non-divert
 662         if ($kind eq 'REDIRECT-LOGGEDOUT') {
 663             $params->{$r->{S}{loggedout_param_names}[0]} = 1;
 664         } elsif ($kind eq 'REDIRECT-LOGOUT') {
 665             $params->{$r->{S}{logout_param_names}[0]} = 1;
 666         } elsif ($kind eq 'REDIRECT-LOGGEDIN') {
 667         } else {
 668             die;
 669         }
 670         my $new_url = $r->url_with_query_params($params);
 671         $r->_ch('do_redirect',$new_url, $cookie);
 672         return 0;
 673     }
 674
 675     my ($title, @body);
 676     if ($kind =~ m/^LOGIN-/) {
 677         $title = $r->_gt('Login');
 678         push @body, $r->_gt($divert->{Message});
 679         push @body, $r->_ch('gen_login_form', $params);
 680     } elsif ($kind =~ m/^SMALLPAGE-/) {
 681         $title = $r->_gt('Not logged in');
 682         push @body, $r->_gt($divert->{Message});
 683         push @body, $r->_ch('gen_login_link');
 684     } else {
 685         die $kind;
 686     }
 687
 688     $r->_print($r->{Cgi}->header($r->_cgi_header_args($cookie)),
 689                $r->_ch('gen_start_html',$title),
 690                (join "\n", @body),
 691                $r->_ch('gen_end_html'));
 692     return 0;
 693 }
 694
 695 sub _random ($$) {
 696     my ($r, $bytes) = @_;
 697     my $v = $r->{V};
 698     my $rsf = $v->{RandomHandle};
 699     my $rsp = $r->{S}{random_source};
 700     if (!$rsf) {
 701         $v->{RandomHandle} = $rsf = new IO::File $rsp, '<' or die "$rsp $!";
 702     }
 703     my $bin;
 704     $!=0;
 705     read($rsf,$bin,$bytes) == $bytes or die "$rsp $!";
 706     close $rsf;
 707     my $out = unpack "H*", $bin;
 708     print STDERR "_random out $out\n";
 709     return $out;
 710 }
 711
 712 sub _fresh_secret ($) {
 713     my ($r) = @_;
 714     print STDERR "_fresh_secret\n";
 715     my $bytes = ($r->{S}{associdlen} + 7) >> 3;
 716     return $r->_random($bytes);
 717 }
 718
 719 sub _assert_checked ($) {
 720     my ($r) = @_;
 721     die "unchecked" unless exists $r->{Divert};
 722 }
 723
 724 sub check_mutate ($) {
 725     my ($r) = @_;
 726     $r->_assert_checked();
 727     die if $r->{Divert};
 728     my $meth = $r->_ch('get_method');
 729     die "mutating non-POST" if $meth ne 'POST';
 730 }
 731
 732 #---------- output ----------
 733
 734 sub secret_cookie_val ($) {
 735     my ($r) = @_;
 736     $r->_assert_checked();
 737     return defined $r->{AssocSecret} ? $r->{AssocSecret} : '';
 738 }
 739
 740 sub secret_hidden_val ($) {
 741     my ($r) = @_;
 742     $r->_assert_checked();
 743     return defined $r->{AssocSecret} ? $r->hash($r->{AssocSecret}) : '';
 744 }
 745
 746 sub secret_hidden_html ($) {
 747     my ($r) = @_;
 748     return $r->{Cgi}->hidden(-name => $r->{S}{assoc_param_name},
 749                              -default => $r->secret_hidden_val());
 750 }
 751
 752 sub secret_cookie ($) {
 753     my ($r) = @_;
 754     my $secret = $r->secret_cookie_val();
 755     return undef if !defined $secret;
 756 #print STDERR "SC\n";
 757     my $cookv = $r->construct_cookie($secret);
 758 #print STDERR "SC=$cookv\n";
 759     return $cookv;
 760 }
 761
 762 __END__
 763
 764 =head1 NAME
 765
 766 CGI::Auth::Hybrid - web authentication optionally using cookies
 767
 768 =head1 SYNOPSYS
 769
 770  my $verifier = CGI::Auth::Hybrid->new_verifier(setting => value,...);
 771  my $authreq = $verifier->new_request($cgi_request_object);
 772
 773  my $authreq = CGI::Auth::Hybrid->new_request($cgi_request_object,
 774                                               setting => value,...);
 775
 776 =head1 USAGE PATTERN FOR SIMPLE APPLICATIONS
 777
 778  $authreq->check_ok() or return;
 779
 780  blah blah blah
 781  $authreq->check_mutate();
 782  blah blah blah
 783
 784 =head1 USAGE PATTERN FOR FANCY APPLICATIONS
 785
 786  my $divert_kind = $authreq->check_divert();
 787  if ($divert_kind) {
 788      if ($divert_kind eq 'LOGGEDOUT') {
 789          print "goodbye you are now logged out" and quit
 790      } elsif ($divert_kind eq 'NOCOOKIES') {
 791          print "you need cookies" and quit
 792      ... etc.
 793      }
 794  }
 795
 796  blah blah blah
 797  $authreq->check_mutate();
 798  blah blah blah