chiark - git - mdw - stgit/blob - contrib/stgit.el

   1 ;; stgit.el: An emacs mode for StGit
   2 ;;
   3 ;; Copyright (C) 2007 David Kågedal <davidk@lysator.liu.se>
   4 ;;
   5 ;; To install: put this file on the load-path and place the following
   6 ;; in your .emacs file:
   7 ;;
   8 ;;    (require 'stgit)
   9 ;;
  10 ;; To start: `M-x stgit'
  11
  12 (defun stgit (dir)
  13   "Manage stgit patches"
  14   (interactive "DDirectory: \n")
  15   (switch-to-stgit-buffer (git-get-top-dir dir))
  16   (stgit-refresh))
  17
  18 (defun git-get-top-dir (dir)
  19   "Retrieve the top-level directory of a git tree."
  20   (let ((cdup (with-output-to-string
  21                 (with-current-buffer standard-output
  22                   (cd dir)
  23                   (unless (eq 0 (call-process "git" nil t nil
  24                                               "rev-parse" "--show-cdup"))
  25                     (error "cannot find top-level git tree for %s." dir))))))
  26     (expand-file-name (concat (file-name-as-directory dir)
  27                               (car (split-string cdup "\n"))))))
  28
  29 (defun switch-to-stgit-buffer (dir)
  30   "Switch to a (possibly new) buffer displaying StGit patches for DIR"
  31   (setq dir (file-name-as-directory dir))
  32   (let ((buffers (buffer-list)))
  33     (while (and buffers
  34                 (not (with-current-buffer (car buffers)
  35                        (and (eq major-mode 'stgit-mode)
  36                             (string= default-directory dir)))))
  37       (setq buffers (cdr buffers)))
  38     (switch-to-buffer (if buffers
  39                           (car buffers)
  40                         (create-stgit-buffer dir)))))
  41
  42 (defun create-stgit-buffer (dir)
  43   "Create a buffer for showing StGit patches.
  44 Argument DIR is the repository path."
  45   (let ((buf (create-file-buffer (concat dir "*stgit*")))
  46         (inhibit-read-only t))
  47     (with-current-buffer buf
  48       (setq default-directory dir)
  49       (stgit-mode)
  50       (setq buffer-read-only t))
  51     buf))
  52
  53 (defmacro stgit-capture-output (name &rest body)
  54   "Capture StGit output and show it in a window at the end"
  55   `(let ((output-buf (get-buffer-create ,(or name "*StGit output*")))
  56          (stgit-dir default-directory)
  57          (inhibit-read-only t))
  58      (with-current-buffer output-buf
  59        (erase-buffer)
  60        (setq default-directory stgit-dir)
  61        (setq buffer-read-only t))
  62      (let ((standard-output output-buf))
  63        ,@body)
  64      (with-current-buffer output-buf
  65        (set-buffer-modified-p nil)
  66        (setq buffer-read-only t)
  67        (if (< (point-min) (point-max))
  68            (display-buffer output-buf t)))))
  69 (put 'stgit-capture-output 'lisp-indent-function 1)
  70
  71 (defun stgit-run (&rest args)
  72   (apply 'call-process "stg" nil standard-output nil args))
  73
  74 (defun stgit-refresh ()
  75   "Update the contents of the stgit buffer"
  76   (interactive)
  77   (let ((inhibit-read-only t)
  78         (curline (line-number-at-pos))
  79         (curpatch (stgit-patch-at-point)))
  80     (erase-buffer)
  81     (insert "Branch: ")
  82     (stgit-run "branch")
  83     (stgit-run "series" "--description")
  84     (stgit-rescan)
  85     (if curpatch
  86         (stgit-goto-patch curpatch)
  87       (goto-line curline))))
  88
  89 (defface stgit-description-face
  90   '((((background dark)) (:foreground "tan"))
  91     (((background light)) (:foreground "dark red")))
  92   "The face used for StGit desriptions")
  93
  94 (defface stgit-top-patch-face
  95   '((((background dark)) (:weight bold :foreground "yellow"))
  96     (((background light)) (:weight bold :foreground "purple"))
  97     (t (:weight bold)))
  98   "The face used for the top patch names")
  99
 100 (defface stgit-applied-patch-face
 101   '((((background dark)) (:foreground "light yellow"))
 102     (((background light)) (:foreground "purple"))
 103     (t ()))
 104   "The face used for applied patch names")
 105
 106 (defface stgit-unapplied-patch-face
 107   '((((background dark)) (:foreground "gray80"))
 108     (((background light)) (:foreground "orchid"))
 109     (t ()))
 110   "The face used for unapplied patch names")
 111
 112 (defun stgit-rescan ()
 113   "Rescan the status buffer."
 114   (save-excursion
 115     (let ((marked ()))
 116       (goto-char (point-min))
 117       (while (not (eobp))
 118         (cond ((looking-at "Branch: \\(.*\\)")
 119                (put-text-property (match-beginning 1) (match-end 1)
 120                                   'face 'bold))
 121               ((looking-at "\\([>+-]\\)\\( \\)\\([^ ]+\\) *[|#] \\(.*\\)")
 122                (let ((state (match-string 1))
 123                      (patchsym (intern (match-string 3))))
 124                  (put-text-property
 125                   (match-beginning 3) (match-end 3) 'face
 126                   (cond ((string= state ">") 'stgit-top-patch-face)
 127                         ((string= state "+") 'stgit-applied-patch-face)
 128                         ((string= state "-") 'stgit-unapplied-patch-face)))
 129                  (put-text-property (match-beginning 4) (match-end 4)
 130                                     'face 'stgit-description-face)
 131                  (when (memq patchsym stgit-marked-patches)
 132                    (replace-match "*" nil nil nil 2)
 133                    (setq marked (cons patchsym marked)))))
 134               ((or (looking-at "stg series: Branch \".*\" not initialised")
 135                    (looking-at "stg series: .*: branch not initialized"))
 136                (forward-line 1)
 137                (insert "Run M-x stgit-init to initialise")))
 138         (forward-line 1))
 139       (setq stgit-marked-patches (nreverse marked)))))
 140
 141 (defvar stgit-mode-hook nil
 142   "Run after `stgit-mode' is setup.")
 143
 144 (defvar stgit-mode-map nil
 145   "Keymap for StGit major mode.")
 146
 147 (unless stgit-mode-map
 148   (setq stgit-mode-map (make-keymap))
 149   (suppress-keymap stgit-mode-map)
 150   (define-key stgit-mode-map " "   'stgit-mark)
 151   (define-key stgit-mode-map "\d" 'stgit-unmark)
 152   (define-key stgit-mode-map "?"   'stgit-help)
 153   (define-key stgit-mode-map "h"   'stgit-help)
 154   (define-key stgit-mode-map "p"   'previous-line)
 155   (define-key stgit-mode-map "n"   'next-line)
 156   (define-key stgit-mode-map "g"   'stgit-refresh)
 157   (define-key stgit-mode-map "r"   'stgit-rename)
 158   (define-key stgit-mode-map "e"   'stgit-edit)
 159   (define-key stgit-mode-map "c"   'stgit-coalesce)
 160   (define-key stgit-mode-map "N"   'stgit-new)
 161   (define-key stgit-mode-map "R"   'stgit-repair)
 162   (define-key stgit-mode-map "C"   'stgit-commit)
 163   (define-key stgit-mode-map "U"   'stgit-uncommit)
 164   (define-key stgit-mode-map ">"   'stgit-push-next)
 165   (define-key stgit-mode-map "<"   'stgit-pop-next)
 166   (define-key stgit-mode-map "P"   'stgit-push-or-pop)
 167   (define-key stgit-mode-map "G"   'stgit-goto)
 168   (define-key stgit-mode-map "="   'stgit-show)
 169   (define-key stgit-mode-map "D"   'stgit-delete))
 170
 171 (defun stgit-mode ()
 172   "Major mode for interacting with StGit.
 173 Commands:
 174 \\{stgit-mode-map}"
 175   (kill-all-local-variables)
 176   (buffer-disable-undo)
 177   (setq mode-name "StGit"
 178         major-mode 'stgit-mode
 179         goal-column 2)
 180   (use-local-map stgit-mode-map)
 181   (set (make-local-variable 'list-buffers-directory) default-directory)
 182   (set (make-local-variable 'stgit-marked-patches) nil)
 183   (set-variable 'truncate-lines 't)
 184   (run-hooks 'stgit-mode-hook))
 185
 186 (defun stgit-add-mark (patch)
 187   (let ((patchsym (intern patch)))
 188     (setq stgit-marked-patches (cons patchsym stgit-marked-patches))))
 189
 190 (defun stgit-remove-mark (patch)
 191   (let ((patchsym (intern patch)))
 192     (setq stgit-marked-patches (delq patchsym stgit-marked-patches))))
 193
 194 (defun stgit-marked-patches ()
 195   "Return the names of the marked patches."
 196   (mapcar 'symbol-name stgit-marked-patches))
 197
 198 (defun stgit-patch-at-point ()
 199   "Return the patch name on the current line"
 200   (save-excursion
 201     (beginning-of-line)
 202     (if (looking-at "[>+-][ *]\\([^ ]*\\)")
 203         (match-string-no-properties 1)
 204       nil)))
 205
 206 (defun stgit-patches-marked-or-at-point ()
 207   "Return the names of the marked patches, or the patch on the current line."
 208   (if stgit-marked-patches
 209       (stgit-marked-patches)
 210     (let ((patch (stgit-patch-at-point)))
 211       (if patch
 212           (list patch)
 213         '()))))
 214
 215 (defun stgit-goto-patch (patch)
 216   "Move point to the line containing PATCH"
 217   (let ((p (point)))
 218     (goto-char (point-min))
 219     (if (re-search-forward (concat "^[>+-][ *]" (regexp-quote patch) " ") nil t)
 220         (progn (move-to-column goal-column)
 221                t)
 222       (goto-char p)
 223       nil)))
 224
 225 (defun stgit-init ()
 226   "Run stg init"
 227   (interactive)
 228   (stgit-capture-output nil
 229    (stgit-run "init"))
 230   (stgit-refresh))
 231
 232 (defun stgit-mark ()
 233   "Mark the patch under point"
 234   (interactive)
 235   (let ((patch (stgit-patch-at-point)))
 236     (stgit-add-mark patch)
 237     (stgit-refresh))
 238   (next-line))
 239
 240 (defun stgit-unmark ()
 241   "Mark the patch on the previous line"
 242   (interactive)
 243   (forward-line -1)
 244   (let ((patch (stgit-patch-at-point)))
 245     (stgit-remove-mark patch)
 246     (stgit-refresh)))
 247
 248 (defun stgit-rename (name)
 249   "Rename the patch under point"
 250   (interactive (list (read-string "Patch name: " (stgit-patch-at-point))))
 251   (let ((old-name (stgit-patch-at-point)))
 252     (unless old-name
 253       (error "No patch on this line"))
 254     (stgit-capture-output nil
 255       (stgit-run "rename" old-name name))
 256     (stgit-refresh)
 257     (stgit-goto-patch name)))
 258
 259 (defun stgit-repair ()
 260   "Run stg repair"
 261   (interactive)
 262   (stgit-capture-output nil
 263    (stgit-run "repair"))
 264   (stgit-refresh))
 265
 266 (defun stgit-commit ()
 267   "Run stg commit."
 268   (interactive)
 269   (stgit-capture-output nil (stgit-run "commit"))
 270   (stgit-refresh))
 271
 272 (defun stgit-uncommit (arg)
 273   "Run stg uncommit. Numeric arg determines number of patches to uncommit."
 274   (interactive "p")
 275   (stgit-capture-output nil (stgit-run "uncommit" "-n" (number-to-string arg)))
 276   (stgit-refresh))
 277
 278 (defun stgit-push-next (npatches)
 279   "Push the first unapplied patch.
 280 With numeric prefix argument, push that many patches."
 281   (interactive "p")
 282   (stgit-capture-output nil (stgit-run "push" "-n"
 283                                        (number-to-string npatches)))
 284   (stgit-refresh))
 285
 286 (defun stgit-pop-next (npatches)
 287   "Pop the topmost applied patch.
 288 With numeric prefix argument, pop that many patches."
 289   (interactive "p")
 290   (stgit-capture-output nil (stgit-run "pop" "-n" (number-to-string npatches)))
 291   (stgit-refresh))
 292
 293 (defun stgit-applied-at-point ()
 294   "Is the patch on the current line applied?"
 295   (save-excursion
 296     (beginning-of-line)
 297     (looking-at "[>+]")))
 298
 299 (defun stgit-push-or-pop ()
 300   "Push or pop the patch on the current line"
 301   (interactive)
 302   (let ((patch (stgit-patch-at-point))
 303         (applied (stgit-applied-at-point)))
 304     (stgit-capture-output nil
 305        (stgit-run (if applied "pop" "push") patch))
 306     (stgit-refresh)))
 307
 308 (defun stgit-goto ()
 309   "Go to the patch on the current line"
 310   (interactive)
 311   (let ((patch (stgit-patch-at-point)))
 312     (stgit-capture-output nil
 313        (stgit-run "goto" patch))
 314     (stgit-refresh)))
 315
 316 (defun stgit-show ()
 317   "Show the patch on the current line"
 318   (interactive)
 319   (stgit-capture-output "*StGit patch*"
 320     (stgit-run "show" (stgit-patch-at-point))
 321     (with-current-buffer standard-output
 322       (goto-char (point-min))
 323       (diff-mode))))
 324
 325 (defun stgit-edit ()
 326   "Edit the patch on the current line"
 327   (interactive)
 328   (let ((patch (stgit-patch-at-point))
 329         (edit-buf (get-buffer-create "*StGit edit*"))
 330         (dir default-directory))
 331     (log-edit 'stgit-confirm-edit t nil edit-buf)
 332     (set (make-local-variable 'stgit-edit-patch) patch)
 333     (setq default-directory dir)
 334     (let ((standard-output edit-buf))
 335       (stgit-run "edit" "--save-template=-" patch))))
 336
 337 (defun stgit-confirm-edit ()
 338   (interactive)
 339   (let ((file (make-temp-file "stgit-edit-")))
 340     (write-region (point-min) (point-max) file)
 341     (stgit-capture-output nil
 342       (stgit-run "edit" "-f" file stgit-edit-patch))
 343     (with-current-buffer log-edit-parent-buffer
 344       (stgit-refresh))))
 345
 346 (defun stgit-new ()
 347   "Create a new patch"
 348   (interactive)
 349   (let ((edit-buf (get-buffer-create "*StGit edit*")))
 350     (log-edit 'stgit-confirm-new t nil edit-buf)))
 351
 352 (defun stgit-confirm-new ()
 353   (interactive)
 354   (let ((file (make-temp-file "stgit-edit-")))
 355     (write-region (point-min) (point-max) file)
 356     (stgit-capture-output nil
 357       (stgit-run "new" "-f" file))
 358     (with-current-buffer log-edit-parent-buffer
 359       (stgit-refresh))))
 360
 361 (defun stgit-create-patch-name (description)
 362   "Create a patch name from a long description"
 363   (let ((patch ""))
 364     (while (> (length description) 0)
 365       (cond ((string-match "\\`[a-zA-Z_-]+" description)
 366              (setq patch (downcase (concat patch (match-string 0 description))))
 367              (setq description (substring description (match-end 0))))
 368             ((string-match "\\` +" description)
 369              (setq patch (concat patch "-"))
 370              (setq description (substring description (match-end 0))))
 371             ((string-match "\\`[^a-zA-Z_-]+" description)
 372              (setq description (substring description (match-end 0))))))
 373     (cond ((= (length patch) 0)
 374            "patch")
 375           ((> (length patch) 20)
 376            (substring patch 0 20))
 377           (t patch))))
 378
 379 (defun stgit-delete (patch-names)
 380   "Delete the named patches"
 381   (interactive (list (stgit-patches-marked-or-at-point)))
 382   (if (zerop (length patch-names))
 383       (error "No patches to delete")
 384     (when (yes-or-no-p (format "Really delete %d patches? "
 385                                (length patch-names)))
 386       (stgit-capture-output nil
 387         (apply 'stgit-run "delete" patch-names))
 388       (stgit-refresh))))
 389
 390 (defun stgit-coalesce (patch-names)
 391   "Run stg coalesce on the named patches"
 392   (interactive (list (stgit-marked-patches)))
 393   (let ((edit-buf (get-buffer-create "*StGit edit*"))
 394         (dir default-directory))
 395     (log-edit 'stgit-confirm-coalesce t nil edit-buf)
 396     (set (make-local-variable 'stgit-patches) patch-names)
 397     (setq default-directory dir)
 398     (let ((standard-output edit-buf))
 399       (apply 'stgit-run "coalesce" "--save-template=-" patch-names))))
 400
 401 (defun stgit-confirm-coalesce ()
 402   (interactive)
 403   (let ((file (make-temp-file "stgit-edit-")))
 404     (write-region (point-min) (point-max) file)
 405     (stgit-capture-output nil
 406       (apply 'stgit-run "coalesce" "-f" file stgit-patches))
 407     (with-current-buffer log-edit-parent-buffer
 408       (stgit-refresh))))
 409
 410 (defun stgit-help ()
 411   "Display help for the StGit mode."
 412   (interactive)
 413   (describe-function 'stgit-mode))
 414
 415 (provide 'stgit)