numbered-alias-sheet

   1 #!/usr/bin/perl -w
   2 use strict;
   3 our $us = $0; $us =~ s#.*/##;
   4
   5 use POSIX;
   6 use Data::Dumper;
   7
   8 our $papersize =  'creditcard';
   9 our $fontname = 'Courier';
  10 our $fontname_num = 'Courier';
  11 our $gapratio = 1;
  12 our $blankratio = 1;
  13 our @borders = (4,4);
  14
  15 our @lp_options = ( [ 'blank-below', 'blank-to-right', ],
  16                     [ 'landscape', 'portrait' ],
  17                     [ 'single-column', 'multi-column', ] );
  18 our @lp_fixed;
  19
  20 our $usage = <<END;
  21 usage: $us [<options>] <foo-mail-pregen> <foo-mail-pregen-opts>...
  22 options:
  23   -p<papersize>           for libpaper, or "creditcard"  default is $papersize
  24   -F[<numberfont>,]<font> font name                      default is $fontname
  25   -b<border>|-b<bx>x<by>  all in mm
  26   -g<gapratio>            number-to-addr gap adjustment
  27   -b<blankratio>          (blank space size) / (text size)
  28   -D                      debug
  29 END
  30
  31 open DEBUG, ">/dev/null" or die $!;
  32
  33 our @paperpts;
  34
  35 sub badusage () { die "bad usage\n\n$usage"; }
  36
  37 sub mm2pt { map { $_ * 72.0 / 25.4 } @_; }
  38
  39 sub max {
  40     my $r = undef;
  41     foreach (@_) {
  42         $r = $_ if !defined $r or $_ > $r;
  43     }
  44     return $r;
  45 }
  46
  47 sub min {
  48     my $r = undef;
  49     foreach (@_) {
  50         $r = $_ if !defined $r or $_ < $r;
  51     }
  52     return $r;
  53 }
  54
  55 my $fontname_re = '[^()\\,]+';
  56 my $dbl_re = '(?:[0-9]+\.?|[0-9]*\.[0-9]+)';
  57
  58 for (;;) {
  59     badusage unless @ARGV;
  60     last unless $ARGV[0] =~ m/^-/;
  61     $_ = shift @ARGV;
  62     last if m/^--?$/;
  63     while (m/^-./) {
  64         if (s/^-p(\w+)$//) {
  65             $papersize = $1;
  66             @paperpts = ();
  67         } elsif (s/^-p($dbl_re)x($dbl_re)$//o) {
  68             $papersize = undef;
  69             @paperpts = mm2pt($1,$2);
  70         } elsif (s/^-F($fontname_re)$//o) {
  71             $fontname = $fontname_num = $1;
  72         } elsif (s/^-F($fontname_re),($fontname_re)$//o) {
  73             ($fontname_num, $fontname) = ($1, $2);
  74         } elsif (s/^-b($dbl_re)$//o) {
  75             @borders = ($1,$1);
  76         } elsif (s/^-b($dbl_re)x($dbl_re)$//o) {
  77             @borders = ($1,$1);
  78         } elsif (s/^-D/-/) {
  79             open DEBUG, ">&STDERR" or die $!;
  80         } else {
  81             badusage;
  82         }
  83     }
  84 }
  85
  86 if (!@paperpts) {
  87     if ($papersize eq 'creditcard') {
  88         # ISO/IEC 7810 ID-1, from en.wikipedia.org/wiki/Payment_card
  89         @paperpts = mm2pt qw(85.60 53.98);
  90     } else {
  91         $!=0; $?=0; my $r = `paperconf -sp $1`;
  92         defined $r or die "paperconf failed: $? $!\n";
  93         $r =~ m/^([0-9.]+) ([0-9.]+)$/ or die "$_ ?";
  94         @paperpts = ($1,$2);
  95     }
  96 }
  97
  98 @borders = mm2pt @borders;
  99
 100 @ARGV >= 2 or badusage;
 101
 102 our @strings;
 103
 104 sub readstrings () {
 105     my $nlen = 0;
 106
 107     open P, "-|", @ARGV or die $!;
 108     while (<P>) {
 109         chomp or die;
 110         m/^(\d+) (\S+)$/ or die "$_ ?";
 111         $nlen = length($1) if length($1) > $nlen;
 112         push @strings, [ $1, $2 ];
 113     }
 114     $!=0; $?=0; close P or die "$us: generator failed: $! $?\n";
 115 }
 116
 117 our @lp_values;
 118 our @numbers_bbox;
 119 our @texts_bbox;
 120 our $gap_width;
 121 our @core_size;
 122 our @item_size;
 123 our $rotate_paper;
 124 our @eff_paper_size;
 125 our @laycount;
 126
 127 sub wontfit ($) {
 128     print DEBUG " NO @_\n";
 129     return 0;
 130 }
 131
 132 sub psstring ($) {
 133     local ($_) = @_;
 134     s/[()\\]/\\$&/g;
 135     return "($_)";
 136 }
 137
 138 sub metrics ($$@) {
 139     my ($sz, $fn, @s) = @_;
 140     die unless @s;
 141     print DEBUG " metrics $fn $sz";
 142     my $pchild = open GI, "-|"; defined $pchild or die $!;
 143     if (!$pchild) {
 144         print psstring($fn)," findfont $sz scalefont setfont\n" or die $!;
 145         print "0 0 moveto ", psstring($_), " show showpage\n" or die $!
 146             foreach @s;
 147         close STDOUT or die $!;
 148         exit 0;
 149     }
 150     my $gchild = open GO, "-|"; defined $gchild or die $!;
 151     if (!$gchild) {
 152         open STDIN, "<&GI" or die $!;
 153         open STDERR, ">&STDOUT" or die $!;
 154         exec qw(gs -dSAFER -dNOPAUSE -q -dBATCH -sDEVICE=bbox -)
 155             or die "$us: exec gs: $!\n";
 156     }
 157     my @bb;
 158     my $count = 0;
 159     while (<GO>) {
 160         my @tbb;
 161         if (@tbb =
 162             m/^\%\%HiResBoundingBox: ($dbl_re) ($dbl_re) ($dbl_re) ($dbl_re)$/
 163             ) {
 164             $count++;
 165             $bb[0] = min $bb[0], $tbb[0];
 166             $bb[1] = min $bb[1], $tbb[1];
 167             $bb[2] = max $bb[2], $tbb[2];
 168             $bb[3] = max $bb[3], $tbb[3];
 169         } elsif (m/^\%\%/) {
 170         } else {
 171             print STDERR "$us: warning: gs: $_" or die;
 172         }
 173     }
 174     $!=0; $?=0; close GO or die "gs $! $?";
 175     $!=0; $?=0; close GI or die "gs paste $! $?";
 176     die "$count ".scalar(@s) unless $count==@s;
 177     print DEBUG " @bb\n";
 178     return @bb;
 179 }
 180
 181 sub do_layout_recursive_search ($);
 182 sub do_layout_recursive_search ($) {
 183     my ($lpi) = @_;
 184
 185     if ($lpi < @lp_options) {
 186         foreach my $v ($lp_fixed[$lpi] or @{ $lp_options[$lpi] }) {
 187             $lp_values[$lpi] = $v;
 188             return 1 if do_layout_recursive_search $lpi+1;
 189         }
 190         return 0;
 191     }
 192
 193     print DEBUG " try", (map { sprintf " %-10.10s", $_ } @lp_values), ":";
 194
 195     my %lp_y;
 196     $lp_y{$_} = 1 foreach @lp_values;
 197
 198     $rotate_paper =
 199         ($paperpts[0] > $paperpts[1] # paper looks like landscape
 200          xor $lp_y{'landscape'});
 201     @eff_paper_size = !$rotate_paper ? @paperpts : reverse @paperpts;
 202
 203     @item_size = @core_size;
 204     my $blank_coord = !!$lp_y{'blank-below'};
 205     $item_size[$blank_coord] *= (1.0 + $blankratio);
 206
 207     foreach my $coord (qw(0 1)) {
 208         my $avail = $eff_paper_size[$coord] - $borders[$coord] * 2;
 209         my $each = $item_size[$coord];
 210         if (!$coord) {
 211             $each += $gap_width;
 212             $avail += $gap_width;
 213         }
 214         $laycount[$coord] = floor($avail / $each);
 215         $laycount[$coord] >= 1 or return wontfit "cannot fit even one $coord";
 216     }
 217
 218     if ($lp_y{'single-column'}) {
 219         $laycount[0] = 1;
 220     } else {
 221         $laycount[0] >= 2
 222             or return wontfit "requested multi-column but only one";
 223     }
 224
 225     $laycount[0] * $laycount[1] >= @strings
 226         or return wontfit "layout fits too few @laycount";
 227
 228     print DEBUG " OK @laycount\n";
 229     return 1;
 230 }
 231
 232 sub do_layout ($) {
 233     my ($fontsize) = @_;
 234
 235     print DEBUG "layout $fontsize\n";
 236
 237     @numbers_bbox = metrics $fontsize, $fontname_num, map { $_->[0] } @strings;
 238
 239     my @nom_gap_bbox = metrics $fontsize, $fontname_num, 'x';
 240     $gap_width = $gapratio * ($nom_gap_bbox[2] - $nom_gap_bbox[0]);
 241
 242     @texts_bbox = metrics $fontsize, $fontname, map { $_->[1] } @strings;
 243
 244     $core_size[0] =
 245         ($numbers_bbox[2] - $numbers_bbox[0]) +
 246         $gap_width +
 247         ($texts_bbox[2] - $texts_bbox[0]);
 248
 249     $core_size[1] = max
 250         $numbers_bbox[3] - $numbers_bbox[1],
 251         $texts_bbox[3] - $texts_bbox[1];
 252
 253     return do_layout_recursive_search 0;
 254 }
 255
 256 our $usesz;
 257
 258 sub determine_size_layout () {
 259     my $minsz;
 260     my $maxsz;
 261
 262     for (;;) {
 263         my $trysz =
 264             !defined $minsz ? 1 :
 265             !defined $maxsz ? $minsz * 4 :
 266             sqrt($minsz * $maxsz);
 267
 268         my $ok = do_layout $trysz;
 269
 270         if ($ok) { $minsz = $trysz; } else { $maxsz = $trysz; }
 271
 272         defined $minsz or die "cannot fit at even at ${trysz}pt\n";
 273
 274         if (defined $maxsz && ($maxsz / $minsz) < 1.01) {
 275             $usesz = $minsz;
 276             last;
 277         }
 278     }
 279
 280     do_layout $usesz or die;
 281
 282     print DEBUG Dumper($usesz, \@lp_values, \@numbers_bbox,
 283                        \@texts_bbox, $gap_width, \@core_size,
 284                        \@item_size, $rotate_paper, \@eff_paper_size,
 285                        \@laycount);
 286 }
 287
 288 readstrings();
 289 determine_size_layout();