| 1 | ;; Common Lisp bindings for GTK+ v2.0 |
| 2 | ;; Copyright (C) 2000-2005 Espen S. Johnsen <espen@users.sf.net> |
| 3 | ;; |
| 4 | ;; This library is free software; you can redistribute it and/or |
| 5 | ;; modify it under the terms of the GNU Lesser General Public |
| 6 | ;; License as published by the Free Software Foundation; either |
| 7 | ;; version 2 of the License, or (at your option) any later version. |
| 8 | ;; |
| 9 | ;; This library is distributed in the hope that it will be useful, |
| 10 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 11 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
| 12 | ;; Lesser General Public License for more details. |
| 13 | ;; |
| 14 | ;; You should have received a copy of the GNU Lesser General Public |
| 15 | ;; License along with this library; if not, write to the Free Software |
| 16 | ;; Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA |
| 17 | |
| 18 | ;; $Id: gobject.lisp,v 1.35 2005-03-11 10:56:58 espen Exp $ |
| 19 | |
| 20 | (in-package "GLIB") |
| 21 | |
| 22 | |
| 23 | ;;;; Metaclass used for subclasses of gobject |
| 24 | |
| 25 | (eval-when (:compile-toplevel :load-toplevel :execute) |
| 26 | (defclass gobject-class (ginstance-class) |
| 27 | ()) |
| 28 | |
| 29 | (defmethod validate-superclass ((class gobject-class) (super standard-class)) |
| 30 | ; (subtypep (class-name super) 'gobject) |
| 31 | t)) |
| 32 | |
| 33 | (defclass direct-property-slot-definition (direct-virtual-slot-definition) |
| 34 | ((pname :reader slot-definition-pname :initarg :pname) |
| 35 | (readable :initform t :reader slot-readable-p :initarg :readable) |
| 36 | (writable :initform t :reader slot-writable-p :initarg :writable) |
| 37 | (construct :initform nil :initarg :construct))) |
| 38 | |
| 39 | (defclass effective-property-slot-definition (effective-virtual-slot-definition) |
| 40 | ((pname :reader slot-definition-pname :initarg :pname) |
| 41 | (readable :reader slot-readable-p :initarg :readable) |
| 42 | (writable :reader slot-writable-p :initarg :writable) |
| 43 | (construct :initarg :construct))) |
| 44 | |
| 45 | (defclass direct-user-data-slot-definition (direct-virtual-slot-definition) |
| 46 | ()) |
| 47 | |
| 48 | (defclass effective-user-data-slot-definition (effective-virtual-slot-definition) |
| 49 | ()) |
| 50 | |
| 51 | |
| 52 | (defbinding %object-ref () pointer |
| 53 | (location pointer)) |
| 54 | |
| 55 | (defbinding %object-unref () nil |
| 56 | (location pointer)) |
| 57 | |
| 58 | (defmethod reference-foreign ((class gobject-class) location) |
| 59 | (declare (ignore class)) |
| 60 | (%object-ref location)) |
| 61 | |
| 62 | (defmethod unreference-foreign ((class gobject-class) location) |
| 63 | (declare (ignore class)) |
| 64 | (%object-unref location)) |
| 65 | |
| 66 | |
| 67 | ; (defbinding object-class-install-param () nil |
| 68 | ; (class pointer) |
| 69 | ; (id unsigned-int) |
| 70 | ; (parameter parameter)) |
| 71 | |
| 72 | ; (defbinding object-class-find-param-spec () parameter |
| 73 | ; (class pointer) |
| 74 | ; (name string)) |
| 75 | |
| 76 | (defun signal-name-to-string (name) |
| 77 | (substitute #\_ #\- (string-downcase (string name)))) |
| 78 | |
| 79 | |
| 80 | (defmethod direct-slot-definition-class ((class gobject-class) &rest initargs) |
| 81 | (case (getf initargs :allocation) |
| 82 | (:property (find-class 'direct-property-slot-definition)) |
| 83 | (:user-data (find-class 'direct-user-data-slot-definition)) |
| 84 | (t (call-next-method)))) |
| 85 | |
| 86 | (defmethod effective-slot-definition-class ((class gobject-class) &rest initargs) |
| 87 | (case (getf initargs :allocation) |
| 88 | (:property (find-class 'effective-property-slot-definition)) |
| 89 | (:user-data (find-class 'effective-user-data-slot-definition)) |
| 90 | (t (call-next-method)))) |
| 91 | |
| 92 | (defmethod compute-effective-slot-definition-initargs ((class gobject-class) direct-slotds) |
| 93 | (if (typep (first direct-slotds) 'direct-property-slot-definition) |
| 94 | (nconc |
| 95 | (list :pname (signal-name-to-string |
| 96 | (most-specific-slot-value direct-slotds 'pname)) |
| 97 | :readable (most-specific-slot-value direct-slotds 'readable) |
| 98 | :writable (most-specific-slot-value direct-slotds 'writable) |
| 99 | :construct (most-specific-slot-value direct-slotds 'construct)) |
| 100 | (call-next-method)) |
| 101 | (call-next-method))) |
| 102 | |
| 103 | |
| 104 | (defmethod initialize-internal-slot-functions ((slotd effective-property-slot-definition)) |
| 105 | (let ((type (slot-definition-type slotd)) |
| 106 | (pname (slot-definition-pname slotd))) |
| 107 | (when (and (not (slot-boundp slotd 'getter)) (slot-readable-p slotd)) |
| 108 | (setf |
| 109 | (slot-value slotd 'getter) |
| 110 | (let ((reader nil)) |
| 111 | #'(lambda (object) |
| 112 | (unless reader |
| 113 | (setq reader (reader-function type))) |
| 114 | (let ((gvalue (gvalue-new type))) |
| 115 | (%object-get-property object pname gvalue) |
| 116 | (unwind-protect |
| 117 | (funcall reader gvalue +gvalue-value-offset+) |
| 118 | (gvalue-free gvalue t))))))) |
| 119 | |
| 120 | (when (and (not (slot-boundp slotd 'setter)) (slot-writable-p slotd)) |
| 121 | (setf |
| 122 | (slot-value slotd 'setter) |
| 123 | (let ((writer nil)) |
| 124 | #'(lambda (value object) |
| 125 | (unless writer |
| 126 | (setq writer (writer-function type))) |
| 127 | (let ((gvalue (gvalue-new type))) |
| 128 | (funcall writer value gvalue +gvalue-value-offset+) |
| 129 | (%object-set-property object pname gvalue) |
| 130 | (gvalue-free gvalue t) |
| 131 | value)))))) |
| 132 | |
| 133 | (call-next-method)) |
| 134 | |
| 135 | (defmethod initialize-internal-slot-functions ((slotd effective-user-data-slot-definition)) |
| 136 | (let ((slot-name (slot-definition-name slotd))) |
| 137 | (unless (slot-boundp slotd 'getter) |
| 138 | (setf |
| 139 | (slot-value slotd 'getter) |
| 140 | #'(lambda (object) |
| 141 | (prog1 (user-data object slot-name))))) |
| 142 | (unless (slot-boundp slotd 'setter) |
| 143 | (setf |
| 144 | (slot-value slotd 'setter) |
| 145 | #'(lambda (value object) |
| 146 | (setf (user-data object slot-name) value)))) |
| 147 | (unless (slot-boundp slotd 'boundp) |
| 148 | (setf |
| 149 | (slot-value slotd 'boundp) |
| 150 | #'(lambda (object) |
| 151 | (user-data-p object slot-name))))) |
| 152 | (call-next-method)) |
| 153 | |
| 154 | |
| 155 | ;;;; Super class for all classes in the GObject type hierarchy |
| 156 | |
| 157 | (eval-when (:compile-toplevel :load-toplevel :execute) |
| 158 | (defclass gobject (ginstance) |
| 159 | () |
| 160 | (:metaclass gobject-class) |
| 161 | (:gtype "GObject"))) |
| 162 | |
| 163 | |
| 164 | (defun initial-add (object function initargs key pkey) |
| 165 | (loop |
| 166 | as (initarg value . rest) = initargs then rest |
| 167 | do (cond |
| 168 | ((eq initarg key) (funcall function object value)) |
| 169 | ((eq initarg pkey) (mapc #'(lambda (value) |
| 170 | (funcall function object value)) |
| 171 | value))) |
| 172 | while rest)) |
| 173 | |
| 174 | (defun initial-apply-add (object function initargs key pkey) |
| 175 | (initial-add object #'(lambda (object value) |
| 176 | (apply function object (mklist value))) |
| 177 | initargs key pkey)) |
| 178 | |
| 179 | |
| 180 | (defmethod initialize-instance ((object gobject) &rest initargs) |
| 181 | (unless (slot-boundp object 'location) |
| 182 | ;; Extract initargs which we should pass directly to the GObeject |
| 183 | ;; constructor |
| 184 | (let* ((slotds (class-slots (class-of object))) |
| 185 | (args (when initargs |
| 186 | (loop |
| 187 | as (key value . rest) = initargs then rest |
| 188 | as slotd = (find-if |
| 189 | #'(lambda (slotd) |
| 190 | (member key (slot-definition-initargs slotd))) |
| 191 | slotds) |
| 192 | when (and (typep slotd 'effective-property-slot-definition) |
| 193 | (slot-value slotd 'construct)) |
| 194 | collect (progn |
| 195 | (remf initargs key) |
| 196 | (list |
| 197 | (slot-definition-pname slotd) |
| 198 | (slot-definition-type slotd) |
| 199 | value)) |
| 200 | while rest)))) |
| 201 | (if args |
| 202 | (let* ((string-size (size-of 'string)) |
| 203 | (string-writer (writer-function 'string)) |
| 204 | (string-destroy (destroy-function 'string)) |
| 205 | (params (allocate-memory |
| 206 | (* (length args) (+ string-size +gvalue-size+))))) |
| 207 | (loop |
| 208 | for (pname type value) in args |
| 209 | as tmp = params then (sap+ tmp (+ string-size +gvalue-size+)) |
| 210 | do (funcall string-writer pname tmp) |
| 211 | (gvalue-init (sap+ tmp string-size) type value)) |
| 212 | (unwind-protect |
| 213 | (setf |
| 214 | (slot-value object 'location) |
| 215 | (%gobject-newv (type-number-of object) (length args) params)) |
| 216 | (loop |
| 217 | repeat (length args) |
| 218 | as tmp = params then (sap+ tmp (+ string-size +gvalue-size+)) |
| 219 | do (funcall string-destroy tmp) |
| 220 | (gvalue-unset (sap+ tmp string-size))) |
| 221 | (deallocate-memory params))) |
| 222 | (setf |
| 223 | (slot-value object 'location) |
| 224 | (%gobject-new (type-number-of object)))))) |
| 225 | |
| 226 | (apply #'call-next-method object initargs)) |
| 227 | |
| 228 | |
| 229 | (defmethod instance-finalizer ((instance gobject)) |
| 230 | (let ((location (proxy-location instance))) |
| 231 | #'(lambda () |
| 232 | (remove-cached-instance location) |
| 233 | (%object-unref location)))) |
| 234 | |
| 235 | |
| 236 | (defbinding (%gobject-new "g_object_new") () pointer |
| 237 | (type type-number) |
| 238 | (nil null)) |
| 239 | |
| 240 | (defbinding (%gobject-newv "g_object_newv") () pointer |
| 241 | (type type-number) |
| 242 | (n-parameters unsigned-int) |
| 243 | (params pointer)) |
| 244 | |
| 245 | |
| 246 | |
| 247 | ;;;; Property stuff |
| 248 | |
| 249 | (defbinding %object-set-property () nil |
| 250 | (object gobject) |
| 251 | (name string) |
| 252 | (value gvalue)) |
| 253 | |
| 254 | (defbinding %object-get-property () nil |
| 255 | (object gobject) |
| 256 | (name string) |
| 257 | (value gvalue)) |
| 258 | |
| 259 | (defbinding %object-notify () nil |
| 260 | (object gobject) |
| 261 | (name string)) |
| 262 | |
| 263 | (defbinding object-freeze-notify () nil |
| 264 | (object gobject)) |
| 265 | |
| 266 | (defbinding object-thaw-notify () nil |
| 267 | (object gobject)) |
| 268 | |
| 269 | |
| 270 | ;;;; User data |
| 271 | |
| 272 | (defbinding %object-set-qdata-full () nil |
| 273 | (object gobject) |
| 274 | (id quark) |
| 275 | (data unsigned-long) |
| 276 | (destroy-marshal pointer)) |
| 277 | |
| 278 | (defcallback user-data-destroy-func (nil (id unsigned-int)) |
| 279 | (destroy-user-data id)) |
| 280 | |
| 281 | (export 'user-data-destroy-func) |
| 282 | |
| 283 | (defun (setf user-data) (data object key) |
| 284 | (%object-set-qdata-full object (quark-intern key) |
| 285 | (register-user-data data) (callback user-data-destroy-func)) |
| 286 | data) |
| 287 | |
| 288 | ;; deprecated |
| 289 | (defun (setf object-data) (data object key &key (test #'eq)) |
| 290 | (assert (eq test #'eq)) |
| 291 | (setf (user-data object key) data)) |
| 292 | |
| 293 | (defbinding %object-get-qdata () unsigned-long |
| 294 | (object gobject) |
| 295 | (id quark)) |
| 296 | |
| 297 | (defun user-data (object key) |
| 298 | (find-user-data (%object-get-qdata object (quark-intern key)))) |
| 299 | |
| 300 | ;; deprecated |
| 301 | (defun object-data (object key &key (test #'eq)) |
| 302 | (assert (eq test #'eq)) |
| 303 | (user-data object key)) |
| 304 | |
| 305 | (defun user-data-p (object key) |
| 306 | (user-data-exists-p (%object-get-qdata object (quark-intern key)))) |
| 307 | |
| 308 | (defbinding %object-steal-qdata () unsigned-long |
| 309 | (object gobject) |
| 310 | (id quark)) |
| 311 | |
| 312 | (defun unset-user-data (object key) |
| 313 | (destroy-user-data (%object-steal-qdata object (quark-intern key)))) |
| 314 | |
| 315 | |
| 316 | ;;;; |
| 317 | |
| 318 | (defbinding %object-class-list-properties () pointer |
| 319 | (class pointer) |
| 320 | (n-properties unsigned-int :out)) |
| 321 | |
| 322 | |
| 323 | (defun %map-params (params length type inherited-p) |
| 324 | (if inherited-p |
| 325 | (map-c-vector 'list #'identity params 'param length) |
| 326 | (let ((properties ())) |
| 327 | (map-c-vector 'list |
| 328 | #'(lambda (param) |
| 329 | (when (eql (param-owner-type param) type) |
| 330 | (push param properties))) |
| 331 | params 'param length) |
| 332 | (nreverse properties)))) |
| 333 | |
| 334 | (defun query-object-class-properties (type &optional inherited-p) |
| 335 | (let* ((type-number (find-type-number type t)) |
| 336 | (class (type-class-ref type-number))) |
| 337 | (unwind-protect |
| 338 | (multiple-value-bind (array length) |
| 339 | (%object-class-list-properties class) |
| 340 | (unless (null-pointer-p array) |
| 341 | (unwind-protect |
| 342 | (%map-params array length type-number inherited-p) |
| 343 | (deallocate-memory array)))) |
| 344 | ; (type-class-unref type-number) |
| 345 | ))) |
| 346 | |
| 347 | |
| 348 | (defun default-slot-name (name) |
| 349 | (intern (substitute #\- #\_ (string-upcase (string-upcase name))))) |
| 350 | |
| 351 | (defun default-slot-accessor (class-name slot-name type) |
| 352 | (intern |
| 353 | (format |
| 354 | nil "~A-~A~A" class-name slot-name |
| 355 | (if (eq type 'boolean) "-P" "")))) |
| 356 | |
| 357 | |
| 358 | (defun slot-definition-from-property (class property &optional slot-name args) |
| 359 | (with-slots (name flags value-type documentation) property |
| 360 | (let* ((slot-name (or slot-name (default-slot-name name))) |
| 361 | (slot-type (or (getf args :type) (type-from-number value-type) 'pointer)) |
| 362 | (accessor (default-slot-accessor class slot-name slot-type))) |
| 363 | |
| 364 | `(,slot-name |
| 365 | :allocation :property :pname ,name |
| 366 | |
| 367 | ,@(when (find :unbound args) (list :unbound (getf args :unbound))) |
| 368 | ,@(when (find :getter args) (list :getter (getf args :getter))) |
| 369 | ,@(when (find :setter args) (list :setter (getf args :setter))) |
| 370 | |
| 371 | ;; accessors |
| 372 | ,@(cond |
| 373 | ((and |
| 374 | (member :writable flags) (member :readable flags) |
| 375 | (not (member :construct-only flags))) |
| 376 | (list :accessor accessor)) |
| 377 | ((and (member :writable flags) (not (member :construct-only flags))) |
| 378 | (list :writer `(setf ,accessor))) |
| 379 | ((member :readable flags) |
| 380 | (list :reader accessor))) |
| 381 | |
| 382 | ;; readable/writable/construct |
| 383 | ,@(when (or (not (member :writable flags)) |
| 384 | (member :construct-only flags)) |
| 385 | '(:writable nil)) |
| 386 | ,@(when (not (member :readable flags)) |
| 387 | '(:readable nil)) |
| 388 | ,@(when (or (member :construct flags) |
| 389 | (member :construct-only flags)) |
| 390 | '(:construct t)) |
| 391 | |
| 392 | ;; initargs |
| 393 | ,@(if (find :initarg args) |
| 394 | (let ((initarg (getf args :initarg))) |
| 395 | (etypecase initarg |
| 396 | (null ()) |
| 397 | (symbol `(:initarg ,initarg)))) |
| 398 | (when (or (member :construct flags) |
| 399 | (member :construct-only flags) |
| 400 | (member :writable flags)) |
| 401 | (list :initarg (intern (string slot-name) "KEYWORD")))) |
| 402 | |
| 403 | :type ,slot-type |
| 404 | :documentation ,documentation)))) |
| 405 | |
| 406 | |
| 407 | (defun slot-definitions (class properties slots) |
| 408 | (loop |
| 409 | for property in properties |
| 410 | as slot = (or |
| 411 | (find (param-name property) slots |
| 412 | :key #'(lambda (slot) (getf (rest slot) :pname)) |
| 413 | :test #'string=) |
| 414 | (find (param-name property) slots |
| 415 | :key #'first :test #'string-equal)) |
| 416 | do (cond |
| 417 | ((not slot) |
| 418 | (push (slot-definition-from-property class property) slots)) |
| 419 | ((getf (rest slot) :merge) |
| 420 | (setf |
| 421 | (rest slot) |
| 422 | (rest (slot-definition-from-property class property (first slot) (rest slot))))))) |
| 423 | (delete-if #'(lambda (slot) (getf (rest slot) :ignore)) slots)) |
| 424 | |
| 425 | |
| 426 | (defun expand-gobject-type (type forward-p options &optional (metaclass 'gobject-class)) |
| 427 | (let ((supers (cons (supertype type) (implements type))) |
| 428 | (class (type-from-number type)) |
| 429 | (slots (getf options :slots))) |
| 430 | `(defclass ,class ,supers |
| 431 | ,(unless forward-p |
| 432 | (slot-definitions class (query-object-class-properties type) slots)) |
| 433 | (:metaclass ,metaclass) |
| 434 | (:gtype ,(register-type-as type))))) |
| 435 | |
| 436 | (defun gobject-dependencies (type) |
| 437 | (delete-duplicates |
| 438 | (cons |
| 439 | (supertype type) |
| 440 | (append |
| 441 | (type-interfaces type) |
| 442 | (mapcar #'param-value-type (query-object-class-properties type)))))) |
| 443 | |
| 444 | |
| 445 | (register-derivable-type 'gobject "GObject" 'expand-gobject-type 'gobject-dependencies) |
| 446 | |
| 447 | |
| 448 | ;;; Pseudo type for gobject instances which have their reference count |
| 449 | ;;; increased by the returning function |
| 450 | |
| 451 | (defmethod alien-type ((type (eql 'referenced)) &rest args) |
| 452 | (declare (ignore type args)) |
| 453 | (alien-type 'gobject)) |
| 454 | |
| 455 | (defmethod from-alien-form (form (type (eql 'referenced)) &rest args) |
| 456 | (declare (ignore type)) |
| 457 | (destructuring-bind (type) args |
| 458 | (if (subtypep type 'gobject) |
| 459 | (let ((instance (make-symbol "INSTANCE"))) |
| 460 | `(let ((,instance ,(from-alien-form form type))) |
| 461 | (when ,instance |
| 462 | (%object-unref (proxy-location ,instance))) |
| 463 | ,instance)) |
| 464 | (error "~A is not a subclass of GOBJECT" type)))) |
| 465 | |
| 466 | (export 'referenced) |