--- /dev/null
+/*\r
+ * ISO-standard metric threads, following this specification:\r
+ * http://en.wikipedia.org/wiki/ISO_metric_screw_thread\r
+ *\r
+ * Copyright 2020 Dan Kirshner - dan_kirshner@yahoo.com\r
+ * This program is free software: you can redistribute it and/or modify\r
+ * it under the terms of the GNU General Public License as published by\r
+ * the Free Software Foundation, either version 3 of the License, or\r
+ * (at your option) any later version.\r
+ *\r
+ * This program is distributed in the hope that it will be useful,\r
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of\r
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the\r
+ * GNU General Public License for more details.\r
+ *\r
+ * See <http://www.gnu.org/licenses/>.\r
+ *\r
+ * Version 2.4. 2019-07-14 Add test option - do not render threads.\r
+ * Version 2.3. 2017-08-31 Default for leadin: 0 (best for internal threads).\r
+ * Version 2.2. 2017-01-01 Correction for angle; leadfac option. (Thanks to\r
+ * Andrew Allen <a2intl@gmail.com>.)\r
+ * Version 2.1. 2016-12-04 Chamfer bottom end (low-z); leadin option.\r
+ * Version 2.0. 2016-11-05 Backwards compatibility (earlier OpenSCAD) fixes.\r
+ * Version 1.9. 2016-07-03 Option: tapered.\r
+ * Version 1.8. 2016-01-08 Option: (non-standard) angle.\r
+ * Version 1.7. 2015-11-28 Larger x-increment - for small-diameters.\r
+ * Version 1.6. 2015-09-01 Options: square threads, rectangular threads.\r
+ * Version 1.5. 2015-06-12 Options: thread_size, groove.\r
+ * Version 1.4. 2014-10-17 Use "faces" instead of "triangles" for polyhedron\r
+ * Version 1.3. 2013-12-01 Correct loop over turns -- don't have early cut-off\r
+ * Version 1.2. 2012-09-09 Use discrete polyhedra rather than linear_extrude ()\r
+ * Version 1.1. 2012-09-07 Corrected to right-hand threads!\r
+ */\r
+\r
+// Examples.\r
+//\r
+// Standard M8 x 1.\r
+// metric_thread (diameter=8, pitch=1, length=4);\r
+\r
+// Square thread.\r
+// metric_thread (diameter=8, pitch=1, length=4, square=true);\r
+\r
+// Non-standard: long pitch, same thread size.\r
+//metric_thread (diameter=8, pitch=4, length=4, thread_size=1, groove=true);\r
+\r
+// Non-standard: 20 mm diameter, long pitch, square "trough" width 3 mm,\r
+// depth 1 mm.\r
+//metric_thread (diameter=20, pitch=8, length=16, square=true, thread_size=6,\r
+// groove=true, rectangle=0.333);\r
+\r
+// English: 1/4 x 20.\r
+//english_thread (diameter=1/4, threads_per_inch=20, length=1);\r
+\r
+// Tapered. Example -- pipe size 3/4" -- per:\r
+// http://www.engineeringtoolbox.com/npt-national-pipe-taper-threads-d_750.html\r
+// english_thread (diameter=1.05, threads_per_inch=14, length=3/4, taper=1/16);\r
+\r
+// Thread for mounting on Rohloff hub.\r
+//difference () {\r
+// cylinder (r=20, h=10, $fn=100);\r
+//\r
+// metric_thread (diameter=34, pitch=1, length=10, internal=true, n_starts=6);\r
+//}\r
+\r
+\r
+// ----------------------------------------------------------------------------\r
+function segments (diameter) = min (50, max (ceil (diameter*6), 25));\r
+\r
+\r
+// ----------------------------------------------------------------------------\r
+// diameter - outside diameter of threads in mm. Default: 8.\r
+// pitch - thread axial "travel" per turn in mm. Default: 1.\r
+// length - overall axial length of thread in mm. Default: 1.\r
+// internal - true = clearances for internal thread (e.g., a nut).\r
+// false = clearances for external thread (e.g., a bolt).\r
+// (Internal threads should be "cut out" from a solid using\r
+// difference ()). Default: false.\r
+// n_starts - Number of thread starts (e.g., DNA, a "double helix," has\r
+// n_starts=2). See wikipedia Screw_thread. Default: 1.\r
+// thread_size - (non-standard) axial width of a single thread "V" - independent\r
+// of pitch. Default: same as pitch.\r
+// groove - (non-standard) true = subtract inverted "V" from cylinder\r
+// (rather thanadd protruding "V" to cylinder). Default: false.\r
+// square - true = square threads (per\r
+// https://en.wikipedia.org/wiki/Square_thread_form). Default:\r
+// false.\r
+// rectangle - (non-standard) "Rectangular" thread - ratio depth/(axial) width\r
+// Default: 0 (standard "v" thread).\r
+// angle - (non-standard) angle (deg) of thread side from perpendicular to\r
+// axis (default = standard = 30 degrees).\r
+// taper - diameter change per length (National Pipe Thread/ANSI B1.20.1\r
+// is 1" diameter per 16" length). Taper decreases from 'diameter'\r
+// as z increases. Default: 0 (no taper).\r
+// leadin - 0 (default): no chamfer; 1: chamfer (45 degree) at max-z end;\r
+// 2: chamfer at both ends, 3: chamfer at z=0 end.\r
+// leadfac - scale of leadin chamfer (default: 1.0 = 1/2 thread).\r
+// test - true = do not render threads (just draw "blank" cylinder).\r
+// Default: false (draw threads).\r
+module metric_thread (diameter=8, pitch=1, length=1, internal=false, n_starts=1,\r
+ thread_size=-1, groove=false, square=false, rectangle=0,\r
+ angle=30, taper=0, leadin=0, leadfac=1.0, test=false)\r
+{\r
+ // thread_size: size of thread "V" different than travel per turn (pitch).\r
+ // Default: same as pitch.\r
+ local_thread_size = thread_size == -1 ? pitch : thread_size;\r
+ local_rectangle = rectangle ? rectangle : 1;\r
+\r
+ n_segments = segments (diameter);\r
+ h = (test && ! internal) ? 0 : (square || rectangle) ? local_thread_size*local_rectangle/2 : local_thread_size / (2 * tan(angle));\r
+\r
+ h_fac1 = (square || rectangle) ? 0.90 : 0.625;\r
+\r
+ // External thread includes additional relief.\r
+ h_fac2 = (square || rectangle) ? 0.95 : 5.3/8;\r
+\r
+ tapered_diameter = diameter - length*taper;\r
+\r
+ difference () {\r
+ union () {\r
+ if (! groove) {\r
+ if (! test) {\r
+ metric_thread_turns (diameter, pitch, length, internal, n_starts,\r
+ local_thread_size, groove, square, rectangle, angle,\r
+ taper);\r
+ }\r
+ }\r
+\r
+ difference () {\r
+\r
+ // Solid center, including Dmin truncation.\r
+ if (groove) {\r
+ cylinder (r1=diameter/2, r2=tapered_diameter/2,\r
+ h=length, $fn=n_segments);\r
+ } else if (internal) {\r
+ cylinder (r1=diameter/2 - h*h_fac1, r2=tapered_diameter/2 - h*h_fac1,\r
+ h=length, $fn=n_segments);\r
+ } else {\r
+\r
+ // External thread.\r
+ cylinder (r1=diameter/2 - h*h_fac2, r2=tapered_diameter/2 - h*h_fac2,\r
+ h=length, $fn=n_segments);\r
+ }\r
+\r
+ if (groove) {\r
+ if (! test) {\r
+ metric_thread_turns (diameter, pitch, length, internal, n_starts,\r
+ local_thread_size, groove, square, rectangle,\r
+ angle, taper);\r
+ }\r
+ }\r
+ }\r
+ }\r
+\r
+ // chamfer z=0 end if leadin is 2 or 3\r
+ if (leadin == 2 || leadin == 3) {\r
+ difference () {\r
+ cylinder (r=diameter/2 + 1, h=h*h_fac1*leadfac, $fn=n_segments);\r
+\r
+ cylinder (r2=diameter/2, r1=diameter/2 - h*h_fac1*leadfac, h=h*h_fac1*leadfac,\r
+ $fn=n_segments);\r
+ }\r
+ }\r
+\r
+ // chamfer z-max end if leadin is 1 or 2.\r
+ if (leadin == 1 || leadin == 2) {\r
+ translate ([0, 0, length + 0.05 - h*h_fac1*leadfac]) {\r
+ difference () {\r
+ cylinder (r=diameter/2 + 1, h=h*h_fac1*leadfac, $fn=n_segments);\r
+ cylinder (r1=tapered_diameter/2, r2=tapered_diameter/2 - h*h_fac1*leadfac, h=h*h_fac1*leadfac,\r
+ $fn=n_segments);\r
+ }\r
+ }\r
+ }\r
+ }\r
+}\r
+\r
+\r
+// ----------------------------------------------------------------------------\r
+// Input units in inches.\r
+// Note: units of measure in drawing are mm!\r
+module english_thread (diameter=0.25, threads_per_inch=20, length=1,\r
+ internal=false, n_starts=1, thread_size=-1, groove=false,\r
+ square=false, rectangle=0, angle=30, taper=0, leadin=0,\r
+ leadfac=1.0, test=false)\r
+{\r
+ // Convert to mm.\r
+ mm_diameter = diameter*25.4;\r
+ mm_pitch = (1.0/threads_per_inch)*25.4;\r
+ mm_length = length*25.4;\r
+\r
+ echo (str ("mm_diameter: ", mm_diameter));\r
+ echo (str ("mm_pitch: ", mm_pitch));\r
+ echo (str ("mm_length: ", mm_length));\r
+ metric_thread (mm_diameter, mm_pitch, mm_length, internal, n_starts,\r
+ thread_size, groove, square, rectangle, angle, taper, leadin,\r
+ leadfac, test);\r
+}\r
+\r
+// ----------------------------------------------------------------------------\r
+module metric_thread_turns (diameter, pitch, length, internal, n_starts,\r
+ thread_size, groove, square, rectangle, angle,\r
+ taper)\r
+{\r
+ // Number of turns needed.\r
+ n_turns = floor (length/pitch);\r
+\r
+ intersection () {\r
+\r
+ // Start one below z = 0. Gives an extra turn at each end.\r
+ for (i=[-1*n_starts : n_turns+1]) {\r
+ translate ([0, 0, i*pitch]) {\r
+ metric_thread_turn (diameter, pitch, internal, n_starts,\r
+ thread_size, groove, square, rectangle, angle,\r
+ taper, i*pitch);\r
+ }\r
+ }\r
+\r
+ // Cut to length.\r
+ translate ([0, 0, length/2]) {\r
+ cube ([diameter*3, diameter*3, length], center=true);\r
+ }\r
+ }\r
+}\r
+\r
+\r
+// ----------------------------------------------------------------------------\r
+module metric_thread_turn (diameter, pitch, internal, n_starts, thread_size,\r
+ groove, square, rectangle, angle, taper, z)\r
+{\r
+ n_segments = segments (diameter);\r
+ fraction_circle = 1.0/n_segments;\r
+ for (i=[0 : n_segments-1]) {\r
+ rotate ([0, 0, i*360*fraction_circle]) {\r
+ translate ([0, 0, i*n_starts*pitch*fraction_circle]) {\r
+ //current_diameter = diameter - taper*(z + i*n_starts*pitch*fraction_circle);\r
+ thread_polyhedron ((diameter - taper*(z + i*n_starts*pitch*fraction_circle))/2,\r
+ pitch, internal, n_starts, thread_size, groove,\r
+ square, rectangle, angle);\r
+ }\r
+ }\r
+ }\r
+}\r
+\r
+\r
+// ----------------------------------------------------------------------------\r
+module thread_polyhedron (radius, pitch, internal, n_starts, thread_size,\r
+ groove, square, rectangle, angle)\r
+{\r
+ n_segments = segments (radius*2);\r
+ fraction_circle = 1.0/n_segments;\r
+\r
+ local_rectangle = rectangle ? rectangle : 1;\r
+\r
+ h = (square || rectangle) ? thread_size*local_rectangle/2 : thread_size / (2 * tan(angle));\r
+ outer_r = radius + (internal ? h/20 : 0); // Adds internal relief.\r
+ //echo (str ("outer_r: ", outer_r));\r
+\r
+ // A little extra on square thread -- make sure overlaps cylinder.\r
+ h_fac1 = (square || rectangle) ? 1.1 : 0.875;\r
+ inner_r = radius - h*h_fac1; // Does NOT do Dmin_truncation - do later with\r
+ // cylinder.\r
+\r
+ translate_y = groove ? outer_r + inner_r : 0;\r
+ reflect_x = groove ? 1 : 0;\r
+\r
+ // Make these just slightly bigger (keep in proportion) so polyhedra will\r
+ // overlap.\r
+ x_incr_outer = (! groove ? outer_r : inner_r) * fraction_circle * 2 * PI * 1.02;\r
+ x_incr_inner = (! groove ? inner_r : outer_r) * fraction_circle * 2 * PI * 1.02;\r
+ z_incr = n_starts * pitch * fraction_circle * 1.005;\r
+\r
+ /*\r
+ (angles x0 and x3 inner are actually 60 deg)\r
+\r
+ /\ (x2_inner, z2_inner) [2]\r
+ / \\r
+ (x3_inner, z3_inner) / \\r
+ [3] \ \\r
+ |\ \ (x2_outer, z2_outer) [6]\r
+ | \ /\r
+ | \ /|\r
+ z |[7]\/ / (x1_outer, z1_outer) [5]\r
+ | | | /\r
+ | x | |/\r
+ | / | / (x0_outer, z0_outer) [4]\r
+ | / | / (behind: (x1_inner, z1_inner) [1]\r
+ |/ | /\r
+ y________| |/\r
+ (r) / (x0_inner, z0_inner) [0]\r
+\r
+ */\r
+\r
+ x1_outer = outer_r * fraction_circle * 2 * PI;\r
+\r
+ z0_outer = (outer_r - inner_r) * tan(angle);\r
+ //echo (str ("z0_outer: ", z0_outer));\r
+\r
+ //polygon ([[inner_r, 0], [outer_r, z0_outer],\r
+ // [outer_r, 0.5*pitch], [inner_r, 0.5*pitch]]);\r
+ z1_outer = z0_outer + z_incr;\r
+\r
+ // Give internal square threads some clearance in the z direction, too.\r
+ bottom = internal ? 0.235 : 0.25;\r
+ top = internal ? 0.765 : 0.75;\r
+\r
+ translate ([0, translate_y, 0]) {\r
+ mirror ([reflect_x, 0, 0]) {\r
+\r
+ if (square || rectangle) {\r
+\r
+ // Rule for face ordering: look at polyhedron from outside: points must\r
+ // be in clockwise order.\r
+ polyhedron (\r
+ points = [\r
+ [-x_incr_inner/2, -inner_r, bottom*thread_size], // [0]\r
+ [x_incr_inner/2, -inner_r, bottom*thread_size + z_incr], // [1]\r
+ [x_incr_inner/2, -inner_r, top*thread_size + z_incr], // [2]\r
+ [-x_incr_inner/2, -inner_r, top*thread_size], // [3]\r
+\r
+ [-x_incr_outer/2, -outer_r, bottom*thread_size], // [4]\r
+ [x_incr_outer/2, -outer_r, bottom*thread_size + z_incr], // [5]\r
+ [x_incr_outer/2, -outer_r, top*thread_size + z_incr], // [6]\r
+ [-x_incr_outer/2, -outer_r, top*thread_size] // [7]\r
+ ],\r
+\r
+ faces = [\r
+ [0, 3, 7, 4], // This-side trapezoid\r
+\r
+ [1, 5, 6, 2], // Back-side trapezoid\r
+\r
+ [0, 1, 2, 3], // Inner rectangle\r
+\r
+ [4, 7, 6, 5], // Outer rectangle\r
+\r
+ // These are not planar, so do with separate triangles.\r
+ [7, 2, 6], // Upper rectangle, bottom\r
+ [7, 3, 2], // Upper rectangle, top\r
+\r
+ [0, 5, 1], // Lower rectangle, bottom\r
+ [0, 4, 5] // Lower rectangle, top\r
+ ]\r
+ );\r
+ } else {\r
+\r
+ // Rule for face ordering: look at polyhedron from outside: points must\r
+ // be in clockwise order.\r
+ polyhedron (\r
+ points = [\r
+ [-x_incr_inner/2, -inner_r, 0], // [0]\r
+ [x_incr_inner/2, -inner_r, z_incr], // [1]\r
+ [x_incr_inner/2, -inner_r, thread_size + z_incr], // [2]\r
+ [-x_incr_inner/2, -inner_r, thread_size], // [3]\r
+\r
+ [-x_incr_outer/2, -outer_r, z0_outer], // [4]\r
+ [x_incr_outer/2, -outer_r, z0_outer + z_incr], // [5]\r
+ [x_incr_outer/2, -outer_r, thread_size - z0_outer + z_incr], // [6]\r
+ [-x_incr_outer/2, -outer_r, thread_size - z0_outer] // [7]\r
+ ],\r
+\r
+ faces = [\r
+ [0, 3, 7, 4], // This-side trapezoid\r
+\r
+ [1, 5, 6, 2], // Back-side trapezoid\r
+\r
+ [0, 1, 2, 3], // Inner rectangle\r
+\r
+ [4, 7, 6, 5], // Outer rectangle\r
+\r
+ // These are not planar, so do with separate triangles.\r
+ [7, 2, 6], // Upper rectangle, bottom\r
+ [7, 3, 2], // Upper rectangle, top\r
+\r
+ [0, 5, 1], // Lower rectangle, bottom\r
+ [0, 4, 5] // Lower rectangle, top\r
+ ]\r
+ );\r
+ }\r
+ }\r
+ }\r
+}\r
+\r
+\r