Custom types are now re-registered when a saved image is loaded

[clg] / gtk / gtkobject.lisp

;; Common Lisp bindings for GTK+ v2.x
;; Copyright 1999-2005 Espen S. Johnsen <espen@users.sf.net>
;;
;; Permission is hereby granted, free of charge, to any person obtaining
;; a copy of this software and associated documentation files (the
;; "Software"), to deal in the Software without restriction, including
;; without limitation the rights to use, copy, modify, merge, publish,
;; distribute, sublicense, and/or sell copies of the Software, and to
;; permit persons to whom the Software is furnished to do so, subject to
;; the following conditions:
;;
;; The above copyright notice and this permission notice shall be
;; included in all copies or substantial portions of the Software.
;;
;; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
;; EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
;; MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
;; IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
;; CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
;; TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
;; SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

;; $Id: gtkobject.lisp,v 1.33 2006/02/28 16:34:37 espen Exp $


(in-package "GTK")


;;;; Superclass for the gtk class hierarchy

(eval-when (:compile-toplevel :load-toplevel :execute)
  (init-types-in-library 
   #.(concatenate 'string (pkg-config:pkg-variable "gtk+-2.0" "libdir") 
		          "/libgtk-x11-2.0.so"))

  (defclass %object (gobject)
    ()
    (:metaclass gobject-class)
    (:gtype |gtk_object_get_type|)))


(defmethod initialize-instance ((object %object) &rest initargs &key signal)
  (declare (ignore signal))
  (call-next-method)
  (dolist (signal-definition (get-all initargs :signal))
    (apply #'signal-connect object signal-definition)))

(defmethod initialize-instance :around ((object %object) &rest initargs)
  (declare (ignore initargs))
  (call-next-method)
  ;; Add a temorary reference which will be removed when the object is
  ;; sinked
  (reference-foreign (class-of object) (foreign-location object))
  (%object-sink object))

(defbinding %object-sink () nil
  (object %object))

;;;; Main loop and event handling

(declaim (inline events-pending-p main-iteration))

(defbinding events-pending-p () boolean)

(defbinding get-current-event () gdk:event)

(defbinding main-do-event () nil
  (event gdk:event))

(defbinding main () nil)

(defbinding main-level () int)

(defbinding main-quit () nil)

(defbinding main-iteration-do (&optional (blocking t)) boolean
  (blocking boolean))

(defun main-iterate-all (&rest args)
  (declare (ignore args))
  (loop
   while (events-pending-p)
   do (main-iteration-do nil)))


;;;; Metaclass for child classes
 
(defvar *container-to-child-class-mappings* (make-hash-table))

(eval-when (:compile-toplevel :load-toplevel :execute)
  (defclass child-class (virtual-slots-class)
    ())

  (defclass direct-child-slot-definition (direct-virtual-slot-definition)
    ((pname :reader slot-definition-pname :initarg :pname)))

  (defclass effective-child-slot-definition (effective-virtual-slot-definition)
    ((pname :reader slot-definition-pname :initarg :pname)))


(defmethod shared-initialize ((class child-class) names &key container)
  (call-next-method)
  (setf
   (gethash (find-class (first container)) *container-to-child-class-mappings*)
    class))

(defmethod direct-slot-definition-class ((class child-class) &rest initargs)
  (case (getf initargs :allocation)
    (:property (find-class 'direct-child-slot-definition))
    (t (call-next-method))))

(defmethod effective-slot-definition-class ((class child-class) &rest initargs)
  (case (getf initargs :allocation)
    (:property (find-class 'effective-child-slot-definition))
    (t (call-next-method))))

(defmethod compute-effective-slot-definition-initargs ((class child-class) direct-slotds)
  (if (eq (slot-definition-allocation (first direct-slotds)) :property)
      (nconc 
       (list :pname (most-specific-slot-value direct-slotds 'pname))
       (call-next-method))
    (call-next-method)))


(defmethod initialize-internal-slot-functions ((slotd effective-child-slot-definition))
  (let ((type (slot-definition-type slotd))
	(pname (slot-definition-pname slotd)))
    (setf 
     (slot-value slotd 'getter)
     #'(lambda (object)
	 (with-slots (parent child) object	   
	   (let ((gvalue (gvalue-new type)))
	     (%container-child-get-property parent child pname gvalue)
	     (unwind-protect
		 (funcall (reader-function type) gvalue +gvalue-value-offset+)
	       (gvalue-free gvalue t))))))
    
    (setf 
     (slot-value slotd 'setter)
     #'(lambda (value object)
	 (with-slots (parent child) object	   
	   (let ((gvalue (gvalue-new type)))
	     (funcall (writer-function type) value gvalue +gvalue-value-offset+)
	     (%container-child-set-property parent child pname gvalue)
	     (gvalue-free gvalue t)
	     value)))))
 
  (call-next-method)))


(defmethod add-reader-method ((class child-class) generic-function slot-name)
  (add-method
   generic-function
   (make-instance 'standard-method
    :specializers (list (find-class 'widget))
    :lambda-list '(widget)
    :function #'(lambda (args next-methods)
		  (declare (ignore next-methods))
		  (child-property-value (first args) slot-name)))))

(defmethod add-writer-method
    ((class child-class) generic-function slot-name)
  (add-method
   generic-function
   (make-instance 'standard-method
    :specializers (list (find-class t) (find-class 'widget))
    :lambda-list '(value widget)
    :function #'(lambda (args next-methods)
		  (declare (ignore next-methods))
		  (destructuring-bind (value widget) args
		    (setf (child-property-value widget slot-name) value))))))


(defmethod validate-superclass ((class child-class) (super standard-class))
  ;(subtypep (class-name super) 'container-child)
  t)


(defclass container-child ()
  ((parent :initarg :parent :type container)
   (child :initarg :child :type widget)))


;;;;

(defbinding %container-class-list-child-properties () pointer
  (class pointer)
  (n-properties unsigned-int :out))

(defun query-container-class-child-properties (type-number)
  (let ((class (type-class-ref type-number)))
    (multiple-value-bind (array length)
	(%container-class-list-child-properties class)
      (unwind-protect
	  (map-c-vector 'list #'identity array 'param length)
	(deallocate-memory array)))))

(defun default-container-child-name (container-class)
  (intern (format nil "~A-CHILD" container-class)))

(defun expand-container-type (type forward-p options)
  (let* ((class (type-from-number type))
	 (super (supertype type))
	 (child-class (default-container-child-name class)))
    (if forward-p 
	(expand-gobject-type type t options)
      `(progn
	 ,(expand-gobject-type type nil options)
	 (defclass ,child-class (,(default-container-child-name super))
	   ,(slot-definitions child-class 
	     (query-container-class-child-properties type) nil)
	   (:metaclass child-class)
	   (:container ,class))))))


(register-derivable-type 'container "GtkContainer" 'expand-container-type 'gobject-dependencies)