cgi-auth-flexible.pm

   1 # -*- perl -*-
   2
   3 # This is part of CGI::Auth::Flexible, a perl CGI authentication module.
   4 # Copyright (C) 2012 Ian Jackson.
   5 # Copyright (C) 2012 Citrix.
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU Affero General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU Affero General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU Affero General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21 use warnings FATAL => 'all';
  22
  23 package CGI::Auth::Flexible;
  24 require Exporter;
  25
  26 BEGIN {
  27     use Exporter   ();
  28     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  29
  30     $VERSION     = 1.00;
  31     @ISA         = qw(Exporter);
  32     @EXPORT      = qw();
  33     %EXPORT_TAGS = ( );     # eg: TAG => [ qw!name1 name2! ],
  34 }
  35 our @EXPORT_OK;
  36
  37 use DBI;
  38 use CGI qw/escapeHTML/;
  39 use Locale::gettext;
  40 use URI;
  41 use IO::File;
  42 use Fcntl qw(:flock);
  43 use POSIX;
  44 use Digest;
  45 use Digest::HMAC;
  46 use Digest::SHA;
  47 use Data::Dumper;
  48 use File::Copy;
  49 use Cwd qw/realpath/;
  50
  51
  52 #---------- public utilities ----------
  53
  54 sub flatten_params ($) {
  55     my ($p) = @_;
  56     my @p;
  57     foreach my $k (keys %$p) {
  58         next if $k eq '';
  59         foreach my $v (@{ $p->{$k} }) {
  60             push @p, $k, $v;
  61         }
  62     }
  63     return @p;
  64 }
  65
  66 #---------- default callbacks ----------
  67
  68 sub has_a_param ($$) {
  69     my ($r,$cn) = @_;
  70     foreach my $pn (@{ $r->{S}{$cn} }) {
  71         return 1 if $r->_ch('get_param',$pn);
  72     }
  73     return 0;
  74 }
  75
  76 sub get_params ($) {
  77     my ($r) = @_;
  78     my $c = $r->{Cgi};
  79     my $vars = $c->Vars();
  80     my %p;
  81     foreach my $name (keys %$vars) {
  82         $p{$name} = [ split "\0", $vars->{$name} ];
  83     }
  84     return \%p;
  85 }
  86
  87 sub get_cookie_domain ($$$) {
  88     my ($c,$r) = @_;
  89     my $uri = new URI $r->_ch('get_url');
  90     return $uri->host();
  91 }
  92
  93 sub login_ok_password ($$) {
  94     my ($c, $r) = @_;
  95     my $username_params = $r->{S}{username_param_names};
  96     my $username = $r->_ch('get_param',$username_params->[0]);
  97     my $password = $r->_rp('password_param_name');
  98     my $error = $r->_ch('username_password_error', $username, $password);
  99     return defined($error) ? (undef,$error) : ($username,undef);
 100 }
 101
 102 sub do_redirect_cgi ($$$$) {
 103     my ($c, $r, $new_url, $cookie) = @_;
 104     $r->_print($c->header($r->_cgi_header_args($cookie,
 105                                                -status => '303 See other',
 106                                                -location => $new_url)),
 107                $r->_ch('gen_start_html',$r->_gt('Redirection')),
 108                '<a href="'.escapeHTML($new_url).'">',
 109                $r->_gt("If you aren't redirected, click to continue."),
 110                "</a>",
 111                $r->_ch('gen_end_html'));
 112 }
 113
 114 sub gen_some_form ($$) {
 115     my ($r, $params, $bodyfn) = @_;
 116     # Calls $bodyfn->($c,$r) which returns @formbits
 117     my $c = $r->{Cgi};
 118     my @form;
 119     my $pathinfo = '';
 120     $pathinfo .= $params->{''}[0] if $params->{''};
 121     push @form, ('<form method="POST" action="'.
 122                  escapeHTML($r->_ch('get_url').$pathinfo).'">');
 123     push @form, $bodyfn->($c,$r);
 124     foreach my $n (keys %$params) {
 125         next if $n eq '';
 126         foreach my $val (@{ $params->{$n} }) {
 127             push @form, ('<input type="hidden"'.
 128                          ' name="'.escapeHTML($n).'"'.
 129                          ' value="'.escapeHTML($val).'">');
 130         }
 131     }
 132     push @form, ('</form>');
 133     return join "\n", @form;
 134 }
 135
 136 sub gen_plain_login_form ($$) {
 137     my ($c,$r, $params) = @_;
 138     return $r->gen_some_form($params, sub {
 139         my @form;
 140         push @form, ('<table>');
 141         my $sz = 'size="'.$r->{S}{form_entry_size}.'"';
 142         foreach my $up (@{ $r->{S}{username_param_names}}) {
 143             push @form, ('<tr><td>',$r->_gt(ucfirst $up),'</td>',
 144                          '<td><input type="text" '.$sz.
 145                          ' name='.$up.'></td></tr>');
 146         }
 147         push @form, ('<tr><td>'.$r->_gt('Password').'</td>',
 148                      '<td><input type="password" '.$sz.
 149                      ' name="'.$r->{S}{password_param_name}.'"></td></tr>');
 150         push @form, ('<tr><td colspan="2">',
 151                      '<input type="submit"'.
 152                      ' name="'.$r->{S}{dummy_param_name_prefix}.'login"'.
 153                      ' value="'.$r->_gt('Login').'"></td></tr>',
 154                      '</table>');
 155         return @form;
 156     });
 157 }
 158
 159 sub gen_postmainpage_form ($$$) {
 160     my ($c,$r, $params) = @_;
 161     return $r->gen_some_form($params, sub {
 162         my @form;
 163         push @form, ('<input type="submit"',
 164                      ' name="'.$r->{S}{dummy_param_name_prefix}.'submit"'.
 165                      ' value="'.$r->_gt('Continue').'">');
 166         return @form;
 167     });
 168 }
 169
 170 sub gen_plain_login_link ($$) {
 171     my ($c,$r, $params) = @_;
 172     my $url = $r->url_with_query_params($params);
 173     return ('<a href="'.escapeHTML($url).'">'.
 174             $r->_gt('Log in again to continue.').
 175             '</a>');
 176 }
 177
 178 sub gen_srcdump_link_html ($$$$) {
 179     my ($c,$r,$anchor,$specval) = @_;
 180     my %params = ($r->{S}{srcdump_param_name} => [ $specval ]);
 181     return '<a href="'.
 182         escapeHTML($r->url_with_query_params(\%params,'SRCDUMP')).
 183         '">'.$anchor."</a>";
 184 }
 185 sub gen_plain_licence_link_html ($$) {
 186     my ($c,$r) = @_;
 187     gen_srcdump_link_html($c,$r, 'GNU Affero GPL', 'licence');
 188 }
 189 sub gen_plain_source_link_html ($$) {
 190     my ($c,$r) = @_;
 191     gen_srcdump_link_html($c,$r, 'Source available', 'source');
 192 }
 193
 194 sub gen_plain_footer_html ($$) {
 195     my ($c,$r) = @_;
 196     return ('<hr><address>',
 197             ("Powered by Free / Libre / Open Source Software".
 198              " according to the ".$r->_ch('gen_licence_link_html')."."),
 199             $r->_ch('gen_source_link_html').".",
 200             '</address>');
 201 }
 202
 203 #---------- licence and source code ----------
 204
 205 sub srcdump_dump ($$$) {
 206     my ($c,$r, $thing) = @_;
 207     die if $thing =~ m/\W/ || $thing !~ m/\w/;
 208     my $path = $r->_get_path('srcdump');
 209     my $ctf = new IO::File "$path/$thing.ctype", 'r'
 210         or die "$path/$thing.ctype $!";
 211     my $ct = <$ctf>;
 212     chomp $ct or die "$path/$thing ?";
 213     $ctf->close or die "$path/$thing $!";
 214     my $df = new IO::File "$path/$thing.data", 'r'
 215         or die "$path/$thing.data $!";
 216     $r->_ch('dump', $ct, $df);
 217 }
 218
 219 sub dump_plain ($$$$) {
 220     my ($c, $r, $ct, $df) = @_;
 221     $r->_print($c->header('-type' => $ct));
 222     my $buffer;
 223     for (;;) {
 224         my $got = read $df, $buffer, 65536;
 225         die $! unless defined $got;
 226         return if !$got;
 227         $r->_print($buffer);
 228     }
 229 }
 230
 231 sub srcdump_process_item ($$$$$$) {
 232     my ($c, $v, $dumpdir, $item, $outfn, $needlicence, $dirsdone) = @_;
 233     if ($v->_ch('srcdump_system_dir', $item)) {
 234         $outfn->("srcdump_process_item: srcdump_system_dir, skipping $item");
 235         return;
 236     }
 237     my $upwards = $item;
 238     for (;;) {
 239         $upwards =~ s#/+$##;
 240         $upwards =~ s#/+\.$##;
 241         last unless $upwards =~ m#[^/]#;
 242         foreach my $try (@{ $v->{S}{srcdump_vcs_dirs} }) {
 243 #print STDERR "TRY $item $upwards $try\n";
 244             if (!stat "$upwards/$try") {
 245                 $!==&ENOENT or $!==&ENOTDIR or die "check $upwards/$try $!";
 246                 next;
 247             }
 248 #print STDERR "VCS $item $upwards $try\n";
 249             if ($dirsdone->{$upwards}++) {
 250                 $outfn->("srcdump_process_item: did $upwards,".
 251                          " skipping $item");
 252                 return;
 253             }
 254 #print STDERR "VCS $item $upwards $try GO\n";
 255             $try =~ m/\w+/ or die;
 256             return $v->_ch('srcdump_byvcs', $dumpdir, $upwards, $outfn, lc $&);
 257         }
 258         $upwards =~ s#/*[^/]+$##;
 259     }
 260     return $v->_ch('srcdump_novcs', $dumpdir, $item, $outfn);
 261 }
 262
 263 sub srcdump_novcs ($$$$$) {
 264     my ($c, $v, $dumpdir, $item, $outfn) = @_;
 265     stat $item or die "$item $!";
 266     if (-d _) {
 267         my $script = 'find -type f -perm +004';
 268         foreach my $excl (@{ $v->{S}{srcdump_excludes} }) {
 269             $script .= " \\! -name '$excl'";
 270         }
 271         $script .= " -print0";
 272         return srcdump_dir_cpio($c,$v,$dumpdir,$item,$outfn,'novcs',$script);
 273     } elsif (-f _) {
 274         return srcdump_file($c,$v,$dumpdir,$item,$outfn);
 275     } else {
 276         die "$item not file or directory";
 277     }
 278 }
 279
 280 sub srcdump_byvcs ($$$$$$) {
 281     my ($c, $v, $dumpdir, $dir, $outfn, $vcs) = @_;
 282 #print STDERR "BYVCS GIT $dir\n";
 283     my $script = $v->{S}{"srcdump_vcsscript"}{$vcs};
 284     die "no script for vcs $vcs" unless defined $script;
 285     return srcdump_dir_cpio($c,$v,$dumpdir,$dir,$outfn,$vcs,$script);
 286 }
 287
 288 sub srcdump_file ($$$$) {
 289     my ($c,$v,$dumpdir,$file,$outfn) = @_;
 290     my $outfile = $outfn->("srcdump_file saved $file", "src");
 291     copy($file,$outfile) or die "$file $outfile $!";
 292 }
 293
 294 sub srcdump_dir_cpio ($$$$$$$) {
 295     my ($c,$v,$dumpdir,$dir,$outfn,$how,$script) = @_;
 296     my $outfile = $outfn->("srcdump_dir_cpio $how saved $dir", "tar");
 297 #print STDERR "CPIO $dir >$script<\n";
 298     my $pid = fork();
 299     defined $pid or die $!;
 300     if (!$pid) {
 301         $SIG{__DIE__} = sub {
 302             print STDERR "CGI::Auth::Flexible srcdump error: $@\n";
 303             exit 127;
 304         };
 305         open STDOUT, ">", $outfile or die "$outfile $!";
 306         chdir $dir or die "chdir $dir: $!";
 307         exec '/bin/bash','-ec',"
 308             set -o pipefail
 309             (
 310              $script
 311             ) | (
 312              cpio -Hustar -o --quiet -0 -R 1000:1000 || \
 313              cpio -Hustar -o --quiet -0
 314             )
 315             ";
 316         die $!;
 317     }
 318     $!=0; (waitpid $pid, 0) == $pid or die "$!";
 319     die "$dir ($how $script) $outfile $?" if $?;
 320 }
 321
 322 sub srcdump_dirscan_prepare ($$) {
 323     my ($c, $v) = @_;
 324     my $dumpdir = $v->_get_path('srcdump');
 325     mkdir $dumpdir or $!==&EEXIST or die "mkdir $dumpdir $!";
 326     my $lockf = new IO::File "$dumpdir/generate.lock", 'w+'
 327         or die "$dumpdir/generate.lock $!";
 328     flock $lockf, LOCK_EX or die "$dumpdir/generate.lock $!";
 329     my $needlicence = "$dumpdir/licence.tmp";
 330     unlink $needlicence or $!==&ENOENT or die "rm $needlicence $!";
 331     if (defined $v->{S}{srcdump_licence_path}) {
 332         copy($v->{S}{srcdump_licence_path}, $needlicence)
 333             or die "$v->{S}{srcdump_licence_path} $!";
 334         $needlicence = undef;
 335     }
 336     unlink <"$dumpdir/s.[a-z][a-z][a-z].*">;
 337     my @srcfiles = qw(licence.data manifest.txt);
 338     my $srcoutcounter = 'aaa';
 339
 340     my $reportfh = new IO::File "$dumpdir/manifest.txt", 'w' or die $!;
 341     my $outfn = sub {
 342         my ($message, $extension) = @_;
 343         if (defined $extension) {
 344             my $leaf = "s.$srcoutcounter.$extension";
 345             $srcoutcounter++;
 346             push @srcfiles, $leaf;
 347             print $reportfh "$leaf: $message\n" or die $!;
 348             return "$dumpdir/$leaf";
 349         } else {
 350             print $reportfh "none: $message\n" or die $!;
 351             return undef;
 352         }
 353     };
 354     my %dirsdone;
 355     foreach my $item ($v->_ch('srcdump_listitems')) {
 356         next unless defined $item;
 357         if ($item eq '.' && $v->{S}{srcdump_filter_cwd}) {
 358             my @bad = grep { !m#^/# } values %INC;
 359             die "filtering . from srcdump items and \@INC but already".
 360                 " included @bad " if @bad;
 361             @INC = grep { $_ ne '.' } @INC;
 362             next;
 363         }
 364         if (!lstat "$item") {
 365             die "stat $item $!" unless $!==&ENOENT;
 366             $outfn->("srcdump_dirscan_prepare stat ENOENT, skipping $item");
 367             next;
 368         };
 369         if (-l _) {
 370             $item = realpath($item);
 371             if (!defined $item) {
 372                 die "realpath $item $!" unless $!==&ENOENT;
 373                 $outfn->("srcdump_dirscan_prepare realpath ENOENT,".
 374                          " skipping $item");
 375             }
 376         }
 377         if (defined $needlicence) {
 378             foreach my $try (@{ $v->{S}{srcdump_licence_files} }) {
 379                 last if copy("$item/$try", $needlicence);
 380                 $!==&ENOENT or $!==&ENOTDIR or die "copy $item/$try $!";
 381             }
 382         }
 383         $v->_ch('srcdump_process_item', $dumpdir, $item,
 384                 $outfn, \$needlicence, \%dirsdone);
 385         $dirsdone{$item}++;
 386     }
 387     close $reportfh or die $!;
 388     srcdump_install($c,$v, $dumpdir, 'licence', 'text/plain');
 389     $!=0;
 390     my @cmd = (qw(sh -ec), 'exec >&2 "$@"', qw(x),
 391                qw(tar -zvvcf), "$dumpdir/source.tmp",
 392                "-C", $dumpdir, qw(  --), @srcfiles);
 393     my $r = system(@cmd);
 394     if ($r) {
 395         print STDERR "CGI::Auth::Flexible tar failed ($r $!) @cmd\n";
 396         die "tar failed";
 397     }
 398     die "licence file not found" unless defined $needlicence;
 399     srcdump_install($c,$v, $dumpdir, 'source', 'application/octet-stream');
 400     close $lockf or die $!;
 401 }
 402
 403 sub srcdump_install ($$$$$) {
 404     my ($c,$v, $dumpdir, $which, $ctype) = @_;
 405     rename "$dumpdir/$which.tmp", "$dumpdir/$which.data"
 406         or die "$dumpdir/$which.data $!";
 407     my $ctf = new IO::File "$dumpdir/$which.tmp", 'w'
 408         or die "$dumpdir/$which.tmp $!";
 409     print $ctf $ctype, "\n" or die $!;
 410     close $ctf or die $!;
 411     rename "$dumpdir/$which.tmp", "$dumpdir/$which.ctype"
 412         or die "$dumpdir/$which.ctype $!";
 413 }
 414
 415 #---------- verifier object methods ----------
 416
 417 sub new_verifier {
 418     my $class = shift;
 419     my $verifier = {
 420         S => {
 421             dir => undef,
 422             db_dbh => undef, # must have AutoCommit=0, RaiseError=1
 423             db_path => 'caf.db',
 424             keys_path => 'caf-keys',
 425             srcdump_path => 'caf-srcdump',
 426             db_dsn => undef,
 427             db_user => '',
 428             db_password => '',
 429             db_prefix => 'caf',
 430             random_source => '/dev/urandom',
 431             secretbits => 128, # bits
 432             hash_algorithm => "SHA-256",
 433             login_timeout => 86400, # seconds
 434             login_form_timeout => 3600, # seconds
 435             key_rollover => 86400, # seconds
 436             assoc_param_name => 'caf_assochash',
 437             dummy_param_name_prefix => 'caf__',
 438             cookie_name => "caf_assocsecret",
 439             password_param_name => 'password',
 440             srcdump_param_name => 'caf_srcdump',
 441             username_param_names => [qw(username)],
 442             form_entry_size => 60,
 443             logout_param_names => [qw(caf_logout)],
 444             loggedout_param_names => [qw(caf_loggedout)],
 445             promise_check_mutate => 0,
 446             get_param => sub { $_[0]->param($_[2]) },
 447             get_params => sub { $_[1]->get_params() },
 448             get_path_info => sub { $_[0]->path_info() },
 449             get_cookie => sub { $_[0]->cookie($_[1]->{S}{cookie_name}) },
 450             get_method => sub { $_[0]->request_method() },
 451             is_https => sub { !!$_[0]->https() },
 452             get_url => sub { $_[0]->url(); },
 453             is_login => sub { defined $_[1]->_rp('password_param_name') },
 454             login_ok => \&login_ok_password,
 455             username_password_error => sub { die },
 456             is_logout => sub { $_[1]->has_a_param('logout_param_names') },
 457             is_loggedout => sub { $_[1]->has_a_param('loggedout_param_names') },
 458             handle_divert => sub { return 0 },
 459             do_redirect => \&do_redirect_cgi, # this hook is allowed to throw
 460             cookie_path => "/",
 461             get_cookie_domain => \&get_cookie_domain,
 462             encrypted_only => 1,
 463             gen_start_html => sub { $_[0]->start_html($_[2]); },
 464             gen_footer_html => \&gen_plain_footer_html,
 465             gen_licence_link_html => \&gen_plain_licence_link_html,
 466             gen_source_link_html => \&gen_plain_source_link_html,
 467             gen_end_html => sub { $_[0]->end_html(); },
 468             gen_login_form => \&gen_plain_login_form,
 469             gen_login_link => \&gen_plain_login_link,
 470             gen_postmainpage_form => \&gen_postmainpage_form,
 471             srcdump_dump => \&srcdump_dump,
 472             srcdump_prepare => \&srcdump_dirscan_prepare,
 473             srcdump_licence_path => undef,
 474             srcdump_licence_files => [qw(AGPLv3 CGI/Auth/Flexible/AGPLv3)],
 475             srcdump_listitems => sub { (@INC, $ENV{'SCRIPT_FILENAME'}, $0); },
 476             srcdump_filter_cwd => 1,
 477             srcdump_system_dir => sub {
 478                 $_[2] =~ m#^/etc/|^/usr/(?!local/)(?!lib/cgi)#;
 479             },
 480             srcdump_process_item => \&srcdump_process_item,
 481             srcdump_vcs_dirs => [qw(.git .hg .bzr .svn)],
 482             srcdump_vcsscript => {git => "
 483                  git ls-files -z
 484                  git ls-files -z --others --exclude-from=.gitignore
 485                  find .git -print0
 486                             "},
 487             srcdump_byvcs => \&srcdump_byvcs,
 488             srcdump_novcs => \&srcdump_novcs,
 489             srcdump_excludes => [qw(*~ *.bak *.tmp), '#*#'],
 490             dump => \&dump_plain,
 491             gettext => sub { gettext($_[2]); },
 492             print => sub { print $_[2] or die $!; },
 493             debug => sub { }, # like print; msgs contain trailing \n
 494         },
 495         Dbh => undef,
 496     };
 497     my ($k,$v);
 498     while (($k,$v,@_) = @_) {
 499         die "unknown setting $k" unless
 500             $k =~ m/^promise_/ or
 501             exists $verifier->{S}{$k};
 502         $verifier->{S}{$k} = $v;
 503     }
 504     $verifier->{S}{db_setup_stmts} //=
 505         ["CREATE TABLE $verifier->{S}{db_prefix}_assocs (".
 506          " assochash VARCHAR PRIMARY KEY,".
 507          " username VARCHAR NOT NULL,".
 508          " last INTEGER NOT NULL".
 509          ")"
 510          ,
 511          "CREATE INDEX $verifier->{S}{db_prefix}_assocs_timeout_index".
 512          " ON $verifier->{S}{db_prefix}_assocs".
 513          " (last)"
 514         ];
 515     bless $verifier, $class;
 516     $verifier->_dbopen();
 517     $verifier->_ch('srcdump_prepare');
 518     return $verifier;
 519 }
 520
 521 sub _db_setup_do ($$) {
 522     my ($v, $sql) = @_;
 523     my $dbh = $v->{Dbh};
 524     eval {
 525         $v->_db_transaction(sub {
 526             local ($dbh->{PrintError}) = 0;
 527             $dbh->do($sql);
 528         });
 529     };
 530 }
 531
 532 sub _dbopen ($) {
 533     my ($v) = @_;
 534     my $dbh = $v->{Dbh};
 535     return $dbh if $dbh;
 536
 537     $dbh = $v->{S}{db_dbh};
 538     if ($dbh) {
 539         die if $dbh->{AutoCommit};
 540         die unless $dbh->{RaiseError};
 541     } else {
 542         $v->{S}{db_dsn} ||= "dbi:SQLite:dbname=".$v->_get_path('db');
 543         my $dsn = $v->{S}{db_dsn};
 544
 545         my $u = umask 077;
 546         $dbh = DBI->connect($dsn, $v->{S}{db_user},
 547                             $v->{S}{db_password}, {
 548                                 AutoCommit => 0,
 549                                 RaiseError => 1,
 550                                 ShowErrorStatement => 1,
 551                             });
 552         umask $u;
 553         die "$dsn $! ?" unless $dbh;
 554     }
 555     $v->{Dbh} = $dbh;
 556
 557     foreach my $stmt (@{ $v->{S}{db_setup_stmts} }) {
 558         $v->_db_setup_do($stmt);
 559     }
 560     return $dbh;
 561 }
 562
 563 sub disconnect ($) {
 564     my ($v) = @_;
 565     my $dbh = $v->{Dbh};
 566     return unless $dbh;
 567     $dbh->disconnect();
 568 }
 569
 570 sub _db_transaction ($$) {
 571     my ($v, $fn) = @_;
 572     my $retries = 10;
 573     my $rv;
 574     my $dbh = $v->{Dbh};
 575 #print STDERR "DT entry\n";
 576     for (;;) {
 577 #print STDERR "DT loop\n";
 578         if (!eval {
 579             $rv = $fn->();
 580 #print STDERR "DT fn ok\n";
 581             1;
 582         }) {
 583 #print STDERR "DT fn error\n";
 584             { local ($@); $dbh->rollback(); }
 585 #print STDERR "DT fn throwing\n";
 586             die $@;
 587         }
 588 #print STDERR "DT fn eval ok\n";
 589         if (eval {
 590             $dbh->commit();
 591 #print STDERR "DT commit ok\n";
 592             1;
 593         }) {
 594 #print STDERR "DT commit eval ok ",Dumper($rv);
 595             return $rv;
 596         }
 597 #print STDERR "DT commit throw?\n";
 598         die $@ if !--$retries;
 599 #print STDERR "DT loop again\n";
 600     }
 601 }
 602
 603 #---------- request object methods ----------
 604
 605 sub new_request {
 606     my ($classbase, $cgi, @extra) = @_;
 607     if (!ref $classbase) {
 608         $classbase = $classbase->new_verifier(@extra);
 609     } else {
 610         die if @extra;
 611     }
 612     my $r = {
 613         V => $classbase,
 614         S => $classbase->{S},
 615         Dbh => $classbase->{Dbh},
 616         Cgi => $cgi,
 617     };
 618     bless $r, ref $classbase;
 619 }
 620
 621 sub _ch ($$@) { # calls an application hook
 622     my ($r,$methname, @args) = @_;
 623     my $methfunc = $r->{S}{$methname};
 624     die "$methname ?" unless $methfunc;
 625     return $methfunc->($r->{Cgi}, $r, @args);
 626 }
 627
 628 sub _rp ($$@) {
 629     my ($r,$pnvb) = @_;
 630     my $pn = $r->{S}{$pnvb};
 631     my $p = scalar $r->_ch('get_param',$pn)
 632 }
 633
 634 sub _debug ($@) {
 635     my ($r,@args) = @_;
 636     $r->_ch('debug',@args);
 637 }
 638
 639 sub _get_path ($$) {
 640     my ($r,$keybase) = @_;
 641     my $leaf = $r->{S}{"${keybase}_path"};
 642     return $r->_absify_path($leaf);
 643 }
 644
 645 sub _absify_path ($$) {
 646     my ($v,$leaf) = @_;
 647     return $leaf if $leaf =~ m,^/,;
 648     my $dir = $v->{S}{dir};
 649     die "relying on cwd by default ?!  set dir" unless defined $dir;
 650     return "$dir/$leaf";
 651 }
 652
 653 sub _gt ($$) { my ($r, $t) = @_; return $r->_ch('gettext',$t); }
 654 sub _print ($$) { my ($r, @t) = @_; return $r->_ch('print', join '', @t); }
 655
 656 sub construct_cookie ($$$) {
 657     my ($r, $cooks) = @_;
 658     return undef unless $cooks;
 659     my $c = $r->{Cgi};
 660     my @ca = (
 661         -name => $r->{S}{cookie_name},
 662         -value => $cooks,
 663         -path => $r->{S}{cookie_path},
 664         -domain => $r->_ch('get_cookie_domain'),
 665         -expires => '+'.$r->{S}{login_timeout}.'s',
 666         -secure => $r->{S}{encrypted_only}
 667         );
 668     my $cookie = $c->cookie(@ca);
 669 #print STDERR "CC $r $c $cooks $cookie (@ca).\n";
 670     return $cookie;
 671 }
 672
 673 # pages/param-sets are
 674 #   n normal non-mutating page
 675 #   r retrieval of information for JS etc., non-mutating
 676 #   m mutating page
 677 #   u update of information by JS etc., mutating
 678 #   i login
 679 #   o logout
 680 #   O "you have just logged out" page load
 681
 682 # in cook and par,
 683 #    -         no value supplied (represented in code as $cookt='')
 684 #    n, nN     value not in our db
 685 #    t, tN     temporary value (in our db, no logged in user yet)
 686 #    y, yN     value corresponds to logged-in user
 687 # and, aggregated conditions:
 688 #    a, aN     anything including -
 689 #    x, xN     t or y
 690 # if N differs the case applies only when the two values differ
 691 # (eg,   a1 y2   does not apply when the logged-in value is supplied twice)
 692
 693 # "stale session" means request originates from a page from a login
 694 # session which has been revoked (eg by logout); "cleared session"
 695 # means request originates from a browser which has a different (or
 696 # no) cookie.
 697
 698     # Case analysis, cookie mode, app promises re mutate:
 699     # cook parm meth form
 700     #
 701     #  any -   POST  nrmuoi   bug or attack, fail
 702     #  any -   GET    rmuoi   bug or attack, fail
 703     #  any any GET     muoi   bug or attack, fail
 704     #  any t   any   nrmu     bug or attack, fail
 705     #
 706     #  -   -   GET         O  "just logged out" page
 707     #  (any other)         O  bug or attack, fail
 708     #
 709     #  a1  a2  POST      o    logout
 710     #                           if a1 is valid, revoke it
 711     #                           if a2 is valid, revoke it
 712     #                           delete cookie
 713     #                           redirect to "just logged out" page
 714     #                             (which contains link to login form)
 715     #
 716     #  -   t   POST       i   complain about cookies being disabled
 717     #                           (with link to login form)
 718     #
 719     #  t1  t1  POST       i   login (or switch user)
 720     #                           if bad
 721     #                             show new login form
 722     #                           if good
 723     #                             upgrade t1 to y1 in our db (setting username)
 724     #                             redirect to GET of remaining params
 725     #
 726     #  y1  a2  POST       i   complain about stale login form
 727     #                           revoke y1
 728     #                           show new login form
 729     #
 730     #  (other) POST       i   complain about stale login form
 731     #                           show new login form
 732     #
 733     #  t1  a2  ANY   nrmu     treat as  - a2 ANY
 734     #
 735     #  y   -   GET   n        cross-site link
 736     #                           show data
 737     #
 738     #  y   y   GET   nr       fine, show page or send data
 739     #  y   y   POST  nrmu     mutation is OK, do operation
 740     #
 741     #  y1  y2  GET   nr       request from stale page
 742     #                           do not revoke y2 as not RESTful
 743     #                           treat as   y1 n GET
 744     #
 745     #  y1  y2  POST  nrmu     request from stale page
 746     #                           revoke y2
 747     #                           treat as   y1 n POST
 748     #
 749     #  y   n   GET   n        intra-site link from stale page,
 750     #                           treat as cross-site link, show data
 751     #
 752     #  y   n   POST  n m      intra-site form submission from stale page
 753     #                           show "session interrupted"
 754     #                           with link to main data page
 755     #
 756     #  y   n   GET    r       intra-site request from stale page
 757     #                           fail
 758     #
 759     #  y   n   POST   r u     intra-site request from stale page
 760     #                           fail
 761     #
 762     #  -/n y2  GET   nr       intra-site link from cleared session
 763     #                           do not revoke y2 as not RESTful
 764     #                           treat as   -/n n GET
 765     #
 766     #  -/n y2  POST  nrmu     request from cleared session
 767     #                           revoke y2
 768     #                           treat as   -/n n POST
 769     #
 770     #  -/n -/n GET   n        cross-site link but user not logged in
 771     #                           show login form with redirect to orig params
 772     #                           generate fresh cookie
 773     #
 774     #  -/n n   GET    rmu     user not logged in
 775     #                           fail
 776     #
 777     #  -/n n   POST  n m      user not logged in
 778     #                           show login form
 779     #
 780     #  -/n n   POST   r u     user not logged in
 781     #                           fail
 782
 783 sub _check_divert_core ($) {
 784     my ($r) = @_;
 785
 786     my $srcdump = $r->_rp('srcdump_param_name');
 787     if ($srcdump) {
 788         die if $srcdump =~ m/\W/;
 789         return ({ Kind => 'SRCDUMP-'.uc $srcdump,
 790                   Message => undef,
 791                   _CookieRaw => undef,
 792                   Params => { } });
 793     }
 794
 795     my $cooksraw = $r->_ch('get_cookie');
 796     my $cooks = $r->_unblind($cooksraw);
 797
 798     if ($r->{S}{encrypted_only} && !$r->_ch('is_https')) {
 799         return ({ Kind => 'REDIRECT-HTTPS',
 800                   Message => $r->_gt("Redirecting to secure server..."),
 801                   _CookieRaw => undef,
 802                   Params => { } });
 803     }
 804
 805     my $meth = $r->_ch('get_method');
 806     my $parmhraw = $r->_rp('assoc_param_name');
 807     my $parmh = $r->_unblind($parmhraw);
 808     my $cookh = defined $cooks ? $r->hash($cooks) : undef;
 809
 810     my ($cookt,$cooku) = $r->_identify($cookh, $cooks);
 811     my $parms = (defined $cooks && defined $parmh && $parmh eq $cookh)
 812         ? $cooks : undef;
 813     my ($parmt) = $r->_identify($parmh, $parms);
 814
 815     $r->_debug("_c_d_c cookt=$cookt parmt=$parmt\n");
 816
 817     if ($r->_ch('is_logout')) {
 818         $r->_must_be_post();
 819         die unless $parmt;
 820         $r->_db_revoke($cookh);
 821         $r->_db_revoke($parmh);
 822         return ({ Kind => 'REDIRECT-LOGGEDOUT',
 823                   Message => $r->_gt("Logging out..."),
 824                   _CookieRaw => '',
 825                   Params => {
 826                       $r->{S}{loggedout_param_names}[0] => [ 1 ],
 827                   } });
 828     }
 829     if ($r->_ch('is_loggedout')) {
 830         die unless $meth eq 'GET';
 831         die if $cookt eq 'y';
 832         die if $parmt;
 833         return ({ Kind => 'SMALLPAGE-LOGGEDOUT',
 834                   Message => $r->_gt("You have been logged out."),
 835                   _CookieRaw => '',
 836                   Params => { } });
 837     }
 838     if ($r->_ch('is_login')) {
 839         $r->_must_be_post();
 840         die unless $parmt;
 841         if (!$cookt && $parmt eq 'n') {
 842             return ({ Kind => 'SMALLPAGE-NOCOOKIE',
 843                       Message => $r->_gt("You do not seem to have cookies".
 844                                          " enabled.  You must enable cookies".
 845                                          " as we use them for login."),
 846                       _CookieRaw => $r->_fresh_secret(),
 847                       Params => $r->chain_params() })
 848         }
 849         if (!$cookt || $cookt eq 'n' || $cookh ne $parmh) {
 850             $r->_db_revoke($cookh);
 851             return ({ Kind => 'LOGIN-STALE',
 852                       Message => $r->_gt("Stale session;".
 853                                          " you need to log in again."),
 854                       _CookieRaw => $r->_fresh_secret(),
 855                       Params => { } })
 856         }
 857         die unless $parmt eq 't' || $parmt eq 'y';
 858         my ($username, $login_errormessage) = $r->_ch('login_ok');
 859         unless (defined $username && length $username) {
 860             $login_errormessage = $r->_gt("Incorrect username/password.")
 861                 if !$login_errormessage;
 862             return ({ Kind => 'LOGIN-BAD',
 863                       Message => $login_errormessage,
 864                       _CookieRaw => $cooks,
 865                       Params => $r->chain_params() })
 866         }
 867         $r->_db_record_login_ok($parmh,$username);
 868         return ({ Kind => 'REDIRECT-LOGGEDIN',
 869                   Message => $r->_gt("Logging in..."),
 870                   _CookieRaw => $cooks,
 871                   Params => $r->chain_params() });
 872     }
 873     if ($cookt eq 't') {
 874         $cookt = '';
 875     }
 876     die if $parmt eq 't';
 877
 878     if ($cookt eq 'y' && $parmt eq 'y' && $cookh ne $parmh) {
 879         $r->_db_revoke($parmh) if $meth eq 'POST';
 880         $parmt = 'n';
 881     }
 882
 883     if ($cookt ne 'y') {
 884         die unless !$cookt || $cookt eq 'n';
 885         die unless !$parmt || $parmt eq 'n' || $parmt eq 'y';
 886         my $news = $r->_fresh_secret();
 887         if ($meth eq 'GET') {
 888             return ({ Kind => 'LOGIN-INCOMINGLINK',
 889                       Message => $r->_gt("You need to log in."),
 890                       _CookieRaw => $news,
 891                       Params => $r->chain_params() });
 892         } else {
 893             $r->_db_revoke($parmh);
 894             return ({ Kind => 'LOGIN-FRESH',
 895                       Message => $r->_gt("You need to log in."),
 896                       _CookieRaw => $news,
 897                       Params => { } });
 898         }
 899     }
 900
 901     if (!$r->{S}{promise_check_mutate}) {
 902         if ($meth ne 'POST') {
 903             return ({ Kind => 'MAINPAGEONLY',
 904                       Message => $r->_gt('Entering via cross-site link.'),
 905                       _CookieRaw => $cooks,
 906                       Params => { } });
 907             # NB caller must then ignore params & path!
 908             # if this is too hard they can spit out a small form
 909             # with a "click to continue"
 910         }
 911     }
 912
 913     die unless $cookt eq 'y';
 914     unless ($r->{S}{promise_check_mutate} && $meth eq 'GET') {
 915         die unless $parmt eq 'y';
 916         die unless $cookh eq $parmh;
 917     }
 918     $r->{ParmT} = $parmt;
 919     $r->{AssocRaw} = $cooks;
 920     $r->{UserOK} = $cooku;
 921 #print STDERR "C-D-C OK\n";
 922     return undef;
 923 }
 924
 925 sub chain_params ($) {
 926     my ($r) = @_;
 927     my %p = %{ $r->_ch('get_params') };
 928     foreach my $pncn (keys %{ $r->{S} }) {
 929         my $names;
 930         if ($pncn =~ m/_param_name$/) {
 931             my $name = $r->{S}{$pncn};
 932             die "$pncn ?" if ref $name;
 933             $names = [ $name ];
 934         } elsif ($pncn =~ m/_param_names$/) {
 935             $names = $r->{S}{$pncn};
 936         } else {
 937             next;
 938         }
 939         foreach my $name (@$names) {
 940             delete $p{$name};
 941         }
 942     }
 943     my $dummy_prefix = $r->{S}{dummy_param_name_prefix};
 944     foreach my $name (grep /^$dummy_prefix/, keys %p) {
 945         delete $p{$name};
 946     }
 947     die if exists $p{''};
 948     $p{''} = [ $r->_ch('get_path_info') ];
 949     return \%p;
 950 }
 951
 952 sub _identify ($$) {
 953     my ($r,$h,$s) = @_;
 954     # returns ($t,$username)
 955     # where $t is one of "t" "y" "n", or "" (for -)
 956     # either $s must be undef, or $h eq $r->hash($s)
 957
 958 #print STDERR "_identify\n";
 959     return '' unless defined $h && length $h;
 960 #print STDERR "_identify h=$h s=".(defined $s ? $s : '<undef>')."\n";
 961
 962     my $dbh = $r->{Dbh};
 963
 964     $dbh->do("DELETE FROM $r->{S}{db_prefix}_assocs".
 965              " WHERE last < ?", {},
 966              time - $r->{S}{login_timeout});
 967
 968     my $row = $dbh->selectrow_arrayref("SELECT username, last".
 969                               " FROM $r->{S}{db_prefix}_assocs".
 970                               " WHERE assochash = ?", {}, $h);
 971     if (defined $row) {
 972 #print STDERR "_identify h=$h s=$s YES @$row\n";
 973         my ($nusername, $nlast) = @$row;
 974         return ('y', $nusername);
 975     }
 976
 977     # Well, it's not in the database.  But maybe it's a hash of a
 978     # temporary secret.
 979
 980     return 'n' unless defined $s;
 981
 982     my ($keyt, $signature, $message, $noncet, $nonce) =
 983         $s =~ m/^(\d+)\.(\w+)\.((\d+)\.(\w+))$/ or die;
 984
 985     return 'n' if time > $noncet + $r->{S}{login_form_timeout};
 986
 987 #print STDERR "_identify noncet=$noncet ok\n";
 988
 989     my $keys = $r->_open_keys();
 990     while (my ($rkeyt, $rkey, $line) = $r->_read_key($keys)) {
 991 #print STDERR "_identify  search rkeyt=$rkeyt rkey=$rkey\n";
 992         last if $rkeyt < $keyt; # too far down in the file
 993         my $trysignature = $r->_hmac($rkey, $message);
 994 #print STDERR "_identify  search rkeyt=$rkeyt rkey=$rkey try=$trysignature\n";
 995         return 't' if $trysignature eq $signature;
 996     }
 997     # oh well
 998 #print STDERR "_identify NO\n";
 999
1000     $keys->error and die $!;
1001     return 'n';
1002 }
1003
1004 sub _db_revoke ($$) {
1005     # revokes $h if it's valid; no-op if it's not
1006     my ($r,$h) = @_;
1007
1008     my $dbh = $r->{Dbh};
1009
1010     $dbh->do("DELETE FROM $r->{S}{db_prefix}_assocs".
1011              " WHERE assochash = ?", {}, $h);
1012 }
1013
1014 sub _db_record_login_ok ($$$) {
1015     my ($r,$h,$user) = @_;
1016     $r->_db_revoke($h);
1017     my $dbh = $r->{Dbh};
1018     $dbh->do("INSERT INTO $r->{S}{db_prefix}_assocs".
1019              " (assochash, username, last) VALUES (?,?,?)", {},
1020              $h, $user, time);
1021 }
1022
1023 sub check_divert ($) {
1024     my ($r) = @_;
1025     if (exists $r->{Divert}) {
1026         return $r->{Divert};
1027     }
1028     my $dbh = $r->{Dbh};
1029     $r->{Divert} = $r->_db_transaction(sub { $r->_check_divert_core(); });
1030     $dbh->commit();
1031
1032     my $divert = $r->{Divert};
1033     my $cookraw = $divert->{_CookieRaw};
1034     $divert->{CookieSecret} = $r->_blind($cookraw);
1035     if ($cookraw) {
1036         $divert->{Params}{$r->{S}{assoc_param_name}} = [
1037             $r->_blind($r->hash($cookraw))
1038             ];
1039     }
1040
1041     $r->_debug(Data::Dumper->Dump([$divert],[qw(divert)]));
1042     return $divert;
1043 }
1044
1045 sub get_divert ($) {
1046     my ($r) = @_;
1047     die "unchecked" unless exists $r->{Divert};
1048     return $r->{Divert};
1049 }
1050
1051 sub get_username ($) {
1052     my ($r) = @_;
1053     my $divert = $r->get_divert();
1054     return undef if $divert;
1055     return $r->{UserOK};
1056 }
1057
1058 sub url_with_query_params ($$;$) {
1059     my ($r, $params, $nonpagetype) = @_;
1060 #print STDERR "PARAMS ",Dumper($params);
1061     my $uri = URI->new($r->_ch('get_url'));
1062     $uri->path($uri->path() . $params->{''}[0]) if $params->{''};
1063     my @flatparams = flatten_params($params);
1064     if (defined $nonpagetype && $r->need_add_hidden('GET',$nonpagetype)) {
1065         push @flatparams, $r->{S}{assoc_param_name}, $r->secret_hidden_val();
1066     }
1067     $uri->query_form(@flatparams);
1068     return $uri->as_string();
1069 }
1070
1071 sub _cgi_header_args ($$@) {
1072     my ($r, $cookie, @ha) = @_;
1073     unshift @ha, qw(-type text/html);
1074     push @ha, (-cookie => $cookie) if defined $cookie;
1075 #print STDERR "_cgi_header_args ",join('|',@ha),".\n";
1076     return @ha;
1077 }
1078
1079 sub check_ok ($) {
1080     my ($r) = @_;
1081
1082     my ($divert) = $r->check_divert();
1083     return 1 if !$divert;
1084
1085     my $handled = $r->_ch('handle_divert',$divert);
1086     return 0 if $handled;
1087
1088     my $kind = $divert->{Kind};
1089     my $cookiesecret = $divert->{CookieSecret};
1090     my $params = $divert->{Params};
1091     my $cookie = $r->construct_cookie($cookiesecret);
1092
1093     if ($kind =~ m/^SRCDUMP-(\w+)$/) {
1094         $r->_ch('srcdump_dump', (lc $1));
1095         return 0;
1096     }
1097
1098     if ($kind =~ m/^REDIRECT-/) {
1099         # for redirects, we honour stored Params and Cookie,
1100         # as we would for non-divert
1101         if ($kind eq 'REDIRECT-LOGGEDOUT') {
1102         } elsif ($kind =~ m/REDIRECT-(?:LOGGEDIN|HTTPS)/) {
1103         } else {
1104             die;
1105         }
1106         my $new_url = $r->url_with_query_params($params);
1107         if ($kind eq 'REDIRECT-HTTPS') {
1108             my $uri = URI->new($new_url);
1109             die unless $uri->scheme eq 'http';
1110             $uri->scheme('https');
1111             $new_url = $uri->as_string();
1112         }
1113         $r->_ch('do_redirect',$new_url, $cookie);
1114         return 0;
1115     }
1116
1117     my ($title, @body);
1118     if ($kind =~ m/^LOGIN-/) {
1119         $title = $r->_gt('Login');
1120         push @body, $divert->{Message};
1121         push @body, $r->_ch('gen_login_form', $params);
1122     } elsif ($kind =~ m/^SMALLPAGE-/) {
1123         $title = $r->_gt('Not logged in');
1124         push @body, $divert->{Message};
1125         push @body, $r->_ch('gen_login_link', $params);
1126     } elsif ($kind =~ m/^MAINPAGEONLY$/) {
1127         $title = $r->_gt('Entering secure site.');
1128         push @body, $divert->{Message};
1129         push @body, $r->_ch('gen_postmainpage_form', $params);
1130     } else {
1131         die $kind;
1132     }
1133
1134     $r->_print($r->{Cgi}->header($r->_cgi_header_args($cookie)),
1135                $r->_ch('gen_start_html',$title),
1136                (join "\n", (@body,
1137                             $r->_ch('gen_footer_html'),
1138                             $r->_ch('gen_end_html'))));
1139     return 0;
1140 }
1141
1142 sub _random ($$) {
1143     my ($r, $bytes) = @_;
1144     my $v = $r->{V};
1145     my $rsf = $v->{RandomHandle};
1146     my $rsp = $r->{S}{random_source};
1147     if (!$rsf) {
1148         $v->{RandomHandle} = $rsf = new IO::File $rsp, '<' or die "$rsp $!";
1149 #print STDERR "RH $rsf\n";
1150     }
1151     my $bin;
1152     $!=0;
1153     read($rsf,$bin,$bytes) == $bytes or die "$rsp $!";
1154     my $out = unpack "H*", $bin;
1155 #print STDERR "_random out $out\n";
1156     return $out;
1157 }
1158
1159 sub _blind_len ($$) {
1160     my ($r, $str) = @_;
1161     return length($str =~ y/0-9a-f//cdr);
1162 }
1163
1164 sub _blind_combine ($$$) {
1165     my ($r, $in, $mask) = @_;
1166     my @mask = split //, $mask;
1167     $in =~ s{[0-9a-f]}{
1168         my $m = shift @mask;
1169         sprintf "%x", hex($m) ^ hex($&);
1170     }ge;
1171     return $in;
1172 }
1173
1174 sub _blind ($$) {
1175     my ($r, $in) = @_;
1176     return $in unless $in;
1177     my $l = $r->_blind_len($in);
1178     my $mask = $r->_random(($l+1)>>1);
1179     $mask = substr $mask, 0, $l;
1180     my $blound = $r->_blind_combine($in, $mask);
1181     return "$blound.$mask";
1182 }
1183
1184 sub _unblind ($$) {
1185     my ($r, $in) = @_;
1186     return $in unless $in;
1187     my ($blound,$mask) = ($in =~ m#^(.*)\.([0-9a-f]+)$#) or die "$in ?";
1188     my $l = $r->_blind_len($blound);
1189     $l == length($mask) or die "$in ?";
1190     return $r->_blind_combine($blound, $mask);
1191 }
1192
1193 sub _random_key ($) {
1194     my ($r) = @_;
1195 #print STDERR "_random_key\n";
1196     my $bytes = ($r->{S}{secretbits} + 7) >> 3;
1197     return $r->_random($bytes);
1198 }
1199
1200 sub _read_key ($$) {
1201     my ($r, $keys) = @_;
1202     # returns $gen_time_t, $key_value_in_hex, $complete_line
1203     while (<$keys>) {
1204         my ($gen, $k) = m/^(\d+) (\S+)$/ or die "$_ ?";
1205         my $age = time - $gen;
1206         next if $age > $r->{S}{key_rollover} &&
1207             $age > $r->{S}{login_form_timeout}*2;
1208         return ($gen, $k, $_);
1209     }
1210     return ();
1211 }
1212
1213 sub _open_keys ($) {
1214     my ($r) = @_;
1215     my $spath = $r->_get_path('keys');
1216     for (;;) {
1217 #print STDERR "_open_keys\n";
1218         my $keys = new IO::File $spath, 'r+';
1219         if ($keys) {
1220 #print STDERR "_open_keys open\n";
1221             stat $keys or die $!; # NB must not disturb stat _
1222             my $size = (stat _)[7];
1223             my $age = time - (stat _)[9];
1224 #print STDERR "_open_keys open size=$size age=$age\n";
1225             return $keys
1226                 if $size && $age <= $r->{S}{key_rollover} / 2;
1227 #print STDERR "_open_keys open bad\n";
1228         }
1229         # file doesn't exist, or is empty or too old
1230         if (!$keys) {
1231 #print STDERR "_open_keys closed\n";
1232             die "$spath $!" unless $!==&ENOENT;
1233             # doesn't exist, so create it just so we can lock it
1234             $keys = new IO::File $spath, 'a+';
1235             die "$keys $!" unless $keys;
1236             stat $keys or die $!; # NB must not disturb stat _
1237             my $size = (stat _)[7];
1238 #print STDERR "_open_keys created size=$size\n";
1239             next if $size; # oh someone else has done it, reopen and read it
1240         }
1241         # file now exists is empty or too old, we must try to replace it
1242         my $our_inum = (stat _)[1]; # last use of that stat _
1243         flock $keys, LOCK_EX or die "$spath $!";
1244         stat $spath or die "$spath $!";
1245         my $path_inum = (stat _)[1];
1246 #print STDERR "_open_keys locked our=$our_inum path=$path_inum\n";
1247         next if $our_inum != $path_inum; # someone else has done it
1248         # We now hold the lock!
1249 #print STDERR "_open_keys creating\n";
1250         my $newkeys = new IO::Handle;
1251         sysopen $newkeys, "$spath.new", O_CREAT|O_TRUNC|O_WRONLY, 0600
1252             or die "$spath.new $!";
1253         # we add the new key to the front which means it's always sorted
1254         print $newkeys time, ' ', $r->_random_key(), "\n" or die $!;
1255         while (my ($gen,$key,$line) = $r->_read_key($keys)) {
1256 #print STDERR "_open_keys copy1\n";
1257             print $newkeys, $line or die $!;
1258         }
1259         $keys->error and die $!;
1260         close $newkeys or die "$spath.new $!";
1261         rename "$spath.new", "$spath" or die "$spath: $!";
1262 #print STDERR "_open_keys installed\n";
1263         # that rename effective unlocks, since it makes the name refer
1264         #  to the new file which we haven't locked
1265         # we go round again opening the file at the beginning
1266         #  so that our caller gets a fresh handle onto the existing key file
1267     }
1268 }
1269
1270 sub _fresh_secret ($) {
1271     my ($r) = @_;
1272 #print STDERR "_fresh_secret\n";
1273
1274     my $keys = $r->_open_keys();
1275     my ($keyt, $key) = $r->_read_key($keys);
1276     die unless defined $keyt;
1277
1278     my $nonce = $r->_random_key();
1279     my $noncet = time;
1280     my $message = "$noncet.$nonce";
1281
1282     my $signature = $r->_hmac($key, $message);
1283     my $secret = "$keyt.$signature.$message";
1284 #print STDERR "FRESH $secret\n";
1285     return $secret;
1286 }
1287
1288 sub _hmac ($$$) {
1289     my ($r, $keyhex, $message) = @_;
1290     my $keybin = pack "H*", $keyhex;
1291     my $alg = $r->{S}{hash_algorithm};
1292 #print STDERR "hmac $alg\n";
1293     my $base = new Digest $alg;
1294 #print STDERR "hmac $alg $base\n";
1295     my $digest = new Digest::HMAC $keybin, $base;
1296 #print STDERR "hmac $alg $base $digest\n";
1297     $digest->add($message);
1298     return $digest->hexdigest();
1299 }
1300
1301 sub hash ($$) {
1302     my ($r, $message) = @_;
1303     my $alg = $r->{S}{hash_algorithm};
1304 #print STDERR "hash $alg\n";
1305     my $digest = new Digest $alg;
1306     $digest->add($message);
1307     return $digest->hexdigest();
1308 }
1309
1310 sub _assert_checked ($) {
1311     my ($r) = @_;
1312     die "unchecked" unless exists $r->{Divert};
1313 }
1314
1315 sub _is_post ($) {
1316     my ($r) = @_;
1317     my $meth = $r->_ch('get_method');
1318     return $meth eq 'POST';
1319 }
1320
1321 sub _must_be_post ($) {
1322     my ($r) = @_;
1323     my $meth = $r->_ch('get_method');
1324     die "mutating non-POST" if $meth ne 'POST';
1325 }
1326
1327 sub check_mutate ($) {
1328     my ($r) = @_;
1329     $r->_assert_checked();
1330     die if $r->{Divert};
1331     $r->_must_be_post();
1332 }
1333
1334 our %_resource_get_needs_secret_hidden =
1335     (map { $_ => 0 } qw(PAGE FRAME IFRAME SRCDUMP STYLESHEET FAVICON ROBOTS),
1336      map { $_ => 1 } qw(IMAGE SCRIPT AJAX-XML AJAX-JSON AJAX-OTHER));
1337
1338 sub update_get_need_add_hidden ($$;$) {
1339     my ($r, $reqtype, $value, $force) = @_;
1340     my $hash = ref $r
1341         ? ($r->{GetNeedsSecretHidden} ||= { })
1342         : \%_resource_get_needs_secret_hidden;
1343     return if !$force &&
1344         (exists $_resource_get_needs_secret_hidden{$reqtype} ||
1345          exists $hash->{$reqtype});
1346     $hash->{$reqtype} = $value;
1347 }
1348
1349 sub need_add_hidden ($$) {
1350     my ($r, $method, $reqtype) = @_;
1351     return 1 if $method ne 'GET';
1352     if (ref $r) {
1353         my $ent = $r->{GetNeedsSecretHidden}{$reqtype};
1354         return $ent if defined $ent;
1355     }
1356     my $ent = $_resource_get_needs_secret_hidden{$reqtype};
1357     return $ent if defined $ent;
1358     die "unsupported nonpage GET type $reqtype";
1359 }
1360
1361 sub check_nonpage ($$) {
1362     my ($r, $reqtype) = @_;
1363     $r->_assert_checked();
1364     return unless $r->resource_get_needs_secret_hidden($reqtype);
1365     return if $r->{ParmT};
1366     die "missing hidden secret parameter on nonpage request $reqtype";
1367 }
1368
1369 #---------- output ----------
1370
1371 sub secret_cookie_val ($) {
1372     my ($r) = @_;
1373     $r->_assert_checked();
1374     return defined $r->{AssocRaw} ? $r->_blind($r->{AssocRaw}) : '';
1375 }
1376
1377 sub secret_hidden_val ($) {
1378     my ($r) = @_;
1379     $r->_assert_checked();
1380     return defined $r->{AssocRaw} ? $r->_blind($r->hash($r->{AssocRaw})) : '';
1381 }
1382
1383 sub secret_hidden_html ($) {
1384     my ($r) = @_;
1385     return $r->{Cgi}->hidden(-name => $r->{S}{assoc_param_name},
1386                              -default => $r->secret_hidden_val());
1387 }
1388
1389 sub secret_cookie ($) {
1390     my ($r) = @_;
1391     my $secret = $r->secret_cookie_val();
1392     return undef if !defined $secret;
1393 #print STDERR "SC\n";
1394     my $cookv = $r->construct_cookie($secret);
1395 #print STDERR "SC=$cookv\n";
1396     return $cookv;
1397 }
1398
1399 1;