chiark - git - mdw - odin-cgi/blob - lib/Odin.pm

   1 ### -*-perl-*-
   2
   3 package Odin;
   4
   5 use DBI;
   6 use Date::Parse;
   7 use Digest::SHA qw(sha256_hex);
   8 use MIME::Base64;
   9 use POSIX;
  10
  11 ###--------------------------------------------------------------------------
  12 ### Early utilities.
  13
  14 sub merge_hash (\%%) {
  15   my ($hashref, %defaults) = @_;
  16   for my $k (keys %defaults)
  17     { $hashref->{$k} = $defaults{$k} unless exists $hashref->{$k}; }
  18 }
  19
  20 ###--------------------------------------------------------------------------
  21 ### Configuration.
  22
  23 our $DSN = "dbi:Pg(pg_enable_utf8=>1):host=db";
  24 our $RETRY = 10;
  25 our @BACKOFF = (0.1, 10, 1.5, 0.5, 2.0);
  26
  27 our $BASEURL = "http://odin.gg/";
  28 our $STATIC = "http://odin.gg/";
  29
  30 our $SHORTURL_PATH = "u";
  31 our $PASTEBIN_PATH = "p";
  32
  33 our $URLMAXLEN = 1024;
  34 our @URLPAT = (
  35   qr{^https?://}
  36 );
  37
  38 our $PASTEMAXLEN = 1024*1024;
  39
  40 our %COOKIE_DEFAULTS = (
  41   -httponly => undef,
  42   -max_age => 3600
  43 );
  44
  45 our $ALPHA = "abcdefghijklmnopqrstuvwxyz";
  46 our $NUM = "0123456789";
  47 our $SAFECH = qr/^[-\w_.+]*$/;
  48
  49 our %GENPARAM = ();
  50 our %GENMAP = ();
  51 our %MAILDOM_POLICY = ();
  52 our $MAIL_QUALDOM;
  53
  54 our @MAIL_DEFGEN = "chars";
  55 our $MAIL_MAXGENTRY = 32;
  56
  57 our $MAIL_DEFDOMAIN = "odin.gg";
  58 our $MAIL_ADDRMAX_LIVE = 16384;
  59 our $MAIL_ADDRMAX_RESV = 32;
  60 our $MAIL_AGEMAX_RESV = 3600;
  61
  62 our ($SCHEME, $DOMAIN, $BASEPATH);
  63 our ($SHORTURL, $PASTEBIN);
  64
  65 ###--------------------------------------------------------------------------
  66 ### Miscellaneous utilities.
  67
  68 our $NOW;
  69 sub update_now () { $NOW = time; }
  70 update_now;
  71
  72 (our $PROG = $0) =~ s:^.*/::;
  73
  74 sub fail_cmdline ($$%) {
  75   my ($msg, $label, %args) = @_;
  76   print STDERR "$PROG: $msg\n";
  77   exit 1;
  78 }
  79
  80 our $FAILPROC = \&fail_cmdline;
  81
  82 sub fail ($;$%) {
  83   my ($msg, $label, %args) = @_;
  84   $FAILPROC->($msg, $label, %args);
  85 }
  86
  87 sub set_mason_failproc ($) {
  88   my ($m) = @_;
  89   $FAILPROC = sub {
  90     my ($msg, $label, %args) = @_;
  91     $m->clear_buffer;
  92     $m->comp($label, %args);
  93     $m->abort;
  94   };
  95 }
  96
  97 sub nice_name ($) {
  98   my ($s) = @_;
  99   $s =~ s/\W+//g;
 100   return lc $s;
 101 }
 102
 103 my %TIMEUNIT = (
 104   "" => 1,
 105   "s" => 1, "m" => 60, "h" => 3600,
 106   "d" => 86400, "w" => 604800
 107 );
 108 sub parse_time ($) {
 109   my ($date) = @_;
 110   return undef unless defined $date;
 111   if ($date =~ /^\+\s*(\d+)\s*([smhdw]?)\s*$/)
 112     { return $NOW + $1 * $TIMEUNIT{$2}; }
 113   my $t = str2time($date);
 114   defined $t or Odin::fail "invalid time `$date'";
 115   return $t;
 116 }
 117
 118 sub print_columns (@) {
 119   my @col = reverse @_;
 120   my @fmt = ();
 121   my @val = ();
 122   while (@col && $col[1] eq "") { splice @col, 0, 2; }
 123   my ($wd, $v) = splice @col, 0, 2;
 124   push @fmt, "%s"; push @val, $v;
 125   while (@col) {
 126     my ($wd, $v) = splice @col, 0, 2;
 127     push @fmt, "%-${wd}s";
 128     push @val, $v;
 129   }
 130   printf join("  ", reverse @fmt) . "\n", reverse @val;
 131 }
 132
 133 sub fmt_time ($) {
 134   my ($t) = @_;
 135   return $t == -1 ? "--" : strftime "%Y-%m-%d %H:%M:%S %z", localtime $t;
 136 }
 137
 138 ###--------------------------------------------------------------------------
 139 ### Database utilities.
 140
 141 sub open_db (@) {
 142   my @attr = @_;
 143   my $db = DBI->connect_cached($DSN, undef, undef, {
 144     PrintError => 0,
 145     RaiseError => 1,
 146     @attr
 147   });
 148
 149   my $drv = $db->{Driver}{Name};
 150   if ($drv eq "Pg") {
 151     $db->{private_odin_retry_p} = sub { $db->state =~ /^40[0P]01$/ };
 152   } elsif ($drv eq "SQLite") {
 153     $db->{private_odin_retry_p} = sub { $db->err == 5 };
 154   } else {
 155     $db->{private_odin_retry_p} = sub { 0 };
 156   }
 157
 158   return $db;
 159 }
 160
 161 sub xact (&$) {
 162   my ($body, $db) = @_;
 163   my @rv;
 164   my $exc;
 165
 166   my ($sleep, $maxsleep, $mult, $minvar, $maxvar) = @BACKOFF;
 167   for (my $i = 0; $i < $RETRY; $i++) {
 168     $db->begin_work;
 169     eval { @rv = $body->(); $db->commit; };
 170     $exc = $@;
 171     return @rv unless $exc;
 172     my $retryp = $db->{private_odin_retry_p}();
 173     eval { $db->rollback; };
 174     die $exc unless $retryp;
 175     my $t = $sleep * ($minvar + rand($maxvar - $minvar));
 176     $sleep *= $mult; $sleep = $max if $sleep > $max;
 177     select undef, undef, undef, $t;
 178   }
 179   die $exc;
 180 }
 181
 182 sub insert_record ($$%) {
 183   my ($db, $table, %fields) = @_;
 184   my @var = ();
 185   my @val = ();
 186
 187   for my $v (keys %fields) {
 188     push @var, $v;
 189     push @val, $fields{$v};
 190   }
 191   $db->do("INSERT INTO $table (" . join(", ", @var) . ")
 192            VALUES (" . join(", ", map { "?" } @var) . ")", undef, @val);
 193 }
 194
 195 ###--------------------------------------------------------------------------
 196 ### Sequence numbers and tagging.
 197
 198 sub next_seq ($$) {
 199   my ($db, $table) = @_;
 200   my ($seq) = $db->selectrow_array("SELECT seq FROM $table");
 201   die "no sequence number in $table" unless defined $seq;
 202   $db->do("UPDATE $table SET seq = ?", undef, $seq + 1);
 203   return $seq;
 204 }
 205
 206 my $ALPHABET =
 207   "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789";
 208 my $NALPHA = length $ALPHABET;
 209
 210 sub encode_tag ($) {
 211   my ($seq) = @_;
 212   my $tag = "";
 213   while ($seq) {
 214     $tag .= substr($ALPHABET, $seq % $NALPHA, 1);
 215     $seq = int $seq/$NALPHA;
 216   }
 217   return $tag;
 218 }
 219
 220 ###--------------------------------------------------------------------------
 221 ### HTTP utilities.
 222
 223 our %COOKIE;
 224 sub fetch_cookies ($) {
 225   my ($r) = @_;
 226
 227   %COOKIE = ();
 228   my $cookies = $r->header_in("Cookie");
 229   if (defined $cookies) {
 230     for my $kv (split /;/, $cookies) {
 231       my ($k, $v) = split /=/, $kv, 2;
 232       $k =~ s/^\s*(|\S|\S.*\S)\s*$/$1/;
 233       $v =~ s/^\s*(|\S|\S.*\S)\s*$/$1/;
 234       $v =~ s/\+/ /g;
 235       $v =~ s/\%([0-9a-f][0-9a-f])/chr hex $1/eg;
 236       $COOKIE{$k} = $v;
 237     }
 238   }
 239 }
 240
 241 sub bake_cookie ($$%) {
 242   my ($r, $cookie, %attr) = @_;
 243   merge_hash %attr, %COOKIE_DEFAULTS;
 244   my @attr = map {
 245     my $v = $attr{$_}; tr/_-/-/d;
 246     defined $v ? "$_=$v" : $_
 247   } keys %attr;
 248   $r->headers_out->add("Set-Cookie", join "; ", $cookie, @attr);
 249 }
 250
 251 sub path_info ($) {
 252   my ($r) = @_;
 253   return $ENV{PATH_INFO} // $r->path_info;
 254 }
 255
 256 ###--------------------------------------------------------------------------
 257 ### HTML utilities.
 258
 259 sub escapify ($$;$) {
 260   my ($m, $s, $mode) = @_;
 261   return $m->interp->apply_escapes($s, $mode // "h");
 262 }
 263
 264 ###--------------------------------------------------------------------------
 265 ### Access control.
 266
 267 our ($WHO, $WHOSURE);
 268 our ($WHOMATCH, $WHOCMP, $WHOPAT);
 269
 270 sub cgi_who ($) {
 271   my ($r) = @_;
 272   my $raddr = $ENV{REMOTE_ADDR} // $r->connection->remote_ip;
 273   $WHO = ":NET-$raddr"; $WHOSURE = 0;
 274   $WHOMATCH = "LIKE"; $WHOCMP = ":NET-\%"; $WHOPAT = qr/^:NET-/;
 275 }
 276
 277 sub cmdline_who () {
 278   $WHO = $ENV{USERV_USER}
 279     // ($< == $> && $ENV{USER})
 280     // @{[getpwuid $<]}[0]
 281     // die "nameless user";
 282   $WHOMATCH = "="; $WHOCMP = $WHO; $WHOPAT = qr/^\Q$WHO\E$/;
 283   $WHOSURE = 1;
 284 }
 285
 286 sub new_editkey () {
 287   open my $fh, "/dev/urandom" or die "open urandom: $!";
 288   sysread $fh, my $rand, 16;
 289   (my $edit = encode_base64 $rand) =~ tr:+/=\n:.-:d;
 290   return $edit, sha256_hex $edit;
 291 }
 292
 293 ###--------------------------------------------------------------------------
 294 ### URL shortening.
 295
 296 sub get_shorturl ($) {
 297   my ($tag) = @_;
 298
 299   my $db = open_db;
 300   my ($url) = $db->selectrow_array
 301     ("SELECT url FROM odin_shorturl WHERE tag = ?", undef, $tag);
 302   fail "tag `$tag' not found", ".notfound", tag => $tag unless defined $url;
 303   return $url;
 304 }
 305
 306 sub valid_url_p ($) {
 307   my ($url) = @_;
 308   return
 309     length $url < $URLMAXLEN &&
 310     scalar grep { $url =~ /$_/ } @URLPAT;
 311 }
 312
 313 sub new_shorturl ($) {
 314   my ($url) = @_;
 315
 316   valid_url_p $url or fail "invalid url", ".badurl", u => $url;
 317
 318   my $db = open_db;
 319   my $tag;
 320   xact {
 321     ($tag) = $db->selectrow_array
 322       ("SELECT tag FROM odin_shorturl WHERE owner $WHOMATCH ? AND url = ?",
 323        undef, $WHOCMP, $url);
 324     unless (defined $tag) {
 325       $tag = encode_tag(next_seq($db, "odin_shorturl_seq"));
 326       insert_record $db, "odin_shorturl",
 327         tag => $tag, stamp => $NOW, owner => $WHO, url => $url;
 328     }
 329   } $db;
 330   return $tag;
 331 }
 332
 333 sub check_shorturl_owner ($$) {
 334   my ($db, $tag) = @_;
 335
 336   my ($owner) = $db->selectrow_array
 337     ("SELECT owner FROM odin_shorturl WHERE tag = ?", undef, $tag);
 338   fail "tag `$tag' not found", ".notfound", tag => $tag
 339     unless defined $owner;
 340   fail "not owner of `$tag'", ".notowner", tag => $tag
 341     unless $owner =~ /$WHOPAT/;
 342 }
 343
 344 sub update_shorturl ($$) {
 345   my ($tag, $url) = @_;
 346
 347   my $db = open_db;
 348   xact {
 349     check_shorturl_owner $db, $tag;
 350     $db->do("UPDATE odin_shorturl SET url = ? WHERE tag = ?",
 351             undef, $url, $tag);
 352   } $db;
 353 }
 354
 355 sub delete_shorturl (@) {
 356   my (@tags) = @_;
 357
 358   my $db = open_db;
 359   xact {
 360     for my $tag (@tags) {
 361       check_shorturl_owner $db, $tag;
 362       $db->do("DELETE FROM odin_shorturl WHERE tag = ?", undef, $tag);
 363     }
 364   } $db;
 365 }
 366
 367 ###--------------------------------------------------------------------------
 368 ### Paste bin.
 369
 370 our %PASTEBIN_DEFAULTS = (
 371   title => "(untitled)",
 372   lang => "txt",
 373   content => ""
 374 );
 375 our @PASTEBIN_PROPS = keys %PASTEBIN_DEFAULTS;
 376 our $PASTEBIN_PROPCOLS = join ", ", @PASTEBIN_PROPS;
 377 our $PASTEBIN_PROPPLACES = join ", ", map "?", @PASTEBIN_PROPS;
 378
 379 sub new_pastebin (\%) {
 380   my ($new) = @_;
 381
 382   my $db = open_db;
 383   my ($editkey, $hash) = new_editkey;
 384   my $tag;
 385
 386   merge_hash %$new, %PASTEBIN_DEFAULTS;
 387   xact {
 388     $tag = encode_tag next_seq $db, "odin_pastebin_seq";
 389     insert_record $db, "odin_pastebin",
 390       tag => $tag, stamp => $NOW, edithash => $hash, owner => $WHO,
 391       %$new;
 392   } $db;
 393   return $tag, $editkey;
 394 }
 395
 396 sub get_pastebin ($$\%) {
 397   my ($db, $tag, $props) = @_;
 398
 399   (my $owner, my $hash, @{$props}{@PASTEBIN_PROPS}) =
 400     $db->selectrow_array("SELECT owner, edithash, $PASTEBIN_PROPCOLS
 401                           FROM odin_pastebin WHERE tag = ?",
 402                          undef, $tag);
 403   fail "tag `$tag' not found", ".notfound", tag => $tag
 404     unless defined $owner;
 405   return $owner, $hash;
 406 }
 407
 408 sub get_pastebin_check_owner ($$\%) {
 409   my ($db, $tag, $props) = @_;
 410
 411   my ($owner, $hash) = get_pastebin $db, $tag, %$props;
 412   fail "not owner of `$tag'", ".notowner", tag => $tag
 413     unless $WHOSURE && $WHO eq $owner;
 414 }
 415
 416 sub get_pastebin_check_editkey_or_owner ($$$\%) {
 417   my ($db, $tag, $editkey, $props) = @_;
 418
 419   if (!defined $editkey) { get_pastebin_check_owner $db, $tag, %$props; }
 420   else {
 421     my ($owner, $hash) = get_pastebin $db, $tag, %$props;
 422     fail "incorrect edit key for `$tag'", ".badhash", tag => $tag
 423       unless $hash eq sha256_hex $editkey;
 424   }
 425 }
 426
 427 sub rekey_pastebin ($) {
 428   my ($tag) = @_;
 429
 430   my $db = open_db;
 431   my $editkey;
 432   xact {
 433     get_pastebin_check_owner $db, $tag, my %hunoz;
 434     ($editkey, my $hash) = new_editkey;
 435     $db->do("UPDATE odin_pastebin SET edithash = ? WHERE tag = ?",
 436             undef, $hash, $tag);
 437   } $db;
 438   return $editkey;
 439 }
 440
 441 sub claim_pastebin ($$) {
 442   my ($tag, $editkey) = @_;
 443
 444   my $db = open_db;
 445   $WHOSURE or fail "you can't claim pastes", ".notsure";
 446   xact {
 447     get_pastebin_check_editkey_or_owner $db, $tag, $editkey, my %hunoz;
 448     $db->do("UPDATE odin_pastebin SET owner = ? WHERE tag = ?",
 449             undef, $WHO, $tag);
 450   } $db;
 451 }
 452
 453 sub update_pastebin ($$\%) {
 454   my ($tag, $editkey, $new) = @_;
 455
 456   my $db = open_db;
 457   my $editp = 0;
 458   xact {
 459     get_pastebin_check_editkey_or_owner $db, $tag, $editkey, my %old;
 460     for my $p (@PASTEBIN_PROPS) {
 461       if (!defined $new->{$p}) { $new->{$p} = $old{$p}; }
 462       else {
 463         $db->do("UPDATE odin_pastebin SET $p = ? WHERE tag = ?",
 464                 undef, $new->{$p}, $tag)
 465           unless $new->{$p} eq $old{$p};
 466         $editp = 1;
 467       }
 468     }
 469   } $db;
 470   return $editp;
 471 }
 472
 473 sub delete_pastebin (@) {
 474   my @a = @_;
 475   my $db = open_db;
 476   xact {
 477     while (@a) {
 478       (my $tag, my $editkey, @a) = @a;
 479       get_pastebin_check_editkey_or_owner $db, $tag, $editkey, my %hunoz;
 480       $db->do("DELETE FROM odin_pastebin WHERE tag = ?", undef, $tag);
 481     }
 482   } $db;
 483 }
 484
 485 sub tidy_pastebin_content ($) {
 486   my ($content) = @_;
 487   return undef unless defined $content;
 488   $content =~ tr/\r//d;
 489   $content =~ s/([^\n])\z/$1\n/;
 490   length $content <= $PASTEMAXLEN or
 491     fail "invalid paste content", ".badpaste";
 492   return $content;
 493 }
 494
 495 ###--------------------------------------------------------------------------
 496 ### Mail redirection utilities.
 497
 498 sub redir_query ($$$;$@) {
 499   my ($db, $dom, $owner, $cond, @args) = @_;
 500   return @{$db->selectall_arrayref
 501              ("SELECT lpart, expire, recip, comment
 502                FROM odin_mailredir WHERE dom = ? AND owner = ?" .
 503                (defined $cond ? " AND $cond" : "") . " " .
 504               "ORDER BY expire", undef, $dom, $owner, @args)};
 505 }
 506
 507 sub clear_redir_reservations ($) {
 508   my ($db) = @_;
 509   $db->do("DELETE FROM odin_mailredir WHERE
 510            st = 'reserved' AND expire < ?", undef,
 511           $NOW);
 512   $db->do("UPDATE odin_mailredir SET st = 'dormant', expire = -1
 513            WHERE st = 'live' AND expire <> -1 AND expire < ?", undef, $NOW);
 514 }
 515
 516 sub check_redir_limits ($) {
 517   my ($db) = @_;
 518   my %h = map { $_->[0] => $_->[1] }
 519     @{ $db->selectall_arrayref("SELECT st, COUNT(*) FROM odin_mailredir
 520                                 WHERE owner = ? GROUP BY st", undef,
 521                                $Odin::WHO) };
 522   for my $st (qw(live dormant reserved)) { $h{$st} //= 0; }
 523   $h{live} + $h{dormant} + $h{reserved} <= $MAIL_ADDRMAX_LIVE or
 524     Odin::fail "too many addresses claimed (see your sysadmin)";
 525   $h{reserved} <= $MAIL_ADDRMAX_RESV or
 526     Odin::fail "too many addresses reserved (time to release some)";
 527 }
 528
 529 sub gencls ($) {
 530   my ($g) = @_;
 531   return $GENMAP{$g} // die "configuration error: no generator class `$g'";
 532 }
 533
 534 sub default_generator_class ($) {
 535   my ($dom) = @_;
 536
 537   my $g = $MAILDOM_POLICY{$dom}{gen}[0] // $MAIL_DEFGEN[0];
 538   return gencls $g;
 539 }
 540
 541 sub get_generator_class ($$) {
 542   my ($dom, $g) = @_;
 543
 544   grep { $_ eq $g } @{$MAILDOM_POLICY{$dom}{gen} // \@MAIL_DEFGEN}
 545     or fail "domain `$dom' doesn't allow generator `$g'";
 546   return gencls $g;
 547 }
 548
 549 sub gen_redir_name ($$) {
 550   my ($db, $gen) = @_;
 551
 552   for (my $try = 0; $try < $MAIL_MAXGENTRY; $try++) {
 553     my $l = $gen->gen;
 554     return $l
 555       unless $db->selectrow_arrayref
 556         ("SELECT 1 FROM odin_mailredir WHERE lpart = ? AND dom = ?",
 557          undef, $l, $DOMAIN);
 558   }
 559   Odin::fail "failed to find unique local part";
 560 }
 561
 562 sub qualify_recip ($) {
 563   my ($r) = @_;
 564
 565   return $r =~ /\@/ || !defined $MAIL_QUALDOM ? $r : "$r\@$MAIL_QUALDOM";
 566 }
 567
 568 sub check_fixup_redir ($) {
 569   my ($r) = @_;
 570
 571   if (exists $r->{recip}) {
 572     $r->{recip} =~ /^[!-~]+$/ or fail "invalid recipient name `$r->{recip}'";
 573     $r->{recip} = qualify_recip $r->{recip};
 574   }
 575 }
 576
 577 sub new_redir ($$\%) {
 578   my ($dom, $gen, $r) = @_;
 579   my $db = open_db;
 580   my $l;
 581
 582   check_fixup_redir $r;
 583   Odin::xact {
 584     clear_redir_reservations $db;
 585     $l = Odin::gen_redir_name $db, $gen;
 586     insert_record $db, "odin_mailredir",
 587       lpart => $l, dom => $dom, owner => $WHO, st => 'live',
 588       recip => $r->{recip} // qualify_recip $Odin::WHO,
 589       expire => $r->{expire} // -1,
 590       comment => $r->{comment} // "";
 591     check_redir_limits $db;
 592   } $db;
 593   return $l;
 594 }
 595
 596 sub reserve_redir ($$$) {
 597   my ($dom, $gen, $n) = @_;
 598   my $db = open_db;
 599   my @l;
 600
 601   Odin::xact {
 602     clear_redir_reservations $db;
 603     @l = ();
 604     for (my $i = 0; $i < $n; $i++) { push @l, gen_redir_name $db, $gen; }
 605     for my $l (@l) {
 606       insert_record $db, "odin_mailredir",
 607         lpart => $l, dom => $dom, owner => $WHO,
 608         st => 'reserved', expire => $NOW + $MAIL_AGEMAX_RESV;
 609     }
 610     check_redir_limits $db;
 611   } $db;
 612   return @l;
 613 }
 614
 615 sub release_all_redir ($) {
 616   my ($dom) = @_;
 617   my $db = open_db;
 618
 619   my $st = $db->prepare("DELETE FROM odin_mailredir
 620                          WHERE dom = ? AND owner = ? AND st = 'reserved'");
 621   Odin::xact {
 622     $st->execute($dom, $WHO);
 623     $st->rows or Odin::fail "no reserved addresses";
 624   } $db;
 625 }
 626
 627 sub release_redir ($@) {
 628   my ($dom, @l) = @_;
 629   my $db = open_db;
 630
 631   my $st = $db->prepare("DELETE FROM odin_mailredir
 632                          WHERE lpart = ? AND dom = ? AND
 633                                owner = ? AND st = 'reserved'");
 634   Odin::xact {
 635     clear_redir_reservations $db;
 636     for my $l (@l) {
 637       $st->execute($l, $dom, $WHO);
 638       Odin::fail "local part `$l' not reserved" unless $st->rows;
 639     }
 640   } $db;
 641 }
 642
 643 sub disable_redir ($$) {
 644   my ($dom, @l) = @_;
 645   my $db = open_db;
 646
 647   my $st = $db->prepare("UPDATE odin_mailredir
 648                          SET st = 'dormant', expire = -1
 649                          WHERE lpart = ? AND dom = ? AND
 650                                owner = ? AND st = 'live'");
 651   Odin::xact {
 652     clear_redir_reservations $db;
 653     for my $l (@ARGV) {
 654       $st->execute($l, $dom, $WHO);
 655       Odin::fail "local part `$l' not live" unless $st->rows;
 656     }
 657   } $db;
 658 }
 659
 660 sub modify_redir ($$\%) {
 661   my ($dom, $l, $r) = @_;
 662   my $db = open_db;
 663
 664   check_fixup_redir $r;
 665   Odin::xact {
 666     clear_redir_reservations $db;
 667     my ($recip, $st) = $db->selectrow_array
 668       ("SELECT recip, st FROM odin_mailredir
 669         WHERE lpart = ? AND dom = ? AND owner = ?", undef,
 670        $l, $dom, $WHO);
 671     if (!defined $recip) { Odin::fail "unknown local part `$l'"; }
 672     elsif ($recip eq "") { $r->{recip} //= qualify_recip $WHO; }
 673     if ($st ne "live") { $r->{st} = "live"; $r->{expire} //= -1; }
 674     my @var = ();
 675     my @val = ();
 676     for my $v (keys %$r) {
 677       push @var, $v;
 678       push @val, $r->{$v};
 679     }
 680     @var or fail "nothing to change";
 681     $db->do("UPDATE odin_mailredir SET " .
 682             join(", ", map { "$_ = ?" } @var) . " " .
 683             "WHERE lpart = ? AND dom = ?", undef,
 684             @val, $l, $dom);
 685   } $db;
 686 }
 687
 688 ###--------------------------------------------------------------------------
 689 ### Simple option parser.
 690
 691 package Odin::OptParse;
 692
 693 sub new {
 694   my ($cls, @args) = @_;
 695   return bless {
 696     cur => "",
 697     args => \@args,
 698     opt => undef,
 699     ok => 1
 700   }, $cls;
 701 }
 702
 703 sub get {
 704   my ($me) = @_;
 705   if (!length $me->{cur}) {
 706     my $args = $me->{args};
 707     if (!@$args) { return undef; }
 708     elsif ($args->[0] =~ /^[^-]|^-$/) { return undef; }
 709     elsif ($args->[0] eq "--") { shift @$args; return undef; }
 710     $me->{cur} = substr shift @$args, 1;
 711   }
 712   my $o = $me->{opt} = substr $me->{cur}, 0, 1;
 713   $me->{cur} = substr $me->{cur}, 1;
 714   return $o;
 715 }
 716
 717 sub arg {
 718   my ($me) = @_;
 719   my $a;
 720   if (length $me->{cur}) { $a = $me->{cur}; $me->{cur} = ""; }
 721   elsif (@{$me->{args}}) { $a = shift @{$me->{args}}; }
 722   else { $a = undef; $me->err("option `-$me->{opt}' requires an argument"); }
 723   return $a;
 724 }
 725
 726 sub intarg {
 727   my ($me, $what, $min, $max) = @_;
 728   $what //= "option `-$me->{opt}'";
 729   defined (my $a = $me->arg) or return undef;
 730   if ($a !~ /^[-+]?\d+$/ ||
 731       (defined $min && $a < $min) ||
 732       (defined $max && $a > $max)) {
 733     $me->err("invalid value `$a' for $what");
 734     $a = undef;
 735   }
 736   return $a;
 737 }
 738
 739 sub rest { return @{$_[0]->{args}}; }
 740 sub ok { return $_[0]->{ok}; }
 741 sub bad { $_[0]->{ok} = 0; }
 742 sub err { $_[0]->bad; print STDERR "$PROG: $_[1]\n"; }
 743 sub unk { $_[0]->err("unknown option `-$_[0]->{opt}'"); }
 744
 745 ###--------------------------------------------------------------------------
 746 ### Parameter objects.
 747
 748 package Odin::Param;
 749 sub dflt { return $_[0]->{dflt}; }
 750
 751 package Odin::Param::Int;
 752 @ISA = qw(Odin::Param);
 753
 754 sub new {
 755   my ($cls, $dflt, $min, $max) = @_;
 756   return bless { dflt => $dflt, min => $min, max => $max }, $cls;
 757 }
 758
 759 sub check {
 760   my ($me, $v) = @_;
 761   return undef unless
 762     $v =~ /^[-+]?\d+$/ &&
 763     (!defined $me->{min} || $v >= $me->{min}) &&
 764     (!defined $me->{max} || $v <= $me->{max});
 765   return $v + 0;
 766 }
 767
 768 package Odin::Param::Str;
 769 @ISA = qw(Odin::Param);
 770
 771 sub new {
 772   my ($cls, $dflt, $rx, $minlen, $maxlen) = @_;
 773   return bless {
 774     dflt => $dflt,
 775     rx => defined $rx ? qr/$rx/ : qr//,
 776     minlen => $minlen,
 777     maxlen => $maxlen
 778   }, $cls;
 779 }
 780
 781 sub check {
 782   my ($me, $v) = @_;
 783   return undef unless
 784     $v =~ /$me->{rx}/ &&
 785     (!defined $me->{minlen} || length $v >= $me->{minlen}) &&
 786     (!defined $me->{maxlen} || length $v <= $me->{maxlen});
 787   return $v . "";
 788 }
 789
 790 ###--------------------------------------------------------------------------
 791 ### Name generators.
 792
 793 package Odin::Gen;
 794
 795 use Scalar::Util qw(blessed);
 796
 797 sub random {
 798   my ($me, $lim) = @_;
 799
 800   defined $me->{rand}
 801     or open $me->{rand}, "/dev/urandom"
 802     or die "open random: $!";
 803
 804   my $nb = 1; my $max = 255;
 805   while ($lim > $max) { $nb++; $max = ($max << 8) | 255; }
 806   my $thresh = $max - ($max%$lim);
 807
 808   for (;;) {
 809     sysread $me->{rand}, my $b, $nb
 810       or die "read random: $!";
 811     my $r = 0;
 812     for (my $i = 0; $i < $nb; $i++)
 813       { $r = ($r << 255) | ord substr $b, $i, 1; }
 814     return $r%$lim if $r < $thresh;
 815   }
 816 }
 817
 818 sub new {
 819   my ($cls, $dom, $param) = @_;
 820   my $pkg = \%::;
 821   for my $p (split /::/, $cls) { $pkg = \%{$pkg->{"${p}::"}}; }
 822
 823   my $label = ${$pkg->{LABEL}};
 824   my $plist = \@{$pkg->{PARAM}};
 825   my $gtmpl = $GENPARAM{$label};
 826   my $dtmpl = $MAILDOM_POLICY{$dom}{$label};
 827   my %pp = ();
 828
 829   for my $p (@$plist) {
 830     $pp->{$p} = 1;
 831     my $t = $dtmpl->{$p} // $gtmpl->{$p};
 832     if (blessed $t && $t->isa("Odin::Param")) {
 833       if (!exists $param->{$p}) { $param->{$p} = $t->dflt; }
 834       else {
 835         my $v = $t->check($param->{$p});
 836         Odin::fail "bad value `$param->{$p}' for $label parameter `$p'"
 837           unless defined $v;
 838         $param->{$p} = $v;
 839       }
 840     } else {
 841       if (exists $param->{$p})
 842         { Odin::fail "not allowed to set $label parameter `$p'"; }
 843       else
 844         { $param->{$p} = $t; }
 845     }
 846   }
 847   for my $p (keys %$param) {
 848     if (!$pp->{$p}) { Odin::fail "unknown $label parameter `$p'"; }
 849   }
 850
 851   my $me = bless { %$param }, $cls;
 852   $me->{rand} = undef;
 853   return $me;
 854 }
 855
 856 package Odin::Gen::Chars;
 857 @ISA = qw(Odin::Gen);
 858
 859 $LABEL = 'chars';
 860 @PARAM = qw(ichars mchars echars len);
 861
 862 $GENMAP{chars} = "Odin::Gen::Chars";
 863 $GENPARAM{chars} = {
 864   ichars => Odin::Param::Str->new($ALPHA, $SAFECH, 1, 255),
 865   mchars => Odin::Param::Str->new($ALPHA . $NUM, $SAFECH, 2, 255),
 866   echars => Odin::Param::Str->new($ALPHA . $NUM, $SAFECH, 2, 255),
 867   len => Odin::Param::Int->new(6, 2, 16)
 868 };
 869
 870 sub _pick {
 871   my ($me, $chars) = @_;
 872   return substr $chars, $me->random(length $chars), 1;
 873 }
 874
 875 sub gen {
 876   my ($me) = @_;
 877
 878   my $n = $me->{len};
 879
 880   my $s = "";
 881   if ($n) { $s .= $me->_pick($me->{ichars}); $n--; }
 882   while ($n > 1) { $s .= $me->_pick($me->{mchars}); $n--; }
 883   if ($n) { $s .= $me->_pick($me->{echars}); $n--; }
 884   if ($n) { die "INTERNAL can't count"; }
 885   return $s;
 886 }
 887
 888 package Odin::Gen::Words;
 889 @ISA = qw(Odin::Gen);
 890
 891 $LABEL = 'words';
 892 @PARAM = qw(wordlist delim nwords);
 893
 894 $GENMAP{words} = "Odin::Gen::Words";
 895 $GENPARAM{words} = {
 896   wordlist => "etc/words",
 897   delim => Odin::Param::Str->new(".", qr/^[-_.+]*$/, 1, 1),
 898   nwords => Odin::Param::Int->new(3, 2, 16)
 899 };
 900
 901 sub gen {
 902   my ($me) = @_;
 903   my @w = ();
 904
 905   if (!exists $me->{words}) {
 906     open my $f, $me->{wordlist} or die "open wordlist: $!";
 907     $me->{words} = [grep chomp, <$f>];
 908     close $f or die "close/read wordlist: $!";
 909   }
 910
 911   for (my $i = 0; $i < $me->{nwords}; $i++)
 912     { push @w, $me->{words}[$me->random(scalar @{$me->{words}})]; }
 913   return join $me->{delim}, @w;
 914 }
 915
 916 ###--------------------------------------------------------------------------
 917 ### Final configuration.
 918
 919 package Odin;
 920
 921 require "config.pl";
 922
 923 ($SCHEME, $DOMAIN, $BASEPATH) = $BASEURL =~ m!^([^:]+)://([^/]+)(/.*)$!;
 924 merge_hash %COOKIE_DEFAULTS, -domain => $DOMAIN, -path => $BASEPATH;
 925 merge_hash %COOKIE_DEFAULTS, -secure => undef if $SCHEME eq "https";
 926
 927 $MAIL_QUALDOM //= $MAIL_DEFDOMAIN;
 928
 929 $SHORTURL = "$BASEURL$SHORTURL_PATH";
 930 $PASTEBIN = "$BASEURL$PASTEBIN_PATH";
 931
 932 ###----- That's all, folks --------------------------------------------------
 933
 934 1;