include <cliphook.scad>

rad=19;
h=3.5;
w=2.0;
teethw=1.5;

looprad=2.5;
loopw=w;

fdia=1.77;
//fdia=3;

d=0.01;

module FilamentClipTeeth(teethw=teethw,
			 stembendd=0.5,	stembendl=7, teethxl=1.5) {
  gapw = fdia-stembendd*2;
  teethbigw = gapw + teethw*2;
  basew = fdia+teethw*2-stembendd*2;
  based = basew/3;

  translate([-based, -basew/2, 0]) cube([based, basew, h]);
  difference() {
    union() {
      translate([-d, -teethbigw/2, 0])
	cube([d+stembendl + teethw, teethbigw, h]);
//  translate([
//  stembigw = fdia + stembend
//  translate([-d, -stemw, 
      linear_extrude(height=h) {
	translate([stembendl-fdia/2, 0]) circle(fdia/2+teethw, $fn=30);
      }
    }
    translate([0,0,-1]) {
      translate([0,-gapw/2])
	cube([stembendl+teethxl+1, gapw, h+2]);
      linear_extrude(height=h+2) {
	translate([stembendl-fdia/2, 0]) circle(fdia/2, $fn=30);
      }
    }
  }

  for (mirr=[0:1]) {
    mirror([0,mirr,0]) {
      translate([stembendl + teethw, gapw/2, 0])
	rotate([0,0,30])
	cube([teethxl, teethw, h]);
    }
  }
}

module our_ClipHook(ye){
  ClipHook(h=h, w=w, g=0.6, k=1.5, g=0.6, ye=ye, cupcaph=0.5, cupcapg=0.8);
}

module FilamentClip() {
  rotate([0,0,-62.5]) {
    translate([0,rad-1.5,0]) {
      rotate([0,0,8])
	our_ClipHook(ye=-1.3);
    }
  }

  rotate([0,0,-30]) {
    translate([0,rad,0]) {
      rotate([0,0,180])
	our_ClipHook(ye=0.8);
    }
  }

  linear_extrude(height=h) {
    assign($fn=80) {
      FlatArc(0,0, rad-w/2,rad+w/2, 80,365);
    }
    assign($fn=30) {
      FlatArc(0,rad+looprad+w, looprad,looprad+loopw);
    }
  }

  for (mir=[0,1]) {
    mirror([mir,0,0])
      rotate([0,0,-20])
      translate([rad+w/2+teethw/2+fdia/2, 0, 0])
      rotate([0,0,100])
      FilamentClipTeeth();
  }
}

FilamentClip();