pctb/dictionary-manager

   1 #!/usr/bin/wish
   2
   3 # helper program for OCR in PCTB upload client
   4
   5 # This is part of ypp-sc-tools, a set of third-party tools for assisting
   6 # players of Yohoho Puzzle Pirates.
   7 #
   8 # Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
   9 #
  10 # This program is free software: you can redistribute it and/or modify
  11 # it under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation, either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # This program is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  22 #
  23 # Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
  24 # are used without permission.  This program is not endorsed or
  25 # sponsored by Three Rings.
  26
  27
  28 # invocation:
  29 # OUT OF DATE
  30 #  run this without args
  31 #  then on stdin write
  32 #     one line which is a Tcl list for unk_{l,r} unk_contexts glyphsdone etc.
  33 #     the xpm in the format expected
  34 #  then expect child to exit 0, or write a single 0 byte to fd 4
  35 #  if it wrote a byte to fd 4, it can take another question
  36
  37
  38 #---------- library routines ----------
  39
  40 proc manyset {list args} {
  41     foreach val $list var $args {
  42         upvar 1 $var my
  43         set my $val
  44     }
  45 }
  46
  47 proc must_gets {f lvar} {
  48     upvar 1 $lvar l
  49     if {[gets $f l] < 0} { error "huh?" }
  50 }
  51
  52 proc must_gets_exactly {f expected} {
  53     must_gets $f got
  54     if {[string compare $expected $got]} { error "$expected $got ?" }
  55 }
  56
  57 proc read_counted {f var} {
  58     upvar 1 $var val
  59     must_gets $f count
  60     set val [read $f $count]
  61     must_gets $f eol
  62     if {[string length $eol]} { error "$eol ?" }
  63     debug "READ_COUNTED $count $var"
  64 }
  65
  66 proc puts_counted {f dvar} {
  67     upvar 1 $dvar d
  68     set count [string length $d]
  69     puts $f $count
  70     puts $f $d
  71     debug "PUTS_COUNTED $count $dvar"
  72 }
  73
  74 #---------- display core ----------
  75
  76 set mul 6
  77 set inter 1
  78
  79 set gotsh 20
  80 set csrh 20
  81 set ctxh 20
  82
  83 proc init_widgets {} {
  84     # idempotent
  85     global csrh gotsh ctxh
  86
  87     if {[winfo exists .d]} return
  88
  89     frame .d
  90
  91     image create bitmap image/main
  92     label .d.mi -image image/main -borderwidth 0
  93
  94     frame .d.csr -bg black -height $csrh
  95     frame .d.got -bg black -height $gotsh
  96     frame .d.ctx -bg black
  97
  98     image create bitmap image/cursor -data \
  99 {#define csr_width 11
 100 #define csr_height 11
 101 static unsigned char csr_bits[] = {
 102    0x20, 0x00, 0x20, 0x00, 0x20, 0x00, 0x21, 0x04, 0x22, 0x02, 0x25, 0x05,
 103    0xaa, 0x02, 0x74, 0x01, 0xa8, 0x00, 0x70, 0x00, 0x20, 0x00};
 104 }
 105
 106     frame .d.csr.csr
 107     label .d.csr.csr.l -image image/cursor -compound left
 108     entry .d.csr.csr.e -bd 0
 109     pack .d.csr.csr.l -side left
 110
 111     frame .d.mi.csr_0 -bg white -width 1
 112     frame .d.mi.csr_1 -bg white -width 1
 113     frame .d.pe
 114     frame .d.pe.grid
 115     button .d.pe.ok -text OK
 116     pack .d.pe.grid .d.pe.ok -side left
 117
 118     pack .d.mi .d.ctx -side top
 119     pack .d
 120
 121     frame .help
 122     pack .help
 123 }
 124
 125 proc resize_widgets_core {} {
 126     global mulcols mulrows csrh gotsh ctxh glyphsdone
 127     global unk_l unk_contexts
 128
 129     foreach w {.d.csr .d.got .d.ctx} {
 130         $w configure -width $mulcols
 131     }
 132
 133     eval destroy [winfo children .d.ctx]
 134 }
 135
 136 set last_ht {}
 137
 138 proc helptext {t} {
 139     global last_ht
 140     if {![string compare $t $last_ht]} return
 141     eval destroy [grid slaves .help]
 142     set y 0; foreach l $t {
 143         set x 0; foreach c $l {
 144             set w .help.at${x}x${y}
 145             label $w -text $c
 146             grid $w -row $y -column $x -padx 5
 147             incr x
 148         }
 149         incr y
 150     }
 151     set last_ht $t
 152 }
 153
 154 proc bind_key {k proc} {
 155     global keybindings
 156     bind . <Key-$k> $proc
 157     set keybindings($k) [expr {!![string length $proc]}]
 158 }
 159 proc unbind_all_keys {} {
 160     global keybindings
 161     foreach k [array names keybindings] { bind_key $k {} }
 162 }
 163
 164 #---------- database read and write common wrapper ----------
 165
 166 proc db_getsl {f} {
 167     if {[gets $f l] < 0} { error "unexpected db eof" }
 168     return $l
 169 }
 170
 171 proc read_database {fn} {
 172     global reqkind database database_fn
 173     upvar #0 database_magic/$reqkind magic
 174     catch { unset database }
 175
 176     set database_fn $fn
 177     if {![file exists $database_fn]} return
 178     set f [open $database_fn r]
 179     if {[string compare [db_getsl $f] $magic]} { error "$l $reqkind ?" }
 180
 181     read_database_header/$reqkind $f
 182     while 1 {
 183         set l1 [db_getsl $f]
 184
 185         if {![string length $l1]} continue
 186         if {[regexp {^\#} $l1]} continue
 187         if {![string compare . $l1]} break
 188
 189         read_database_entry/$reqkind $f $l1
 190     }
 191     close $f
 192 }
 193
 194 proc write_database {} {
 195     global reqkind database_fn database
 196     upvar #0 database_magic/$reqkind magic
 197
 198     set f [open $database_fn.new w]
 199     puts $f $magic
 200
 201     write_database_header/$reqkind $f
 202
 203     set ol {}
 204     foreach bm [array names database] {
 205         lappend ol [format_database_entry/$reqkind $bm $database($bm)]
 206     }
 207     foreach o [lsort $ol] {
 208         puts $f $o
 209     }
 210     puts $f "."
 211     close $f
 212     file rename -force $database_fn.new $database_fn
 213 }
 214
 215 proc required/char {} {
 216     global mulrows glyphsdone unk_l unk_r unk_contexts rows
 217
 218     must_gets stdin l
 219
 220     manyset [lrange $l 0 3] unk_l unk_r unk_contexts
 221     set glyphsdone [lrange $l 3 end]
 222     debug "GOT $l"
 223
 224     char_read_xpm stdin
 225
 226     resize_widgets_core
 227     foreach w {0 1} {
 228         .d.mi.csr_$w configure -height $mulrows
 229     }
 230     set maxh 0
 231     foreach {min max contexts got} $glyphsdone {
 232         show_context maxh $min $contexts
 233     }
 234     show_context maxh $unk_l $unk_contexts
 235     .d.ctx configure -height $maxh
 236     pack forget .d.pe
 237     pack .d.csr -side top -before .d.mi
 238     pack .d.got .d.ctx -side top -after .d.mi
 239
 240     read_database ./charset-$rows.txt
 241     draw_glyphsdone
 242     startup_cursor
 243 }
 244
 245 #========== PIXMAPS ==========
 246
 247 #---------- pixmap database read and write ----------
 248
 249 set database_magic/pixmap {# ypp-sc-tools pctb pixmaps v1}
 250
 251 proc read_database_header/pixmap {f} { }
 252 proc read_database_entry/pixmap {f def} {
 253     global database
 254
 255     set im ""
 256
 257     set p3 [db_getsl $f];       append im $p3    "\n"
 258     if {[string compare $p3 P3]} { error "$p3 ?" }
 259
 260     set wh [db_getsl $f];       append im $wh    "\n";   manyset $wh w h
 261     set depth [db_getsl $f];    append im $depth "\n"
 262
 263     for {set y 0} {$y < $h} {incr y} {
 264         set line [db_getsl $f]; append im $line  "\n"
 265     }
 266     set database($im) $def
 267 }
 268 proc write_database_header/pixmap {f} { puts $f "" }
 269 proc format_database_entry/pixmap {im def} {
 270     return "$def\n$im"
 271 }
 272
 273 #---------- pixmap display and input handling ----------
 274
 275 proc foreach_pixmap_col {var body} {
 276     global alloptions
 277     upvar 1 $var col
 278     for {set col 0} {$col < [llength $alloptions]/3} {incr col} {
 279         uplevel 1 $body
 280     }
 281 }
 282
 283 proc pixmap_select {ncol} {
 284     global alloptions
 285     debug "PIX SELECT $ncol [llength $alloptions]"
 286     foreach_pixmap_col col {
 287         if {$col==$ncol} continue
 288         .d.pe.grid.l$col selection clear 0 end
 289     }
 290     pixmap_maybe_ok
 291 }
 292 proc pixmap_maybe_ok {} {
 293     global alloptions pixmap_selcol pixmap_selrow
 294     set nsel 0
 295     foreach_pixmap_col col {
 296         set cs [.d.pe.grid.l$col curselection]
 297         incr nsel [llength $cs]
 298         set pixmap_selcol $col
 299         set pixmap_selrow [lindex $cs 0]
 300     }
 301     if {$nsel==1} {
 302         .d.pe.ok configure -state normal -command pixmap_ok
 303     } else {
 304         .d.pe.ok configure -state disabled -command {}
 305     }
 306 }
 307 proc pixmap_ok {} {
 308     global database ppm pixmap_selcol pixmap_selrow mainkind alloptions
 309     foreach_pixmap_col col {
 310         .d.pe.grid.l$col configure -state disabled
 311     }
 312     .d.pe.ok configure -state disabled
 313     helptext {{{ Processing }}}
 314     manyset [lrange $alloptions [expr {$pixmap_selcol*3}] end] \
 315         colname coldesc rows
 316     manyset [lrange $rows [expr {$pixmap_selrow*2}] end] \
 317         rowname rowdesc
 318     set result "$colname - $rowname"
 319     debug "UPDATE PIXMAP AS >$result<"
 320     set database($ppm) $result
 321     write_database
 322     done/$mainkind
 323 }
 324
 325 proc required/pixmap {} {
 326     global unk_what ppm mulcols alloptions
 327     must_gets stdin unk_what
 328     debug "GOT pixmap $unk_what"
 329     set ppm {}
 330     while 1 {
 331         must_gets stdin ppml
 332         if {![string length $ppml]} break
 333         append ppm $ppml "\n"
 334     }
 335     set data [exec pnmscale 2 << $ppm]
 336     image create photo image/main -data $data
 337
 338     set alloptions [exec ./yppsc-resolver-pixoptions $unk_what]
 339
 340     read_database ./pixmaps.txt
 341
 342     set mulcols [image width image/main]
 343     set mulrows [image height image/main]
 344     resize_widgets_core
 345     place forget .d.mi.csr_0
 346     place forget .d.mi.csr_1
 347
 348     pack forget .d.csr .d.got
 349     pack .d.pe -side top -before .d.mi -pady 10
 350
 351     eval destroy [winfo children .d.pe.grid]
 352     set col 0; foreach {colname coldesc rows} $alloptions {
 353         debug "INIT $col $colname \"$coldesc\""
 354         label .d.pe.grid.t$col -text $colname
 355         listbox .d.pe.grid.l$col
 356         foreach {rowname rowdesc} $rows {
 357             debug "INIT $col $colname \"$coldesc\" $rowname \"$rowdesc\""
 358             .d.pe.grid.l$col insert end $rowdesc
 359         }
 360         bind .d.pe.grid.l$col <<ListboxSelect>> [list pixmap_select $col]
 361         grid .d.pe.grid.t$col -column $col -row 0
 362         grid .d.pe.grid.l$col -column $col -row 1
 363         incr col
 364     }
 365     pixmap_maybe_ok
 366
 367     helptext {
 368         {{Indicate the correct parse of this image, and click OK.}}
 369     }
 370 }
 371
 372 #========== CHARACTER SET ==========
 373
 374 #---------- xpm input processor ----------
 375
 376 proc char_read_xpm {f} {
 377     global glyphsdone mul inter rhsmost_max unk_l unk_r mulcols mulrows
 378     global cols rows wordmap
 379
 380     set o {}
 381     set y -3
 382     while 1 {
 383         must_gets $f l
 384         if {![regexp {^"(.*)",$} $l dummy l]} {
 385             append o "$l\n"
 386             if {[regexp {^\}\;$} $l]} break
 387             continue
 388         }
 389         if {$y==-3} {
 390             manyset $l cols rows colours cpp
 391             if {$colours!=2 || $cpp!=1} { error "$l ?" }
 392
 393             set chop_l [expr {$unk_l - 80}]
 394             set chop_r [expr {$cols - $unk_l - 100}]
 395             if {$chop_l<0} { set chop_l 0 }
 396
 397             set unk_l [expr {$unk_l - $chop_l}]
 398             set unk_r [expr {$unk_r - $chop_l}]
 399             set ngd {}
 400             foreach {min max contexts got} $glyphsdone {
 401                 lappend ngd \
 402                     [expr {$min-$chop_l}] \
 403                     [expr {$max-$chop_l}] \
 404                     $contexts $got
 405             }
 406             set glyphsdone $ngd
 407
 408             set realcols $cols
 409             set cols [expr {$cols - $chop_l - $chop_r}]
 410             debug "NOW cols=$cols chop_l,r=$chop_l,$chop_r rows=$rows\
 411                 $unk_l $unk_r $ngd"
 412
 413             set mulcols [expr {$cols*$mul+$inter}]
 414             set mulrows [expr {$rows*$mul+$inter}]
 415             append o "\"$mulcols $mulrows 9 1\",\n"
 416             for {set x 0} {$x<$cols} {incr x} { set wordmap($x) 0 }
 417         } elseif {$y==-2} { # first pixel
 418             append o \
 419 "\"+ c #111\",
 420 \"a c #800\",
 421 \"A c #fcc\",
 422 \"b c #00c\",
 423 \"B c #fff\",
 424 \"u c #000\",
 425 \"U c #ff0\",
 426 \"q c #000\",
 427 \"Q c #ff0\",\n"
 428         } elseif {$y==-1} { # 2nd pixel but we've already printed ours
 429         } else {
 430             set ybit [expr {1<<$y}]
 431             set x 0
 432             set ol "\"+"
 433             set olh $ol
 434             if {$chop_r>=0} {
 435                 set l [string range $l $chop_l end-$chop_r]
 436             } else {
 437                 set l [string range $l $chop_l end]
 438                 append l [string repeat " " [expr -$chop_r]]
 439             }
 440             foreach c [split $l ""] {
 441                 set how "u"
 442                 if {$x >= $unk_l && $x <= $unk_r} {
 443                     set how q
 444                 } else {
 445                     set ab 0
 446                     foreach {min max contexts got} $glyphsdone {
 447                         set rhsmost_max $max
 448                         if {$x >= $min && $x <= $max} {
 449                             set how [lindex {a b} $ab]
 450                             break
 451                         }
 452                         set ab [expr {!$ab}]
 453                     }
 454                 }
 455                 switch -exact $c {
 456                     " " { set p $how }
 457                     "o" {
 458                         set p [string toupper $how]
 459                         incr wordmap($x) $ybit
 460                     }
 461                     default { error "$c ?" }
 462                 }
 463                 append ol "[string repeat $p [expr {$mul-$inter}]][
 464                          string repeat + $inter]"
 465                 append olh [string repeat + $mul]
 466                 incr x
 467             }
 468             set ole "\",\n"
 469             append ol $ole
 470             append olh $ole
 471             set olhn [string repeat $olh $inter]
 472             if {!$y} { append o $olhn }
 473             append o [string repeat $ol [expr {$mul-1}]]
 474             append o $olhn
 475         }
 476         incr y
 477     }
 478     set data [exec xpmtoppm << $o]
 479     image create photo image/main -data $data
 480 }
 481
 482 #---------- character set editor display ----------
 483
 484 proc show_context {maxhv x ctxs} {
 485     global mul
 486     upvar 1 $maxhv maxh
 487     set w .d.ctx.at$x
 488     if {[llength $ctxs]==1} { set fg blue } { set fg yellow }
 489     label $w -bg black -fg $fg -text [join $ctxs "/\n"] -justify left
 490     place $w -x [expr {($x-1)*$mul}] -y 0
 491     set wh [winfo reqheight $w]
 492     if {$wh > $maxh} { set maxh $wh }
 493 }
 494
 495 proc draw_glyphsdone {} {
 496     global glyphsdone mul inter
 497     eval destroy [winfo children .d.got]
 498     foreach {min max contexts got} $glyphsdone {
 499         frame .d.got.m$min -bd 0 -background \#888
 500         label .d.got.m$min.l -text "$got" -fg white -bg black -bd 0
 501         pack .d.got.m$min.l -padx 1 -pady 1
 502         place .d.got.m$min -x [expr {$min*$mul+$inter}] -y 0
 503     }
 504 }
 505
 506 proc startup_cursor {} {
 507     global cur_already cur_mode cur_0 cur_1 last_ht
 508     global glyphsdone unk_l unk_r
 509
 510     set cur_already [expr {[llength $glyphsdone]/4-1}]
 511     set cur_mode 1 ;# one of:   0 1 already text
 512
 513     set cur_0 $unk_l
 514     set cur_1 [expr {$unk_r+1}]
 515
 516     recursor
 517 }
 518
 519 #---------- character set runtime display and keystroke handling ----------
 520
 521 proc recursor/0 {} { recursor//01 0 }
 522 proc recursor/1 {} { recursor//01 1 }
 523 proc recursor//01 {z1} {
 524     global mul rhsmost_max cols glyphsdone
 525     upvar #0 cur_$z1 cur
 526     .d.csr.csr.l configure -text {adjust}
 527     place .d.csr.csr -x [expr {$cur*$mul - 7}]
 528     bind_key space { othercursor }
 529     bind_leftright_q cur_$z1 0 [expr {$cols-1}]
 530     if {[llength $glyphsdone]} {
 531         bind_key Tab { set cur_mode already; recursor }
 532     } else {
 533         bind_key Tab {}
 534     }
 535     bind_key Return {
 536         if {$cur_0 != $cur_1} {
 537             .d.csr.csr.e delete 0 end
 538             set cur_mode text
 539             recursor
 540         }
 541     }
 542     helptext {
 543         {{<- ->}   {move cursor, adjusting area to define}}
 544         {Space     {switch to moving other cursor}}
 545         {Return    {confirm location, enter letter(s)}}
 546         {Tab       {switch to correcting earlier ocr}}
 547         {Q         {quit and abandon OCR run}}
 548     }
 549 }
 550 proc othercursor {} {
 551     global cur_mode
 552     set cur_mode [expr {!$cur_mode}]
 553     recursor
 554 }
 555
 556 proc recursor/text {} {
 557     helptext {
 558         {Return   {confirm entry of new glyph}}
 559         {Escape   {abandon entry}}
 560     }
 561     unbind_all_keys
 562     .d.csr.csr.l configure -text {define:}
 563     pack .d.csr.csr.e -side left
 564     focus .d.csr.csr.e
 565     bind_key Return {
 566         set strq [.d.csr.csr.e get]
 567         if {[regexp -line {^(?:[!-[]|[]-~]|\\\\|\\x[0-9a-f]{2})+} $strq]} {
 568             RETURN_RESULT DEFINE "$cur_0 $cur_1 $strq"
 569         }
 570     }
 571     bind_key Escape {
 572         bind_key Escape {}
 573         pack forget .d.csr.csr.e
 574         set cur_mode 1
 575         recursor
 576     }
 577 }
 578
 579 proc recursor/already {} {
 580     global mul
 581     global glyphsdone
 582     global cur_already mul
 583     global glyphsdone cur_already mul
 584     .d.csr.csr.l configure -text {correct}
 585     set rmax [lindex $glyphsdone [expr {$cur_already*4}]]
 586     place .d.csr.csr -x [expr {$rmax*$mul-3}]
 587     bind_key Return {}
 588     bind_key space {}
 589     bind_leftright_q cur_already 0 [expr {[llength $glyphsdone]/4-1}]
 590     bind_key Tab { bind_key Delete {}; set cur_mode 1; recursor }
 591     bind_key Delete {
 592         RETURN_RESULT DELETE [lrange $glyphsdone \
 593                                   [expr $cur_already*4] \
 594                                   [expr $cur_already*4+2]]
 595     }
 596     helptext {
 597         {{<- ->}   {move cursor, selecting glyph to correct}}
 598         {Del       {clear this glyph from the recognition database}}
 599         {Tab       {switch to selecting area to define as new glyph}}
 600         {Q         {quit and abandon OCR run}}
 601     }
 602 }
 603
 604 proc bind_leftright_q {var min max} {
 605     bind_key Left  [list leftright $var $min $max -1]
 606     bind_key Right [list leftright $var $min $max +1]
 607     bind_key q     {
 608         puts stderr "\nCharacter resolver quitting as you requested."
 609         exit 1
 610     }
 611 }
 612 proc leftright {var min max inc} {
 613     upvar #0 $var v
 614     set vnew $v
 615     incr vnew $inc
 616     if {$vnew < $min || $vnew > $max} return
 617     set v $vnew
 618     recursor
 619 }
 620
 621 proc recursor {} {
 622     global csrh cur_mode cur_0 cur_1 mul
 623     foreach z1 {0 1} {
 624         place .d.mi.csr_$z1 -y 0 -x [expr {[set cur_$z1] * $mul}]
 625     }
 626     recursor/$cur_mode
 627 }
 628
 629 #---------- character database read and write ----------
 630
 631 # OUT OF DATE
 632 # database format:
 633 # series of glyphs:
 634 #   <context> <ncharacters> <hex>...
 635 #   width
 636 #   <hex-bitmap>
 637
 638 # $database($context 0x<bits> 0x<bits>...) = $hex
 639
 640 set database_magic/char {# ypp-sc-tools pctb font v1}
 641
 642 proc read_database_header/char {f} {
 643     global rows
 644     if {([db_getsl $f])+0 != $rows} { error "wrong h ?" }
 645 }
 646 proc read_database_entry/char {f context} {
 647     global database
 648     set bm $context
 649     set strq [db_getsl $f]
 650     while 1 {
 651         set l [db_getsl $f]
 652         if {![string length $l]} break
 653         lappend bm [format %x 0x$l]
 654     }
 655     set database($bm) $strq
 656 }
 657
 658 proc write_database_header/char {f} {
 659     global rows
 660     puts $f "$rows\n"
 661 }
 662 proc format_database_entry/char {bm strq} {
 663     global database rows
 664     set o "[lindex $bm 0]\n$strq\n"
 665     foreach x [lrange $bm 1 end] { append o "$x\n" }
 666     return $o
 667 }
 668
 669 proc dbkey {ctx l r} {
 670     global wordmap
 671     set bm $ctx
 672     for {set x $l} {$x <= $r} {incr x} {
 673         lappend bm [format %x $wordmap($x)]
 674     }
 675     return $bm
 676 }
 677
 678 proc update_database/DEFINE {c0 c1 strq} {
 679     global glyphsdone unk_l unk_contexts wordmap database
 680     if {$c0 > $c1} { manyset [list $c0 $c1] c1 c0 }
 681     if {$c0 == $unk_l} {
 682         set ncontexts $unk_contexts
 683     } else {
 684         foreach {l r contexts got} $glyphsdone {
 685             if {$l==$c0} { set ncontexts $contexts; break }
 686         }
 687         if {![info exists ncontexts]} {
 688             puts stderr "must start at letter LHS!"
 689             return
 690         }
 691     }
 692     incr c1 -1
 693     foreach c $ncontexts {
 694         set bm [dbkey $c $c0 $c1]
 695         set database($bm) $strq
 696     }
 697     write_database
 698 }
 699
 700 proc update_database/DELETE {l r ctxs} {
 701     global database
 702     foreach ctx $ctxs {
 703         set bm [dbkey $ctx $l $r]
 704         catch { unset database($bm) }
 705     }
 706     write_database
 707 }
 708
 709 proc RETURN_RESULT {how what} {
 710     global mainkind
 711     place forget .d.csr.csr
 712     pack forget .d.csr.csr.e
 713     helptext {{{ Processing }}}
 714     unbind_all_keys
 715     update idletasks
 716     debug "$how $what"
 717     eval update_database/$how $what
 718     done/$mainkind
 719 }
 720
 721 #========== server for approving updates ==========
 722
 723 proc remote-serv-log {dict pirate file event} {
 724     global remoteserv_logf
 725     set t [clock format [clock seconds] -format {%Y-%m-%d %H:%M:%S %Z}]
 726     set s [format "%s %-6s %-31s %s %s\n" \
 727                $t $dict $pirate [file tail $file] $event]
 728     puts -nonewline $remoteserv_logf $s
 729 }
 730
 731 proc remote-serv/list {} {
 732     global dropdir
 733     foreach file [glob -nocomplain -type f -directory $dropdir _update.*.rdy] {
 734         puts yes
 735         puts $file
 736         set f [open $file]
 737         set d [read $f]
 738         close $f
 739         puts_counted stdout d
 740     }
 741     puts end
 742 }
 743
 744 proc remote-serv/take {yesno file dict} {
 745     global dropdir dictdir rows reqkind database
 746     set rows ""
 747     debug "TAKE [list $yesno $file $dict]"
 748     read_counted stdin pirate
 749     read_counted stdin key
 750     read_counted stdin val
 751
 752     must_gets_exactly stdin confirmed
 753
 754     if {![string compare pixmap $dict]} {
 755         set reqkind pixmap
 756         debug "DICT PIXMAP"
 757     } elseif {[regexp {^(char)([1-9]\d*)$} $dict dummy reqkind rows]} {
 758         debug "DICT CHAR rqk=$reqkind r=$rows."
 759     } else {
 760         error "$dict ?"
 761     }
 762
 763     if {$yesno} {
 764         read_database $dictdir/master-$dict.txt
 765         set database($key) $val
 766         write_database
 767         set desc approve
 768     } else {
 769         set desc reject
 770     }
 771     remote-serv-log $dict $pirate $file "$desc $reqkind $rows"
 772     file delete -force $file
 773
 774     puts done
 775 }
 776
 777 proc remote-serv/noop {} {
 778     puts ok
 779 }
 780
 781 set remoteserv_banner {ypp-sc-tools pctb remote-server v1}
 782
 783 proc main/remoteserv {} {
 784     global argv dropdir remoteserv_banner remoteserv_logf dictdir
 785     manyset $argv dropdir dictdir
 786     puts $remoteserv_banner
 787     set remoteserv_logf [open $dropdir/_dict.log a]
 788     fconfigure $remoteserv_logf -buffering line
 789     while 1 {
 790         flush stdout
 791         if {[gets stdin l] < 0} break
 792         eval remote-serv/$l
 793     }
 794 }
 795
 796 #========== updates approver ==========
 797
 798 proc puts_server {s} {
 799     global server
 800     debug ">> $s"
 801     puts $server $s
 802 }
 803 proc must_gets_server {lv} {
 804     upvar 1 $lv l
 805     global server
 806     must_gets $server l
 807     debug "<< $l"
 808 }
 809
 810 proc must_gets_exactly_server {expected} {
 811     must_gets_server got
 812     if {[string compare $expected $got]} { error "$expected $got ?" }
 813 }
 814
 815 proc regsub-data {exp subspec args} {
 816     global data
 817     if {![eval regsub $args -- [list $exp $data $subspec data]]} {
 818         error "$exp >$data< ?"
 819     }
 820 }
 821
 822 proc chop_counted {var} {
 823     upvar 1 $var val
 824     global data
 825     if {![regexp {^(0|[1-9]\d*)\n} $data dummy l]} { error "$data ?" }
 826     regsub-data {^.*\n} {} -line
 827     set val [string range $data 0 [expr {$l-1}]]
 828     set data [string range $data $l end]
 829     debug "CHOP_COUNTED $l $var"
 830     regsub-data {^\n} {}
 831 }
 832
 833 proc approve_decompose_data {specdata} {
 834     global data
 835     set data $specdata
 836
 837     regsub-data {^ypp-sc-tools dictionary update v1\n} {}
 838     uplevel 1 chop_counted pirate
 839     uplevel 1 chop_counted dict
 840     uplevel 1 chop_counted ctx
 841     uplevel 1 chop_counted def
 842     uplevel 1 chop_counted image
 843     uplevel 1 chop_counted key
 844     uplevel 1 chop_counted val
 845
 846     return [uplevel 1 {list $dict $def $image}]
 847 }
 848
 849 proc approve_compare {fd1 fd2} {
 850     manyset $fd1 file data; set sv1 [approve_decompose_data $data]
 851     manyset $fd2 file data; set sv2 [approve_decompose_data $data]
 852     return [string compare $sv1 $sv2]
 853 }
 854
 855 proc approve_showentry {ix file specdata} {
 856     global approve_ixes
 857
 858     approve_decompose_data $specdata
 859
 860     set wb .app.e$ix
 861
 862     frame $wb-inf
 863     label $wb-inf.who -text $pirate
 864
 865     entry $wb-inf.file -font fixed -relief flat
 866     $wb-inf.file insert end [file tail $file]
 867     $wb-inf.file configure -state readonly -width -1
 868
 869     pack $wb-inf.who $wb-inf.file -side top
 870
 871     frame $wb-def
 872     label $wb-def.scope -text "$dict $ctx"
 873     label $wb-def.def -text $def
 874     pack $wb-def.scope $wb-def.def -side bottom
 875
 876     set ppm [exec pnmscale 2 << $image]
 877     image create photo approve/$ix -data $ppm
 878     label $wb-image -image approve/$ix -bd 2 -relief sunken
 879
 880     frame $wb-act
 881     button $wb-act.rej -text Reject -command [list approve_reject $ix]
 882     pack $wb-act.rej
 883
 884     grid $wb-def $wb-image $wb-act $wb-inf -padx 3
 885     grid configure $wb-image -ipadx 3 -ipady 3
 886
 887     lappend approve_ixes $ix
 888 }
 889
 890 proc approve_approve_reject_one {ix yesno} {
 891     global approve_list server
 892     manyset [lindex $approve_list $ix] file tdata
 893     approve_decompose_data $tdata
 894     puts_server "take $yesno $file $dict"
 895     puts_counted $server pirate
 896     puts_counted $server key
 897     puts_counted $server val
 898     puts_server confirmed
 899     flush $server
 900     must_gets_exactly_server done
 901 }
 902
 903 proc approve_check_server {} {
 904     global server
 905     puts_server noop
 906     flush $server
 907     must_gets_exactly_server ok
 908 }
 909
 910 proc approve_reject {ix} {
 911     approve_check_server
 912     approve_approve_reject_one $ix 0
 913     approve_fetch_list
 914 }
 915
 916 proc approve_these {} {
 917     global approve_ixes
 918     approve_check_server
 919     foreach ix $approve_ixes { approve_approve_reject_one $ix 1 }
 920     approve_fetch_list
 921 }
 922
 923 proc approve_fetch_list {} {
 924     global server approve_list
 925     set approve_list {}
 926     puts_server list
 927     flush $server
 928     while 1 {
 929         must_gets_server more
 930         switch -exact $more {
 931             yes { }
 932             end { break }
 933             default { error "$more ?" }
 934         }
 935         must_gets_server file
 936         read_counted $server data
 937         lappend approve_list [list $file $data]
 938     }
 939
 940     if {![llength $approve_list]} { puts "Nothing (more) to approve."; exit 0 }
 941
 942     set approve_list [lsort -command approve_compare $approve_list]
 943     approve_show_page 0
 944 }
 945
 946 proc main/approve {} {
 947     global argv server remoteserv_banner data approve_list approve_page
 948     global userhost directory dictdir debug
 949
 950     if {[llength $argv] != 3} { error "wrong # args" }
 951     manyset $argv userhost directory dictdir
 952     set cmd [list tclsh $directory/dictionary-manager]
 953     if {$debug} { lappend cmd --debug-server }
 954     lappend cmd --remote-server-1 $directory $dictdir
 955     switch -glob $userhost {
 956         {} { }
 957         {* *} { set cmd $userhost }
 958         * { set cmd [append [list ssh $userhost] $cmd] }
 959     }
 960     lappend cmd 2>@ stderr
 961     set server [open |$cmd r+]
 962     must_gets_exactly_server $remoteserv_banner
 963
 964     button .left -text {<<} -command {approve_show_page -1}
 965     button .right -text {>>} -command {approve_show_page +1}
 966
 967     label .title -text {}
 968     frame .app -bd 2 -relief groove
 969     button .ok -text "Approve These" -command approve_these
 970     pack .title .app -side top
 971     pack .left -side left
 972     pack .right -side right
 973     pack .ok -side bottom
 974
 975     set approve_page 0
 976     approve_fetch_list
 977 }
 978
 979 proc approve_show_page {delta} {
 980     global approve_page approve_ixes approve_list userhost directory dictdir
 981
 982     eval destroy [winfo children .app]
 983     set approve_ixes {}
 984
 985     set per_page 2
 986     incr approve_page $delta
 987
 988     set ll [llength $approve_list]
 989     set npages [expr {($ll+$per_page-1)/$per_page}]
 990     if {$approve_page >= $npages} { incr approve_page -1 }
 991
 992     set page_start [expr {$approve_page*$per_page}]
 993     set page_end [expr {$page_start+$per_page-1}]
 994
 995     for {set ix $page_start} {$ix < $ll && $ix <= $page_end} {incr ix} {
 996         set fd [lindex $approve_list $ix]
 997         eval approve_showentry $ix $fd
 998     }
 999
1000     .title configure -text \
1001  "$userhost\n$directory => $dictdir\nPage [expr {$approve_page+1}]/$npages"
1002
1003     .left configure -state disabled
1004     .right configure -state disabled
1005     if {$approve_page>0} { .left configure -state normal }
1006     if {$approve_page<$npages-1} { .right configure -state normal }
1007 }
1008
1009 #========== main program ==========
1010
1011 proc main/default {} {
1012     puts stderr "Do not run this program directly."
1013     exit 12
1014 }
1015 proc done/default {} {
1016 }
1017
1018 proc required {} {
1019     global reqkind
1020
1021     fileevent stdin readable {}
1022     fconfigure stdin -blocking yes
1023
1024     if {[gets stdin reqkind]<0} {
1025         if {[eof stdin]} { fconfigure stdin -blocking yes; exit 0 }
1026         return
1027     }
1028     init_widgets
1029
1030     required/$reqkind
1031 }
1032
1033 proc main/automatic {} {
1034     fconfigure stdin -blocking no
1035     fileevent stdin readable required
1036 }
1037 proc done/automatic {} {
1038     exec sh -c {printf \\0 >&4}
1039     main/automatic
1040 }
1041
1042 proc debug {m} { }
1043
1044 set mainkind default
1045 set ai 0
1046 set debug 0
1047 foreach arg $argv {
1048     incr ai
1049     switch -exact -- $arg {
1050         {--debug}           { set debug 1 }
1051         {--debug-server}    { proc debug {m} { puts stderr "DICT-MGR-SVR $m" }}
1052         {--noop-arg}        { }
1053         {--approve-updates} { set mainkind approve; break }
1054         {--automatic-1}     { set mainkind automatic }
1055         {--remote-server-1} { set mainkind remoteserv; break }
1056         {--automatic*} - {--remote-server}
1057                             { error "incompatible versions - install problem" }
1058         default             { error "huh $argv ?" }
1059     }
1060 }
1061 if {$debug} {
1062     proc debug {m} { puts stderr "DICT-MGR $m" }
1063 }
1064 set argv [lrange $argv $ai end]
1065
1066 main/$mainkind