#!/usr/bin/perl
#
# A git daemon with an added userv security boundary.
#
# This was written by Tony Finch <dot@dotat.at>
# You may do anything with it, at your own risk.
# http://creativecommons.org/publicdomain/zero/1.0/

use strict;
use warnings;

use POSIX;
use Socket;
use Sys::Syslog;

sub ntoa {
    my $sockaddr = shift;
    return ('(local)') unless defined $sockaddr;
    my ($port,$addr) = sockaddr_in $sockaddr;
    $addr = inet_ntoa $addr;
    return ("[$addr]:$port",$addr,$port);
}
our ($client,$client_addr,$client_port) = ntoa getpeername STDIN;
our ($server,$server_addr,$server_port) = ntoa getsockname STDIN;
our ($service,$path,$host,$user);

openlog 'userv-git-daemon', 'pid', 'daemon';
sub fail { syslog 'err', "$client @_"; exit }

$SIG{ALRM} = sub { fail "timeout" };
alarm 30;

sub xread {
    my $length = shift; $_ = "";
    while ($length > length) {
        my $ret = sysread STDIN, $_, $length, length;
        fail "Expected $length bytes, got ".length
                            if defined $ret and $ret == 0;
        fail "read: $!" if not defined $ret and $! != EINTR and $! != EAGAIN;
    }
}
xread 4;
fail "Bad hex in packet length" unless m|^[0-9a-fA-F]{4}$|;
xread hex;
unless (($service,$path,$host) =
        m|^(git-[a-z-]+) /*([!-~]+)\0host=([!-~]+)\0$|) {
    s|[^ -~]+| |g;
    fail "Could not parse \"$_\""
}
our $uri = $_ = "git://$host/$path";
for my $cf (@ARGV) { do $cf }

fail "No user for $uri" unless defined $user;
syslog 'notice', "$client $service $uri";

my @opts = map "-D$_=${$::{$_}}",
        grep defined ${$::{$_}} && /^[a-z_]+$/, keys %::;

my @cmd = ('userv', @opts, $user, $service);
no warnings; # suppress errors to stderr
exec @cmd or fail "exec userv: $!";

# end
