chiark - git - mdw - clg/blob - glib/gtype.lisp

   1 ;; Common Lisp bindings for GTK+ v2.x
   2 ;; Copyright 2000-2005 Espen S. Johnsen <espen@users.sf.net>
   3 ;;
   4 ;; Permission is hereby granted, free of charge, to any person obtaining
   5 ;; a copy of this software and associated documentation files (the
   6 ;; "Software"), to deal in the Software without restriction, including
   7 ;; without limitation the rights to use, copy, modify, merge, publish,
   8 ;; distribute, sublicense, and/or sell copies of the Software, and to
   9 ;; permit persons to whom the Software is furnished to do so, subject to
  10 ;; the following conditions:
  11 ;;
  12 ;; The above copyright notice and this permission notice shall be
  13 ;; included in all copies or substantial portions of the Software.
  14 ;;
  15 ;; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  16 ;; EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 ;; MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  18 ;; IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
  19 ;; CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 ;; TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 ;; SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 ;; $Id: gtype.lisp,v 1.33 2006/01/31 14:02:51 espen Exp $
  24
  25 (in-package "GLIB")
  26
  27 (use-prefix "g")
  28
  29 ;; Initialize the glib type system
  30 (defbinding type-init () nil)
  31 (type-init)
  32
  33 (deftype type-number () '(unsigned 32))
  34
  35 (deftype gtype () 'symbol)
  36
  37 (defmethod alien-type ((type (eql 'gtype)) &rest args)
  38   (declare (ignore type args))
  39   (alien-type 'type-number))
  40
  41 (defmethod size-of ((type (eql 'gtype)) &rest args)
  42   (declare (ignore type args))
  43   (size-of 'type-number))
  44
  45 (defmethod to-alien-form (gtype (type (eql 'gtype)) &rest args)
  46   (declare (ignore type args))
  47   `(find-type-number ,gtype t))
  48
  49 (defmethod to-alien-function ((type (eql 'gtype)) &rest args)
  50   (declare (ignore type args))
  51   #'(lambda (gtype)
  52       (find-type-number gtype t)))
  53
  54 (defmethod from-alien-form (type-number (type (eql 'gtype)) &rest args)
  55   (declare (ignore type args))
  56   `(type-from-number ,type-number))
  57
  58 (defmethod from-alien-function ((type (eql 'gtype)) &rest args)
  59   (declare (ignore type args))
  60   #'(lambda (type-number)
  61       (type-from-number type-number)))
  62
  63 (defmethod writer-function ((type (eql 'gtype)) &rest args)
  64   (declare (ignore type args))
  65   (let ((writer (writer-function 'type-number)))
  66     #'(lambda (gtype location &optional (offset 0))
  67         (funcall writer (find-type-number gtype t) location offset))))
  68
  69 (defmethod reader-function ((type (eql 'gtype)) &rest args)
  70   (declare (ignore type args))
  71   (let ((reader (reader-function 'type-number)))
  72     #'(lambda (location &optional (offset 0))
  73         (type-from-number (funcall reader location offset)))))
  74
  75
  76 (eval-when (:compile-toplevel :load-toplevel :execute)
  77   (defclass type-query (struct)
  78     ((type-number :allocation :alien :type type-number)
  79      (name :allocation :alien :type string)
  80      (class-size :allocation :alien :type unsigned-int)
  81      (instance-size :allocation :alien :type unsigned-int))
  82     (:metaclass struct-class)))
  83
  84
  85 (defbinding type-query (type) nil
  86   ((find-type-number type t) type-number)
  87   ((make-instance 'type-query) type-query :return))
  88
  89 (defun type-instance-size (type)
  90   (slot-value (type-query type) 'instance-size))
  91
  92 (defun type-class-size (type)
  93   (slot-value (type-query type) 'class-size))
  94
  95 (defbinding type-class-ref (type) pointer
  96   ((find-type-number type t) type-number))
  97
  98 (defbinding type-class-unref (type) nil
  99   ((find-type-number type t) type-number))
 100
 101 (defbinding type-class-peek (type) pointer
 102   ((find-type-number type t) type-number))
 103
 104
 105 ;;;; Mapping between lisp types and glib types
 106
 107 (defvar *registered-types* ())
 108 (defvar *registered-type-aliases* ())
 109 (defvar *lisp-type-to-type-number* (make-hash-table))
 110 (defvar *type-number-to-lisp-type* (make-hash-table))
 111
 112 (defbinding %type-from-name () type-number
 113   (name string))
 114
 115 (defun type-number-from-glib-name (name &optional (error-p t))
 116   (let ((type-number (%type-from-name name)))
 117     (cond
 118      ((not (zerop type-number)) type-number)
 119      (error-p (error "Invalid gtype name: ~A" name)))))
 120
 121 (defun register-type (type id)
 122   (pushnew (cons type id) *registered-types* :key #'car)
 123   (let ((type-number
 124          (typecase id
 125            (string (type-number-from-glib-name id))
 126            (symbol (funcall id)))))
 127        (setf (gethash type *lisp-type-to-type-number*) type-number)
 128        (setf (gethash type-number *type-number-to-lisp-type*) type)
 129        type-number))
 130
 131 (defun register-type-alias (type alias)
 132   (pushnew (cons type alias) *registered-type-aliases* :key #'car)
 133   (setf
 134    (gethash type *lisp-type-to-type-number*)
 135    (find-type-number alias t)))
 136
 137 (defun reinitialize-all-types ()
 138   (clrhash *lisp-type-to-type-number*)
 139   (clrhash *type-number-to-lisp-type*)
 140   (type-init) ; initialize the glib type system
 141   (mapc #'(lambda (type)
 142             (register-type (car type) (cdr type)))
 143         *registered-types*)
 144   (mapc #'(lambda (type)
 145             (register-type-alias (car type) (cdr type)))
 146         *registered-type-aliases*))
 147
 148 (pushnew 'reinitialize-all-types
 149   #+cmu *after-save-initializations*
 150   #+sbcl *init-hooks*)
 151
 152 #+cmu
 153 (pushnew 'system::reinitialize-global-table ; we shouldn't have to do this?
 154  *after-save-initializations*)
 155
 156
 157 (defun find-type-number (type &optional error-p)
 158   (etypecase type
 159     (integer type)
 160     (string (type-number-from-glib-name type error-p))
 161     (symbol
 162      (or
 163       (gethash type *lisp-type-to-type-number*)
 164       (and error-p (error "Type not registered: ~A" type))))
 165     (class (find-type-number (class-name type) error-p))))
 166
 167 (defun type-from-number (type-number &optional error)
 168   (multiple-value-bind (type found)
 169       (gethash type-number *type-number-to-lisp-type*)
 170     (when (and error (not found))
 171       (let ((name (find-foreign-type-name type-number)))
 172         (if name
 173             (error "Type number not registered: ~A (~A)" type-number name)
 174           (error "Invalid type number: ~A" type-number))))
 175     type))
 176
 177 (defbinding (find-foreign-type-name "g_type_name") (type) (copy-of string)
 178   ((find-type-number type t) type-number))
 179
 180 (defun type-number-of (object)
 181   (find-type-number (type-of object) t))
 182
 183 (eval-when (:compile-toplevel :load-toplevel :execute)
 184   (defvar *type-initializers* ())
 185   (defun %find-types-in-library (pathname prefixes ignore)
 186     (let ((process (run-program
 187                     "/usr/bin/nm" (list "--defined-only" "-D" (namestring (truename pathname)))
 188                     :output :stream :wait nil)))
 189       (unwind-protect
 190           (loop
 191            as symbol = (let ((line (read-line (process-output process) nil)))
 192                          (when line (subseq line 11)))
 193            while symbol
 194            when (and
 195                  (> (length symbol) 9)
 196                  (or
 197                   (not prefixes)
 198                   (some #'(lambda (prefix)
 199                             (and
 200                              (> (length symbol) (length prefix))
 201                              (string= prefix symbol :end2 (length prefix))))
 202                         (mklist prefixes)))
 203                  (string= "_get_type" symbol :start2 (- (length symbol) 9))
 204                  (not (member symbol ignore :test #'string=)))
 205            collect symbol)
 206         (process-close process)))))
 207
 208
 209 (defmacro init-types-in-library (filename &key prefix ignore)
 210   (let ((names (%find-types-in-library filename prefix ignore)))
 211     `(progn
 212        ,@(mapcar #'(lambda (name)
 213                      `(progn
 214                         (defbinding (,(intern name) ,name) () type-number)
 215                         (,(intern name))
 216                         (pushnew ',(intern name) *type-initializers*)))
 217                  names))))
 218
 219 (defun find-type-init-function (type-number)
 220   (loop
 221    for type-init in *type-initializers*
 222    when (= type-number (funcall type-init))
 223    do (return type-init)))
 224
 225 (defun register-type-as (type-number)
 226   (or
 227    (find-type-init-function type-number)
 228    (find-foreign-type-name type-number)
 229    (error "Unknown type-number: ~A" type-number)))
 230
 231 (defun default-type-init-name (type)
 232   (find-symbol (format nil "~A_~A_get_type"
 233                 (package-prefix *package*)
 234                 (substitute #\_ #\- (string-downcase type)))))
 235
 236
 237 (eval-when (:compile-toplevel :load-toplevel :execute)
 238   (defclass type-info (struct)
 239     ((class-size :allocation :alien :type (unsigned 16) :initarg :class-size)
 240      (base-init :allocation :alien :type pointer)
 241      (base-finalize :allocation :alien :type pointer)
 242      (class-init :allocation :alien :type pointer)
 243      (class-finalize :allocation :alien :type pointer)
 244      (class-data :allocation :alien :type pointer)
 245      (instance-size :allocation :alien :type (unsigned 16)
 246                     :initarg :instance-size)
 247      (n-preallocs :allocation :alien :type (unsigned 16))
 248      (instance-init :allocation :alien :type pointer)
 249      (value-table :allocation :alien :type pointer))
 250     (:metaclass struct-class)))
 251
 252 (defbinding %type-register-static () type-number
 253   (parent-type gtype)
 254   (name string)
 255   (info type-info)
 256   (0 unsigned-int))
 257
 258 (defun register-new-type (type parent)
 259   (let ((parent-info (type-query parent)))
 260     (with-slots ((parent-number type-number) class-size instance-size) parent-info
 261       (let ((type-number
 262              (%type-register-static
 263               parent-number
 264               (default-alien-type-name type)
 265               (make-instance 'type-info :class-size class-size :instance-size instance-size))))
 266        (setf (gethash type *lisp-type-to-type-number*) type-number)
 267        (setf (gethash type-number *type-number-to-lisp-type*) type)
 268        type-number))))
 269
 270
 271
 272 ;;;; Metaclass for subclasses of ginstance
 273
 274 (eval-when (:compile-toplevel :load-toplevel :execute)
 275   (defclass ginstance-class (proxy-class)
 276     ()))
 277
 278
 279 (defmethod shared-initialize ((class ginstance-class) names &rest initargs &key name gtype)
 280   (declare (ignore names))
 281   (let* ((class-name (or name (class-name class)))
 282          (type-number
 283           (or
 284            (find-type-number class-name)
 285            (register-type class-name
 286              (or (first gtype) (default-type-init-name class-name))))))
 287     (if (getf initargs :size)
 288          (call-next-method)
 289        (let ((size (type-instance-size type-number)))
 290          (apply #'call-next-method class names :size (list size) initargs)))))
 291
 292
 293 (defmethod validate-superclass ((class ginstance-class) (super standard-class))
 294   (subtypep (class-name super) 'ginstance))
 295
 296
 297 ;;;; Superclass for wrapping types in the glib type system
 298
 299 (eval-when (:compile-toplevel :load-toplevel :execute)
 300   (defclass ginstance (proxy)
 301     ((class :allocation :alien :type pointer))
 302     (:metaclass proxy-class)))
 303
 304 (defun %type-number-of-ginstance (location)
 305   (let ((class (sap-ref-sap location 0)))
 306     (sap-ref-32 class 0)))
 307
 308 (defmethod ensure-proxy-instance ((class ginstance-class) location)
 309   (declare (ignore class))
 310   (let ((class (labels ((find-known-class (type-number)
 311                           (or
 312                            (find-class (type-from-number type-number) nil)
 313                            (unless (zerop type-number)
 314                              (find-known-class (type-parent type-number))))))
 315                  (find-known-class (%type-number-of-ginstance location)))))
 316     (if class
 317         (make-instance class :location (reference-foreign class location))
 318       (error "Object at ~A has an unkown type number: ~A"
 319         location (%type-number-of-ginstance location)))))
 320
 321 (defmethod copy-from-alien-form (location (class ginstance-class) &rest args)
 322   (declare (ignore location class args))
 323   (error "Doing copy-from-alien on a ref. counted class is most certainly an error, but if it really is what you want you should use REFERENCE-FOREIGN on the returned instance instead."))
 324
 325 (defmethod copy-from-alien-function ((class ginstance-class) &rest args)
 326   (declare (ignore class args))
 327   (error "Doing copy-from-alien on a ref. counted class is most certainly an error, but if it really is what you want you should use REFERENCE-FOREIGN on the returned instance instead."))
 328
 329 (defmethod reader-function ((class ginstance-class) &rest args)
 330   (declare (ignore args))
 331   #'(lambda (location &optional (offset 0))
 332       (ensure-proxy-instance class (sap-ref-sap location offset))))
 333
 334
 335 ;;;; Registering fundamental types
 336
 337 (register-type 'nil "void")
 338 (register-type 'pointer "gpointer")
 339 (register-type 'char "gchar")
 340 (register-type 'unsigned-char "guchar")
 341 (register-type 'boolean "gboolean")
 342 (register-type 'int "gint")
 343 (register-type-alias 'integer 'int)
 344 (register-type-alias 'fixnum 'int)
 345 (register-type 'unsigned-int "guint")
 346 (register-type 'long "glong")
 347 (register-type 'unsigned-long "gulong")
 348 (register-type 'single-float "gfloat")
 349 (register-type 'double-float "gdouble")
 350 (register-type 'pathname "gchararray")
 351 (register-type 'string "gchararray")
 352
 353
 354 ;;;; Introspection of type information
 355
 356 (defvar *derivable-type-info* (make-hash-table))
 357
 358 (defun register-derivable-type (type id expander &optional dependencies)
 359   (register-type type id)
 360   (let ((type-number (register-type type id)))
 361     (setf
 362      (gethash type-number *derivable-type-info*)
 363      (list expander dependencies))))
 364
 365 (defun find-type-info (type)
 366   (dolist (super (cdr (type-hierarchy type)))
 367     (let ((info (gethash super *derivable-type-info*)))
 368       (return-if info))))
 369
 370 (defun expand-type-definition (type forward-p options)
 371   (let ((expander (first (find-type-info type))))
 372     (funcall expander (find-type-number type t) forward-p options)))
 373
 374 (defbinding type-parent (type) type-number
 375   ((find-type-number type t) type-number))
 376
 377 (defun supertype (type)
 378   (type-from-number (type-parent type)))
 379
 380 (defbinding %type-interfaces (type) pointer
 381   ((find-type-number type t) type-number)
 382   (n-interfaces unsigned-int :out))
 383
 384 (defun type-interfaces (type)
 385   (multiple-value-bind (array length) (%type-interfaces type)
 386     (unwind-protect
 387         (map-c-vector 'list #'identity array 'type-number length)
 388       (deallocate-memory array))))
 389
 390 (defun implements (type)
 391   (mapcar #'type-from-number (type-interfaces type)))
 392
 393 (defun type-hierarchy (type)
 394   (let ((type-number (find-type-number type t)))
 395     (unless (= type-number 0)
 396       (cons type-number (type-hierarchy (type-parent type-number))))))
 397
 398 (defbinding (type-is-p "g_type_is_a") (type super) boolean
 399   ((find-type-number type) type-number)
 400   ((find-type-number super) type-number))
 401
 402 (defbinding %type-children () pointer
 403   (type-number type-number)
 404   (num-children unsigned-int :out))
 405
 406 (defun map-subtypes (function type &optional prefix)
 407   (let ((type-number (find-type-number type t)))
 408     (multiple-value-bind (array length) (%type-children type-number)
 409       (unwind-protect
 410           (map-c-vector
 411            'nil
 412            #'(lambda (type-number)
 413                (when (or
 414                       (not prefix)
 415                       (string-prefix-p prefix (find-foreign-type-name type-number)))
 416                  (funcall function type-number))
 417                (map-subtypes function type-number prefix))
 418            array 'type-number length)
 419         (deallocate-memory array)))))
 420
 421 (defun find-types (prefix)
 422   (let ((type-list nil))
 423     (maphash
 424      #'(lambda (type-number expander)
 425          (declare (ignore expander))
 426          (map-subtypes
 427           #'(lambda (type-number)
 428               (pushnew type-number type-list))
 429           type-number prefix))
 430      *derivable-type-info*)
 431     type-list))
 432
 433 (defun find-type-dependencies (type)
 434   (let ((list-dependencies (second (find-type-info type))))
 435     (when list-dependencies
 436       (funcall list-dependencies (find-type-number type t)))))
 437
 438 (defun %sort-types-topologicaly (types)
 439   (let ((partial-sorted
 440          (sort
 441           (mapcar
 442            #'(lambda (type)
 443                (cons type (remove-if #'(lambda (dep)
 444                                          (not (find dep types)))
 445                                      (find-type-dependencies type))))
 446            types)
 447           #'(lambda (type1 type2) (type-is-p type2 type1)) :key #'car))
 448         (sorted ()))
 449
 450     (loop
 451      as tmp = partial-sorted then (or (rest tmp) partial-sorted)
 452      while tmp
 453      do (destructuring-bind (type . dependencies) (first tmp)
 454           (cond
 455            ((every #'(lambda (dep)
 456                        (assoc dep sorted))
 457                    dependencies)
 458             (push (cons type nil) sorted) ; no forward definition needed
 459             (setq partial-sorted (delete type partial-sorted :key #'first)))
 460            ((some #'(lambda (dep)
 461                       (find type (find-type-dependencies dep)))
 462                   dependencies)
 463             (push (cons type t) sorted) ; forward definition needed
 464             (setq partial-sorted (delete type partial-sorted :key #'first))))))
 465     (nreverse sorted)))
 466
 467
 468 (defun expand-type-definitions (prefix &optional args)
 469   (flet ((type-options (type-number)
 470            (let ((name (find-foreign-type-name type-number)))
 471              (cdr (assoc name args :test #'string=)))))
 472
 473    (let ((type-list
 474           (delete-if
 475            #'(lambda (type-number)
 476                (let ((name (find-foreign-type-name type-number)))
 477                  (or
 478                   (getf (type-options type-number) :ignore)
 479                   (find-if
 480                    #'(lambda (options)
 481                        (and
 482                         (string-prefix-p (first options) name)
 483                         (getf (cdr options) :ignore-prefix)
 484                         (not (some
 485                               #'(lambda (exception)
 486                                   (string= name exception))
 487                               (getf (cdr options) :except)))))
 488                    args))))
 489            (find-types prefix))))
 490
 491      (dolist (type-number type-list)
 492        (let ((name (find-foreign-type-name type-number)))
 493          (register-type
 494           (getf (type-options type-number) :type (default-type-name name))
 495           (register-type-as type-number))))
 496
 497      (let ((sorted-type-list (%sort-types-topologicaly type-list)))
 498        `(progn
 499           ,@(mapcar
 500              #'(lambda (pair)
 501                  (destructuring-bind (type . forward-p) pair
 502                    (expand-type-definition type forward-p (type-options type))))
 503              sorted-type-list)
 504           ,@(mapcar
 505              #'(lambda (pair)
 506                  (destructuring-bind (type . forward-p) pair
 507                    (when forward-p
 508                      (expand-type-definition type nil (type-options type)))))
 509              sorted-type-list))))))
 510
 511 (defmacro define-types-by-introspection (prefix &rest args)
 512   (expand-type-definitions prefix args))
 513
 514
 515 ;;;; Initialize all non static types in GObject
 516
 517 (init-types-in-library #.(concatenate 'string (pkg-config:pkg-variable "glib-2.0" "libdir") "/libgobject-2.0.so"))