chiark - git - mdw - clg/blob - glib/gtype.lisp

   1 ;; Common Lisp bindings for GTK+ v2.0
   2 ;; Copyright (C) 2000-2001 Espen S. Johnsen <esj@stud.cs.uit.no>
   3 ;;
   4 ;; This library is free software; you can redistribute it and/or
   5 ;; modify it under the terms of the GNU Lesser General Public
   6 ;; License as published by the Free Software Foundation; either
   7 ;; version 2 of the License, or (at your option) any later version.
   8 ;;
   9 ;; This library is distributed in the hope that it will be useful,
  10 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 ;; Lesser General Public License for more details.
  13 ;;
  14 ;; You should have received a copy of the GNU Lesser General Public
  15 ;; License along with this library; if not, write to the Free Software
  16 ;; Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18 ;; $Id: gtype.lisp,v 1.30 2005/03/12 19:38:12 espen Exp $
  19
  20 (in-package "GLIB")
  21
  22 (use-prefix "g")
  23
  24 ;; Initialize the glib type system
  25 (defbinding type-init () nil)
  26 (type-init)
  27
  28 (deftype type-number () '(unsigned 32))
  29
  30 (deftype gtype () 'symbol)
  31
  32 (defmethod alien-type ((type (eql 'gtype)) &rest args)
  33   (declare (ignore type args))
  34   (alien-type 'type-number))
  35
  36 (defmethod size-of ((type (eql 'gtype)) &rest args)
  37   (declare (ignore type args))
  38   (size-of 'type-number))
  39
  40 (defmethod to-alien-form (gtype (type (eql 'gtype)) &rest args)
  41   (declare (ignore type args))
  42   `(find-type-number ,gtype t))
  43
  44 (defmethod to-alien-function ((type (eql 'gtype)) &rest args)
  45   (declare (ignore type args))
  46   #'(lambda (gtype)
  47       (find-type-number gtype t)))
  48
  49 (defmethod from-alien-form (type-number (type (eql 'gtype)) &rest args)
  50   (declare (ignore type args))
  51   `(type-from-number ,type-number))
  52
  53 (defmethod from-alien-function ((type (eql 'gtype)) &rest args)
  54   (declare (ignore type args))
  55   #'(lambda (type-number)
  56       (type-from-number type-number)))
  57
  58 (defmethod writer-function ((type (eql 'gtype)) &rest args)
  59   (declare (ignore type args))
  60   (let ((writer (writer-function 'type-number)))
  61     #'(lambda (gtype location &optional (offset 0))
  62         (funcall writer (find-type-number gtype t) location offset))))
  63
  64 (defmethod reader-function ((type (eql 'gtype)) &rest args)
  65   (declare (ignore type args))
  66   (let ((reader (reader-function 'type-number)))
  67     #'(lambda (location &optional (offset 0))
  68         (type-from-number (funcall reader location offset)))))
  69
  70
  71 (eval-when (:compile-toplevel :load-toplevel :execute)
  72   (defclass type-query (struct)
  73     ((type-number :allocation :alien :type type-number)
  74      (name :allocation :alien :type string)
  75      (class-size :allocation :alien :type unsigned-int)
  76      (instance-size :allocation :alien :type unsigned-int))
  77     (:metaclass struct-class)))
  78
  79
  80 (defbinding type-query (type) nil
  81   ((find-type-number type t) type-number)
  82   ((make-instance 'type-query) type-query :return))
  83
  84 (defun type-instance-size (type)
  85   (slot-value (type-query type) 'instance-size))
  86
  87 (defun type-class-size (type)
  88   (slot-value (type-query type) 'class-size))
  89
  90 (defbinding type-class-ref (type) pointer
  91   ((find-type-number type t) type-number))
  92
  93 (defbinding type-class-unref (type) nil
  94   ((find-type-number type t) type-number))
  95
  96 (defbinding type-class-peek (type) pointer
  97   ((find-type-number type t) type-number))
  98
  99
 100 ;;;; Mapping between lisp types and glib types
 101
 102 (defvar *registered-types* ())
 103 (defvar *registered-type-aliases* ())
 104 (defvar *lisp-type-to-type-number* (make-hash-table))
 105 (defvar *type-number-to-lisp-type* (make-hash-table))
 106
 107 (defbinding %type-from-name () type-number
 108   (name string))
 109
 110 (defun type-number-from-glib-name (name &optional (error-p t))
 111   (let ((type-number (%type-from-name name)))
 112     (cond
 113      ((not (zerop type-number)) type-number)
 114      (error-p (error "Invalid gtype name: ~A" name)))))
 115
 116 (defun register-type (type id)
 117   (pushnew (cons type id) *registered-types* :key #'car)
 118   (let ((type-number
 119          (typecase id
 120            (string (type-number-from-glib-name id))
 121            (symbol (funcall id)))))
 122        (setf (gethash type *lisp-type-to-type-number*) type-number)
 123        (setf (gethash type-number *type-number-to-lisp-type*) type)
 124        type-number))
 125
 126 (defun register-type-alias (type alias)
 127   (pushnew (cons type alias) *registered-type-aliases* :key #'car)
 128   (setf
 129    (gethash type *lisp-type-to-type-number*)
 130    (find-type-number alias t)))
 131
 132 (defun reinitialize-all-types ()
 133   (clrhash *lisp-type-to-type-number*)
 134   (clrhash *type-number-to-lisp-type*)
 135   (type-init) ; initialize the glib type system
 136   (mapc #'(lambda (type)
 137             (register-type (car type) (cdr type)))
 138         *registered-types*)
 139   (mapc #'(lambda (type)
 140             (register-type-alias (car type) (cdr type)))
 141         *registered-type-aliases*))
 142
 143 (pushnew 'reinitialize-all-types
 144   #+cmu *after-save-initializations*
 145   #+sbcl *init-hooks*)
 146
 147 #+cmu
 148 (pushnew 'system::reinitialize-global-table ; we shouldn't have to do this?
 149  *after-save-initializations*)
 150
 151
 152 (defun find-type-number (type &optional error-p)
 153   (etypecase type
 154     (integer type)
 155     (string (type-number-from-glib-name type error-p))
 156     (symbol
 157      (or
 158       (gethash type *lisp-type-to-type-number*)
 159       (and error-p (error "Type not registered: ~A" type))))
 160     (class (find-type-number (class-name type) error-p))))
 161
 162 (defun type-from-number (type-number &optional error)
 163   (multiple-value-bind (type found)
 164       (gethash type-number *type-number-to-lisp-type*)
 165     (when (and error (not found))
 166       (let ((name (find-foreign-type-name type-number)))
 167         (if name
 168             (error "Type number not registered: ~A (~A)" type-number name)
 169           (error "Invalid type number: ~A" type-number))))
 170     type))
 171
 172 (defbinding (find-foreign-type-name "g_type_name") (type) (copy-of string)
 173   ((find-type-number type t) type-number))
 174
 175 (defun type-number-of (object)
 176   (find-type-number (type-of object) t))
 177
 178 (eval-when (:compile-toplevel :load-toplevel :execute)
 179   (defvar *type-initializers* ())
 180   (defun %find-types-in-library (pathname prefixes ignore)
 181     (let ((process (run-program
 182                     "/usr/bin/nm" (list "--defined-only" "-D" (namestring (truename pathname)))
 183                     :output :stream :wait nil)))
 184       (unwind-protect
 185           (loop
 186            as symbol = (let ((line (read-line (process-output process) nil)))
 187                          (when line (subseq line 11)))
 188            while symbol
 189            when (and
 190                  (> (length symbol) 9)
 191                  (or
 192                   (not prefixes)
 193                   (some #'(lambda (prefix)
 194                             (and
 195                              (> (length symbol) (length prefix))
 196                              (string= prefix symbol :end2 (length prefix))))
 197                         (mklist prefixes)))
 198                  (string= "_get_type" symbol :start2 (- (length symbol) 9))
 199                  (not (member symbol ignore :test #'string=)))
 200            collect symbol)
 201         (process-close process)))))
 202
 203
 204 (defmacro init-types-in-library (filename &key prefix ignore)
 205   (let ((names (%find-types-in-library filename prefix ignore)))
 206     `(progn
 207        ,@(mapcar #'(lambda (name)
 208                      `(progn
 209                         (defbinding (,(intern name) ,name) () type-number)
 210                         (,(intern name))
 211                         (pushnew ',(intern name) *type-initializers*)))
 212                  names))))
 213
 214 (defun find-type-init-function (type-number)
 215   (loop
 216    for type-init in *type-initializers*
 217    when (= type-number (funcall type-init))
 218    do (return type-init)))
 219
 220 (defun register-type-as (type-number)
 221   (or
 222    (find-type-init-function type-number)
 223    (find-foreign-type-name type-number)
 224    (error "Unknown type-number: ~A" type-number)))
 225
 226 (defun default-type-init-name (type)
 227   (find-symbol (format nil "~A_~A_get_type"
 228                 (package-prefix *package*)
 229                 (substitute #\_ #\- (string-downcase type)))))
 230
 231
 232
 233 ;;;; Metaclass for subclasses of ginstance
 234
 235 (eval-when (:compile-toplevel :load-toplevel :execute)
 236   (defclass ginstance-class (proxy-class)
 237     ()))
 238
 239
 240 (defmethod shared-initialize ((class ginstance-class) names &rest initargs &key name gtype)
 241   (declare (ignore names))
 242   (let* ((class-name (or name (class-name class)))
 243          (type-number
 244           (or
 245            (find-type-number class-name)
 246            (register-type class-name
 247              (or (first gtype) (default-type-init-name class-name))))))
 248     (if (getf initargs :size)
 249          (call-next-method)
 250        (let ((size (type-instance-size type-number)))
 251          (apply #'call-next-method class names :size (list size) initargs)))))
 252
 253
 254 (defmethod validate-superclass ((class ginstance-class) (super standard-class))
 255   (subtypep (class-name super) 'ginstance))
 256
 257
 258 ;;;; Superclass for wrapping types in the glib type system
 259
 260 (eval-when (:compile-toplevel :load-toplevel :execute)
 261   (defclass ginstance (proxy)
 262     ((class :allocation :alien :type pointer))
 263     (:metaclass proxy-class)))
 264
 265 (defun %type-number-of-ginstance (location)
 266   (let ((class (sap-ref-sap location 0)))
 267     (sap-ref-32 class 0)))
 268
 269 (defmethod ensure-proxy-instance ((class ginstance-class) location)
 270   (declare (ignore class))
 271   (let ((class (labels ((find-known-class (type-number)
 272                           (or
 273                            (find-class (type-from-number type-number) nil)
 274                            (unless (zerop type-number)
 275                              (find-known-class (type-parent type-number))))))
 276                  (find-known-class (%type-number-of-ginstance location)))))
 277     (if class
 278         (make-instance class :location (reference-foreign class location))
 279       (error "Object at ~A has an unkown type number: ~A"
 280         location (%type-number-of-ginstance location)))))
 281
 282 (defmethod copy-from-alien-form (location (class ginstance-class) &rest args)
 283   (declare (ignore location class args))
 284   (error "Doing copy-from-alien on a ref. counted class is most certainly an error, but if it really is what you want you should use REFERENCE-FOREIGN on the returned instance instead."))
 285
 286 (defmethod copy-from-alien-function ((class ginstance-class) &rest args)
 287   (declare (ignore class args))
 288   (error "Doing copy-from-alien on a ref. counted class is most certainly an error, but if it really is what you want you should use REFERENCE-FOREIGN on the returned instance instead."))
 289
 290 (defmethod reader-function ((class ginstance-class) &rest args)
 291   (declare (ignore args))
 292   #'(lambda (location &optional (offset 0))
 293       (ensure-proxy-instance class (sap-ref-sap location offset))))
 294
 295
 296 ;;;; Registering fundamental types
 297
 298 (register-type 'nil "void")
 299 (register-type 'pointer "gpointer")
 300 (register-type 'char "gchar")
 301 (register-type 'unsigned-char "guchar")
 302 (register-type 'boolean "gboolean")
 303 (register-type 'int "gint")
 304 (register-type-alias 'fixnum 'int)
 305 (register-type 'unsigned-int "guint")
 306 (register-type 'long "glong")
 307 (register-type 'unsigned-long "gulong")
 308 (register-type 'single-float "gfloat")
 309 (register-type 'double-float "gdouble")
 310 (register-type 'pathname "gchararray")
 311 (register-type 'string "gchararray")
 312
 313
 314 ;;;; Introspection of type information
 315
 316 (defvar *derivable-type-info* (make-hash-table))
 317
 318 (defun register-derivable-type (type id expander &optional dependencies)
 319   (register-type type id)
 320   (let ((type-number (register-type type id)))
 321     (setf
 322      (gethash type-number *derivable-type-info*)
 323      (list expander dependencies))))
 324
 325 (defun find-type-info (type)
 326   (dolist (super (cdr (type-hierarchy type)))
 327     (let ((info (gethash super *derivable-type-info*)))
 328       (return-if info))))
 329
 330 (defun expand-type-definition (type forward-p options)
 331   (let ((expander (first (find-type-info type))))
 332     (funcall expander (find-type-number type t) forward-p options)))
 333
 334 (defbinding type-parent (type) type-number
 335   ((find-type-number type t) type-number))
 336
 337 (defun supertype (type)
 338   (type-from-number (type-parent type)))
 339
 340 (defbinding %type-interfaces (type) pointer
 341   ((find-type-number type t) type-number)
 342   (n-interfaces unsigned-int :out))
 343
 344 (defun type-interfaces (type)
 345   (multiple-value-bind (array length) (%type-interfaces type)
 346     (unwind-protect
 347         (map-c-vector 'list #'identity array 'type-number length)
 348       (deallocate-memory array))))
 349
 350 (defun implements (type)
 351   (mapcar #'type-from-number (type-interfaces type)))
 352
 353 (defun type-hierarchy (type)
 354   (let ((type-number (find-type-number type t)))
 355     (unless (= type-number 0)
 356       (cons type-number (type-hierarchy (type-parent type-number))))))
 357
 358 (defbinding (type-is-p "g_type_is_a") (type super) boolean
 359   ((find-type-number type) type-number)
 360   ((find-type-number super) type-number))
 361
 362 (defbinding %type-children () pointer
 363   (type-number type-number)
 364   (num-children unsigned-int :out))
 365
 366 (defun map-subtypes (function type &optional prefix)
 367   (let ((type-number (find-type-number type t)))
 368     (multiple-value-bind (array length) (%type-children type-number)
 369       (unwind-protect
 370           (map-c-vector
 371            'nil
 372            #'(lambda (type-number)
 373                (when (or
 374                       (not prefix)
 375                       (string-prefix-p prefix (find-foreign-type-name type-number)))
 376                  (funcall function type-number))
 377                (map-subtypes function type-number prefix))
 378            array 'type-number length)
 379         (deallocate-memory array)))))
 380
 381 (defun find-types (prefix)
 382   (let ((type-list nil))
 383     (maphash
 384      #'(lambda (type-number expander)
 385          (declare (ignore expander))
 386          (map-subtypes
 387           #'(lambda (type-number)
 388               (pushnew type-number type-list))
 389           type-number prefix))
 390      *derivable-type-info*)
 391     type-list))
 392
 393 (defun find-type-dependencies (type)
 394   (let ((list-dependencies (second (find-type-info type))))
 395     (when list-dependencies
 396       (funcall list-dependencies (find-type-number type t)))))
 397
 398 (defun %sort-types-topologicaly (types)
 399   (let ((partial-sorted
 400          (sort
 401           (mapcar
 402            #'(lambda (type)
 403                (cons type (remove-if #'(lambda (dep)
 404                                          (not (find dep types)))
 405                                      (find-type-dependencies type))))
 406            types)
 407           #'(lambda (type1 type2) (type-is-p type2 type1)) :key #'car))
 408         (sorted ()))
 409
 410     (loop
 411      as tmp = partial-sorted then (or (rest tmp) partial-sorted)
 412      while tmp
 413      do (destructuring-bind (type . dependencies) (first tmp)
 414           (cond
 415            ((every #'(lambda (dep)
 416                        (assoc dep sorted))
 417                    dependencies)
 418             (push (cons type nil) sorted) ; no forward definition needed
 419             (setq partial-sorted (delete type partial-sorted :key #'first)))
 420            ((some #'(lambda (dep)
 421                       (find type (find-type-dependencies dep)))
 422                   dependencies)
 423             (push (cons type t) sorted) ; forward definition needed
 424             (setq partial-sorted (delete type partial-sorted :key #'first))))))
 425     (nreverse sorted)))
 426
 427
 428 (defun expand-type-definitions (prefix &optional args)
 429   (flet ((type-options (type-number)
 430            (let ((name (find-foreign-type-name type-number)))
 431              (cdr (assoc name args :test #'string=)))))
 432
 433    (let ((type-list
 434           (delete-if
 435            #'(lambda (type-number)
 436                (let ((name (find-foreign-type-name type-number)))
 437                  (or
 438                   (getf (type-options type-number) :ignore)
 439                   (find-if
 440                    #'(lambda (options)
 441                        (and
 442                         (string-prefix-p (first options) name)
 443                         (getf (cdr options) :ignore-prefix)
 444                         (not (some
 445                               #'(lambda (exception)
 446                                   (string= name exception))
 447                               (getf (cdr options) :except)))))
 448                    args))))
 449            (find-types prefix))))
 450
 451      (dolist (type-number type-list)
 452        (let ((name (find-foreign-type-name type-number)))
 453          (register-type
 454           (getf (type-options type-number) :type (default-type-name name))
 455           (register-type-as type-number))))
 456
 457      (let ((sorted-type-list (%sort-types-topologicaly type-list)))
 458        `(progn
 459           ,@(mapcar
 460              #'(lambda (pair)
 461                  (destructuring-bind (type . forward-p) pair
 462                    (expand-type-definition type forward-p (type-options type))))
 463              sorted-type-list)
 464           ,@(mapcar
 465              #'(lambda (pair)
 466                  (destructuring-bind (type . forward-p) pair
 467                    (when forward-p
 468                      (expand-type-definition type nil (type-options type)))))
 469              sorted-type-list))))))
 470
 471 (defmacro define-types-by-introspection (prefix &rest args)
 472   (expand-type-definitions prefix args))
 473
 474
 475 ;;;; Initialize all non static types in GObject
 476
 477 (init-types-in-library #.(concatenate 'string (pkg-config:pkg-variable "glib-2.0" "libdir") "/libgobject-2.0.so"))