chiark - git - mdw - sod/blob - src/module-parse.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Top-level parser for module syntax
   4 ;;;
   5 ;;; (c) 2010 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This file is part of the Sensible Object Design, an object system for C.
  11 ;;;
  12 ;;; SOD is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; SOD is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with SOD; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 (in-package #:sod)
  27
  28 ;;;--------------------------------------------------------------------------
  29 ;;; Toplevel syntax.
  30
  31 ;;; Type names.
  32
  33 (define-pluggable-parser module typename (scanner pset)
  34   ;; `typename' list[id] `;'
  35   (declare (ignore pset))
  36   (with-parser-context (token-scanner-context :scanner scanner)
  37     (parse (and "typename"
  38                 (skip-many ()
  39                   (seq ((id :id))
  40                     (if (gethash id *module-type-map*)
  41                         (cerror* "Type `~A' already defined" id)
  42                         (add-to-module *module*
  43                                        (make-instance 'type-item
  44                                                       :name id))))
  45                   #\,)
  46                 #\;))))
  47
  48 ;;; Fragments.
  49
  50 (define-pluggable-parser module code (scanner pset)
  51   ;; `code' id `:' item-name [constraints] `{' c-fragment `}'
  52   ;;
  53   ;; constraints ::= `[' list[constraint] `]'
  54   ;; constraint ::= item-name+
  55   ;; item-name ::= id | `(' id+ `)'
  56   (declare (ignore pset))
  57   (with-parser-context (token-scanner-context :scanner scanner)
  58     (labels ((kw ()
  59                (parse (seq ((kw :id))
  60                         (intern (frob-identifier kw) 'keyword))))
  61              (item ()
  62                (parse (or (kw)
  63                           (seq (#\( (names (list (:min 1) (kw))) #\))
  64                             names)))))
  65       (parse (seq ("code"
  66                    (reason (kw))
  67                    #\:
  68                    (name (item))
  69                    (constraints (? (seq (#\[
  70                                          (constraints (list (:min 1)
  71                                                         (list (:min 1)
  72                                                           (item))
  73                                                         #\,))
  74                                          #\])
  75                                      constraints)))
  76                    (fragment (parse-delimited-fragment scanner #\{ #\})))
  77                (add-to-module *module*
  78                               (make-instance 'code-fragment-item
  79                                              :fragment fragment
  80                                              :constraints constraints
  81                                              :reason reason
  82                                              :name name)))))))
  83
  84 ;;; External files.
  85
  86 (export 'read-module)
  87 (defun read-module (pathname &key (truename nil truep) location)
  88   "Parse the file at PATHNAME as a module, returning it.
  89
  90    This is the main entry point for parsing module files.  You may well know
  91    the file's TRUENAME already (e.g., because `probe-file' dropped it into
  92    your lap) so you can avoid repeating the search by providing it.
  93
  94    The LOCATION is the thing which wanted the module imported -- usually a
  95    `file-location' object, though it might be anything other than `t' which
  96    can be printed in the event of circular imports."
  97
  98   (setf pathname (merge-pathnames pathname
  99                                   (make-pathname :type "SOD" :case :common)))
 100   (unless truep (setf truename (truename pathname)))
 101   (define-module (pathname :location location :truename truename)
 102     (with-open-file (f-stream pathname :direction :input)
 103       (let* ((*readtable* (copy-readtable))
 104              (*package* (find-package '#:sod-user))
 105              (char-scanner (make-instance 'charbuf-scanner
 106                                           :stream f-stream))
 107              (scanner (make-instance 'sod-token-scanner
 108                                      :char-scanner char-scanner)))
 109         (with-default-error-location (scanner)
 110           (with-parser-context (token-scanner-context :scanner scanner)
 111             (multiple-value-bind (result winp consumedp)
 112                 (parse (skip-many ()
 113                           (seq ((pset (parse-property-set scanner))
 114                                 (nil (error ()
 115                                          (plug module scanner pset)
 116                                        (skip-until (:keep-end nil)
 117                                          #\; #\}))))
 118                             (check-unused-properties pset))))
 119               (declare (ignore consumedp))
 120               (unless winp (syntax-error scanner result)))))))))
 121
 122 (define-pluggable-parser module test (scanner pset)
 123   ;; `demo' string `;'
 124   (declare (ignore pset))
 125   (with-parser-context (token-scanner-context :scanner scanner)
 126     (parse (seq ("demo" (string :string) #\;)
 127              (format t ";; DEMO ~S~%" string)))))
 128
 129 (define-pluggable-parser module file (scanner pset)
 130   ;; `import' string `;'
 131   ;; `load' string `;'
 132   (declare (ignore pset))
 133   (flet ((common (name type what thunk)
 134            (find-file scanner
 135                       (merge-pathnames name
 136                                        (make-pathname :type type
 137                                                       :case :common))
 138                       what
 139                       thunk)))
 140     (with-parser-context (token-scanner-context :scanner scanner)
 141       (parse (or (seq ("import" (name :string) #\;)
 142                    (common name "SOD" "module"
 143                            (lambda (path true)
 144                              (handler-case
 145                                  (let ((module (read-module path
 146                                                             :truename true)))
 147                                    (when module
 148                                      (module-import module)
 149                                      (pushnew module
 150                                               (module-dependencies
 151                                                *module*))))
 152                                (file-error (error)
 153                                  (cerror* "Error reading module ~S: ~A"
 154                                           path error))))))
 155                  (seq ("load" (name :string) #\;)
 156                    (common name "LISP" "Lisp file"
 157                            (lambda (path true)
 158                              (handler-case
 159                                  (load true :verbose nil :print nil)
 160                                (error (error)
 161                                  (cerror* "Error loading Lisp file ~S: ~A"
 162                                           path error)))))))))))
 163
 164 ;;; Setting properties.
 165
 166 (define-pluggable-parser module set (scanner pset)
 167   ;; `set' list[property] `;'
 168   (with-parser-context (token-scanner-context :scanner scanner)
 169     (parse (and "set"
 170                 (lisp (let ((module-pset (module-pset *module*)))
 171                         (when pset
 172                           (pset-map (lambda (prop)
 173                                       (add-property
 174                                        module-pset
 175                                        (p-name prop) (p-value prop)
 176                                        :type (p-type prop)
 177                                        :location (p-location prop))
 178                                       (setf (p-seenp prop) t))
 179                                     pset))
 180                         (parse (skip-many (:min 0)
 181                                  (error (:ignore-unconsumed t)
 182                                      (parse-property scanner module-pset)
 183                                    (skip-until () #\, #\;))
 184                                  #\,))))
 185                 #\;))))
 186
 187 ;;; Lisp escape.
 188
 189 (define-pluggable-parser module lisp (scanner pset)
 190   ;; `lisp' s-expression `;'
 191   (declare (ignore pset))
 192   (with-parser-context (token-scanner-context :scanner scanner)
 193     (parse (seq ((sexp (if (and (eql (token-type scanner) :id)
 194                                 (string= (token-value scanner) "lisp"))
 195                            (let* ((stream (make-scanner-stream scanner))
 196                                   (sexp (read stream t)))
 197                              (scanner-step scanner)
 198                              (values sexp t t))
 199                            (values '((:id "lisp")) nil nil)))
 200                  #\;)
 201              (eval sexp)))))
 202
 203 ;;;--------------------------------------------------------------------------
 204 ;;; Class declarations.
 205
 206 (export 'class-item)
 207
 208 (define-pluggable-parser class-item initfrags (scanner class pset)
 209   ;; raw-class-item ::= frag-keyword `{' c-fragment `}'
 210   ;; frag-keyword ::= `init' | `teardown'
 211   (with-parser-context (token-scanner-context :scanner scanner)
 212     (parse (seq ((make (or (seq ("init") #'make-sod-class-initfrag)
 213                            (seq ("teardown") #'make-sod-class-tearfrag)))
 214                  (frag (parse-delimited-fragment scanner #\{ #\})))
 215              (funcall make class frag pset scanner)))))
 216
 217 (define-pluggable-parser class-item initargs (scanner class pset)
 218   ;; initarg-item ::= `initarg' declspec+ list[init-declarator]
 219   ;; init-declarator ::= declarator [`=' initializer]
 220   (with-parser-context (token-scanner-context :scanner scanner)
 221     (parse (seq ("initarg"
 222                  (base-type (parse-c-type scanner))
 223                  (nil (skip-many (:min 1)
 224                         (seq ((declarator (parse-declarator scanner
 225                                                             base-type))
 226                               (init (? (parse-delimited-fragment
 227                                         scanner #\= (list #\; #\,)
 228                                         :keep-end t))))
 229                           (make-sod-user-initarg class
 230                                                  (cdr declarator)
 231                                                  (car declarator)
 232                                                  pset init scanner))
 233                         #\,))
 234                    #\;)))))
 235
 236 (defun parse-class-body (scanner pset name supers)
 237   ;; class-body ::= `{' class-item* `}'
 238   ;;
 239   ;; class-item ::= property-set raw-class-item
 240   (with-parser-context (token-scanner-context :scanner scanner)
 241     (make-class-type name)
 242     (let* ((duff nil)
 243            (class (make-sod-class name
 244                                   (restart-case
 245                                       (mapcar #'find-sod-class supers)
 246                                     (continue ()
 247                                       (setf duff t)
 248                                       (list (find-sod-class "SodObject"))))
 249                                   pset scanner))
 250            (nick (sod-class-nickname class)))
 251
 252       (labels ((parse-maybe-dotted-declarator (base-type)
 253                  ;; Parse a declarator or dotted-declarator, i.e., one whose
 254                  ;; centre is
 255                  ;;
 256                  ;; maybe-dotted-identifier ::= [id `.'] id
 257                  ;;
 258                  ;; A plain identifier is returned as a string, as usual; a
 259                  ;; dotted identifier is returned as a cons cell of the two
 260                  ;; names.
 261                  (parse-declarator
 262                   scanner base-type
 263                   :keywordp t
 264                   :kernel (parser ()
 265                             (seq ((name-a :id)
 266                                   (name-b (? (seq (#\. (id :id)) id))))
 267                               (if name-b (cons name-a name-b)
 268                                   name-a)))))
 269
 270                (parse-message-item (sub-pset type name)
 271                  ;; message-item ::=
 272                  ;;     declspec+ declarator -!- (method-body | `;')
 273                  ;;
 274                  ;; Don't allow a method-body here if the message takes a
 275                  ;; varargs list, because we don't have a name for the
 276                  ;; `va_list' parameter.
 277                  (let ((message (make-sod-message class name type
 278                                                   sub-pset scanner)))
 279                    (if (varargs-message-p message)
 280                        (parse #\;)
 281                        (parse (or #\; (parse-method-item sub-pset
 282                                                          type nick name))))))
 283
 284                (parse-method-item (sub-pset type sub-nick name)
 285                  ;; method-item ::=
 286                  ;;     declspec+ dotted-declarator -!- method-body
 287                  ;;
 288                  ;; method-body ::= `{' c-fragment `}' | `extern' `;'
 289                  (parse (seq ((body (or (seq ("extern" #\;) nil)
 290                                         (parse-delimited-fragment
 291                                          scanner #\{ #\}))))
 292                           (make-sod-method class sub-nick name type
 293                                            body sub-pset scanner))))
 294
 295                (parse-initializer ()
 296                  ;; initializer ::= `=' c-fragment
 297                  ;;
 298                  ;; Return a VALUE, ready for passing to a `sod-initializer'
 299                  ;; constructor.
 300                  (parse-delimited-fragment scanner #\= (list #\, #\;)
 301                                            :keep-end t))
 302
 303                (parse-slot-item (sub-pset base-type type name)
 304                  ;; slot-item ::=
 305                  ;;     declspec+ declarator -!- [initializer]
 306                  ;;             [`,' list[init-declarator]] `;'
 307                  ;;
 308                  ;; init-declarator ::= declarator [initializer]
 309                  (parse (and (seq ((init (? (parse-initializer))))
 310                                (make-sod-slot class name type
 311                                               sub-pset scanner)
 312                                (when init
 313                                  (make-sod-instance-initializer
 314                                   class nick name init sub-pset scanner)))
 315                              (skip-many ()
 316                                (seq (#\,
 317                                      (ds (parse-declarator scanner
 318                                                            base-type))
 319                                      (init (? (parse-initializer))))
 320                                  (make-sod-slot class (cdr ds) (car ds)
 321                                                 sub-pset scanner)
 322                                  (when init
 323                                    (make-sod-instance-initializer
 324                                     class nick (cdr ds) init
 325                                     sub-pset scanner))))
 326                              #\;)))
 327
 328                (parse-initializer-item (sub-pset must-init-p constructor)
 329                  ;; initializer-item ::=
 330                  ;;     [`class'] -!- list[slot-initializer] `;'
 331                  ;;
 332                  ;; slot-initializer ::= id `.' id [initializer]
 333                  (let ((parse-init (if must-init-p #'parse-initializer
 334                                        (parser () (? (parse-initializer))))))
 335                    (parse (and (skip-many ()
 336                                  (seq ((name-a :id) #\. (name-b :id)
 337                                        (init (funcall parse-init)))
 338                                    (funcall constructor class
 339                                             name-a name-b init
 340                                             sub-pset scanner))
 341                                  #\,)
 342                                #\;))))
 343
 344                (class-item-dispatch (sub-pset base-type type name)
 345                  ;; Logically part of `parse-raw-class-item', but the
 346                  ;; indentation was getting crazy.  We're currently at
 347                  ;;
 348                  ;; raw-class-item ::=
 349                  ;;     declspec+ (declarator | dotted-declarator) -!- ...
 350                  ;;   | other-items
 351                  ;;
 352                  ;; If the declarator is dotted then this must be a method
 353                  ;; definition; otherwise it might be a message or slot.
 354                  (cond ((not (typep type 'c-function-type))
 355                         (when (consp name)
 356                           (cerror*
 357                            "Method declarations must have function type")
 358                           (setf name (cdr name)))
 359                         (parse-slot-item sub-pset base-type type name))
 360                        ((consp name)
 361                         (parse-method-item sub-pset type
 362                                            (car name) (cdr name)))
 363                        (t
 364                         (parse-message-item sub-pset type name))))
 365
 366                (parse-raw-class-item (sub-pset)
 367                  ;; raw-class-item ::=
 368                  ;;     message-item
 369                  ;;   | method-item
 370                  ;;   | slot-item
 371                  ;;   | initializer-item
 372                  ;;   | initfrag-item
 373                  ;;
 374                  ;; Most of the above begin with declspecs and a declarator
 375                  ;; (which might be dotted).  So we parse that here and
 376                  ;; dispatch based on what we find.
 377                  (parse (or (plug class-item scanner class sub-pset)
 378                             (peek
 379                              (seq ((ds (parse-c-type scanner))
 380                                    (dc (parse-maybe-dotted-declarator ds))
 381                                    (nil (commit))
 382                                    (nil (class-item-dispatch sub-pset
 383                                                              ds
 384                                                              (car dc)
 385                                                              (cdr dc))))))
 386                             (and "class"
 387                                  (parse-initializer-item sub-pset t
 388                                   #'make-sod-class-initializer))
 389                             (parse-initializer-item sub-pset nil
 390                              #'make-sod-instance-initializer)))))
 391
 392         (parse (seq (#\{
 393                      (nil (skip-many ()
 394                             (seq ((sub-pset (parse-property-set scanner))
 395                                   (nil (parse-raw-class-item sub-pset)))
 396                               (check-unused-properties sub-pset))))
 397                      (nil (error () #\})))
 398                  (unless (finalize-sod-class class)
 399                    (setf duff t))
 400                  (unless duff
 401                    (add-to-module *module* class))))))))
 402
 403 (define-pluggable-parser module class (scanner pset)
 404   ;; `class' id `:' list[id] class-body
 405   ;; `class' id `;'
 406   (with-parser-context (token-scanner-context :scanner scanner)
 407     (parse (seq ("class"
 408                  (name :id)
 409                  (nil (or (seq (#\;)
 410                             (make-class-type name))
 411                           (seq ((supers (seq (#\: (ids (list () :id #\,)))
 412                                           ids))
 413                                 (nil (parse-class-body
 414                                       scanner
 415                                       pset name supers)))))))))))
 416
 417 ;;;----- That's all, folks --------------------------------------------------