// -*- C -*-

toothheight = 1.2;
webthick = 1.8;
height = 7;
pinlengthfact = 1.2;
nomrad = height/2 - toothheight;
minrad = nomrad - 0.75;
maxrad = nomrad + 0.25;
jawthick = 1.5;

webgap = 0.4;
basepinclear = 1.0;

toothgap = webthick + webgap*2;
basethick = toothheight;

module DoveClipPin(h=height) {
  pinh = h * pinlengthfact;
  pinheight = nomrad*2 + jawthick*2;
  translate([0,0, pinheight/2]) intersection(){
    union(){
      for (m=[0,1]) {
	mirror([0,0,m]) translate([0,0,pinheight/2]) rotate([90,0,0])
	  cylinder($fn=20, r1=minrad, r2=maxrad, h=pinh);
      }
      translate([-webthick/2, -pinh, -pinheight/2-1])
	cube([webthick, pinh, pinheight+2]);
    }
    translate([-maxrad-1, -pinh-1, -pinheight/2])
      cube([maxrad*2+2, pinh+2, pinheight]);
  }
}

function DoveClip_depth() =
  basethick + nomrad*2 + toothheight;

module DoveClipEnd(baseextend=1, h=7) {
  cubex = nomrad*2 + jawthick*2;
  cube0y = -basethick-nomrad*2-toothheight;
  centrey = -basethick-nomrad;
  difference(){
    translate([-cubex/2, cube0y, 0])
      cube([cubex, -cube0y+baseextend, h]);
    translate([0, centrey, -1])
      cylinder($fn=20, r=nomrad, h=h+2);
    translate([-toothgap/2, cube0y-1, -1])
      cube([toothgap, toothheight+nomrad+1, h+2]);
  }
}

module DoveClipPair(baseextend=1, h=7) {
  delta =  nomrad*2 + jawthick*2 + toothgap;
  for (x=[-delta/2,delta/2])
    translate([x,0,0])
      DoveClipEnd(baseextend=baseextend, h=h);
}

module DoveClipPairBase(baseextend=0.1, h=7, count=2) {
  delta = nomrad*2 + jawthick;
  intrude = nomrad + basethick - basepinclear;
  for (i=[0:count-1]) {
    translate([(i - (count-1)/2) * delta, 0, 0])
      DoveClipEnd(baseextend=baseextend, h=h);
  }
  translate([-delta * count/2, -intrude, 0])
    cube([delta * count, intrude+0.1, h]);
}

module DoveClipPairSane(baseextend=0, h=7, count=2) {
  rotate([0,0,90])
    translate([0, DoveClip_depth(), 0])
    DoveClipPairBase(baseextend=baseextend, h=h, count=count);
}

function DoveClipPairSane_width(count=2) =
  2 * (nomrad + jawthick + ((nomrad*2 + jawthick) * (count-1)/2));

module DoveClipExtender(length, ha=7, hb=7, counta=2, countb=2,
			pillarw=3, pillarh=6, webthick=1) {
  mirror([1,0,0])
    DoveClipPairSane(h=ha, count=counta);
  translate([length,0,0])
    DoveClipPairSane(h=hb, count=countb);
  pillarlen = length - DoveClip_depth() * 2 + 2;
  pilesw =
    min(DoveClipPairSane_width(counta), DoveClipPairSane_width(countb)) - 0.5;
  pilesh = min(ha, hb) - 0.5;
  d = 0.25;
  echo(pilesh);
  translate([DoveClip_depth() - 1, 0, 0]) {
    for (mir=[0,1]) mirror([0,mir,0]) translate([0,-pilesw/2,0]) {
      mirror([1,0,0]) rotate([0,-90,0]) linear_extrude(height=pillarlen){
	polygon([[0,0], [pillarh,0], [0,pillarw]]);
	polygon([[pilesh,0], [pilesh-pillarh,0], [pilesh,pillarw]]);
	polygon([[0,d], [0,webthick], [pilesh-d,webthick], [pilesh-d,0]]);
      }
    }
  }
}

//DoveClipExtender(length=100, ha=16, hb=12, counta=3, countb=4);