cgi-auth-flexible.pm

   1 # -*- perl -*-
   2
   3 # This is part of CGI::Auth::Flexible, a perl CGI authentication module.
   4 # Copyright (C) 2012 Ian Jackson.
   5 # Copyright (C) 2012 Citrix.
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU Affero General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU Affero General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU Affero General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21 use warnings FATAL => 'all';
  22
  23 package CGI::Auth::Flexible;
  24 require Exporter;
  25
  26 BEGIN {
  27     use Exporter   ();
  28     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  29
  30     $VERSION     = 1.00;
  31     @ISA         = qw(Exporter);
  32     @EXPORT      = qw();
  33     %EXPORT_TAGS = ( );     # eg: TAG => [ qw!name1 name2! ],
  34
  35     @EXPORT_OK   = qw();
  36 }
  37 our @EXPORT_OK;
  38
  39 use DBI;
  40 use CGI qw/escapeHTML/;
  41 use Locale::gettext;
  42 use URI;
  43 use IO::File;
  44 use Fcntl qw(:flock);
  45 use POSIX;
  46 use Digest;
  47 use Digest::HMAC;
  48 use Digest::SHA;
  49 use Data::Dumper;
  50 use File::Copy;
  51 use Cwd qw/realpath/;
  52
  53
  54 #---------- public utilities ----------
  55
  56 sub flatten_params ($) {
  57     my ($p) = @_;
  58     my @p;
  59     foreach my $k (keys %$p) {
  60         next if $k eq '';
  61         foreach my $v (@{ $p->{$k} }) {
  62             push @p, $k, $v;
  63         }
  64     }
  65     return @p;
  66 }
  67
  68 #---------- default callbacks ----------
  69
  70 sub has_a_param ($$) {
  71     my ($r,$cn) = @_;
  72     foreach my $pn (@{ $r->{S}{$cn} }) {
  73         return 1 if $r->_ch('get_param',$pn);
  74     }
  75     return 0;
  76 }
  77
  78 sub get_params ($) {
  79     my ($r) = @_;
  80     my $c = $r->{Cgi};
  81     my $vars = $c->Vars();
  82     my %p;
  83     foreach my $name (keys %$vars) {
  84         $p{$name} = [ split "\0", $vars->{$name} ];
  85     }
  86     return \%p;
  87 }
  88
  89 sub get_cookie_domain ($$$) {
  90     my ($c,$r) = @_;
  91     my $uri = new URI $r->_ch('get_url');
  92     return $uri->host();
  93 }
  94
  95 sub login_ok_password ($$) {
  96     my ($c, $r) = @_;
  97     my $username_params = $r->{S}{username_param_names};
  98     my $username = $r->_ch('get_param',$username_params->[0]);
  99     my $password = $r->_rp('password_param_name');
 100     my $error = $r->_ch('username_password_error', $username, $password);
 101     return defined($error) ? (undef,$error) : ($username,undef);
 102 }
 103
 104 sub do_redirect_cgi ($$$$) {
 105     my ($c, $r, $new_url, $cookie) = @_;
 106     $r->_print($c->header($r->_cgi_header_args($cookie,
 107                                                -status => '303 See other',
 108                                                -location => $new_url)),
 109                $r->_ch('gen_start_html',$r->_gt('Redirection')),
 110                '<a href="'.escapeHTML($new_url).'">',
 111                $r->_gt("If you aren't redirected, click to continue."),
 112                "</a>",
 113                $r->_ch('gen_end_html'));
 114 }
 115
 116 sub gen_some_form ($$) {
 117     my ($r, $params, $bodyfn) = @_;
 118     # Calls $bodyfn->($c,$r) which returns @formbits
 119     my $c = $r->{Cgi};
 120     my @form;
 121     my $pathinfo = '';
 122     $pathinfo .= $params->{''}[0] if $params->{''};
 123     push @form, ('<form method="POST" action="'.
 124                  escapeHTML($r->_ch('get_url').$pathinfo).'">');
 125     push @form, $bodyfn->($c,$r);
 126     foreach my $n (keys %$params) {
 127         next if $n eq '';
 128         foreach my $val (@{ $params->{$n} }) {
 129             push @form, ('<input type="hidden"'.
 130                          ' name="'.escapeHTML($n).'"'.
 131                          ' value="'.escapeHTML($val).'">');
 132         }
 133     }
 134     push @form, ('</form>');
 135     return join "\n", @form;
 136 }
 137
 138 sub gen_plain_login_form ($$) {
 139     my ($c,$r, $params) = @_;
 140     return $r->gen_some_form($params, sub {
 141         my @form;
 142         push @form, ('<table>');
 143         my $sz = 'size="'.$r->{S}{form_entry_size}.'"';
 144         foreach my $up (@{ $r->{S}{username_param_names}}) {
 145             push @form, ('<tr><td>',$r->_gt(ucfirst $up),'</td>',
 146                          '<td><input type="text" '.$sz.
 147                          ' name='.$up.'></td></tr>');
 148         }
 149         push @form, ('<tr><td>'.$r->_gt('Password').'</td>',
 150                      '<td><input type="password" '.$sz.
 151                      ' name="'.$r->{S}{password_param_name}.'"></td></tr>');
 152         push @form, ('<tr><td colspan="2">',
 153                      '<input type="submit"'.
 154                      ' name="'.$r->{S}{dummy_param_name_prefix}.'login"'.
 155                      ' value="'.$r->_gt('Login').'"></td></tr>',
 156                      '</table>');
 157         return @form;
 158     });
 159 }
 160
 161 sub gen_postmainpage_form ($$$) {
 162     my ($c,$r, $params) = @_;
 163     return $r->gen_some_form($params, sub {
 164         my @form;
 165         push @form, ('<input type="submit"',
 166                      ' name="'.$r->{S}{dummy_param_name_prefix}.'submit"'.
 167                      ' value="'.$r->_gt('Continue').'">');
 168         return @form;
 169     });
 170 }
 171
 172 sub gen_plain_login_link ($$) {
 173     my ($c,$r, $params) = @_;
 174     my $url = $r->url_with_query_params($params);
 175     return ('<a href="'.escapeHTML($url).'">'.
 176             $r->_gt('Log in again to continue.').
 177             '</a>');
 178 }
 179
 180 sub gen_srcdump_link_html ($$$$) {
 181     my ($c,$r,$anchor,$specval) = @_;
 182     my %params = ($r->{S}{srcdump_param_name} => [ $specval ]);
 183     return '<a href="'.
 184         escapeHTML($r->url_with_query_params(\%params,'SRCDUMP')).
 185         '">'.$anchor."</a>";
 186 }
 187 sub gen_plain_licence_link_html ($$) {
 188     my ($c,$r) = @_;
 189     gen_srcdump_link_html($c,$r, 'GNU Affero GPL', 'licence');
 190 }
 191 sub gen_plain_source_link_html ($$) {
 192     my ($c,$r) = @_;
 193     gen_srcdump_link_html($c,$r, 'Source available', 'source');
 194 }
 195
 196 sub gen_plain_footer_html ($$) {
 197     my ($c,$r) = @_;
 198     return ('<hr><address>',
 199             ("Powered by Free / Libre / Open Source Software".
 200              " according to the ".$r->_ch('gen_licence_link_html')."."),
 201             $r->_ch('gen_source_link_html').".",
 202             '</address>');
 203 }
 204
 205 #---------- licence and source code ----------
 206
 207 sub srcdump_dump ($$$) {
 208     my ($c,$r, $thing) = @_;
 209     die if $thing =~ m/\W/ || $thing !~ m/\w/;
 210     my $path = $r->_get_path('srcdump');
 211     my $ctf = new IO::File "$path/$thing.ctype", 'r'
 212         or die "$path/$thing.ctype $!";
 213     my $ct = <$ctf>;
 214     chomp $ct or die "$path/$thing ?";
 215     $ctf->close or die "$path/$thing $!";
 216     my $df = new IO::File "$path/$thing.data", 'r'
 217         or die "$path/$thing.data $!";
 218     $r->_ch('dump', $ct, $df);
 219 }
 220
 221 sub dump_plain ($$$$) {
 222     my ($c, $r, $ct, $df) = @_;
 223     $r->_print($c->header('-type' => $ct));
 224     my $buffer;
 225     for (;;) {
 226         my $got = read $df, $buffer, 65536;
 227         die $! unless defined $got;
 228         return if !$got;
 229         $r->_print($buffer);
 230     }
 231 }
 232
 233 sub srcdump_process_item ($$$$$$) {
 234     my ($c, $v, $dumpdir, $item, $outfn, $needlicence, $dirsdone) = @_;
 235     if ($v->_ch('srcdump_system_dir', $item)) {
 236         $outfn->("srcdump_process_item: srcdump_system_dir, skipping $item");
 237         return;
 238     }
 239     my $upwards = $item;
 240     for (;;) {
 241         $upwards =~ s#/+$##;
 242         $upwards =~ s#/+\.$##;
 243         last unless $upwards =~ m#[^/]#;
 244         foreach my $try (@{ $v->{S}{srcdump_vcs_dirs} }) {
 245 #print STDERR "TRY $item $upwards $try\n";
 246             if (!stat "$upwards/$try") {
 247                 $!==&ENOENT or $!==&ENOTDIR or die "check $upwards/$try $!";
 248                 next;
 249             }
 250 #print STDERR "VCS $item $upwards $try\n";
 251             if ($dirsdone->{$upwards}++) {
 252                 $outfn->("srcdump_process_item: did $upwards,".
 253                          " skipping $item");
 254                 return;
 255             }
 256 #print STDERR "VCS $item $upwards $try GO\n";
 257             $try =~ m/\w+/ or die;
 258             return $v->_ch('srcdump_byvcs', $dumpdir, $upwards, $outfn, lc $&);
 259         }
 260         $upwards =~ s#/*[^/]+$##;
 261     }
 262     return $v->_ch('srcdump_novcs', $dumpdir, $item, $outfn);
 263 }
 264
 265 sub srcdump_novcs ($$$$$) {
 266     my ($c, $v, $dumpdir, $item, $outfn) = @_;
 267     stat $item or die "$item $!";
 268     if (-d _) {
 269         my $script = 'find -type f -perm +004';
 270         foreach my $excl (@{ $v->{S}{srcdump_excludes} }) {
 271             $script .= " \\! -name '$excl'";
 272         }
 273         $script .= " -print0";
 274         return srcdump_dir_cpio($c,$v,$dumpdir,$item,$outfn,'novcs',$script);
 275     } elsif (-f _) {
 276         return srcdump_file($c,$v,$dumpdir,$item,$outfn);
 277     } else {
 278         die "$item not file or directory";
 279     }
 280 }
 281
 282 sub srcdump_byvcs ($$$$$$) {
 283     my ($c, $v, $dumpdir, $dir, $outfn, $vcs) = @_;
 284 #print STDERR "BYVCS GIT $dir\n";
 285     my $script = $v->{S}{"srcdump_vcsscript"}{$vcs};
 286     die "no script for vcs $vcs" unless defined $script;
 287     return srcdump_dir_cpio($c,$v,$dumpdir,$dir,$outfn,$vcs,$script);
 288 }
 289
 290 sub srcdump_file ($$$$) {
 291     my ($c,$v,$dumpdir,$file,$outfn) = @_;
 292     my $outfile = $outfn->("srcdump_file saved $file", "src");
 293     copy($file,$outfile) or die "$file $outfile $!";
 294 }
 295
 296 sub srcdump_dir_cpio ($$$$$$$) {
 297     my ($c,$v,$dumpdir,$dir,$outfn,$how,$script) = @_;
 298     my $outfile = $outfn->("srcdump_dir_cpio $how saved $dir", "tar");
 299 #print STDERR "CPIO $dir >$script<\n";
 300     my $pid = fork();
 301     defined $pid or die $!;
 302     if (!$pid) {
 303         $SIG{__DIE__} = sub {
 304             print STDERR "CGI::Auth::Flexible srcdump error: $@\n";
 305             exit 127;
 306         };
 307         open STDOUT, ">", $outfile or die "$outfile $!";
 308         chdir $dir or die "chdir $dir: $!";
 309         exec '/bin/bash','-ec',"
 310             set -o pipefail
 311             (
 312              $script
 313             ) | (
 314              cpio -Hustar -o --quiet -0 -R 1000:1000 || \
 315              cpio -Hustar -o --quiet -0
 316             )
 317             ";
 318         die $!;
 319     }
 320     $!=0; (waitpid $pid, 0) == $pid or die "$!";
 321     die "$dir ($how $script) $outfile $?" if $?;
 322 }
 323
 324 sub srcdump_dirscan_prepare ($$) {
 325     my ($c, $v) = @_;
 326     my $dumpdir = $v->_get_path('srcdump');
 327     mkdir $dumpdir or $!==&EEXIST or die "mkdir $dumpdir $!";
 328     my $lockf = new IO::File "$dumpdir/generate.lock", 'w+'
 329         or die "$dumpdir/generate.lock $!";
 330     flock $lockf, LOCK_EX or die "$dumpdir/generate.lock $!";
 331     my $needlicence = "$dumpdir/licence.tmp";
 332     unlink $needlicence or $!==&ENOENT or die "rm $needlicence $!";
 333     if (defined $v->{S}{srcdump_licence_path}) {
 334         copy($v->{S}{srcdump_licence_path}, $needlicence)
 335             or die "$v->{S}{srcdump_licence_path} $!";
 336         $needlicence = undef;
 337     }
 338     unlink <"$dumpdir/s.[a-z][a-z][a-z].*">;
 339     my @srcfiles = qw(licence.data manifest.txt);
 340     my $srcoutcounter = 'aaa';
 341
 342     my $reportfh = new IO::File "$dumpdir/manifest.txt", 'w' or die $!;
 343     my $outfn = sub {
 344         my ($message, $extension) = @_;
 345         if (defined $extension) {
 346             my $leaf = "s.$srcoutcounter.$extension";
 347             $srcoutcounter++;
 348             push @srcfiles, $leaf;
 349             print $reportfh "$leaf: $message\n" or die $!;
 350             return "$dumpdir/$leaf";
 351         } else {
 352             print $reportfh "none: $message\n" or die $!;
 353             return undef;
 354         }
 355     };
 356     my %dirsdone;
 357     foreach my $item ($v->_ch('srcdump_listitems')) {
 358         if ($item eq '.' && $v->{S}{srcdump_filter_cwd}) {
 359             my @bad = grep { !m#^/# } values %INC;
 360             die "filtering . from srcdump items and \@INC but already".
 361                 " included @bad " if @bad;
 362             @INC = grep { $_ ne '.' } @INC;
 363             next;
 364         }
 365         if (!lstat "$item") {
 366             die "stat $item $!" unless $!==&ENOENT;
 367             $outfn->("srcdump_dirscan_prepare stat ENOENT, skipping $item");
 368             next;
 369         };
 370         if (-l _) {
 371             $item = realpath($item);
 372             if (!defined $item) {
 373                 die "realpath $item $!" unless $!==&ENOENT;
 374                 $outfn->("srcdump_dirscan_prepare realpath ENOENT,".
 375                          " skipping $item");
 376             }
 377         }
 378         if (defined $needlicence) {
 379             foreach my $try (@{ $v->{S}{srcdump_licence_files} }) {
 380                 last if copy("$item/$try", $needlicence);
 381                 $!==&ENOENT or $!==&ENOTDIR or die "copy $item/$try $!";
 382             }
 383         }
 384         $v->_ch('srcdump_process_item', $dumpdir, $item,
 385                 $outfn, \$needlicence, \%dirsdone);
 386         $dirsdone{$item}++;
 387     }
 388     close $reportfh or die $!;
 389     srcdump_install($c,$v, $dumpdir, 'licence', 'text/plain');
 390     $!=0;
 391     my @cmd = (qw(tar -zvvcf), "$dumpdir/source.tmp",
 392                "-C", $dumpdir, qw(  --), @srcfiles);
 393     my $r = system(@cmd);
 394     if ($r) {
 395         print STDERR "CGI::Auth::Flexible tar failed ($r $!) @cmd\n";
 396         die "tar failed";
 397     }
 398     die "licence file not found" unless defined $needlicence;
 399     srcdump_install($c,$v, $dumpdir, 'source', 'application/octet-stream');
 400     close $lockf or die $!;
 401 }
 402
 403 sub srcdump_install ($$$$$) {
 404     my ($c,$v, $dumpdir, $which, $ctype) = @_;
 405     rename "$dumpdir/$which.tmp", "$dumpdir/$which.data"
 406         or die "$dumpdir/$which.data $!";
 407     my $ctf = new IO::File "$dumpdir/$which.tmp", 'w'
 408         or die "$dumpdir/$which.tmp $!";
 409     print $ctf $ctype, "\n" or die $!;
 410     close $ctf or die $!;
 411     rename "$dumpdir/$which.tmp", "$dumpdir/$which.ctype"
 412         or die "$dumpdir/$which.ctype $!";
 413 }
 414
 415 #---------- verifier object methods ----------
 416
 417 sub new_verifier {
 418     my $class = shift;
 419     my $verifier = {
 420         S => {
 421             dir => undef,
 422             assocdb_dbh => undef, # must have AutoCommit=0, RaiseError=1
 423             assocdb_path => 'caf-assocs.db',
 424             keys_path => 'caf-keys',
 425             srcdump_path => 'caf-srcdump',
 426             assocdb_dsn => undef,
 427             assocdb_user => '',
 428             assocdb_password => '',
 429             assocdb_table => 'caf_assocs',
 430             random_source => '/dev/urandom',
 431             secretbits => 128, # bits
 432             hash_algorithm => "SHA-256",
 433             login_timeout => 86400, # seconds
 434             login_form_timeout => 3600, # seconds
 435             key_rollover => 86400, # seconds
 436             assoc_param_name => 'caf_assochash',
 437             dummy_param_name_prefix => 'caf__',
 438             cookie_name => "caf_assocsecret",
 439             password_param_name => 'password',
 440             srcdump_param_name => 'caf_srcdump',
 441             username_param_names => [qw(username)],
 442             form_entry_size => 60,
 443             logout_param_names => [qw(caf_logout)],
 444             loggedout_param_names => [qw(caf_loggedout)],
 445             promise_check_mutate => 0,
 446             get_param => sub { $_[0]->param($_[2]) },
 447             get_params => sub { $_[1]->get_params() },
 448             get_path_info => sub { $_[0]->path_info() },
 449             get_cookie => sub { $_[0]->cookie($_[1]->{S}{cookie_name}) },
 450             get_method => sub { $_[0]->request_method() },
 451             is_https => sub { !!$_[0]->https() },
 452             get_url => sub { $_[0]->url(); },
 453             is_login => sub { defined $_[1]->_rp('password_param_name') },
 454             login_ok => \&login_ok_password,
 455             username_password_error => sub { die },
 456             is_logout => sub { $_[1]->has_a_param('logout_param_names') },
 457             is_loggedout => sub { $_[1]->has_a_param('loggedout_param_names') },
 458             handle_divert => sub { return 0 },
 459             do_redirect => \&do_redirect_cgi, # this hook is allowed to throw
 460             cookie_path => "/",
 461             get_cookie_domain => \&get_cookie_domain,
 462             encrypted_only => 1,
 463             gen_start_html => sub { $_[0]->start_html($_[2]); },
 464             gen_footer_html => \&gen_plain_footer_html,
 465             gen_licence_link_html => \&gen_plain_licence_link_html,
 466             gen_source_link_html => \&gen_plain_source_link_html,
 467             gen_end_html => sub { $_[0]->end_html(); },
 468             gen_login_form => \&gen_plain_login_form,
 469             gen_login_link => \&gen_plain_login_link,
 470             gen_postmainpage_form => \&gen_postmainpage_form,
 471             srcdump_dump => \&srcdump_dump,
 472             srcdump_prepare => \&srcdump_dirscan_prepare,
 473             srcdump_licence_path => undef,
 474             srcdump_licence_files => [qw(AGPLv3 CGI/Auth/Flexible/AGPLv3)],
 475             srcdump_listitems => sub { (@INC, $ENV{'SCRIPT_FILENAME'}, $0); },
 476             srcdump_filter_cwd => 1,
 477             srcdump_system_dir => sub {
 478                 $_[2] =~ m#^/etc/|^/usr/(?!local/)(?!lib/cgi)#;
 479             },
 480             srcdump_process_item => \&srcdump_process_item,
 481             srcdump_vcs_dirs => [qw(.git .hg .bzr .svn)],
 482             srcdump_vcsscript => [git => "
 483                  git ls-files -z
 484                  git ls-files -z --others --exclude-from=.gitignore
 485                  find .git -print0
 486                             "],
 487             srcdump_byvcs => \&srcdump_byvcs,
 488             srcdump_novcs => \&srcdump_novcs,
 489             srcdump_excludes => [qw(*~ *.bak *.tmp), '#*#'],
 490             dump => \&dump_plain,
 491             gettext => sub { gettext($_[2]); },
 492             print => sub { print $_[2] or die $!; },
 493             debug => sub { }, # like print; msgs contain trailing \n
 494         },
 495         Dbh => undef,
 496     };
 497     my ($k,$v);
 498     while (($k,$v,@_) = @_) {
 499         die "unknown setting $k" unless
 500             $k =~ m/^promise_/ or
 501             exists $verifier->{S}{$k};
 502         $verifier->{S}{$k} = $v;
 503     }
 504     bless $verifier, $class;
 505     $verifier->_dbopen();
 506     $verifier->_ch('srcdump_prepare');
 507     return $verifier;
 508 }
 509
 510 sub _db_setup_do ($$) {
 511     my ($v, $sql) = @_;
 512     my $dbh = $v->{Dbh};
 513     eval {
 514         $v->_db_transaction(sub {
 515             local ($dbh->{PrintError}) = 0;
 516             $dbh->do($sql);
 517         });
 518     };
 519 }
 520
 521 sub _dbopen ($) {
 522     my ($v) = @_;
 523     my $dbh = $v->{Dbh};
 524     return $dbh if $dbh;
 525
 526     $dbh = $v->{S}{assocdb_dbh};
 527     if ($dbh) {
 528         die if $dbh->{AutoCommit};
 529         die unless $dbh->{RaiseError};
 530     } else {
 531         $v->{S}{assocdb_dsn} ||= "dbi:SQLite:dbname=".$v->_get_path('assocdb');
 532         my $dsn = $v->{S}{assocdb_dsn};
 533
 534         my $u = umask 077;
 535         $dbh = DBI->connect($dsn, $v->{S}{assocdb_user},
 536                             $v->{S}{assocdb_password}, {
 537                                 AutoCommit => 0,
 538                                 RaiseError => 1,
 539                                 ShowErrorStatement => 1,
 540                             });
 541         umask $u;
 542         die "$dsn $! ?" unless $dbh;
 543     }
 544     $v->{Dbh} = $dbh;
 545
 546     $v->_db_setup_do("CREATE TABLE $v->{S}{assocdb_table} (".
 547                      " assochash VARCHAR PRIMARY KEY,".
 548                      " username VARCHAR NOT NULL,".
 549                      " last INTEGER NOT NULL".
 550                      ")");
 551     $v->_db_setup_do("CREATE INDEX $v->{S}{assocdb_table}_timeout_index".
 552                      " ON $v->{S}{assocdb_table}".
 553                      " (last)");
 554     return $dbh;
 555 }
 556
 557 sub disconnect ($) {
 558     my ($v) = @_;
 559     my $dbh = $v->{Dbh};
 560     return unless $dbh;
 561     $dbh->disconnect();
 562 }
 563
 564 sub _db_transaction ($$) {
 565     my ($v, $fn) = @_;
 566     my $retries = 10;
 567     my $rv;
 568     my $dbh = $v->{Dbh};
 569 #print STDERR "DT entry\n";
 570     for (;;) {
 571 #print STDERR "DT loop\n";
 572         if (!eval {
 573             $rv = $fn->();
 574 #print STDERR "DT fn ok\n";
 575             1;
 576         }) {
 577 #print STDERR "DT fn error\n";
 578             { local ($@); $dbh->rollback(); }
 579 #print STDERR "DT fn throwing\n";
 580             die $@;
 581         }
 582 #print STDERR "DT fn eval ok\n";
 583         if (eval {
 584             $dbh->commit();
 585 #print STDERR "DT commit ok\n";
 586             1;
 587         }) {
 588 #print STDERR "DT commit eval ok ",Dumper($rv);
 589             return $rv;
 590         }
 591 #print STDERR "DT commit throw?\n";
 592         die $@ if !--$retries;
 593 #print STDERR "DT loop again\n";
 594     }
 595 }
 596
 597 #---------- request object methods ----------
 598
 599 sub new_request {
 600     my ($classbase, $cgi, @extra) = @_;
 601     if (!ref $classbase) {
 602         $classbase = $classbase->new_verifier(@extra);
 603     } else {
 604         die if @extra;
 605     }
 606     my $r = {
 607         V => $classbase,
 608         S => $classbase->{S},
 609         Dbh => $classbase->{Dbh},
 610         Cgi => $cgi,
 611     };
 612     bless $r, ref $classbase;
 613 }
 614
 615 sub _ch ($$@) { # calls an application hook
 616     my ($r,$methname, @args) = @_;
 617     my $methfunc = $r->{S}{$methname};
 618     die "$methname ?" unless $methfunc;
 619     return $methfunc->($r->{Cgi}, $r, @args);
 620 }
 621
 622 sub _rp ($$@) {
 623     my ($r,$pnvb) = @_;
 624     my $pn = $r->{S}{$pnvb};
 625     my $p = scalar $r->_ch('get_param',$pn)
 626 }
 627
 628 sub _debug ($@) {
 629     my ($r,@args) = @_;
 630     $r->_ch('debug',@args);
 631 }
 632
 633 sub _get_path ($$) {
 634     my ($r,$keybase) = @_;
 635     my $leaf = $r->{S}{"${keybase}_path"};
 636     return $r->_absify_path($leaf);
 637 }
 638
 639 sub _absify_path ($$) {
 640     my ($v,$leaf) = @_;
 641     return $leaf if $leaf =~ m,^/,;
 642     my $dir = $v->{S}{dir};
 643     die "relying on cwd by default ?!  set dir" unless defined $dir;
 644     return "$dir/$leaf";
 645 }
 646
 647 sub _gt ($$) { my ($r, $t) = @_; return $r->_ch('gettext',$t); }
 648 sub _print ($$) { my ($r, @t) = @_; return $r->_ch('print', join '', @t); }
 649
 650 sub construct_cookie ($$$) {
 651     my ($r, $cooks) = @_;
 652     return undef unless $cooks;
 653     my $c = $r->{Cgi};
 654 my @ca = (-name => $r->{S}{cookie_name},
 655                              -value => $cooks,
 656                              -path => $r->{S}{cookie_path},
 657                              -domain => $r->_ch('get_cookie_domain'),
 658                              -expires => '+'.$r->{S}{login_timeout}.'s',
 659                              -secure => $r->{S}{encrypted_only});
 660     my $cookie = $c->cookie(@ca);
 661 #print STDERR "CC $r $c $cooks $cookie (@ca).\n";
 662     return $cookie;
 663 }
 664
 665 # pages/param-sets are
 666 #   n normal non-mutating page
 667 #   r retrieval of information for JS etc., non-mutating
 668 #   m mutating page
 669 #   u update of information by JS etc., mutating
 670 #   i login
 671 #   o logout
 672 #   O "you have just logged out" page load
 673
 674 # in cook and par,
 675 #    -         no value supplied (represented in code as $cookt='')
 676 #    n, nN     value not in our db
 677 #    t, tN     temporary value (in our db, no logged in user yet)
 678 #    y, yN     value corresponds to logged-in user
 679 # and, aggregated conditions:
 680 #    a, aN     anything including -
 681 #    x, xN     t or y
 682 # if N differs the case applies only when the two values differ
 683 # (eg,   a1 y2   does not apply when the logged-in value is supplied twice)
 684
 685 # "stale session" means request originates from a page from a login
 686 # session which has been revoked (eg by logout); "cleared session"
 687 # means request originates from a browser which has a different (or
 688 # no) cookie.
 689
 690     # Case analysis, cookie mode, app promises re mutate:
 691     # cook parm meth form
 692     #
 693     #  any -   POST  nrmuoi   bug or attack, fail
 694     #  any -   GET    rmuoi   bug or attack, fail
 695     #  any any GET     muoi   bug or attack, fail
 696     #  any t   any   nrmu     bug or attack, fail
 697     #
 698     #  -   -   GET         O  "just logged out" page
 699     #  (any other)         O  bug or attack, fail
 700     #
 701     #  a1  a2  POST      o    logout
 702     #                           if a1 is valid, revoke it
 703     #                           if a2 is valid, revoke it
 704     #                           delete cookie
 705     #                           redirect to "just logged out" page
 706     #                             (which contains link to login form)
 707     #
 708     #  -   t   POST       i   complain about cookies being disabled
 709     #                           (with link to login form)
 710     #
 711     #  t1  t1  POST       i   login (or switch user)
 712     #                           if bad
 713     #                             show new login form
 714     #                           if good
 715     #                             upgrade t1 to y1 in our db (setting username)
 716     #                             redirect to GET of remaining params
 717     #
 718     #  y1  a2  POST       i   complain about stale login form
 719     #                           revoke y1
 720     #                           show new login form
 721     #
 722     #  (other) POST       i   complain about stale login form
 723     #                           show new login form
 724     #
 725     #  t1  a2  ANY   nrmu     treat as  - a2 ANY
 726     #
 727     #  y   -   GET   n        cross-site link
 728     #                           show data
 729     #
 730     #  y   y   GET   nr       fine, show page or send data
 731     #  y   y   POST  nrmu     mutation is OK, do operation
 732     #
 733     #  y1  y2  GET   nr       request from stale page
 734     #                           do not revoke y2 as not RESTful
 735     #                           treat as   y1 n GET
 736     #
 737     #  y1  y2  POST  nrmu     request from stale page
 738     #                           revoke y2
 739     #                           treat as   y1 n POST
 740     #
 741     #  y   n   GET   n        intra-site link from stale page,
 742     #                           treat as cross-site link, show data
 743     #
 744     #  y   n   POST  n m      intra-site form submission from stale page
 745     #                           show "session interrupted"
 746     #                           with link to main data page
 747     #
 748     #  y   n   GET    r       intra-site request from stale page
 749     #                           fail
 750     #
 751     #  y   n   POST   r u     intra-site request from stale page
 752     #                           fail
 753     #
 754     #  -/n y2  GET   nr       intra-site link from cleared session
 755     #                           do not revoke y2 as not RESTful
 756     #                           treat as   -/n n GET
 757     #
 758     #  -/n y2  POST  nrmu     request from cleared session
 759     #                           revoke y2
 760     #                           treat as   -/n n POST
 761     #
 762     #  -/n -/n GET   n        cross-site link but user not logged in
 763     #                           show login form with redirect to orig params
 764     #                           generate fresh cookie
 765     #
 766     #  -/n n   GET    rmu     user not logged in
 767     #                           fail
 768     #
 769     #  -/n n   POST  n m      user not logged in
 770     #                           show login form
 771     #
 772     #  -/n n   POST   r u     user not logged in
 773     #                           fail
 774
 775 sub _check_divert_core ($) {
 776     my ($r) = @_;
 777
 778     my $srcdump = $r->_rp('srcdump_param_name');
 779     if ($srcdump) {
 780         die if $srcdump =~ m/\W/;
 781         return ({ Kind => 'SRCDUMP-'.uc $srcdump,
 782                   Message => undef,
 783                   CookieSecret => undef,
 784                   Params => { } });
 785     }
 786
 787     my $cooks = $r->_ch('get_cookie');
 788
 789     if ($r->{S}{encrypted_only} && !$r->_ch('is_https')) {
 790         return ({ Kind => 'REDIRECT-HTTPS',
 791                   Message => $r->_gt("Redirecting to secure server..."),
 792                   CookieSecret => undef,
 793                   Params => { } });
 794     }
 795
 796     my $meth = $r->_ch('get_method');
 797     my $parmh = $r->_rp('assoc_param_name');
 798     my $cookh = defined $cooks ? $r->hash($cooks) : undef;
 799
 800     my ($cookt,$cooku) = $r->_identify($cookh, $cooks);
 801     my $parms = (defined $cooks && defined $parmh && $parmh eq $cookh)
 802         ? $cooks : undef;
 803     my ($parmt) = $r->_identify($parmh, $parms);
 804
 805     $r->_debug("_c_d_c cookt=$cookt parmt=$parmt\n");
 806
 807     if ($r->_ch('is_logout')) {
 808         $r->_must_be_post();
 809         die unless $parmt;
 810         $r->_db_revoke($cookh);
 811         $r->_db_revoke($parmh);
 812         return ({ Kind => 'REDIRECT-LOGGEDOUT',
 813                   Message => $r->_gt("Logging out..."),
 814                   CookieSecret => '',
 815                   Params => { } });
 816     }
 817     if ($r->_ch('is_loggedout')) {
 818         die unless $meth eq 'GET';
 819         die if $cookt eq 'y';
 820         die if $parmt;
 821         return ({ Kind => 'SMALLPAGE-LOGGEDOUT',
 822                   Message => $r->_gt("You have been logged out."),
 823                   CookieSecret => '',
 824                   Params => { } });
 825     }
 826     if ($r->_ch('is_login')) {
 827         $r->_must_be_post();
 828         die unless $parmt;
 829         if (!$cookt && $parmt eq 'n') {
 830             return ({ Kind => 'SMALLPAGE-NOCOOKIE',
 831                       Message => $r->_gt("You do not seem to have cookies".
 832                                          " enabled.  You must enable cookies".
 833                                          " as we use them for login."),
 834                       CookieSecret => $r->_fresh_secret(),
 835                       Params => $r->chain_params() })
 836         }
 837         if (!$cookt || $cookt eq 'n' || $cookh ne $parmh) {
 838             $r->_db_revoke($cookh);
 839             return ({ Kind => 'LOGIN-STALE',
 840                       Message => $r->_gt("Stale session;".
 841                                          " you need to log in again."),
 842                       CookieSecret => $r->_fresh_secret(),
 843                       Params => { } })
 844         }
 845         die unless $parmt eq 't' || $parmt eq 'y';
 846         my ($username, $login_errormessage) = $r->_ch('login_ok');
 847         unless (defined $username && length $username) {
 848             $login_errormessage = $r->_gt("Incorrect username/password.")
 849                 if !$login_errormessage;
 850             return ({ Kind => 'LOGIN-BAD',
 851                       Message => $login_errormessage,
 852                       CookieSecret => $cooks,
 853                       Params => $r->chain_params() })
 854         }
 855         $r->_db_record_login_ok($parmh,$username);
 856         return ({ Kind => 'REDIRECT-LOGGEDIN',
 857                   Message => $r->_gt("Logging in..."),
 858                   CookieSecret => $cooks,
 859                   Params => $r->chain_params() });
 860     }
 861     if ($cookt eq 't') {
 862         $cookt = '';
 863     }
 864     die if $parmt eq 't';
 865
 866     if ($cookt eq 'y' && $parmt eq 'y' && $cookh ne $parmh) {
 867         $r->_db_revoke($parmh) if $meth eq 'POST';
 868         $parmt = 'n';
 869     }
 870
 871     if ($cookt ne 'y') {
 872         die unless !$cookt || $cookt eq 'n';
 873         die unless !$parmt || $parmt eq 'n' || $parmt eq 'y';
 874         my $news = $r->_fresh_secret();
 875         if ($meth eq 'GET') {
 876             return ({ Kind => 'LOGIN-INCOMINGLINK',
 877                       Message => $r->_gt("You need to log in."),
 878                       CookieSecret => $news,
 879                       Params => $r->chain_params() });
 880         } else {
 881             $r->_db_revoke($parmh);
 882             return ({ Kind => 'LOGIN-FRESH',
 883                       Message => $r->_gt("You need to log in."),
 884                       CookieSecret => $news,
 885                       Params => { } });
 886         }
 887     }
 888
 889     if (!$r->{S}{promise_check_mutate}) {
 890         if ($meth ne 'POST') {
 891             return ({ Kind => 'MAINPAGEONLY',
 892                       Message => $r->_gt('Entering via cross-site link.'),
 893                       CookieSecret => $cooks,
 894                       Params => { } });
 895             # NB caller must then ignore params & path!
 896             # if this is too hard they can spit out a small form
 897             # with a "click to continue"
 898         }
 899     }
 900
 901     die unless $cookt eq 'y';
 902     unless ($r->{S}{promise_check_mutate} && $meth eq 'GET') {
 903         die unless $parmt eq 'y';
 904         die unless $cookh eq $parmh;
 905     }
 906     $r->{ParmT} = $parmt;
 907     $r->{AssocSecret} = $cooks;
 908     $r->{UserOK} = $cooku;
 909 #print STDERR "C-D-C OK\n";
 910     return undef;
 911 }
 912
 913 sub chain_params ($) {
 914     my ($r) = @_;
 915     my %p = %{ $r->_ch('get_params') };
 916     foreach my $pncn (keys %{ $r->{S} }) {
 917         my $names;
 918         if ($pncn =~ m/_param_name$/) {
 919             my $name = $r->{S}{$pncn};
 920             die "$pncn ?" if ref $name;
 921             $names = [ $name ];
 922         } elsif ($pncn =~ m/_param_names$/) {
 923             $names = $r->{S}{$pncn};
 924         } else {
 925             next;
 926         }
 927         foreach my $name (@$names) {
 928             delete $p{$name};
 929         }
 930     }
 931     my $dummy_prefix = $r->{S}{dummy_param_name_prefix};
 932     foreach my $name (grep /^$dummy_prefix/, keys %p) {
 933         delete $p{$name};
 934     }
 935     die if exists $p{''};
 936     $p{''} = [ $r->_ch('get_path_info') ];
 937     return \%p;
 938 }
 939
 940 sub _identify ($$) {
 941     my ($r,$h,$s) = @_;
 942     # returns ($t,$username)
 943     # where $t is one of "t" "y" "n", or "" (for -)
 944     # either $s must be undef, or $h eq $r->hash($s)
 945
 946 #print STDERR "_identify\n";
 947     return '' unless defined $h && length $h;
 948 #print STDERR "_identify h=$h s=".(defined $s ? $s : '<undef>')."\n";
 949
 950     my $dbh = $r->{Dbh};
 951
 952     $dbh->do("DELETE FROM $r->{S}{assocdb_table}".
 953              " WHERE last < ?", {},
 954              time - $r->{S}{login_timeout});
 955
 956     my $row = $dbh->selectrow_arrayref("SELECT username, last".
 957                               " FROM $r->{S}{assocdb_table}".
 958                               " WHERE assochash = ?", {}, $h);
 959     if (defined $row) {
 960 #print STDERR "_identify h=$h s=$s YES @$row\n";
 961         my ($nusername, $nlast) = @$row;
 962         return ('y', $nusername);
 963     }
 964
 965     # Well, it's not in the database.  But maybe it's a hash of a
 966     # temporary secret.
 967
 968     return 'n' unless defined $s;
 969
 970     my ($keyt, $signature, $message, $noncet, $nonce) =
 971         $s =~ m/^(\d+)\.(\w+)\.((\d+)\.(\w+))$/ or die;
 972
 973     return 'n' if time > $noncet + $r->{S}{login_form_timeout};
 974
 975 #print STDERR "_identify noncet=$noncet ok\n";
 976
 977     my $keys = $r->_open_keys();
 978     while (my ($rkeyt, $rkey, $line) = $r->_read_key($keys)) {
 979 #print STDERR "_identify  search rkeyt=$rkeyt rkey=$rkey\n";
 980         last if $rkeyt < $keyt; # too far down in the file
 981         my $trysignature = $r->_hmac($rkey, $message);
 982 #print STDERR "_identify  search rkeyt=$rkeyt rkey=$rkey try=$trysignature\n";
 983         return 't' if $trysignature eq $signature;
 984     }
 985     # oh well
 986 #print STDERR "_identify NO\n";
 987
 988     $keys->error and die $!;
 989     return 'n';
 990 }
 991
 992 sub _db_revoke ($$) {
 993     # revokes $h if it's valid; no-op if it's not
 994     my ($r,$h) = @_;
 995
 996     my $dbh = $r->{Dbh};
 997
 998     $dbh->do("DELETE FROM $r->{S}{assocdb_table}".
 999              " WHERE assochash = ?", {}, $h);
1000 }
1001
1002 sub _db_record_login_ok ($$$) {
1003     my ($r,$h,$user) = @_;
1004     $r->_db_revoke($h);
1005     my $dbh = $r->{Dbh};
1006     $dbh->do("INSERT INTO $r->{S}{assocdb_table}".
1007              " (assochash, username, last) VALUES (?,?,?)", {},
1008              $h, $user, time);
1009 }
1010
1011 sub check_divert ($) {
1012     my ($r) = @_;
1013     if (exists $r->{Divert}) {
1014         return $r->{Divert};
1015     }
1016     my $dbh = $r->{Dbh};
1017     $r->{Divert} = $r->_db_transaction(sub { $r->_check_divert_core(); });
1018     $dbh->commit();
1019     $r->_debug(Data::Dumper->Dump([$r->{Divert}],[qw(divert)]));
1020     return $r->{Divert};
1021 }
1022
1023 sub get_divert ($) {
1024     my ($r) = @_;
1025     die "unchecked" unless exists $r->{Divert};
1026     return $r->{Divert};
1027 }
1028
1029 sub get_username ($) {
1030     my ($r) = @_;
1031     my $divert = $r->get_divert();
1032     return undef if $divert;
1033     return $r->{UserOK};
1034 }
1035
1036 sub url_with_query_params ($$;$) {
1037     my ($r, $params, $nonpagetype) = @_;
1038 #print STDERR "PARAMS ",Dumper($params);
1039     my $uri = URI->new($r->_ch('get_url'));
1040     $uri->path($uri->path() . $params->{''}[0]) if $params->{''};
1041     my @flatparams = flatten_params($params);
1042     if (defined $nonpagetype && $r->need_add_hidden('GET',$nonpagetype)) {
1043         push @flatparams, $r->{S}{assoc_param_name}, $r->secret_hidden_val();
1044     }
1045     $uri->query_form(@flatparams);
1046     return $uri->as_string();
1047 }
1048
1049 sub _cgi_header_args ($$@) {
1050     my ($r, $cookie, @ha) = @_;
1051     unshift @ha, qw(-type text/html);
1052     push @ha, (-cookie => $cookie) if defined $cookie;
1053 #print STDERR "_cgi_header_args ",join('|',@ha),".\n";
1054     return @ha;
1055 }
1056
1057 sub check_ok ($) {
1058     my ($r) = @_;
1059
1060     my ($divert) = $r->check_divert();
1061     return 1 if !$divert;
1062
1063     my $handled = $r->_ch('handle_divert',$divert);
1064     return 0 if $handled;
1065
1066     my $kind = $divert->{Kind};
1067     my $cookiesecret = $divert->{CookieSecret};
1068     my $params = $divert->{Params};
1069     my $cookie = $r->construct_cookie($cookiesecret);
1070
1071     if ($kind =~ m/^SRCDUMP-(\w+)$/) {
1072         $r->_ch('srcdump_dump', (lc $1));
1073         return 0;
1074     }
1075
1076     if ($kind =~ m/^REDIRECT-/) {
1077         # for redirects, we honour stored Params and Cookie,
1078         # as we would for non-divert
1079         if ($kind eq 'REDIRECT-LOGGEDOUT') {
1080             $params->{$r->{S}{loggedout_param_names}[0]} = [ 1 ];
1081         } elsif ($kind eq 'REDIRECT-LOGOUT') {
1082             $params->{$r->{S}{logout_param_names}[0]} = [ 1 ];
1083         } elsif ($kind =~ m/REDIRECT-(?:LOGGEDIN|HTTPS)/) {
1084         } else {
1085             die;
1086         }
1087         my $new_url = $r->url_with_query_params($params);
1088         if ($kind eq 'REDIRECT-HTTPS') {
1089             my $uri = URI->new($new_url);
1090             die unless $uri->scheme eq 'http';
1091             $uri->scheme('https');
1092             $new_url = $uri->as_string();
1093         }
1094         $r->_ch('do_redirect',$new_url, $cookie);
1095         return 0;
1096     }
1097
1098     if (defined $cookiesecret) {
1099         $params->{$r->{S}{assoc_param_name}} = [ $r->hash($cookiesecret) ];
1100     }
1101
1102     my ($title, @body);
1103     if ($kind =~ m/^LOGIN-/) {
1104         $title = $r->_gt('Login');
1105         push @body, $divert->{Message};
1106         push @body, $r->_ch('gen_login_form', $params);
1107     } elsif ($kind =~ m/^SMALLPAGE-/) {
1108         $title = $r->_gt('Not logged in');
1109         push @body, $divert->{Message};
1110         push @body, $r->_ch('gen_login_link', $params);
1111     } elsif ($kind =~ m/^MAINPAGEONLY$/) {
1112         $title = $r->_gt('Entering secure site.');
1113         push @body, $divert->{Message};
1114         push @body, $r->_ch('gen_postmainpage_form', $params);
1115     } else {
1116         die $kind;
1117     }
1118
1119     $r->_print($r->{Cgi}->header($r->_cgi_header_args($cookie)),
1120                $r->_ch('gen_start_html',$title),
1121                (join "\n", (@body,
1122                             $r->_ch('gen_footer_html'),
1123                             $r->_ch('gen_end_html'))));
1124     return 0;
1125 }
1126
1127 sub _random ($$) {
1128     my ($r, $bytes) = @_;
1129     my $v = $r->{V};
1130     my $rsf = $v->{RandomHandle};
1131     my $rsp = $r->{S}{random_source};
1132     if (!$rsf) {
1133         $v->{RandomHandle} = $rsf = new IO::File $rsp, '<' or die "$rsp $!";
1134 #print STDERR "RH $rsf\n";
1135     }
1136     my $bin;
1137     $!=0;
1138     read($rsf,$bin,$bytes) == $bytes or die "$rsp $!";
1139     my $out = unpack "H*", $bin;
1140 #print STDERR "_random out $out\n";
1141     return $out;
1142 }
1143
1144 sub _random_key ($) {
1145     my ($r) = @_;
1146 #print STDERR "_random_key\n";
1147     my $bytes = ($r->{S}{secretbits} + 7) >> 3;
1148     return $r->_random($bytes);
1149 }
1150
1151 sub _read_key ($$) {
1152     my ($r, $keys) = @_;
1153     # returns $gen_time_t, $key_value_in_hex, $complete_line
1154     while (<$keys>) {
1155         my ($gen, $k) = m/^(\d+) (\S+)$/ or die "$_ ?";
1156         my $age = time - $gen;
1157         next if $age > $r->{S}{key_rollover} &&
1158             $age > $r->{S}{login_form_timeout}*2;
1159         return ($gen, $k, $_);
1160     }
1161     return ();
1162 }
1163
1164 sub _open_keys ($) {
1165     my ($r) = @_;
1166     my $spath = $r->_get_path('keys');
1167     for (;;) {
1168 #print STDERR "_open_keys\n";
1169         my $keys = new IO::File $spath, 'r+';
1170         if ($keys) {
1171 #print STDERR "_open_keys open\n";
1172             stat $keys or die $!; # NB must not disturb stat _
1173             my $size = (stat _)[7];
1174             my $age = time - (stat _)[9];
1175 #print STDERR "_open_keys open size=$size age=$age\n";
1176             return $keys
1177                 if $size && $age <= $r->{S}{key_rollover} / 2;
1178 #print STDERR "_open_keys open bad\n";
1179         }
1180         # file doesn't exist, or is empty or too old
1181         if (!$keys) {
1182 #print STDERR "_open_keys closed\n";
1183             die "$spath $!" unless $!==&ENOENT;
1184             # doesn't exist, so create it just so we can lock it
1185             $keys = new IO::File $spath, 'a+';
1186             die "$keys $!" unless $keys;
1187             stat $keys or die $!; # NB must not disturb stat _
1188             my $size = (stat _)[7];
1189 #print STDERR "_open_keys created size=$size\n";
1190             next if $size; # oh someone else has done it, reopen and read it
1191         }
1192         # file now exists is empty or too old, we must try to replace it
1193         my $our_inum = (stat _)[1]; # last use of that stat _
1194         flock $keys, LOCK_EX or die "$spath $!";
1195         stat $spath or die "$spath $!";
1196         my $path_inum = (stat _)[1];
1197 #print STDERR "_open_keys locked our=$our_inum path=$path_inum\n";
1198         next if $our_inum != $path_inum; # someone else has done it
1199         # We now hold the lock!
1200 #print STDERR "_open_keys creating\n";
1201         my $newkeys = new IO::Handle;
1202         sysopen $newkeys, "$spath.new", O_CREAT|O_TRUNC|O_WRONLY, 0600
1203             or die "$spath.new $!";
1204         # we add the new key to the front which means it's always sorted
1205         print $newkeys time, ' ', $r->_random_key(), "\n" or die $!;
1206         while (my ($gen,$key,$line) = $r->_read_key($keys)) {
1207 #print STDERR "_open_keys copy1\n";
1208             print $newkeys, $line or die $!;
1209         }
1210         $keys->error and die $!;
1211         close $newkeys or die "$spath.new $!";
1212         rename "$spath.new", "$spath" or die "$spath: $!";
1213 #print STDERR "_open_keys installed\n";
1214         # that rename effective unlocks, since it makes the name refer
1215         #  to the new file which we haven't locked
1216         # we go round again opening the file at the beginning
1217         #  so that our caller gets a fresh handle onto the existing key file
1218     }
1219 }
1220
1221 sub _fresh_secret ($) {
1222     my ($r) = @_;
1223 #print STDERR "_fresh_secret\n";
1224
1225     my $keys = $r->_open_keys();
1226     my ($keyt, $key) = $r->_read_key($keys);
1227     die unless defined $keyt;
1228
1229     my $nonce = $r->_random_key();
1230     my $noncet = time;
1231     my $message = "$noncet.$nonce";
1232
1233     my $signature = $r->_hmac($key, $message);
1234     my $secret = "$keyt.$signature.$message";
1235 #print STDERR "FRESH $secret\n";
1236     return $secret;
1237 }
1238
1239 sub _hmac ($$$) {
1240     my ($r, $keyhex, $message) = @_;
1241     my $keybin = pack "H*", $keyhex;
1242     my $alg = $r->{S}{hash_algorithm};
1243 #print STDERR "hmac $alg\n";
1244     my $base = new Digest $alg;
1245 #print STDERR "hmac $alg $base\n";
1246     my $digest = new Digest::HMAC $keybin, $base;
1247 #print STDERR "hmac $alg $base $digest\n";
1248     $digest->add($message);
1249     return $digest->hexdigest();
1250 }
1251
1252 sub hash ($$) {
1253     my ($r, $message) = @_;
1254     my $alg = $r->{S}{hash_algorithm};
1255 #print STDERR "hash $alg\n";
1256     my $digest = new Digest $alg;
1257     $digest->add($message);
1258     return $digest->hexdigest();
1259 }
1260
1261 sub _assert_checked ($) {
1262     my ($r) = @_;
1263     die "unchecked" unless exists $r->{Divert};
1264 }
1265
1266 sub _is_post ($) {
1267     my ($r) = @_;
1268     my $meth = $r->_ch('get_method');
1269     return $meth eq 'POST';
1270 }
1271
1272 sub _must_be_post ($) {
1273     my ($r) = @_;
1274     my $meth = $r->_ch('get_method');
1275     die "mutating non-POST" if $meth ne 'POST';
1276 }
1277
1278 sub check_mutate ($) {
1279     my ($r) = @_;
1280     $r->_assert_checked();
1281     die if $r->{Divert};
1282     $r->_must_be_post();
1283 }
1284
1285 our %_resource_get_needs_secret_hidden =
1286     (map { $_ => 0 } qw(PAGE FRAME IFRAME SRCDUMP STYLESHEET FAVICON ROBOTS),
1287      map { $_ => 1 } qw(IMAGE SCRIPT AJAX-XML AJAX-JSON AJAX-OTHER));
1288
1289 sub update_get_need_add_hidden ($$;$) {
1290     my ($r, $reqtype, $value, $force) = @_;
1291     my $hash = ref $r
1292         ? ($r->{GetNeedsSecretHidden} ||= { })
1293         : \%_resource_get_needs_secret_hidden;
1294     return if !$force &&
1295         (exists $_resource_get_needs_secret_hidden{$reqtype} ||
1296          exists $hash->{$reqtype});
1297     $hash->{$reqtype} = $value;
1298 }
1299
1300 sub need_add_hidden ($$) {
1301     my ($r, $method, $reqtype) = @_;
1302     return 1 if $method ne 'GET';
1303     if (ref $r) {
1304         my $ent = $r->{GetNeedsSecretHidden}{$reqtype};
1305         return $ent if defined $ent;
1306     }
1307     my $ent = $_resource_get_needs_secret_hidden{$reqtype};
1308     return $ent if defined $ent;
1309     die "unsupported nonpage GET type $reqtype";
1310 }
1311
1312 sub check_nonpage ($$) {
1313     my ($r, $reqtype) = @_;
1314     $r->_assert_checked();
1315     return unless $r->resource_get_needs_secret_hidden($nonpagetype);
1316     return if $r->{ParmT};
1317     die "missing hidden secret parameter on nonpage request $nonpagetype";
1318 }
1319
1320 #---------- output ----------
1321
1322 sub secret_cookie_val ($) {
1323     my ($r) = @_;
1324     $r->_assert_checked();
1325     return defined $r->{AssocSecret} ? $r->{AssocSecret} : '';
1326 }
1327
1328 sub secret_hidden_val ($) {
1329     my ($r) = @_;
1330     $r->_assert_checked();
1331     return defined $r->{AssocSecret} ? $r->hash($r->{AssocSecret}) : '';
1332 }
1333
1334 sub secret_hidden_html ($) {
1335     my ($r) = @_;
1336     return $r->{Cgi}->hidden(-name => $r->{S}{assoc_param_name},
1337                              -default => $r->secret_hidden_val());
1338 }
1339
1340 sub secret_cookie ($) {
1341     my ($r) = @_;
1342     my $secret = $r->secret_cookie_val();
1343     return undef if !defined $secret;
1344 #print STDERR "SC\n";
1345     my $cookv = $r->construct_cookie($secret);
1346 #print STDERR "SC=$cookv\n";
1347     return $cookv;
1348 }
1349
1350 1;