# This is part of ypp-sc-tools, a set of third-party tools for assisting
# players of Yohoho Puzzle Pirates.
#
# Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.
#
# Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
# are used without permission.  This program is not endorsed or
# sponsored by Three Rings.

package CommodsDatabase;

# Valid calling sequences:
#    db_setocean('Midnight')
#  [ db_filename() => 'OCEAN-Midnight.db'  also OK at any later time ]
#  [ db_writer() ]                         helpful but not essential
#    db_connect()
#  [ db_onconflict(sub { .... }) ]         essential if just dieing is not OK
#    $dbh->do(...), $dbh->prepare(...), db_doall("stmt;stmt;"), etc.

use strict;
use warnings;

use DBI;
use POSIX;

use Commods;

BEGIN {
    use Exporter ();
    our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
    $VERSION     = 1.00;
    @ISA         = qw(Exporter);
    @EXPORT      = qw(&db_setocean &db_writer &db_connect $dbh
		      &db_filename &db_doall &db_onconflict);
    %EXPORT_TAGS = ( );

    @EXPORT_OK   = qw();
}

our $dbfn;
our $dbh;

sub db_setocean ($) {
    my ($oceanname) = @_;
    $dbfn= "OCEAN-$oceanname.db";
}
sub db_filename () {
    return $dbfn;
}

sub db_onconflict (&) {
    my ($conflictproc) = @_;
    $dbh->{HandleError}= sub {
	my ($emsg,$dbh,$val1) = @_;
	my $native_ecode= $dbh->err();
	&$conflictproc($emsg) if grep { $_ == $native_ecode } qw(5 6);
	# 5==SQLITE_BUSY, 6==SQLITE_LOCKED according to the SQLite3
	# API documentation, .../capi3ref.html#extended-result-codes.
	return 0; # RaiseError happens next.
    };
}

our $writerlockh;

sub db_writer () {
    my $lockfn= "Writer.lock";
    $writerlockh= new IO::File "$lockfn", "w" or die "$lockfn $!";

    my $flockall= pack 's!s!LLLLLL', F_WRLCK, SEEK_SET, 0,0,0,0,0,0;
    # should work everywhere to lock the whole file, provided that
    # l_type and l_whence are `short int' and come first in that order,
    # and that start, len and pid are no more than 64 bits each.

    my $r= fcntl($writerlockh, F_SETLKW, $flockall);
    $r or die "$lockfn fcntl $!";
}

sub db_connect () {
    $dbh= DBI->connect("dbi:SQLite:$dbfn",'','',
		       { AutoCommit=>0,
			 RaiseError=>1, ShowErrorStatement=>1,
			 unicode=>1 })
	or die "$dbfn $DBI::errstr ?";
    # default timeout is 30s which is plenty
}

sub db_doall ($) {
    foreach my $cmd (split /\;/, $_[0]) {
	$dbh->do("$cmd;") if $cmd =~ m/\S/;
    }
}

1;
